media/libjpeg/simd/jfsseflt-64.asm@b8a032363ba2 (annotated)
media/libjpeg/simd/jfsseflt-64.asm
Thu, 22 Jan 2015 13:21:57 +0100
- author
- Michael Schloh von Bennewitz <michael@schloh.com>
- date
- Thu, 22 Jan 2015 13:21:57 +0100
- branch
- TOR_BUG_9701
- changeset 15
- b8a032363ba2
- permissions
- -rw-r--r--
Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6
| michael@0 | 1 | ; |
| michael@0 | 2 | ; jfsseflt-64.asm - floating-point FDCT (64-bit SSE) |
| michael@0 | 3 | ; |
| michael@0 | 4 | ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB |
| michael@0 | 5 | ; Copyright 2009 D. R. Commander |
| michael@0 | 6 | ; |
| michael@0 | 7 | ; Based on |
| michael@0 | 8 | ; x86 SIMD extension for IJG JPEG library |
| michael@0 | 9 | ; Copyright (C) 1999-2006, MIYASAKA Masaru. |
| michael@0 | 10 | ; For conditions of distribution and use, see copyright notice in jsimdext.inc |
| michael@0 | 11 | ; |
| michael@0 | 12 | ; This file should be assembled with NASM (Netwide Assembler), |
| michael@0 | 13 | ; can *not* be assembled with Microsoft's MASM or any compatible |
| michael@0 | 14 | ; assembler (including Borland's Turbo Assembler). |
| michael@0 | 15 | ; NASM is available from http://nasm.sourceforge.net/ or |
| michael@0 | 16 | ; http://sourceforge.net/project/showfiles.php?group_id=6208 |
| michael@0 | 17 | ; |
| michael@0 | 18 | ; This file contains a floating-point implementation of the forward DCT |
| michael@0 | 19 | ; (Discrete Cosine Transform). The following code is based directly on |
| michael@0 | 20 | ; the IJG's original jfdctflt.c; see the jfdctflt.c for more details. |
| michael@0 | 21 | ; |
| michael@0 | 22 | ; [TAB8] |
| michael@0 | 23 | |
| michael@0 | 24 | %include "jsimdext.inc" |
| michael@0 | 25 | %include "jdct.inc" |
| michael@0 | 26 | |
| michael@0 | 27 | ; -------------------------------------------------------------------------- |
| michael@0 | 28 | |
| michael@0 | 29 | %macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5) |
| michael@0 | 30 | shufps %1,%2,0x44 |
| michael@0 | 31 | %endmacro |
| michael@0 | 32 | |
| michael@0 | 33 | %macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7) |
| michael@0 | 34 | shufps %1,%2,0xEE |
| michael@0 | 35 | %endmacro |
| michael@0 | 36 | |
| michael@0 | 37 | ; -------------------------------------------------------------------------- |
| michael@0 | 38 | SECTION SEG_CONST |
| michael@0 | 39 | |
| michael@0 | 40 | alignz 16 |
| michael@0 | 41 | global EXTN(jconst_fdct_float_sse) |
| michael@0 | 42 | |
| michael@0 | 43 | EXTN(jconst_fdct_float_sse): |
| michael@0 | 44 | |
| michael@0 | 45 | PD_0_382 times 4 dd 0.382683432365089771728460 |
| michael@0 | 46 | PD_0_707 times 4 dd 0.707106781186547524400844 |
| michael@0 | 47 | PD_0_541 times 4 dd 0.541196100146196984399723 |
| michael@0 | 48 | PD_1_306 times 4 dd 1.306562964876376527856643 |
| michael@0 | 49 | |
| michael@0 | 50 | alignz 16 |
| michael@0 | 51 | |
| michael@0 | 52 | ; -------------------------------------------------------------------------- |
| michael@0 | 53 | SECTION SEG_TEXT |
| michael@0 | 54 | BITS 64 |
| michael@0 | 55 | ; |
| michael@0 | 56 | ; Perform the forward DCT on one block of samples. |
| michael@0 | 57 | ; |
| michael@0 | 58 | ; GLOBAL(void) |
| michael@0 | 59 | ; jsimd_fdct_float_sse (FAST_FLOAT * data) |
| michael@0 | 60 | ; |
| michael@0 | 61 | |
| michael@0 | 62 | ; r10 = FAST_FLOAT * data |
| michael@0 | 63 | |
| michael@0 | 64 | %define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM] |
| michael@0 | 65 | %define WK_NUM 2 |
| michael@0 | 66 | |
| michael@0 | 67 | align 16 |
| michael@0 | 68 | global EXTN(jsimd_fdct_float_sse) |
| michael@0 | 69 | |
| michael@0 | 70 | EXTN(jsimd_fdct_float_sse): |
| michael@0 | 71 | push rbp |
| michael@0 | 72 | mov rax,rsp ; rax = original rbp |
| michael@0 | 73 | sub rsp, byte 4 |
| michael@0 | 74 | and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits |
| michael@0 | 75 | mov [rsp],rax |
| michael@0 | 76 | mov rbp,rsp ; rbp = aligned rbp |
| michael@0 | 77 | lea rsp, [wk(0)] |
| michael@0 | 78 | collect_args |
| michael@0 | 79 | |
| michael@0 | 80 | ; ---- Pass 1: process rows. |
| michael@0 | 81 | |
| michael@0 | 82 | mov rdx, r10 ; (FAST_FLOAT *) |
| michael@0 | 83 | mov rcx, DCTSIZE/4 |
| michael@0 | 84 | .rowloop: |
| michael@0 | 85 | |
| michael@0 | 86 | movaps xmm0, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 87 | movaps xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 88 | movaps xmm2, XMMWORD [XMMBLOCK(2,1,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 89 | movaps xmm3, XMMWORD [XMMBLOCK(3,1,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 90 | |
| michael@0 | 91 | ; xmm0=(20 21 22 23), xmm2=(24 25 26 27) |
| michael@0 | 92 | ; xmm1=(30 31 32 33), xmm3=(34 35 36 37) |
| michael@0 | 93 | |
| michael@0 | 94 | movaps xmm4,xmm0 ; transpose coefficients(phase 1) |
| michael@0 | 95 | unpcklps xmm0,xmm1 ; xmm0=(20 30 21 31) |
| michael@0 | 96 | unpckhps xmm4,xmm1 ; xmm4=(22 32 23 33) |
| michael@0 | 97 | movaps xmm5,xmm2 ; transpose coefficients(phase 1) |
| michael@0 | 98 | unpcklps xmm2,xmm3 ; xmm2=(24 34 25 35) |
| michael@0 | 99 | unpckhps xmm5,xmm3 ; xmm5=(26 36 27 37) |
| michael@0 | 100 | |
| michael@0 | 101 | movaps xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 102 | movaps xmm7, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 103 | movaps xmm1, XMMWORD [XMMBLOCK(0,1,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 104 | movaps xmm3, XMMWORD [XMMBLOCK(1,1,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 105 | |
| michael@0 | 106 | ; xmm6=(00 01 02 03), xmm1=(04 05 06 07) |
| michael@0 | 107 | ; xmm7=(10 11 12 13), xmm3=(14 15 16 17) |
| michael@0 | 108 | |
| michael@0 | 109 | movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 32 23 33) |
| michael@0 | 110 | movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(24 34 25 35) |
| michael@0 | 111 | |
| michael@0 | 112 | movaps xmm4,xmm6 ; transpose coefficients(phase 1) |
| michael@0 | 113 | unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11) |
| michael@0 | 114 | unpckhps xmm4,xmm7 ; xmm4=(02 12 03 13) |
| michael@0 | 115 | movaps xmm2,xmm1 ; transpose coefficients(phase 1) |
| michael@0 | 116 | unpcklps xmm1,xmm3 ; xmm1=(04 14 05 15) |
| michael@0 | 117 | unpckhps xmm2,xmm3 ; xmm2=(06 16 07 17) |
| michael@0 | 118 | |
| michael@0 | 119 | movaps xmm7,xmm6 ; transpose coefficients(phase 2) |
| michael@0 | 120 | unpcklps2 xmm6,xmm0 ; xmm6=(00 10 20 30)=data0 |
| michael@0 | 121 | unpckhps2 xmm7,xmm0 ; xmm7=(01 11 21 31)=data1 |
| michael@0 | 122 | movaps xmm3,xmm2 ; transpose coefficients(phase 2) |
| michael@0 | 123 | unpcklps2 xmm2,xmm5 ; xmm2=(06 16 26 36)=data6 |
| michael@0 | 124 | unpckhps2 xmm3,xmm5 ; xmm3=(07 17 27 37)=data7 |
| michael@0 | 125 | |
| michael@0 | 126 | movaps xmm0,xmm7 |
| michael@0 | 127 | movaps xmm5,xmm6 |
| michael@0 | 128 | subps xmm7,xmm2 ; xmm7=data1-data6=tmp6 |
| michael@0 | 129 | subps xmm6,xmm3 ; xmm6=data0-data7=tmp7 |
| michael@0 | 130 | addps xmm0,xmm2 ; xmm0=data1+data6=tmp1 |
| michael@0 | 131 | addps xmm5,xmm3 ; xmm5=data0+data7=tmp0 |
| michael@0 | 132 | |
| michael@0 | 133 | movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 32 23 33) |
| michael@0 | 134 | movaps xmm3, XMMWORD [wk(1)] ; xmm3=(24 34 25 35) |
| michael@0 | 135 | movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6 |
| michael@0 | 136 | movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7 |
| michael@0 | 137 | |
| michael@0 | 138 | movaps xmm7,xmm4 ; transpose coefficients(phase 2) |
| michael@0 | 139 | unpcklps2 xmm4,xmm2 ; xmm4=(02 12 22 32)=data2 |
| michael@0 | 140 | unpckhps2 xmm7,xmm2 ; xmm7=(03 13 23 33)=data3 |
| michael@0 | 141 | movaps xmm6,xmm1 ; transpose coefficients(phase 2) |
| michael@0 | 142 | unpcklps2 xmm1,xmm3 ; xmm1=(04 14 24 34)=data4 |
| michael@0 | 143 | unpckhps2 xmm6,xmm3 ; xmm6=(05 15 25 35)=data5 |
| michael@0 | 144 | |
| michael@0 | 145 | movaps xmm2,xmm7 |
| michael@0 | 146 | movaps xmm3,xmm4 |
| michael@0 | 147 | addps xmm7,xmm1 ; xmm7=data3+data4=tmp3 |
| michael@0 | 148 | addps xmm4,xmm6 ; xmm4=data2+data5=tmp2 |
| michael@0 | 149 | subps xmm2,xmm1 ; xmm2=data3-data4=tmp4 |
| michael@0 | 150 | subps xmm3,xmm6 ; xmm3=data2-data5=tmp5 |
| michael@0 | 151 | |
| michael@0 | 152 | ; -- Even part |
| michael@0 | 153 | |
| michael@0 | 154 | movaps xmm1,xmm5 |
| michael@0 | 155 | movaps xmm6,xmm0 |
| michael@0 | 156 | subps xmm5,xmm7 ; xmm5=tmp13 |
| michael@0 | 157 | subps xmm0,xmm4 ; xmm0=tmp12 |
| michael@0 | 158 | addps xmm1,xmm7 ; xmm1=tmp10 |
| michael@0 | 159 | addps xmm6,xmm4 ; xmm6=tmp11 |
| michael@0 | 160 | |
| michael@0 | 161 | addps xmm0,xmm5 |
| michael@0 | 162 | mulps xmm0,[rel PD_0_707] ; xmm0=z1 |
| michael@0 | 163 | |
| michael@0 | 164 | movaps xmm7,xmm1 |
| michael@0 | 165 | movaps xmm4,xmm5 |
| michael@0 | 166 | subps xmm1,xmm6 ; xmm1=data4 |
| michael@0 | 167 | subps xmm5,xmm0 ; xmm5=data6 |
| michael@0 | 168 | addps xmm7,xmm6 ; xmm7=data0 |
| michael@0 | 169 | addps xmm4,xmm0 ; xmm4=data2 |
| michael@0 | 170 | |
| michael@0 | 171 | movaps XMMWORD [XMMBLOCK(0,1,rdx,SIZEOF_FAST_FLOAT)], xmm1 |
| michael@0 | 172 | movaps XMMWORD [XMMBLOCK(2,1,rdx,SIZEOF_FAST_FLOAT)], xmm5 |
| michael@0 | 173 | movaps XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)], xmm7 |
| michael@0 | 174 | movaps XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)], xmm4 |
| michael@0 | 175 | |
| michael@0 | 176 | ; -- Odd part |
| michael@0 | 177 | |
| michael@0 | 178 | movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6 |
| michael@0 | 179 | movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7 |
| michael@0 | 180 | |
| michael@0 | 181 | addps xmm2,xmm3 ; xmm2=tmp10 |
| michael@0 | 182 | addps xmm3,xmm6 ; xmm3=tmp11 |
| michael@0 | 183 | addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7 |
| michael@0 | 184 | |
| michael@0 | 185 | mulps xmm3,[rel PD_0_707] ; xmm3=z3 |
| michael@0 | 186 | |
| michael@0 | 187 | movaps xmm1,xmm2 ; xmm1=tmp10 |
| michael@0 | 188 | subps xmm2,xmm6 |
| michael@0 | 189 | mulps xmm2,[rel PD_0_382] ; xmm2=z5 |
| michael@0 | 190 | mulps xmm1,[rel PD_0_541] ; xmm1=MULTIPLY(tmp10,FIX_0_541196) |
| michael@0 | 191 | mulps xmm6,[rel PD_1_306] ; xmm6=MULTIPLY(tmp12,FIX_1_306562) |
| michael@0 | 192 | addps xmm1,xmm2 ; xmm1=z2 |
| michael@0 | 193 | addps xmm6,xmm2 ; xmm6=z4 |
| michael@0 | 194 | |
| michael@0 | 195 | movaps xmm5,xmm0 |
| michael@0 | 196 | subps xmm0,xmm3 ; xmm0=z13 |
| michael@0 | 197 | addps xmm5,xmm3 ; xmm5=z11 |
| michael@0 | 198 | |
| michael@0 | 199 | movaps xmm7,xmm0 |
| michael@0 | 200 | movaps xmm4,xmm5 |
| michael@0 | 201 | subps xmm0,xmm1 ; xmm0=data3 |
| michael@0 | 202 | subps xmm5,xmm6 ; xmm5=data7 |
| michael@0 | 203 | addps xmm7,xmm1 ; xmm7=data5 |
| michael@0 | 204 | addps xmm4,xmm6 ; xmm4=data1 |
| michael@0 | 205 | |
| michael@0 | 206 | movaps XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)], xmm0 |
| michael@0 | 207 | movaps XMMWORD [XMMBLOCK(3,1,rdx,SIZEOF_FAST_FLOAT)], xmm5 |
| michael@0 | 208 | movaps XMMWORD [XMMBLOCK(1,1,rdx,SIZEOF_FAST_FLOAT)], xmm7 |
| michael@0 | 209 | movaps XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)], xmm4 |
| michael@0 | 210 | |
| michael@0 | 211 | add rdx, 4*DCTSIZE*SIZEOF_FAST_FLOAT |
| michael@0 | 212 | dec rcx |
| michael@0 | 213 | jnz near .rowloop |
| michael@0 | 214 | |
| michael@0 | 215 | ; ---- Pass 2: process columns. |
| michael@0 | 216 | |
| michael@0 | 217 | mov rdx, r10 ; (FAST_FLOAT *) |
| michael@0 | 218 | mov rcx, DCTSIZE/4 |
| michael@0 | 219 | .columnloop: |
| michael@0 | 220 | |
| michael@0 | 221 | movaps xmm0, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 222 | movaps xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 223 | movaps xmm2, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 224 | movaps xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 225 | |
| michael@0 | 226 | ; xmm0=(02 12 22 32), xmm2=(42 52 62 72) |
| michael@0 | 227 | ; xmm1=(03 13 23 33), xmm3=(43 53 63 73) |
| michael@0 | 228 | |
| michael@0 | 229 | movaps xmm4,xmm0 ; transpose coefficients(phase 1) |
| michael@0 | 230 | unpcklps xmm0,xmm1 ; xmm0=(02 03 12 13) |
| michael@0 | 231 | unpckhps xmm4,xmm1 ; xmm4=(22 23 32 33) |
| michael@0 | 232 | movaps xmm5,xmm2 ; transpose coefficients(phase 1) |
| michael@0 | 233 | unpcklps xmm2,xmm3 ; xmm2=(42 43 52 53) |
| michael@0 | 234 | unpckhps xmm5,xmm3 ; xmm5=(62 63 72 73) |
| michael@0 | 235 | |
| michael@0 | 236 | movaps xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 237 | movaps xmm7, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 238 | movaps xmm1, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 239 | movaps xmm3, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_FAST_FLOAT)] |
| michael@0 | 240 | |
| michael@0 | 241 | ; xmm6=(00 10 20 30), xmm1=(40 50 60 70) |
| michael@0 | 242 | ; xmm7=(01 11 21 31), xmm3=(41 51 61 71) |
| michael@0 | 243 | |
| michael@0 | 244 | movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 23 32 33) |
| michael@0 | 245 | movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(42 43 52 53) |
| michael@0 | 246 | |
| michael@0 | 247 | movaps xmm4,xmm6 ; transpose coefficients(phase 1) |
| michael@0 | 248 | unpcklps xmm6,xmm7 ; xmm6=(00 01 10 11) |
| michael@0 | 249 | unpckhps xmm4,xmm7 ; xmm4=(20 21 30 31) |
| michael@0 | 250 | movaps xmm2,xmm1 ; transpose coefficients(phase 1) |
| michael@0 | 251 | unpcklps xmm1,xmm3 ; xmm1=(40 41 50 51) |
| michael@0 | 252 | unpckhps xmm2,xmm3 ; xmm2=(60 61 70 71) |
| michael@0 | 253 | |
| michael@0 | 254 | movaps xmm7,xmm6 ; transpose coefficients(phase 2) |
| michael@0 | 255 | unpcklps2 xmm6,xmm0 ; xmm6=(00 01 02 03)=data0 |
| michael@0 | 256 | unpckhps2 xmm7,xmm0 ; xmm7=(10 11 12 13)=data1 |
| michael@0 | 257 | movaps xmm3,xmm2 ; transpose coefficients(phase 2) |
| michael@0 | 258 | unpcklps2 xmm2,xmm5 ; xmm2=(60 61 62 63)=data6 |
| michael@0 | 259 | unpckhps2 xmm3,xmm5 ; xmm3=(70 71 72 73)=data7 |
| michael@0 | 260 | |
| michael@0 | 261 | movaps xmm0,xmm7 |
| michael@0 | 262 | movaps xmm5,xmm6 |
| michael@0 | 263 | subps xmm7,xmm2 ; xmm7=data1-data6=tmp6 |
| michael@0 | 264 | subps xmm6,xmm3 ; xmm6=data0-data7=tmp7 |
| michael@0 | 265 | addps xmm0,xmm2 ; xmm0=data1+data6=tmp1 |
| michael@0 | 266 | addps xmm5,xmm3 ; xmm5=data0+data7=tmp0 |
| michael@0 | 267 | |
| michael@0 | 268 | movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 23 32 33) |
| michael@0 | 269 | movaps xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53) |
| michael@0 | 270 | movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6 |
| michael@0 | 271 | movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7 |
| michael@0 | 272 | |
| michael@0 | 273 | movaps xmm7,xmm4 ; transpose coefficients(phase 2) |
| michael@0 | 274 | unpcklps2 xmm4,xmm2 ; xmm4=(20 21 22 23)=data2 |
| michael@0 | 275 | unpckhps2 xmm7,xmm2 ; xmm7=(30 31 32 33)=data3 |
| michael@0 | 276 | movaps xmm6,xmm1 ; transpose coefficients(phase 2) |
| michael@0 | 277 | unpcklps2 xmm1,xmm3 ; xmm1=(40 41 42 43)=data4 |
| michael@0 | 278 | unpckhps2 xmm6,xmm3 ; xmm6=(50 51 52 53)=data5 |
| michael@0 | 279 | |
| michael@0 | 280 | movaps xmm2,xmm7 |
| michael@0 | 281 | movaps xmm3,xmm4 |
| michael@0 | 282 | addps xmm7,xmm1 ; xmm7=data3+data4=tmp3 |
| michael@0 | 283 | addps xmm4,xmm6 ; xmm4=data2+data5=tmp2 |
| michael@0 | 284 | subps xmm2,xmm1 ; xmm2=data3-data4=tmp4 |
| michael@0 | 285 | subps xmm3,xmm6 ; xmm3=data2-data5=tmp5 |
| michael@0 | 286 | |
| michael@0 | 287 | ; -- Even part |
| michael@0 | 288 | |
| michael@0 | 289 | movaps xmm1,xmm5 |
| michael@0 | 290 | movaps xmm6,xmm0 |
| michael@0 | 291 | subps xmm5,xmm7 ; xmm5=tmp13 |
| michael@0 | 292 | subps xmm0,xmm4 ; xmm0=tmp12 |
| michael@0 | 293 | addps xmm1,xmm7 ; xmm1=tmp10 |
| michael@0 | 294 | addps xmm6,xmm4 ; xmm6=tmp11 |
| michael@0 | 295 | |
| michael@0 | 296 | addps xmm0,xmm5 |
| michael@0 | 297 | mulps xmm0,[rel PD_0_707] ; xmm0=z1 |
| michael@0 | 298 | |
| michael@0 | 299 | movaps xmm7,xmm1 |
| michael@0 | 300 | movaps xmm4,xmm5 |
| michael@0 | 301 | subps xmm1,xmm6 ; xmm1=data4 |
| michael@0 | 302 | subps xmm5,xmm0 ; xmm5=data6 |
| michael@0 | 303 | addps xmm7,xmm6 ; xmm7=data0 |
| michael@0 | 304 | addps xmm4,xmm0 ; xmm4=data2 |
| michael@0 | 305 | |
| michael@0 | 306 | movaps XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_FAST_FLOAT)], xmm1 |
| michael@0 | 307 | movaps XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_FAST_FLOAT)], xmm5 |
| michael@0 | 308 | movaps XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)], xmm7 |
| michael@0 | 309 | movaps XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)], xmm4 |
| michael@0 | 310 | |
| michael@0 | 311 | ; -- Odd part |
| michael@0 | 312 | |
| michael@0 | 313 | movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6 |
| michael@0 | 314 | movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7 |
| michael@0 | 315 | |
| michael@0 | 316 | addps xmm2,xmm3 ; xmm2=tmp10 |
| michael@0 | 317 | addps xmm3,xmm6 ; xmm3=tmp11 |
| michael@0 | 318 | addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7 |
| michael@0 | 319 | |
| michael@0 | 320 | mulps xmm3,[rel PD_0_707] ; xmm3=z3 |
| michael@0 | 321 | |
| michael@0 | 322 | movaps xmm1,xmm2 ; xmm1=tmp10 |
| michael@0 | 323 | subps xmm2,xmm6 |
| michael@0 | 324 | mulps xmm2,[rel PD_0_382] ; xmm2=z5 |
| michael@0 | 325 | mulps xmm1,[rel PD_0_541] ; xmm1=MULTIPLY(tmp10,FIX_0_541196) |
| michael@0 | 326 | mulps xmm6,[rel PD_1_306] ; xmm6=MULTIPLY(tmp12,FIX_1_306562) |
| michael@0 | 327 | addps xmm1,xmm2 ; xmm1=z2 |
| michael@0 | 328 | addps xmm6,xmm2 ; xmm6=z4 |
| michael@0 | 329 | |
| michael@0 | 330 | movaps xmm5,xmm0 |
| michael@0 | 331 | subps xmm0,xmm3 ; xmm0=z13 |
| michael@0 | 332 | addps xmm5,xmm3 ; xmm5=z11 |
| michael@0 | 333 | |
| michael@0 | 334 | movaps xmm7,xmm0 |
| michael@0 | 335 | movaps xmm4,xmm5 |
| michael@0 | 336 | subps xmm0,xmm1 ; xmm0=data3 |
| michael@0 | 337 | subps xmm5,xmm6 ; xmm5=data7 |
| michael@0 | 338 | addps xmm7,xmm1 ; xmm7=data5 |
| michael@0 | 339 | addps xmm4,xmm6 ; xmm4=data1 |
| michael@0 | 340 | |
| michael@0 | 341 | movaps XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)], xmm0 |
| michael@0 | 342 | movaps XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_FAST_FLOAT)], xmm5 |
| michael@0 | 343 | movaps XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_FAST_FLOAT)], xmm7 |
| michael@0 | 344 | movaps XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)], xmm4 |
| michael@0 | 345 | |
| michael@0 | 346 | add rdx, byte 4*SIZEOF_FAST_FLOAT |
| michael@0 | 347 | dec rcx |
| michael@0 | 348 | jnz near .columnloop |
| michael@0 | 349 | |
| michael@0 | 350 | uncollect_args |
| michael@0 | 351 | mov rsp,rbp ; rsp <- aligned rbp |
| michael@0 | 352 | pop rsp ; rsp <- original rbp |
| michael@0 | 353 | pop rbp |
| michael@0 | 354 | ret |
| michael@0 | 355 | |
| michael@0 | 356 | ; For some reason, the OS X linker does not honor the request to align the |
| michael@0 | 357 | ; segment unless we do this. |
| michael@0 | 358 | align 16 |
