The Tor Browser / annotate

media/libjpeg/simd/jcqnts2f.asm@b8a032363ba2 (annotated)

media/libjpeg/simd/jcqnts2f.asm

Thu, 22 Jan 2015 13:21:57 +0100

author
Michael Schloh von Bennewitz <michael@schloh.com>
date
Thu, 22 Jan 2015 13:21:57 +0100
branch
TOR_BUG_9701
changeset 15
b8a032363ba2
permissions
-rw-r--r--

Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6

michael@0 1 ;
michael@0 2 ; jcqnts2f.asm - sample data conversion and quantization (SSE & SSE2)
michael@0 3 ;
michael@0 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0 5 ;
michael@0 6 ; Based on
michael@0 7 ; x86 SIMD extension for IJG JPEG library
michael@0 8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0 9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0 10 ;
michael@0 11 ; This file should be assembled with NASM (Netwide Assembler),
michael@0 12 ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0 13 ; assembler (including Borland's Turbo Assembler).
michael@0 14 ; NASM is available from http://nasm.sourceforge.net/ or
michael@0 15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0 16 ;
michael@0 17 ; [TAB8]
michael@0 18
michael@0 19 %include "jsimdext.inc"
michael@0 20 %include "jdct.inc"
michael@0 21
michael@0 22 ; --------------------------------------------------------------------------
michael@0 23 SECTION SEG_TEXT
michael@0 24 BITS 32
michael@0 25 ;
michael@0 26 ; Load data into workspace, applying unsigned->signed conversion
michael@0 27 ;
michael@0 28 ; GLOBAL(void)
michael@0 29 ; jsimd_convsamp_float_sse2 (JSAMPARRAY sample_data, JDIMENSION start_col,
michael@0 30 ; FAST_FLOAT * workspace);
michael@0 31 ;
michael@0 32
michael@0 33 %define sample_data ebp+8 ; JSAMPARRAY sample_data
michael@0 34 %define start_col ebp+12 ; JDIMENSION start_col
michael@0 35 %define workspace ebp+16 ; FAST_FLOAT * workspace
michael@0 36
michael@0 37 align 16
michael@0 38 global EXTN(jsimd_convsamp_float_sse2)
michael@0 39
michael@0 40 EXTN(jsimd_convsamp_float_sse2):
michael@0 41 push ebp
michael@0 42 mov ebp,esp
michael@0 43 push ebx
michael@0 44 ; push ecx ; need not be preserved
michael@0 45 ; push edx ; need not be preserved
michael@0 46 push esi
michael@0 47 push edi
michael@0 48
michael@0 49 pcmpeqw xmm7,xmm7
michael@0 50 psllw xmm7,7
michael@0 51 packsswb xmm7,xmm7 ; xmm7 = PB_CENTERJSAMPLE (0x808080..)
michael@0 52
michael@0 53 mov esi, JSAMPARRAY [sample_data] ; (JSAMPROW *)
michael@0 54 mov eax, JDIMENSION [start_col]
michael@0 55 mov edi, POINTER [workspace] ; (DCTELEM *)
michael@0 56 mov ecx, DCTSIZE/2
michael@0 57 alignx 16,7
michael@0 58 .convloop:
michael@0 59 mov ebx, JSAMPROW [esi+0*SIZEOF_JSAMPROW] ; (JSAMPLE *)
michael@0 60 mov edx, JSAMPROW [esi+1*SIZEOF_JSAMPROW] ; (JSAMPLE *)
michael@0 61
michael@0 62 movq xmm0, XMM_MMWORD [ebx+eax*SIZEOF_JSAMPLE]
michael@0 63 movq xmm1, XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE]
michael@0 64
michael@0 65 psubb xmm0,xmm7 ; xmm0=(01234567)
michael@0 66 psubb xmm1,xmm7 ; xmm1=(89ABCDEF)
michael@0 67
michael@0 68 punpcklbw xmm0,xmm0 ; xmm0=(*0*1*2*3*4*5*6*7)
michael@0 69 punpcklbw xmm1,xmm1 ; xmm1=(*8*9*A*B*C*D*E*F)
michael@0 70
michael@0 71 punpcklwd xmm2,xmm0 ; xmm2=(***0***1***2***3)
michael@0 72 punpckhwd xmm0,xmm0 ; xmm0=(***4***5***6***7)
michael@0 73 punpcklwd xmm3,xmm1 ; xmm3=(***8***9***A***B)
michael@0 74 punpckhwd xmm1,xmm1 ; xmm1=(***C***D***E***F)
michael@0 75
michael@0 76 psrad xmm2,(DWORD_BIT-BYTE_BIT) ; xmm2=(0123)
michael@0 77 psrad xmm0,(DWORD_BIT-BYTE_BIT) ; xmm0=(4567)
michael@0 78 cvtdq2ps xmm2,xmm2 ; xmm2=(0123)
michael@0 79 cvtdq2ps xmm0,xmm0 ; xmm0=(4567)
michael@0 80 psrad xmm3,(DWORD_BIT-BYTE_BIT) ; xmm3=(89AB)
michael@0 81 psrad xmm1,(DWORD_BIT-BYTE_BIT) ; xmm1=(CDEF)
michael@0 82 cvtdq2ps xmm3,xmm3 ; xmm3=(89AB)
michael@0 83 cvtdq2ps xmm1,xmm1 ; xmm1=(CDEF)
michael@0 84
michael@0 85 movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm2
michael@0 86 movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0 87 movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm3
michael@0 88 movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm1
michael@0 89
michael@0 90 add esi, byte 2*SIZEOF_JSAMPROW
michael@0 91 add edi, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0 92 dec ecx
michael@0 93 jnz short .convloop
michael@0 94
michael@0 95 pop edi
michael@0 96 pop esi
michael@0 97 ; pop edx ; need not be preserved
michael@0 98 ; pop ecx ; need not be preserved
michael@0 99 pop ebx
michael@0 100 pop ebp
michael@0 101 ret
michael@0 102
michael@0 103
michael@0 104 ; --------------------------------------------------------------------------
michael@0 105 ;
michael@0 106 ; Quantize/descale the coefficients, and store into coef_block
michael@0 107 ;
michael@0 108 ; GLOBAL(void)
michael@0 109 ; jsimd_quantize_float_sse2 (JCOEFPTR coef_block, FAST_FLOAT * divisors,
michael@0 110 ; FAST_FLOAT * workspace);
michael@0 111 ;
michael@0 112
michael@0 113 %define coef_block ebp+8 ; JCOEFPTR coef_block
michael@0 114 %define divisors ebp+12 ; FAST_FLOAT * divisors
michael@0 115 %define workspace ebp+16 ; FAST_FLOAT * workspace
michael@0 116
michael@0 117 align 16
michael@0 118 global EXTN(jsimd_quantize_float_sse2)
michael@0 119
michael@0 120 EXTN(jsimd_quantize_float_sse2):
michael@0 121 push ebp
michael@0 122 mov ebp,esp
michael@0 123 ; push ebx ; unused
michael@0 124 ; push ecx ; unused
michael@0 125 ; push edx ; need not be preserved
michael@0 126 push esi
michael@0 127 push edi
michael@0 128
michael@0 129 mov esi, POINTER [workspace]
michael@0 130 mov edx, POINTER [divisors]
michael@0 131 mov edi, JCOEFPTR [coef_block]
michael@0 132 mov eax, DCTSIZE2/16
michael@0 133 alignx 16,7
michael@0 134 .quantloop:
michael@0 135 movaps xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 136 movaps xmm1, XMMWORD [XMMBLOCK(0,1,esi,SIZEOF_FAST_FLOAT)]
michael@0 137 mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0 138 mulps xmm1, XMMWORD [XMMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0 139 movaps xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 140 movaps xmm3, XMMWORD [XMMBLOCK(1,1,esi,SIZEOF_FAST_FLOAT)]
michael@0 141 mulps xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0 142 mulps xmm3, XMMWORD [XMMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0 143
michael@0 144 cvtps2dq xmm0,xmm0
michael@0 145 cvtps2dq xmm1,xmm1
michael@0 146 cvtps2dq xmm2,xmm2
michael@0 147 cvtps2dq xmm3,xmm3
michael@0 148
michael@0 149 packssdw xmm0,xmm1
michael@0 150 packssdw xmm2,xmm3
michael@0 151
michael@0 152 movdqa XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_JCOEF)], xmm0
michael@0 153 movdqa XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_JCOEF)], xmm2
michael@0 154
michael@0 155 add esi, byte 16*SIZEOF_FAST_FLOAT
michael@0 156 add edx, byte 16*SIZEOF_FAST_FLOAT
michael@0 157 add edi, byte 16*SIZEOF_JCOEF
michael@0 158 dec eax
michael@0 159 jnz short .quantloop
michael@0 160
michael@0 161 pop edi
michael@0 162 pop esi
michael@0 163 ; pop edx ; need not be preserved
michael@0 164 ; pop ecx ; unused
michael@0 165 ; pop ebx ; unused
michael@0 166 pop ebp
michael@0 167 ret
michael@0 168
michael@0 169 ; For some reason, the OS X linker does not honor the request to align the
michael@0 170 ; segment unless we do this.
michael@0 171 align 16

Mercurial Repository: The Tor Browser

Europalab SCM Repository Server

mercurial