The Tor Browser / annotate

media/libjpeg/simd/jfss2int.asm@b8a032363ba2 (annotated)

media/libjpeg/simd/jfss2int.asm

Thu, 22 Jan 2015 13:21:57 +0100

author
Michael Schloh von Bennewitz <michael@schloh.com>
date
Thu, 22 Jan 2015 13:21:57 +0100
branch
TOR_BUG_9701
changeset 15
b8a032363ba2
permissions
-rw-r--r--

Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6

michael@0 1 ;
michael@0 2 ; jfss2int.asm - accurate integer FDCT (SSE2)
michael@0 3 ;
michael@0 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0 5 ;
michael@0 6 ; Based on
michael@0 7 ; x86 SIMD extension for IJG JPEG library
michael@0 8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0 9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0 10 ;
michael@0 11 ; This file should be assembled with NASM (Netwide Assembler),
michael@0 12 ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0 13 ; assembler (including Borland's Turbo Assembler).
michael@0 14 ; NASM is available from http://nasm.sourceforge.net/ or
michael@0 15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0 16 ;
michael@0 17 ; This file contains a slow-but-accurate integer implementation of the
michael@0 18 ; forward DCT (Discrete Cosine Transform). The following code is based
michael@0 19 ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
michael@0 20 ; more details.
michael@0 21 ;
michael@0 22 ; [TAB8]
michael@0 23
michael@0 24 %include "jsimdext.inc"
michael@0 25 %include "jdct.inc"
michael@0 26
michael@0 27 ; --------------------------------------------------------------------------
michael@0 28
michael@0 29 %define CONST_BITS 13
michael@0 30 %define PASS1_BITS 2
michael@0 31
michael@0 32 %define DESCALE_P1 (CONST_BITS-PASS1_BITS)
michael@0 33 %define DESCALE_P2 (CONST_BITS+PASS1_BITS)
michael@0 34
michael@0 35 %if CONST_BITS == 13
michael@0 36 F_0_298 equ 2446 ; FIX(0.298631336)
michael@0 37 F_0_390 equ 3196 ; FIX(0.390180644)
michael@0 38 F_0_541 equ 4433 ; FIX(0.541196100)
michael@0 39 F_0_765 equ 6270 ; FIX(0.765366865)
michael@0 40 F_0_899 equ 7373 ; FIX(0.899976223)
michael@0 41 F_1_175 equ 9633 ; FIX(1.175875602)
michael@0 42 F_1_501 equ 12299 ; FIX(1.501321110)
michael@0 43 F_1_847 equ 15137 ; FIX(1.847759065)
michael@0 44 F_1_961 equ 16069 ; FIX(1.961570560)
michael@0 45 F_2_053 equ 16819 ; FIX(2.053119869)
michael@0 46 F_2_562 equ 20995 ; FIX(2.562915447)
michael@0 47 F_3_072 equ 25172 ; FIX(3.072711026)
michael@0 48 %else
michael@0 49 ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0 50 %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
michael@0 51 F_0_298 equ DESCALE( 320652955,30-CONST_BITS) ; FIX(0.298631336)
michael@0 52 F_0_390 equ DESCALE( 418953276,30-CONST_BITS) ; FIX(0.390180644)
michael@0 53 F_0_541 equ DESCALE( 581104887,30-CONST_BITS) ; FIX(0.541196100)
michael@0 54 F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)
michael@0 55 F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)
michael@0 56 F_1_175 equ DESCALE(1262586813,30-CONST_BITS) ; FIX(1.175875602)
michael@0 57 F_1_501 equ DESCALE(1612031267,30-CONST_BITS) ; FIX(1.501321110)
michael@0 58 F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
michael@0 59 F_1_961 equ DESCALE(2106220350,30-CONST_BITS) ; FIX(1.961570560)
michael@0 60 F_2_053 equ DESCALE(2204520673,30-CONST_BITS) ; FIX(2.053119869)
michael@0 61 F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)
michael@0 62 F_3_072 equ DESCALE(3299298341,30-CONST_BITS) ; FIX(3.072711026)
michael@0 63 %endif
michael@0 64
michael@0 65 ; --------------------------------------------------------------------------
michael@0 66 SECTION SEG_CONST
michael@0 67
michael@0 68 alignz 16
michael@0 69 global EXTN(jconst_fdct_islow_sse2)
michael@0 70
michael@0 71 EXTN(jconst_fdct_islow_sse2):
michael@0 72
michael@0 73 PW_F130_F054 times 4 dw (F_0_541+F_0_765), F_0_541
michael@0 74 PW_F054_MF130 times 4 dw F_0_541, (F_0_541-F_1_847)
michael@0 75 PW_MF078_F117 times 4 dw (F_1_175-F_1_961), F_1_175
michael@0 76 PW_F117_F078 times 4 dw F_1_175, (F_1_175-F_0_390)
michael@0 77 PW_MF060_MF089 times 4 dw (F_0_298-F_0_899),-F_0_899
michael@0 78 PW_MF089_F060 times 4 dw -F_0_899, (F_1_501-F_0_899)
michael@0 79 PW_MF050_MF256 times 4 dw (F_2_053-F_2_562),-F_2_562
michael@0 80 PW_MF256_F050 times 4 dw -F_2_562, (F_3_072-F_2_562)
michael@0 81 PD_DESCALE_P1 times 4 dd 1 << (DESCALE_P1-1)
michael@0 82 PD_DESCALE_P2 times 4 dd 1 << (DESCALE_P2-1)
michael@0 83 PW_DESCALE_P2X times 8 dw 1 << (PASS1_BITS-1)
michael@0 84
michael@0 85 alignz 16
michael@0 86
michael@0 87 ; --------------------------------------------------------------------------
michael@0 88 SECTION SEG_TEXT
michael@0 89 BITS 32
michael@0 90 ;
michael@0 91 ; Perform the forward DCT on one block of samples.
michael@0 92 ;
michael@0 93 ; GLOBAL(void)
michael@0 94 ; jsimd_fdct_islow_sse2 (DCTELEM * data)
michael@0 95 ;
michael@0 96
michael@0 97 %define data(b) (b)+8 ; DCTELEM * data
michael@0 98
michael@0 99 %define original_ebp ebp+0
michael@0 100 %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
michael@0 101 %define WK_NUM 6
michael@0 102
michael@0 103 align 16
michael@0 104 global EXTN(jsimd_fdct_islow_sse2)
michael@0 105
michael@0 106 EXTN(jsimd_fdct_islow_sse2):
michael@0 107 push ebp
michael@0 108 mov eax,esp ; eax = original ebp
michael@0 109 sub esp, byte 4
michael@0 110 and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
michael@0 111 mov [esp],eax
michael@0 112 mov ebp,esp ; ebp = aligned ebp
michael@0 113 lea esp, [wk(0)]
michael@0 114 pushpic ebx
michael@0 115 ; push ecx ; unused
michael@0 116 ; push edx ; need not be preserved
michael@0 117 ; push esi ; unused
michael@0 118 ; push edi ; unused
michael@0 119
michael@0 120 get_GOT ebx ; get GOT address
michael@0 121
michael@0 122 ; ---- Pass 1: process rows.
michael@0 123
michael@0 124 mov edx, POINTER [data(eax)] ; (DCTELEM *)
michael@0 125
michael@0 126 movdqa xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
michael@0 127 movdqa xmm1, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
michael@0 128 movdqa xmm2, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
michael@0 129 movdqa xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
michael@0 130
michael@0 131 ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
michael@0 132 ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
michael@0 133
michael@0 134 movdqa xmm4,xmm0 ; transpose coefficients(phase 1)
michael@0 135 punpcklwd xmm0,xmm1 ; xmm0=(00 10 01 11 02 12 03 13)
michael@0 136 punpckhwd xmm4,xmm1 ; xmm4=(04 14 05 15 06 16 07 17)
michael@0 137 movdqa xmm5,xmm2 ; transpose coefficients(phase 1)
michael@0 138 punpcklwd xmm2,xmm3 ; xmm2=(20 30 21 31 22 32 23 33)
michael@0 139 punpckhwd xmm5,xmm3 ; xmm5=(24 34 25 35 26 36 27 37)
michael@0 140
michael@0 141 movdqa xmm6, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)]
michael@0 142 movdqa xmm7, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)]
michael@0 143 movdqa xmm1, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)]
michael@0 144 movdqa xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)]
michael@0 145
michael@0 146 ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
michael@0 147 ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
michael@0 148
michael@0 149 movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=(20 30 21 31 22 32 23 33)
michael@0 150 movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(24 34 25 35 26 36 27 37)
michael@0 151
michael@0 152 movdqa xmm2,xmm6 ; transpose coefficients(phase 1)
michael@0 153 punpcklwd xmm6,xmm7 ; xmm6=(40 50 41 51 42 52 43 53)
michael@0 154 punpckhwd xmm2,xmm7 ; xmm2=(44 54 45 55 46 56 47 57)
michael@0 155 movdqa xmm5,xmm1 ; transpose coefficients(phase 1)
michael@0 156 punpcklwd xmm1,xmm3 ; xmm1=(60 70 61 71 62 72 63 73)
michael@0 157 punpckhwd xmm5,xmm3 ; xmm5=(64 74 65 75 66 76 67 77)
michael@0 158
michael@0 159 movdqa xmm7,xmm6 ; transpose coefficients(phase 2)
michael@0 160 punpckldq xmm6,xmm1 ; xmm6=(40 50 60 70 41 51 61 71)
michael@0 161 punpckhdq xmm7,xmm1 ; xmm7=(42 52 62 72 43 53 63 73)
michael@0 162 movdqa xmm3,xmm2 ; transpose coefficients(phase 2)
michael@0 163 punpckldq xmm2,xmm5 ; xmm2=(44 54 64 74 45 55 65 75)
michael@0 164 punpckhdq xmm3,xmm5 ; xmm3=(46 56 66 76 47 57 67 77)
michael@0 165
michael@0 166 movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(20 30 21 31 22 32 23 33)
michael@0 167 movdqa xmm5, XMMWORD [wk(1)] ; xmm5=(24 34 25 35 26 36 27 37)
michael@0 168 movdqa XMMWORD [wk(2)], xmm7 ; wk(2)=(42 52 62 72 43 53 63 73)
michael@0 169 movdqa XMMWORD [wk(3)], xmm2 ; wk(3)=(44 54 64 74 45 55 65 75)
michael@0 170
michael@0 171 movdqa xmm7,xmm0 ; transpose coefficients(phase 2)
michael@0 172 punpckldq xmm0,xmm1 ; xmm0=(00 10 20 30 01 11 21 31)
michael@0 173 punpckhdq xmm7,xmm1 ; xmm7=(02 12 22 32 03 13 23 33)
michael@0 174 movdqa xmm2,xmm4 ; transpose coefficients(phase 2)
michael@0 175 punpckldq xmm4,xmm5 ; xmm4=(04 14 24 34 05 15 25 35)
michael@0 176 punpckhdq xmm2,xmm5 ; xmm2=(06 16 26 36 07 17 27 37)
michael@0 177
michael@0 178 movdqa xmm1,xmm0 ; transpose coefficients(phase 3)
michael@0 179 punpcklqdq xmm0,xmm6 ; xmm0=(00 10 20 30 40 50 60 70)=data0
michael@0 180 punpckhqdq xmm1,xmm6 ; xmm1=(01 11 21 31 41 51 61 71)=data1
michael@0 181 movdqa xmm5,xmm2 ; transpose coefficients(phase 3)
michael@0 182 punpcklqdq xmm2,xmm3 ; xmm2=(06 16 26 36 46 56 66 76)=data6
michael@0 183 punpckhqdq xmm5,xmm3 ; xmm5=(07 17 27 37 47 57 67 77)=data7
michael@0 184
michael@0 185 movdqa xmm6,xmm1
michael@0 186 movdqa xmm3,xmm0
michael@0 187 psubw xmm1,xmm2 ; xmm1=data1-data6=tmp6
michael@0 188 psubw xmm0,xmm5 ; xmm0=data0-data7=tmp7
michael@0 189 paddw xmm6,xmm2 ; xmm6=data1+data6=tmp1
michael@0 190 paddw xmm3,xmm5 ; xmm3=data0+data7=tmp0
michael@0 191
michael@0 192 movdqa xmm2, XMMWORD [wk(2)] ; xmm2=(42 52 62 72 43 53 63 73)
michael@0 193 movdqa xmm5, XMMWORD [wk(3)] ; xmm5=(44 54 64 74 45 55 65 75)
michael@0 194 movdqa XMMWORD [wk(0)], xmm1 ; wk(0)=tmp6
michael@0 195 movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=tmp7
michael@0 196
michael@0 197 movdqa xmm1,xmm7 ; transpose coefficients(phase 3)
michael@0 198 punpcklqdq xmm7,xmm2 ; xmm7=(02 12 22 32 42 52 62 72)=data2
michael@0 199 punpckhqdq xmm1,xmm2 ; xmm1=(03 13 23 33 43 53 63 73)=data3
michael@0 200 movdqa xmm0,xmm4 ; transpose coefficients(phase 3)
michael@0 201 punpcklqdq xmm4,xmm5 ; xmm4=(04 14 24 34 44 54 64 74)=data4
michael@0 202 punpckhqdq xmm0,xmm5 ; xmm0=(05 15 25 35 45 55 65 75)=data5
michael@0 203
michael@0 204 movdqa xmm2,xmm1
michael@0 205 movdqa xmm5,xmm7
michael@0 206 paddw xmm1,xmm4 ; xmm1=data3+data4=tmp3
michael@0 207 paddw xmm7,xmm0 ; xmm7=data2+data5=tmp2
michael@0 208 psubw xmm2,xmm4 ; xmm2=data3-data4=tmp4
michael@0 209 psubw xmm5,xmm0 ; xmm5=data2-data5=tmp5
michael@0 210
michael@0 211 ; -- Even part
michael@0 212
michael@0 213 movdqa xmm4,xmm3
michael@0 214 movdqa xmm0,xmm6
michael@0 215 paddw xmm3,xmm1 ; xmm3=tmp10
michael@0 216 paddw xmm6,xmm7 ; xmm6=tmp11
michael@0 217 psubw xmm4,xmm1 ; xmm4=tmp13
michael@0 218 psubw xmm0,xmm7 ; xmm0=tmp12
michael@0 219
michael@0 220 movdqa xmm1,xmm3
michael@0 221 paddw xmm3,xmm6 ; xmm3=tmp10+tmp11
michael@0 222 psubw xmm1,xmm6 ; xmm1=tmp10-tmp11
michael@0 223
michael@0 224 psllw xmm3,PASS1_BITS ; xmm3=data0
michael@0 225 psllw xmm1,PASS1_BITS ; xmm1=data4
michael@0 226
michael@0 227 movdqa XMMWORD [wk(2)], xmm3 ; wk(2)=data0
michael@0 228 movdqa XMMWORD [wk(3)], xmm1 ; wk(3)=data4
michael@0 229
michael@0 230 ; (Original)
michael@0 231 ; z1 = (tmp12 + tmp13) * 0.541196100;
michael@0 232 ; data2 = z1 + tmp13 * 0.765366865;
michael@0 233 ; data6 = z1 + tmp12 * -1.847759065;
michael@0 234 ;
michael@0 235 ; (This implementation)
michael@0 236 ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
michael@0 237 ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
michael@0 238
michael@0 239 movdqa xmm7,xmm4 ; xmm4=tmp13
michael@0 240 movdqa xmm6,xmm4
michael@0 241 punpcklwd xmm7,xmm0 ; xmm0=tmp12
michael@0 242 punpckhwd xmm6,xmm0
michael@0 243 movdqa xmm4,xmm7
michael@0 244 movdqa xmm0,xmm6
michael@0 245 pmaddwd xmm7,[GOTOFF(ebx,PW_F130_F054)] ; xmm7=data2L
michael@0 246 pmaddwd xmm6,[GOTOFF(ebx,PW_F130_F054)] ; xmm6=data2H
michael@0 247 pmaddwd xmm4,[GOTOFF(ebx,PW_F054_MF130)] ; xmm4=data6L
michael@0 248 pmaddwd xmm0,[GOTOFF(ebx,PW_F054_MF130)] ; xmm0=data6H
michael@0 249
michael@0 250 paddd xmm7,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 251 paddd xmm6,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 252 psrad xmm7,DESCALE_P1
michael@0 253 psrad xmm6,DESCALE_P1
michael@0 254 paddd xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 255 paddd xmm0,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 256 psrad xmm4,DESCALE_P1
michael@0 257 psrad xmm0,DESCALE_P1
michael@0 258
michael@0 259 packssdw xmm7,xmm6 ; xmm7=data2
michael@0 260 packssdw xmm4,xmm0 ; xmm4=data6
michael@0 261
michael@0 262 movdqa XMMWORD [wk(4)], xmm7 ; wk(4)=data2
michael@0 263 movdqa XMMWORD [wk(5)], xmm4 ; wk(5)=data6
michael@0 264
michael@0 265 ; -- Odd part
michael@0 266
michael@0 267 movdqa xmm3, XMMWORD [wk(0)] ; xmm3=tmp6
michael@0 268 movdqa xmm1, XMMWORD [wk(1)] ; xmm1=tmp7
michael@0 269
michael@0 270 movdqa xmm6,xmm2 ; xmm2=tmp4
michael@0 271 movdqa xmm0,xmm5 ; xmm5=tmp5
michael@0 272 paddw xmm6,xmm3 ; xmm6=z3
michael@0 273 paddw xmm0,xmm1 ; xmm0=z4
michael@0 274
michael@0 275 ; (Original)
michael@0 276 ; z5 = (z3 + z4) * 1.175875602;
michael@0 277 ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644;
michael@0 278 ; z3 += z5; z4 += z5;
michael@0 279 ;
michael@0 280 ; (This implementation)
michael@0 281 ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
michael@0 282 ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
michael@0 283
michael@0 284 movdqa xmm7,xmm6
michael@0 285 movdqa xmm4,xmm6
michael@0 286 punpcklwd xmm7,xmm0
michael@0 287 punpckhwd xmm4,xmm0
michael@0 288 movdqa xmm6,xmm7
michael@0 289 movdqa xmm0,xmm4
michael@0 290 pmaddwd xmm7,[GOTOFF(ebx,PW_MF078_F117)] ; xmm7=z3L
michael@0 291 pmaddwd xmm4,[GOTOFF(ebx,PW_MF078_F117)] ; xmm4=z3H
michael@0 292 pmaddwd xmm6,[GOTOFF(ebx,PW_F117_F078)] ; xmm6=z4L
michael@0 293 pmaddwd xmm0,[GOTOFF(ebx,PW_F117_F078)] ; xmm0=z4H
michael@0 294
michael@0 295 movdqa XMMWORD [wk(0)], xmm7 ; wk(0)=z3L
michael@0 296 movdqa XMMWORD [wk(1)], xmm4 ; wk(1)=z3H
michael@0 297
michael@0 298 ; (Original)
michael@0 299 ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6;
michael@0 300 ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869;
michael@0 301 ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110;
michael@0 302 ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447;
michael@0 303 ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4;
michael@0 304 ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4;
michael@0 305 ;
michael@0 306 ; (This implementation)
michael@0 307 ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
michael@0 308 ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
michael@0 309 ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
michael@0 310 ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
michael@0 311 ; data7 = tmp4 + z3; data5 = tmp5 + z4;
michael@0 312 ; data3 = tmp6 + z3; data1 = tmp7 + z4;
michael@0 313
michael@0 314 movdqa xmm7,xmm2
michael@0 315 movdqa xmm4,xmm2
michael@0 316 punpcklwd xmm7,xmm1
michael@0 317 punpckhwd xmm4,xmm1
michael@0 318 movdqa xmm2,xmm7
michael@0 319 movdqa xmm1,xmm4
michael@0 320 pmaddwd xmm7,[GOTOFF(ebx,PW_MF060_MF089)] ; xmm7=tmp4L
michael@0 321 pmaddwd xmm4,[GOTOFF(ebx,PW_MF060_MF089)] ; xmm4=tmp4H
michael@0 322 pmaddwd xmm2,[GOTOFF(ebx,PW_MF089_F060)] ; xmm2=tmp7L
michael@0 323 pmaddwd xmm1,[GOTOFF(ebx,PW_MF089_F060)] ; xmm1=tmp7H
michael@0 324
michael@0 325 paddd xmm7, XMMWORD [wk(0)] ; xmm7=data7L
michael@0 326 paddd xmm4, XMMWORD [wk(1)] ; xmm4=data7H
michael@0 327 paddd xmm2,xmm6 ; xmm2=data1L
michael@0 328 paddd xmm1,xmm0 ; xmm1=data1H
michael@0 329
michael@0 330 paddd xmm7,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 331 paddd xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 332 psrad xmm7,DESCALE_P1
michael@0 333 psrad xmm4,DESCALE_P1
michael@0 334 paddd xmm2,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 335 paddd xmm1,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 336 psrad xmm2,DESCALE_P1
michael@0 337 psrad xmm1,DESCALE_P1
michael@0 338
michael@0 339 packssdw xmm7,xmm4 ; xmm7=data7
michael@0 340 packssdw xmm2,xmm1 ; xmm2=data1
michael@0 341
michael@0 342 movdqa xmm4,xmm5
michael@0 343 movdqa xmm1,xmm5
michael@0 344 punpcklwd xmm4,xmm3
michael@0 345 punpckhwd xmm1,xmm3
michael@0 346 movdqa xmm5,xmm4
michael@0 347 movdqa xmm3,xmm1
michael@0 348 pmaddwd xmm4,[GOTOFF(ebx,PW_MF050_MF256)] ; xmm4=tmp5L
michael@0 349 pmaddwd xmm1,[GOTOFF(ebx,PW_MF050_MF256)] ; xmm1=tmp5H
michael@0 350 pmaddwd xmm5,[GOTOFF(ebx,PW_MF256_F050)] ; xmm5=tmp6L
michael@0 351 pmaddwd xmm3,[GOTOFF(ebx,PW_MF256_F050)] ; xmm3=tmp6H
michael@0 352
michael@0 353 paddd xmm4,xmm6 ; xmm4=data5L
michael@0 354 paddd xmm1,xmm0 ; xmm1=data5H
michael@0 355 paddd xmm5, XMMWORD [wk(0)] ; xmm5=data3L
michael@0 356 paddd xmm3, XMMWORD [wk(1)] ; xmm3=data3H
michael@0 357
michael@0 358 paddd xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 359 paddd xmm1,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 360 psrad xmm4,DESCALE_P1
michael@0 361 psrad xmm1,DESCALE_P1
michael@0 362 paddd xmm5,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 363 paddd xmm3,[GOTOFF(ebx,PD_DESCALE_P1)]
michael@0 364 psrad xmm5,DESCALE_P1
michael@0 365 psrad xmm3,DESCALE_P1
michael@0 366
michael@0 367 packssdw xmm4,xmm1 ; xmm4=data5
michael@0 368 packssdw xmm5,xmm3 ; xmm5=data3
michael@0 369
michael@0 370 ; ---- Pass 2: process columns.
michael@0 371
michael@0 372 ; mov edx, POINTER [data(eax)] ; (DCTELEM *)
michael@0 373
michael@0 374 movdqa xmm6, XMMWORD [wk(2)] ; xmm6=col0
michael@0 375 movdqa xmm0, XMMWORD [wk(4)] ; xmm0=col2
michael@0 376
michael@0 377 ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72)
michael@0 378 ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73)
michael@0 379
michael@0 380 movdqa xmm1,xmm6 ; transpose coefficients(phase 1)
michael@0 381 punpcklwd xmm6,xmm2 ; xmm6=(00 01 10 11 20 21 30 31)
michael@0 382 punpckhwd xmm1,xmm2 ; xmm1=(40 41 50 51 60 61 70 71)
michael@0 383 movdqa xmm3,xmm0 ; transpose coefficients(phase 1)
michael@0 384 punpcklwd xmm0,xmm5 ; xmm0=(02 03 12 13 22 23 32 33)
michael@0 385 punpckhwd xmm3,xmm5 ; xmm3=(42 43 52 53 62 63 72 73)
michael@0 386
michael@0 387 movdqa xmm2, XMMWORD [wk(3)] ; xmm2=col4
michael@0 388 movdqa xmm5, XMMWORD [wk(5)] ; xmm5=col6
michael@0 389
michael@0 390 ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76)
michael@0 391 ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77)
michael@0 392
michael@0 393 movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=(02 03 12 13 22 23 32 33)
michael@0 394 movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=(42 43 52 53 62 63 72 73)
michael@0 395
michael@0 396 movdqa xmm0,xmm2 ; transpose coefficients(phase 1)
michael@0 397 punpcklwd xmm2,xmm4 ; xmm2=(04 05 14 15 24 25 34 35)
michael@0 398 punpckhwd xmm0,xmm4 ; xmm0=(44 45 54 55 64 65 74 75)
michael@0 399 movdqa xmm3,xmm5 ; transpose coefficients(phase 1)
michael@0 400 punpcklwd xmm5,xmm7 ; xmm5=(06 07 16 17 26 27 36 37)
michael@0 401 punpckhwd xmm3,xmm7 ; xmm3=(46 47 56 57 66 67 76 77)
michael@0 402
michael@0 403 movdqa xmm4,xmm2 ; transpose coefficients(phase 2)
michael@0 404 punpckldq xmm2,xmm5 ; xmm2=(04 05 06 07 14 15 16 17)
michael@0 405 punpckhdq xmm4,xmm5 ; xmm4=(24 25 26 27 34 35 36 37)
michael@0 406 movdqa xmm7,xmm0 ; transpose coefficients(phase 2)
michael@0 407 punpckldq xmm0,xmm3 ; xmm0=(44 45 46 47 54 55 56 57)
michael@0 408 punpckhdq xmm7,xmm3 ; xmm7=(64 65 66 67 74 75 76 77)
michael@0 409
michael@0 410 movdqa xmm5, XMMWORD [wk(0)] ; xmm5=(02 03 12 13 22 23 32 33)
michael@0 411 movdqa xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53 62 63 72 73)
michael@0 412 movdqa XMMWORD [wk(2)], xmm4 ; wk(2)=(24 25 26 27 34 35 36 37)
michael@0 413 movdqa XMMWORD [wk(3)], xmm0 ; wk(3)=(44 45 46 47 54 55 56 57)
michael@0 414
michael@0 415 movdqa xmm4,xmm6 ; transpose coefficients(phase 2)
michael@0 416 punpckldq xmm6,xmm5 ; xmm6=(00 01 02 03 10 11 12 13)
michael@0 417 punpckhdq xmm4,xmm5 ; xmm4=(20 21 22 23 30 31 32 33)
michael@0 418 movdqa xmm0,xmm1 ; transpose coefficients(phase 2)
michael@0 419 punpckldq xmm1,xmm3 ; xmm1=(40 41 42 43 50 51 52 53)
michael@0 420 punpckhdq xmm0,xmm3 ; xmm0=(60 61 62 63 70 71 72 73)
michael@0 421
michael@0 422 movdqa xmm5,xmm6 ; transpose coefficients(phase 3)
michael@0 423 punpcklqdq xmm6,xmm2 ; xmm6=(00 01 02 03 04 05 06 07)=data0
michael@0 424 punpckhqdq xmm5,xmm2 ; xmm5=(10 11 12 13 14 15 16 17)=data1
michael@0 425 movdqa xmm3,xmm0 ; transpose coefficients(phase 3)
michael@0 426 punpcklqdq xmm0,xmm7 ; xmm0=(60 61 62 63 64 65 66 67)=data6
michael@0 427 punpckhqdq xmm3,xmm7 ; xmm3=(70 71 72 73 74 75 76 77)=data7
michael@0 428
michael@0 429 movdqa xmm2,xmm5
michael@0 430 movdqa xmm7,xmm6
michael@0 431 psubw xmm5,xmm0 ; xmm5=data1-data6=tmp6
michael@0 432 psubw xmm6,xmm3 ; xmm6=data0-data7=tmp7
michael@0 433 paddw xmm2,xmm0 ; xmm2=data1+data6=tmp1
michael@0 434 paddw xmm7,xmm3 ; xmm7=data0+data7=tmp0
michael@0 435
michael@0 436 movdqa xmm0, XMMWORD [wk(2)] ; xmm0=(24 25 26 27 34 35 36 37)
michael@0 437 movdqa xmm3, XMMWORD [wk(3)] ; xmm3=(44 45 46 47 54 55 56 57)
michael@0 438 movdqa XMMWORD [wk(0)], xmm5 ; wk(0)=tmp6
michael@0 439 movdqa XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
michael@0 440
michael@0 441 movdqa xmm5,xmm4 ; transpose coefficients(phase 3)
michael@0 442 punpcklqdq xmm4,xmm0 ; xmm4=(20 21 22 23 24 25 26 27)=data2
michael@0 443 punpckhqdq xmm5,xmm0 ; xmm5=(30 31 32 33 34 35 36 37)=data3
michael@0 444 movdqa xmm6,xmm1 ; transpose coefficients(phase 3)
michael@0 445 punpcklqdq xmm1,xmm3 ; xmm1=(40 41 42 43 44 45 46 47)=data4
michael@0 446 punpckhqdq xmm6,xmm3 ; xmm6=(50 51 52 53 54 55 56 57)=data5
michael@0 447
michael@0 448 movdqa xmm0,xmm5
michael@0 449 movdqa xmm3,xmm4
michael@0 450 paddw xmm5,xmm1 ; xmm5=data3+data4=tmp3
michael@0 451 paddw xmm4,xmm6 ; xmm4=data2+data5=tmp2
michael@0 452 psubw xmm0,xmm1 ; xmm0=data3-data4=tmp4
michael@0 453 psubw xmm3,xmm6 ; xmm3=data2-data5=tmp5
michael@0 454
michael@0 455 ; -- Even part
michael@0 456
michael@0 457 movdqa xmm1,xmm7
michael@0 458 movdqa xmm6,xmm2
michael@0 459 paddw xmm7,xmm5 ; xmm7=tmp10
michael@0 460 paddw xmm2,xmm4 ; xmm2=tmp11
michael@0 461 psubw xmm1,xmm5 ; xmm1=tmp13
michael@0 462 psubw xmm6,xmm4 ; xmm6=tmp12
michael@0 463
michael@0 464 movdqa xmm5,xmm7
michael@0 465 paddw xmm7,xmm2 ; xmm7=tmp10+tmp11
michael@0 466 psubw xmm5,xmm2 ; xmm5=tmp10-tmp11
michael@0 467
michael@0 468 paddw xmm7,[GOTOFF(ebx,PW_DESCALE_P2X)]
michael@0 469 paddw xmm5,[GOTOFF(ebx,PW_DESCALE_P2X)]
michael@0 470 psraw xmm7,PASS1_BITS ; xmm7=data0
michael@0 471 psraw xmm5,PASS1_BITS ; xmm5=data4
michael@0 472
michael@0 473 movdqa XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)], xmm7
michael@0 474 movdqa XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)], xmm5
michael@0 475
michael@0 476 ; (Original)
michael@0 477 ; z1 = (tmp12 + tmp13) * 0.541196100;
michael@0 478 ; data2 = z1 + tmp13 * 0.765366865;
michael@0 479 ; data6 = z1 + tmp12 * -1.847759065;
michael@0 480 ;
michael@0 481 ; (This implementation)
michael@0 482 ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
michael@0 483 ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
michael@0 484
michael@0 485 movdqa xmm4,xmm1 ; xmm1=tmp13
michael@0 486 movdqa xmm2,xmm1
michael@0 487 punpcklwd xmm4,xmm6 ; xmm6=tmp12
michael@0 488 punpckhwd xmm2,xmm6
michael@0 489 movdqa xmm1,xmm4
michael@0 490 movdqa xmm6,xmm2
michael@0 491 pmaddwd xmm4,[GOTOFF(ebx,PW_F130_F054)] ; xmm4=data2L
michael@0 492 pmaddwd xmm2,[GOTOFF(ebx,PW_F130_F054)] ; xmm2=data2H
michael@0 493 pmaddwd xmm1,[GOTOFF(ebx,PW_F054_MF130)] ; xmm1=data6L
michael@0 494 pmaddwd xmm6,[GOTOFF(ebx,PW_F054_MF130)] ; xmm6=data6H
michael@0 495
michael@0 496 paddd xmm4,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 497 paddd xmm2,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 498 psrad xmm4,DESCALE_P2
michael@0 499 psrad xmm2,DESCALE_P2
michael@0 500 paddd xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 501 paddd xmm6,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 502 psrad xmm1,DESCALE_P2
michael@0 503 psrad xmm6,DESCALE_P2
michael@0 504
michael@0 505 packssdw xmm4,xmm2 ; xmm4=data2
michael@0 506 packssdw xmm1,xmm6 ; xmm1=data6
michael@0 507
michael@0 508 movdqa XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)], xmm4
michael@0 509 movdqa XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)], xmm1
michael@0 510
michael@0 511 ; -- Odd part
michael@0 512
michael@0 513 movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp6
michael@0 514 movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp7
michael@0 515
michael@0 516 movdqa xmm2,xmm0 ; xmm0=tmp4
michael@0 517 movdqa xmm6,xmm3 ; xmm3=tmp5
michael@0 518 paddw xmm2,xmm7 ; xmm2=z3
michael@0 519 paddw xmm6,xmm5 ; xmm6=z4
michael@0 520
michael@0 521 ; (Original)
michael@0 522 ; z5 = (z3 + z4) * 1.175875602;
michael@0 523 ; z3 = z3 * -1.961570560; z4 = z4 * -0.390180644;
michael@0 524 ; z3 += z5; z4 += z5;
michael@0 525 ;
michael@0 526 ; (This implementation)
michael@0 527 ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
michael@0 528 ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
michael@0 529
michael@0 530 movdqa xmm4,xmm2
michael@0 531 movdqa xmm1,xmm2
michael@0 532 punpcklwd xmm4,xmm6
michael@0 533 punpckhwd xmm1,xmm6
michael@0 534 movdqa xmm2,xmm4
michael@0 535 movdqa xmm6,xmm1
michael@0 536 pmaddwd xmm4,[GOTOFF(ebx,PW_MF078_F117)] ; xmm4=z3L
michael@0 537 pmaddwd xmm1,[GOTOFF(ebx,PW_MF078_F117)] ; xmm1=z3H
michael@0 538 pmaddwd xmm2,[GOTOFF(ebx,PW_F117_F078)] ; xmm2=z4L
michael@0 539 pmaddwd xmm6,[GOTOFF(ebx,PW_F117_F078)] ; xmm6=z4H
michael@0 540
michael@0 541 movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=z3L
michael@0 542 movdqa XMMWORD [wk(1)], xmm1 ; wk(1)=z3H
michael@0 543
michael@0 544 ; (Original)
michael@0 545 ; z1 = tmp4 + tmp7; z2 = tmp5 + tmp6;
michael@0 546 ; tmp4 = tmp4 * 0.298631336; tmp5 = tmp5 * 2.053119869;
michael@0 547 ; tmp6 = tmp6 * 3.072711026; tmp7 = tmp7 * 1.501321110;
michael@0 548 ; z1 = z1 * -0.899976223; z2 = z2 * -2.562915447;
michael@0 549 ; data7 = tmp4 + z1 + z3; data5 = tmp5 + z2 + z4;
michael@0 550 ; data3 = tmp6 + z2 + z3; data1 = tmp7 + z1 + z4;
michael@0 551 ;
michael@0 552 ; (This implementation)
michael@0 553 ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
michael@0 554 ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
michael@0 555 ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
michael@0 556 ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
michael@0 557 ; data7 = tmp4 + z3; data5 = tmp5 + z4;
michael@0 558 ; data3 = tmp6 + z3; data1 = tmp7 + z4;
michael@0 559
michael@0 560 movdqa xmm4,xmm0
michael@0 561 movdqa xmm1,xmm0
michael@0 562 punpcklwd xmm4,xmm5
michael@0 563 punpckhwd xmm1,xmm5
michael@0 564 movdqa xmm0,xmm4
michael@0 565 movdqa xmm5,xmm1
michael@0 566 pmaddwd xmm4,[GOTOFF(ebx,PW_MF060_MF089)] ; xmm4=tmp4L
michael@0 567 pmaddwd xmm1,[GOTOFF(ebx,PW_MF060_MF089)] ; xmm1=tmp4H
michael@0 568 pmaddwd xmm0,[GOTOFF(ebx,PW_MF089_F060)] ; xmm0=tmp7L
michael@0 569 pmaddwd xmm5,[GOTOFF(ebx,PW_MF089_F060)] ; xmm5=tmp7H
michael@0 570
michael@0 571 paddd xmm4, XMMWORD [wk(0)] ; xmm4=data7L
michael@0 572 paddd xmm1, XMMWORD [wk(1)] ; xmm1=data7H
michael@0 573 paddd xmm0,xmm2 ; xmm0=data1L
michael@0 574 paddd xmm5,xmm6 ; xmm5=data1H
michael@0 575
michael@0 576 paddd xmm4,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 577 paddd xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 578 psrad xmm4,DESCALE_P2
michael@0 579 psrad xmm1,DESCALE_P2
michael@0 580 paddd xmm0,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 581 paddd xmm5,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 582 psrad xmm0,DESCALE_P2
michael@0 583 psrad xmm5,DESCALE_P2
michael@0 584
michael@0 585 packssdw xmm4,xmm1 ; xmm4=data7
michael@0 586 packssdw xmm0,xmm5 ; xmm0=data1
michael@0 587
michael@0 588 movdqa XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)], xmm4
michael@0 589 movdqa XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)], xmm0
michael@0 590
michael@0 591 movdqa xmm1,xmm3
michael@0 592 movdqa xmm5,xmm3
michael@0 593 punpcklwd xmm1,xmm7
michael@0 594 punpckhwd xmm5,xmm7
michael@0 595 movdqa xmm3,xmm1
michael@0 596 movdqa xmm7,xmm5
michael@0 597 pmaddwd xmm1,[GOTOFF(ebx,PW_MF050_MF256)] ; xmm1=tmp5L
michael@0 598 pmaddwd xmm5,[GOTOFF(ebx,PW_MF050_MF256)] ; xmm5=tmp5H
michael@0 599 pmaddwd xmm3,[GOTOFF(ebx,PW_MF256_F050)] ; xmm3=tmp6L
michael@0 600 pmaddwd xmm7,[GOTOFF(ebx,PW_MF256_F050)] ; xmm7=tmp6H
michael@0 601
michael@0 602 paddd xmm1,xmm2 ; xmm1=data5L
michael@0 603 paddd xmm5,xmm6 ; xmm5=data5H
michael@0 604 paddd xmm3, XMMWORD [wk(0)] ; xmm3=data3L
michael@0 605 paddd xmm7, XMMWORD [wk(1)] ; xmm7=data3H
michael@0 606
michael@0 607 paddd xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 608 paddd xmm5,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 609 psrad xmm1,DESCALE_P2
michael@0 610 psrad xmm5,DESCALE_P2
michael@0 611 paddd xmm3,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 612 paddd xmm7,[GOTOFF(ebx,PD_DESCALE_P2)]
michael@0 613 psrad xmm3,DESCALE_P2
michael@0 614 psrad xmm7,DESCALE_P2
michael@0 615
michael@0 616 packssdw xmm1,xmm5 ; xmm1=data5
michael@0 617 packssdw xmm3,xmm7 ; xmm3=data3
michael@0 618
michael@0 619 movdqa XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)], xmm1
michael@0 620 movdqa XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)], xmm3
michael@0 621
michael@0 622 ; pop edi ; unused
michael@0 623 ; pop esi ; unused
michael@0 624 ; pop edx ; need not be preserved
michael@0 625 ; pop ecx ; unused
michael@0 626 poppic ebx
michael@0 627 mov esp,ebp ; esp <- aligned ebp
michael@0 628 pop esp ; esp <- original ebp
michael@0 629 pop ebp
michael@0 630 ret
michael@0 631
michael@0 632 ; For some reason, the OS X linker does not honor the request to align the
michael@0 633 ; segment unless we do this.
michael@0 634 align 16

Mercurial Repository: The Tor Browser

Europalab SCM Repository Server

mercurial