The Tor Browser / annotate

media/libjpeg/simd/jimmxred.asm@b8a032363ba2 (annotated)

media/libjpeg/simd/jimmxred.asm

Thu, 22 Jan 2015 13:21:57 +0100

author
Michael Schloh von Bennewitz <michael@schloh.com>
date
Thu, 22 Jan 2015 13:21:57 +0100
branch
TOR_BUG_9701
changeset 15
b8a032363ba2
permissions
-rw-r--r--

Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6

michael@0 1 ;
michael@0 2 ; jimmxred.asm - reduced-size IDCT (MMX)
michael@0 3 ;
michael@0 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0 5 ;
michael@0 6 ; Based on
michael@0 7 ; x86 SIMD extension for IJG JPEG library
michael@0 8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0 9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0 10 ;
michael@0 11 ; This file should be assembled with NASM (Netwide Assembler),
michael@0 12 ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0 13 ; assembler (including Borland's Turbo Assembler).
michael@0 14 ; NASM is available from http://nasm.sourceforge.net/ or
michael@0 15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0 16 ;
michael@0 17 ; This file contains inverse-DCT routines that produce reduced-size
michael@0 18 ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.
michael@0 19 ; The following code is based directly on the IJG's original jidctred.c;
michael@0 20 ; see the jidctred.c for more details.
michael@0 21 ;
michael@0 22 ; [TAB8]
michael@0 23
michael@0 24 %include "jsimdext.inc"
michael@0 25 %include "jdct.inc"
michael@0 26
michael@0 27 ; --------------------------------------------------------------------------
michael@0 28
michael@0 29 %define CONST_BITS 13
michael@0 30 %define PASS1_BITS 2
michael@0 31
michael@0 32 %define DESCALE_P1_4 (CONST_BITS-PASS1_BITS+1)
michael@0 33 %define DESCALE_P2_4 (CONST_BITS+PASS1_BITS+3+1)
michael@0 34 %define DESCALE_P1_2 (CONST_BITS-PASS1_BITS+2)
michael@0 35 %define DESCALE_P2_2 (CONST_BITS+PASS1_BITS+3+2)
michael@0 36
michael@0 37 %if CONST_BITS == 13
michael@0 38 F_0_211 equ 1730 ; FIX(0.211164243)
michael@0 39 F_0_509 equ 4176 ; FIX(0.509795579)
michael@0 40 F_0_601 equ 4926 ; FIX(0.601344887)
michael@0 41 F_0_720 equ 5906 ; FIX(0.720959822)
michael@0 42 F_0_765 equ 6270 ; FIX(0.765366865)
michael@0 43 F_0_850 equ 6967 ; FIX(0.850430095)
michael@0 44 F_0_899 equ 7373 ; FIX(0.899976223)
michael@0 45 F_1_061 equ 8697 ; FIX(1.061594337)
michael@0 46 F_1_272 equ 10426 ; FIX(1.272758580)
michael@0 47 F_1_451 equ 11893 ; FIX(1.451774981)
michael@0 48 F_1_847 equ 15137 ; FIX(1.847759065)
michael@0 49 F_2_172 equ 17799 ; FIX(2.172734803)
michael@0 50 F_2_562 equ 20995 ; FIX(2.562915447)
michael@0 51 F_3_624 equ 29692 ; FIX(3.624509785)
michael@0 52 %else
michael@0 53 ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0 54 %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
michael@0 55 F_0_211 equ DESCALE( 226735879,30-CONST_BITS) ; FIX(0.211164243)
michael@0 56 F_0_509 equ DESCALE( 547388834,30-CONST_BITS) ; FIX(0.509795579)
michael@0 57 F_0_601 equ DESCALE( 645689155,30-CONST_BITS) ; FIX(0.601344887)
michael@0 58 F_0_720 equ DESCALE( 774124714,30-CONST_BITS) ; FIX(0.720959822)
michael@0 59 F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)
michael@0 60 F_0_850 equ DESCALE( 913142361,30-CONST_BITS) ; FIX(0.850430095)
michael@0 61 F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)
michael@0 62 F_1_061 equ DESCALE(1139878239,30-CONST_BITS) ; FIX(1.061594337)
michael@0 63 F_1_272 equ DESCALE(1366614119,30-CONST_BITS) ; FIX(1.272758580)
michael@0 64 F_1_451 equ DESCALE(1558831516,30-CONST_BITS) ; FIX(1.451774981)
michael@0 65 F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
michael@0 66 F_2_172 equ DESCALE(2332956230,30-CONST_BITS) ; FIX(2.172734803)
michael@0 67 F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)
michael@0 68 F_3_624 equ DESCALE(3891787747,30-CONST_BITS) ; FIX(3.624509785)
michael@0 69 %endif
michael@0 70
michael@0 71 ; --------------------------------------------------------------------------
michael@0 72 SECTION SEG_CONST
michael@0 73
michael@0 74 alignz 16
michael@0 75 global EXTN(jconst_idct_red_mmx)
michael@0 76
michael@0 77 EXTN(jconst_idct_red_mmx):
michael@0 78
michael@0 79 PW_F184_MF076 times 2 dw F_1_847,-F_0_765
michael@0 80 PW_F256_F089 times 2 dw F_2_562, F_0_899
michael@0 81 PW_F106_MF217 times 2 dw F_1_061,-F_2_172
michael@0 82 PW_MF060_MF050 times 2 dw -F_0_601,-F_0_509
michael@0 83 PW_F145_MF021 times 2 dw F_1_451,-F_0_211
michael@0 84 PW_F362_MF127 times 2 dw F_3_624,-F_1_272
michael@0 85 PW_F085_MF072 times 2 dw F_0_850,-F_0_720
michael@0 86 PD_DESCALE_P1_4 times 2 dd 1 << (DESCALE_P1_4-1)
michael@0 87 PD_DESCALE_P2_4 times 2 dd 1 << (DESCALE_P2_4-1)
michael@0 88 PD_DESCALE_P1_2 times 2 dd 1 << (DESCALE_P1_2-1)
michael@0 89 PD_DESCALE_P2_2 times 2 dd 1 << (DESCALE_P2_2-1)
michael@0 90 PB_CENTERJSAMP times 8 db CENTERJSAMPLE
michael@0 91
michael@0 92 alignz 16
michael@0 93
michael@0 94 ; --------------------------------------------------------------------------
michael@0 95 SECTION SEG_TEXT
michael@0 96 BITS 32
michael@0 97 ;
michael@0 98 ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0 99 ; producing a reduced-size 4x4 output block.
michael@0 100 ;
michael@0 101 ; GLOBAL(void)
michael@0 102 ; jsimd_idct_4x4_mmx (void * dct_table, JCOEFPTR coef_block,
michael@0 103 ; JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0 104 ;
michael@0 105
michael@0 106 %define dct_table(b) (b)+8 ; void * dct_table
michael@0 107 %define coef_block(b) (b)+12 ; JCOEFPTR coef_block
michael@0 108 %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
michael@0 109 %define output_col(b) (b)+20 ; JDIMENSION output_col
michael@0 110
michael@0 111 %define original_ebp ebp+0
michael@0 112 %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
michael@0 113 %define WK_NUM 2
michael@0 114 %define workspace wk(0)-DCTSIZE2*SIZEOF_JCOEF
michael@0 115 ; JCOEF workspace[DCTSIZE2]
michael@0 116
michael@0 117 align 16
michael@0 118 global EXTN(jsimd_idct_4x4_mmx)
michael@0 119
michael@0 120 EXTN(jsimd_idct_4x4_mmx):
michael@0 121 push ebp
michael@0 122 mov eax,esp ; eax = original ebp
michael@0 123 sub esp, byte 4
michael@0 124 and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
michael@0 125 mov [esp],eax
michael@0 126 mov ebp,esp ; ebp = aligned ebp
michael@0 127 lea esp, [workspace]
michael@0 128 pushpic ebx
michael@0 129 ; push ecx ; need not be preserved
michael@0 130 ; push edx ; need not be preserved
michael@0 131 push esi
michael@0 132 push edi
michael@0 133
michael@0 134 get_GOT ebx ; get GOT address
michael@0 135
michael@0 136 ; ---- Pass 1: process columns from input, store into work array.
michael@0 137
michael@0 138 ; mov eax, [original_ebp]
michael@0 139 mov edx, POINTER [dct_table(eax)] ; quantptr
michael@0 140 mov esi, JCOEFPTR [coef_block(eax)] ; inptr
michael@0 141 lea edi, [workspace] ; JCOEF * wsptr
michael@0 142 mov ecx, DCTSIZE/4 ; ctr
michael@0 143 alignx 16,7
michael@0 144 .columnloop:
michael@0 145 %ifndef NO_ZERO_COLUMN_TEST_4X4_MMX
michael@0 146 mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 147 or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 148 jnz short .columnDCT
michael@0 149
michael@0 150 movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 151 movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 152 por mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 153 por mm1, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 154 por mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0 155 por mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 156 por mm0,mm1
michael@0 157 packsswb mm0,mm0
michael@0 158 movd eax,mm0
michael@0 159 test eax,eax
michael@0 160 jnz short .columnDCT
michael@0 161
michael@0 162 ; -- AC terms all zero
michael@0 163
michael@0 164 movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 165 pmullw mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 166
michael@0 167 psllw mm0,PASS1_BITS
michael@0 168
michael@0 169 movq mm2,mm0 ; mm0=in0=(00 01 02 03)
michael@0 170 punpcklwd mm0,mm0 ; mm0=(00 00 01 01)
michael@0 171 punpckhwd mm2,mm2 ; mm2=(02 02 03 03)
michael@0 172
michael@0 173 movq mm1,mm0
michael@0 174 punpckldq mm0,mm0 ; mm0=(00 00 00 00)
michael@0 175 punpckhdq mm1,mm1 ; mm1=(01 01 01 01)
michael@0 176 movq mm3,mm2
michael@0 177 punpckldq mm2,mm2 ; mm2=(02 02 02 02)
michael@0 178 punpckhdq mm3,mm3 ; mm3=(03 03 03 03)
michael@0 179
michael@0 180 movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0 181 movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1
michael@0 182 movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2
michael@0 183 movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
michael@0 184 jmp near .nextcolumn
michael@0 185 alignx 16,7
michael@0 186 %endif
michael@0 187 .columnDCT:
michael@0 188
michael@0 189 ; -- Odd part
michael@0 190
michael@0 191 movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 192 movq mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 193 pmullw mm0, MMWORD [MMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 194 pmullw mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 195 movq mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 196 movq mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 197 pmullw mm2, MMWORD [MMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 198 pmullw mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 199
michael@0 200 movq mm4,mm0
michael@0 201 movq mm5,mm0
michael@0 202 punpcklwd mm4,mm1
michael@0 203 punpckhwd mm5,mm1
michael@0 204 movq mm0,mm4
michael@0 205 movq mm1,mm5
michael@0 206 pmaddwd mm4,[GOTOFF(ebx,PW_F256_F089)] ; mm4=(tmp2L)
michael@0 207 pmaddwd mm5,[GOTOFF(ebx,PW_F256_F089)] ; mm5=(tmp2H)
michael@0 208 pmaddwd mm0,[GOTOFF(ebx,PW_F106_MF217)] ; mm0=(tmp0L)
michael@0 209 pmaddwd mm1,[GOTOFF(ebx,PW_F106_MF217)] ; mm1=(tmp0H)
michael@0 210
michael@0 211 movq mm6,mm2
michael@0 212 movq mm7,mm2
michael@0 213 punpcklwd mm6,mm3
michael@0 214 punpckhwd mm7,mm3
michael@0 215 movq mm2,mm6
michael@0 216 movq mm3,mm7
michael@0 217 pmaddwd mm6,[GOTOFF(ebx,PW_MF060_MF050)] ; mm6=(tmp2L)
michael@0 218 pmaddwd mm7,[GOTOFF(ebx,PW_MF060_MF050)] ; mm7=(tmp2H)
michael@0 219 pmaddwd mm2,[GOTOFF(ebx,PW_F145_MF021)] ; mm2=(tmp0L)
michael@0 220 pmaddwd mm3,[GOTOFF(ebx,PW_F145_MF021)] ; mm3=(tmp0H)
michael@0 221
michael@0 222 paddd mm6,mm4 ; mm6=tmp2L
michael@0 223 paddd mm7,mm5 ; mm7=tmp2H
michael@0 224 paddd mm2,mm0 ; mm2=tmp0L
michael@0 225 paddd mm3,mm1 ; mm3=tmp0H
michael@0 226
michael@0 227 movq MMWORD [wk(0)], mm2 ; wk(0)=tmp0L
michael@0 228 movq MMWORD [wk(1)], mm3 ; wk(1)=tmp0H
michael@0 229
michael@0 230 ; -- Even part
michael@0 231
michael@0 232 movq mm4, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 233 movq mm5, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 234 movq mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0 235 pmullw mm4, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 236 pmullw mm5, MMWORD [MMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 237 pmullw mm0, MMWORD [MMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 238
michael@0 239 pxor mm1,mm1
michael@0 240 pxor mm2,mm2
michael@0 241 punpcklwd mm1,mm4 ; mm1=tmp0L
michael@0 242 punpckhwd mm2,mm4 ; mm2=tmp0H
michael@0 243 psrad mm1,(16-CONST_BITS-1) ; psrad mm1,16 & pslld mm1,CONST_BITS+1
michael@0 244 psrad mm2,(16-CONST_BITS-1) ; psrad mm2,16 & pslld mm2,CONST_BITS+1
michael@0 245
michael@0 246 movq mm3,mm5 ; mm5=in2=z2
michael@0 247 punpcklwd mm5,mm0 ; mm0=in6=z3
michael@0 248 punpckhwd mm3,mm0
michael@0 249 pmaddwd mm5,[GOTOFF(ebx,PW_F184_MF076)] ; mm5=tmp2L
michael@0 250 pmaddwd mm3,[GOTOFF(ebx,PW_F184_MF076)] ; mm3=tmp2H
michael@0 251
michael@0 252 movq mm4,mm1
michael@0 253 movq mm0,mm2
michael@0 254 paddd mm1,mm5 ; mm1=tmp10L
michael@0 255 paddd mm2,mm3 ; mm2=tmp10H
michael@0 256 psubd mm4,mm5 ; mm4=tmp12L
michael@0 257 psubd mm0,mm3 ; mm0=tmp12H
michael@0 258
michael@0 259 ; -- Final output stage
michael@0 260
michael@0 261 movq mm5,mm1
michael@0 262 movq mm3,mm2
michael@0 263 paddd mm1,mm6 ; mm1=data0L
michael@0 264 paddd mm2,mm7 ; mm2=data0H
michael@0 265 psubd mm5,mm6 ; mm5=data3L
michael@0 266 psubd mm3,mm7 ; mm3=data3H
michael@0 267
michael@0 268 movq mm6,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; mm6=[PD_DESCALE_P1_4]
michael@0 269
michael@0 270 paddd mm1,mm6
michael@0 271 paddd mm2,mm6
michael@0 272 psrad mm1,DESCALE_P1_4
michael@0 273 psrad mm2,DESCALE_P1_4
michael@0 274 paddd mm5,mm6
michael@0 275 paddd mm3,mm6
michael@0 276 psrad mm5,DESCALE_P1_4
michael@0 277 psrad mm3,DESCALE_P1_4
michael@0 278
michael@0 279 packssdw mm1,mm2 ; mm1=data0=(00 01 02 03)
michael@0 280 packssdw mm5,mm3 ; mm5=data3=(30 31 32 33)
michael@0 281
michael@0 282 movq mm7, MMWORD [wk(0)] ; mm7=tmp0L
michael@0 283 movq mm6, MMWORD [wk(1)] ; mm6=tmp0H
michael@0 284
michael@0 285 movq mm2,mm4
michael@0 286 movq mm3,mm0
michael@0 287 paddd mm4,mm7 ; mm4=data1L
michael@0 288 paddd mm0,mm6 ; mm0=data1H
michael@0 289 psubd mm2,mm7 ; mm2=data2L
michael@0 290 psubd mm3,mm6 ; mm3=data2H
michael@0 291
michael@0 292 movq mm7,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; mm7=[PD_DESCALE_P1_4]
michael@0 293
michael@0 294 paddd mm4,mm7
michael@0 295 paddd mm0,mm7
michael@0 296 psrad mm4,DESCALE_P1_4
michael@0 297 psrad mm0,DESCALE_P1_4
michael@0 298 paddd mm2,mm7
michael@0 299 paddd mm3,mm7
michael@0 300 psrad mm2,DESCALE_P1_4
michael@0 301 psrad mm3,DESCALE_P1_4
michael@0 302
michael@0 303 packssdw mm4,mm0 ; mm4=data1=(10 11 12 13)
michael@0 304 packssdw mm2,mm3 ; mm2=data2=(20 21 22 23)
michael@0 305
michael@0 306 movq mm6,mm1 ; transpose coefficients(phase 1)
michael@0 307 punpcklwd mm1,mm4 ; mm1=(00 10 01 11)
michael@0 308 punpckhwd mm6,mm4 ; mm6=(02 12 03 13)
michael@0 309 movq mm7,mm2 ; transpose coefficients(phase 1)
michael@0 310 punpcklwd mm2,mm5 ; mm2=(20 30 21 31)
michael@0 311 punpckhwd mm7,mm5 ; mm7=(22 32 23 33)
michael@0 312
michael@0 313 movq mm0,mm1 ; transpose coefficients(phase 2)
michael@0 314 punpckldq mm1,mm2 ; mm1=(00 10 20 30)
michael@0 315 punpckhdq mm0,mm2 ; mm0=(01 11 21 31)
michael@0 316 movq mm3,mm6 ; transpose coefficients(phase 2)
michael@0 317 punpckldq mm6,mm7 ; mm6=(02 12 22 32)
michael@0 318 punpckhdq mm3,mm7 ; mm3=(03 13 23 33)
michael@0 319
michael@0 320 movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm1
michael@0 321 movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm0
michael@0 322 movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm6
michael@0 323 movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
michael@0 324
michael@0 325 .nextcolumn:
michael@0 326 add esi, byte 4*SIZEOF_JCOEF ; coef_block
michael@0 327 add edx, byte 4*SIZEOF_ISLOW_MULT_TYPE ; quantptr
michael@0 328 add edi, byte 4*DCTSIZE*SIZEOF_JCOEF ; wsptr
michael@0 329 dec ecx ; ctr
michael@0 330 jnz near .columnloop
michael@0 331
michael@0 332 ; ---- Pass 2: process rows from work array, store into output array.
michael@0 333
michael@0 334 mov eax, [original_ebp]
michael@0 335 lea esi, [workspace] ; JCOEF * wsptr
michael@0 336 mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
michael@0 337 mov eax, JDIMENSION [output_col(eax)]
michael@0 338
michael@0 339 ; -- Odd part
michael@0 340
michael@0 341 movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 342 movq mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 343 movq mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 344 movq mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 345
michael@0 346 movq mm4,mm0
michael@0 347 movq mm5,mm0
michael@0 348 punpcklwd mm4,mm1
michael@0 349 punpckhwd mm5,mm1
michael@0 350 movq mm0,mm4
michael@0 351 movq mm1,mm5
michael@0 352 pmaddwd mm4,[GOTOFF(ebx,PW_F256_F089)] ; mm4=(tmp2L)
michael@0 353 pmaddwd mm5,[GOTOFF(ebx,PW_F256_F089)] ; mm5=(tmp2H)
michael@0 354 pmaddwd mm0,[GOTOFF(ebx,PW_F106_MF217)] ; mm0=(tmp0L)
michael@0 355 pmaddwd mm1,[GOTOFF(ebx,PW_F106_MF217)] ; mm1=(tmp0H)
michael@0 356
michael@0 357 movq mm6,mm2
michael@0 358 movq mm7,mm2
michael@0 359 punpcklwd mm6,mm3
michael@0 360 punpckhwd mm7,mm3
michael@0 361 movq mm2,mm6
michael@0 362 movq mm3,mm7
michael@0 363 pmaddwd mm6,[GOTOFF(ebx,PW_MF060_MF050)] ; mm6=(tmp2L)
michael@0 364 pmaddwd mm7,[GOTOFF(ebx,PW_MF060_MF050)] ; mm7=(tmp2H)
michael@0 365 pmaddwd mm2,[GOTOFF(ebx,PW_F145_MF021)] ; mm2=(tmp0L)
michael@0 366 pmaddwd mm3,[GOTOFF(ebx,PW_F145_MF021)] ; mm3=(tmp0H)
michael@0 367
michael@0 368 paddd mm6,mm4 ; mm6=tmp2L
michael@0 369 paddd mm7,mm5 ; mm7=tmp2H
michael@0 370 paddd mm2,mm0 ; mm2=tmp0L
michael@0 371 paddd mm3,mm1 ; mm3=tmp0H
michael@0 372
michael@0 373 movq MMWORD [wk(0)], mm2 ; wk(0)=tmp0L
michael@0 374 movq MMWORD [wk(1)], mm3 ; wk(1)=tmp0H
michael@0 375
michael@0 376 ; -- Even part
michael@0 377
michael@0 378 movq mm4, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 379 movq mm5, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 380 movq mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0 381
michael@0 382 pxor mm1,mm1
michael@0 383 pxor mm2,mm2
michael@0 384 punpcklwd mm1,mm4 ; mm1=tmp0L
michael@0 385 punpckhwd mm2,mm4 ; mm2=tmp0H
michael@0 386 psrad mm1,(16-CONST_BITS-1) ; psrad mm1,16 & pslld mm1,CONST_BITS+1
michael@0 387 psrad mm2,(16-CONST_BITS-1) ; psrad mm2,16 & pslld mm2,CONST_BITS+1
michael@0 388
michael@0 389 movq mm3,mm5 ; mm5=in2=z2
michael@0 390 punpcklwd mm5,mm0 ; mm0=in6=z3
michael@0 391 punpckhwd mm3,mm0
michael@0 392 pmaddwd mm5,[GOTOFF(ebx,PW_F184_MF076)] ; mm5=tmp2L
michael@0 393 pmaddwd mm3,[GOTOFF(ebx,PW_F184_MF076)] ; mm3=tmp2H
michael@0 394
michael@0 395 movq mm4,mm1
michael@0 396 movq mm0,mm2
michael@0 397 paddd mm1,mm5 ; mm1=tmp10L
michael@0 398 paddd mm2,mm3 ; mm2=tmp10H
michael@0 399 psubd mm4,mm5 ; mm4=tmp12L
michael@0 400 psubd mm0,mm3 ; mm0=tmp12H
michael@0 401
michael@0 402 ; -- Final output stage
michael@0 403
michael@0 404 movq mm5,mm1
michael@0 405 movq mm3,mm2
michael@0 406 paddd mm1,mm6 ; mm1=data0L
michael@0 407 paddd mm2,mm7 ; mm2=data0H
michael@0 408 psubd mm5,mm6 ; mm5=data3L
michael@0 409 psubd mm3,mm7 ; mm3=data3H
michael@0 410
michael@0 411 movq mm6,[GOTOFF(ebx,PD_DESCALE_P2_4)] ; mm6=[PD_DESCALE_P2_4]
michael@0 412
michael@0 413 paddd mm1,mm6
michael@0 414 paddd mm2,mm6
michael@0 415 psrad mm1,DESCALE_P2_4
michael@0 416 psrad mm2,DESCALE_P2_4
michael@0 417 paddd mm5,mm6
michael@0 418 paddd mm3,mm6
michael@0 419 psrad mm5,DESCALE_P2_4
michael@0 420 psrad mm3,DESCALE_P2_4
michael@0 421
michael@0 422 packssdw mm1,mm2 ; mm1=data0=(00 10 20 30)
michael@0 423 packssdw mm5,mm3 ; mm5=data3=(03 13 23 33)
michael@0 424
michael@0 425 movq mm7, MMWORD [wk(0)] ; mm7=tmp0L
michael@0 426 movq mm6, MMWORD [wk(1)] ; mm6=tmp0H
michael@0 427
michael@0 428 movq mm2,mm4
michael@0 429 movq mm3,mm0
michael@0 430 paddd mm4,mm7 ; mm4=data1L
michael@0 431 paddd mm0,mm6 ; mm0=data1H
michael@0 432 psubd mm2,mm7 ; mm2=data2L
michael@0 433 psubd mm3,mm6 ; mm3=data2H
michael@0 434
michael@0 435 movq mm7,[GOTOFF(ebx,PD_DESCALE_P2_4)] ; mm7=[PD_DESCALE_P2_4]
michael@0 436
michael@0 437 paddd mm4,mm7
michael@0 438 paddd mm0,mm7
michael@0 439 psrad mm4,DESCALE_P2_4
michael@0 440 psrad mm0,DESCALE_P2_4
michael@0 441 paddd mm2,mm7
michael@0 442 paddd mm3,mm7
michael@0 443 psrad mm2,DESCALE_P2_4
michael@0 444 psrad mm3,DESCALE_P2_4
michael@0 445
michael@0 446 packssdw mm4,mm0 ; mm4=data1=(01 11 21 31)
michael@0 447 packssdw mm2,mm3 ; mm2=data2=(02 12 22 32)
michael@0 448
michael@0 449 movq mm6,[GOTOFF(ebx,PB_CENTERJSAMP)] ; mm6=[PB_CENTERJSAMP]
michael@0 450
michael@0 451 packsswb mm1,mm2 ; mm1=(00 10 20 30 02 12 22 32)
michael@0 452 packsswb mm4,mm5 ; mm4=(01 11 21 31 03 13 23 33)
michael@0 453 paddb mm1,mm6
michael@0 454 paddb mm4,mm6
michael@0 455
michael@0 456 movq mm7,mm1 ; transpose coefficients(phase 1)
michael@0 457 punpcklbw mm1,mm4 ; mm1=(00 01 10 11 20 21 30 31)
michael@0 458 punpckhbw mm7,mm4 ; mm7=(02 03 12 13 22 23 32 33)
michael@0 459
michael@0 460 movq mm0,mm1 ; transpose coefficients(phase 2)
michael@0 461 punpcklwd mm1,mm7 ; mm1=(00 01 02 03 10 11 12 13)
michael@0 462 punpckhwd mm0,mm7 ; mm0=(20 21 22 23 30 31 32 33)
michael@0 463
michael@0 464 mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0 465 mov esi, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
michael@0 466 movd DWORD [edx+eax*SIZEOF_JSAMPLE], mm1
michael@0 467 movd DWORD [esi+eax*SIZEOF_JSAMPLE], mm0
michael@0 468
michael@0 469 psrlq mm1,4*BYTE_BIT
michael@0 470 psrlq mm0,4*BYTE_BIT
michael@0 471
michael@0 472 mov edx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0 473 mov esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
michael@0 474 movd DWORD [edx+eax*SIZEOF_JSAMPLE], mm1
michael@0 475 movd DWORD [esi+eax*SIZEOF_JSAMPLE], mm0
michael@0 476
michael@0 477 emms ; empty MMX state
michael@0 478
michael@0 479 pop edi
michael@0 480 pop esi
michael@0 481 ; pop edx ; need not be preserved
michael@0 482 ; pop ecx ; need not be preserved
michael@0 483 poppic ebx
michael@0 484 mov esp,ebp ; esp <- aligned ebp
michael@0 485 pop esp ; esp <- original ebp
michael@0 486 pop ebp
michael@0 487 ret
michael@0 488
michael@0 489
michael@0 490 ; --------------------------------------------------------------------------
michael@0 491 ;
michael@0 492 ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0 493 ; producing a reduced-size 2x2 output block.
michael@0 494 ;
michael@0 495 ; GLOBAL(void)
michael@0 496 ; jsimd_idct_2x2_mmx (void * dct_table, JCOEFPTR coef_block,
michael@0 497 ; JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0 498 ;
michael@0 499
michael@0 500 %define dct_table(b) (b)+8 ; void * dct_table
michael@0 501 %define coef_block(b) (b)+12 ; JCOEFPTR coef_block
michael@0 502 %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
michael@0 503 %define output_col(b) (b)+20 ; JDIMENSION output_col
michael@0 504
michael@0 505 align 16
michael@0 506 global EXTN(jsimd_idct_2x2_mmx)
michael@0 507
michael@0 508 EXTN(jsimd_idct_2x2_mmx):
michael@0 509 push ebp
michael@0 510 mov ebp,esp
michael@0 511 push ebx
michael@0 512 ; push ecx ; need not be preserved
michael@0 513 ; push edx ; need not be preserved
michael@0 514 push esi
michael@0 515 push edi
michael@0 516
michael@0 517 get_GOT ebx ; get GOT address
michael@0 518
michael@0 519 ; ---- Pass 1: process columns from input.
michael@0 520
michael@0 521 mov edx, POINTER [dct_table(ebp)] ; quantptr
michael@0 522 mov esi, JCOEFPTR [coef_block(ebp)] ; inptr
michael@0 523
michael@0 524 ; | input: | result: |
michael@0 525 ; | 00 01 ** 03 ** 05 ** 07 | |
michael@0 526 ; | 10 11 ** 13 ** 15 ** 17 | |
michael@0 527 ; | ** ** ** ** ** ** ** ** | |
michael@0 528 ; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 |
michael@0 529 ; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 |
michael@0 530 ; | 50 51 ** 53 ** 55 ** 57 | |
michael@0 531 ; | ** ** ** ** ** ** ** ** | |
michael@0 532 ; | 70 71 ** 73 ** 75 ** 77 | |
michael@0 533
michael@0 534 ; -- Odd part
michael@0 535
michael@0 536 movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 537 movq mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 538 pmullw mm0, MMWORD [MMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 539 pmullw mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 540 movq mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 541 movq mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 542 pmullw mm2, MMWORD [MMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 543 pmullw mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 544
michael@0 545 ; mm0=(10 11 ** 13), mm1=(30 31 ** 33)
michael@0 546 ; mm2=(50 51 ** 53), mm3=(70 71 ** 73)
michael@0 547
michael@0 548 pcmpeqd mm7,mm7
michael@0 549 pslld mm7,WORD_BIT ; mm7={0x0000 0xFFFF 0x0000 0xFFFF}
michael@0 550
michael@0 551 movq mm4,mm0 ; mm4=(10 11 ** 13)
michael@0 552 movq mm5,mm2 ; mm5=(50 51 ** 53)
michael@0 553 punpcklwd mm4,mm1 ; mm4=(10 30 11 31)
michael@0 554 punpcklwd mm5,mm3 ; mm5=(50 70 51 71)
michael@0 555 pmaddwd mm4,[GOTOFF(ebx,PW_F362_MF127)]
michael@0 556 pmaddwd mm5,[GOTOFF(ebx,PW_F085_MF072)]
michael@0 557
michael@0 558 psrld mm0,WORD_BIT ; mm0=(11 -- 13 --)
michael@0 559 pand mm1,mm7 ; mm1=(-- 31 -- 33)
michael@0 560 psrld mm2,WORD_BIT ; mm2=(51 -- 53 --)
michael@0 561 pand mm3,mm7 ; mm3=(-- 71 -- 73)
michael@0 562 por mm0,mm1 ; mm0=(11 31 13 33)
michael@0 563 por mm2,mm3 ; mm2=(51 71 53 73)
michael@0 564 pmaddwd mm0,[GOTOFF(ebx,PW_F362_MF127)]
michael@0 565 pmaddwd mm2,[GOTOFF(ebx,PW_F085_MF072)]
michael@0 566
michael@0 567 paddd mm4,mm5 ; mm4=tmp0[col0 col1]
michael@0 568
michael@0 569 movq mm6, MMWORD [MMBLOCK(1,1,esi,SIZEOF_JCOEF)]
michael@0 570 movq mm1, MMWORD [MMBLOCK(3,1,esi,SIZEOF_JCOEF)]
michael@0 571 pmullw mm6, MMWORD [MMBLOCK(1,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 572 pmullw mm1, MMWORD [MMBLOCK(3,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 573 movq mm3, MMWORD [MMBLOCK(5,1,esi,SIZEOF_JCOEF)]
michael@0 574 movq mm5, MMWORD [MMBLOCK(7,1,esi,SIZEOF_JCOEF)]
michael@0 575 pmullw mm3, MMWORD [MMBLOCK(5,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 576 pmullw mm5, MMWORD [MMBLOCK(7,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 577
michael@0 578 ; mm6=(** 15 ** 17), mm1=(** 35 ** 37)
michael@0 579 ; mm3=(** 55 ** 57), mm5=(** 75 ** 77)
michael@0 580
michael@0 581 psrld mm6,WORD_BIT ; mm6=(15 -- 17 --)
michael@0 582 pand mm1,mm7 ; mm1=(-- 35 -- 37)
michael@0 583 psrld mm3,WORD_BIT ; mm3=(55 -- 57 --)
michael@0 584 pand mm5,mm7 ; mm5=(-- 75 -- 77)
michael@0 585 por mm6,mm1 ; mm6=(15 35 17 37)
michael@0 586 por mm3,mm5 ; mm3=(55 75 57 77)
michael@0 587 pmaddwd mm6,[GOTOFF(ebx,PW_F362_MF127)]
michael@0 588 pmaddwd mm3,[GOTOFF(ebx,PW_F085_MF072)]
michael@0 589
michael@0 590 paddd mm0,mm2 ; mm0=tmp0[col1 col3]
michael@0 591 paddd mm6,mm3 ; mm6=tmp0[col5 col7]
michael@0 592
michael@0 593 ; -- Even part
michael@0 594
michael@0 595 movq mm1, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 596 movq mm5, MMWORD [MMBLOCK(0,1,esi,SIZEOF_JCOEF)]
michael@0 597 pmullw mm1, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 598 pmullw mm5, MMWORD [MMBLOCK(0,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0 599
michael@0 600 ; mm1=(00 01 ** 03), mm5=(** 05 ** 07)
michael@0 601
michael@0 602 movq mm2,mm1 ; mm2=(00 01 ** 03)
michael@0 603 pslld mm1,WORD_BIT ; mm1=(-- 00 -- **)
michael@0 604 psrad mm1,(WORD_BIT-CONST_BITS-2) ; mm1=tmp10[col0 ****]
michael@0 605
michael@0 606 pand mm2,mm7 ; mm2=(-- 01 -- 03)
michael@0 607 pand mm5,mm7 ; mm5=(-- 05 -- 07)
michael@0 608 psrad mm2,(WORD_BIT-CONST_BITS-2) ; mm2=tmp10[col1 col3]
michael@0 609 psrad mm5,(WORD_BIT-CONST_BITS-2) ; mm5=tmp10[col5 col7]
michael@0 610
michael@0 611 ; -- Final output stage
michael@0 612
michael@0 613 movq mm3,mm1
michael@0 614 paddd mm1,mm4 ; mm1=data0[col0 ****]=(A0 **)
michael@0 615 psubd mm3,mm4 ; mm3=data1[col0 ****]=(B0 **)
michael@0 616 punpckldq mm1,mm3 ; mm1=(A0 B0)
michael@0 617
michael@0 618 movq mm7,[GOTOFF(ebx,PD_DESCALE_P1_2)] ; mm7=[PD_DESCALE_P1_2]
michael@0 619
michael@0 620 movq mm4,mm2
michael@0 621 movq mm3,mm5
michael@0 622 paddd mm2,mm0 ; mm2=data0[col1 col3]=(A1 A3)
michael@0 623 paddd mm5,mm6 ; mm5=data0[col5 col7]=(A5 A7)
michael@0 624 psubd mm4,mm0 ; mm4=data1[col1 col3]=(B1 B3)
michael@0 625 psubd mm3,mm6 ; mm3=data1[col5 col7]=(B5 B7)
michael@0 626
michael@0 627 paddd mm1,mm7
michael@0 628 psrad mm1,DESCALE_P1_2
michael@0 629
michael@0 630 paddd mm2,mm7
michael@0 631 paddd mm5,mm7
michael@0 632 psrad mm2,DESCALE_P1_2
michael@0 633 psrad mm5,DESCALE_P1_2
michael@0 634 paddd mm4,mm7
michael@0 635 paddd mm3,mm7
michael@0 636 psrad mm4,DESCALE_P1_2
michael@0 637 psrad mm3,DESCALE_P1_2
michael@0 638
michael@0 639 ; ---- Pass 2: process rows, store into output array.
michael@0 640
michael@0 641 mov edi, JSAMPARRAY [output_buf(ebp)] ; (JSAMPROW *)
michael@0 642 mov eax, JDIMENSION [output_col(ebp)]
michael@0 643
michael@0 644 ; | input:| result:|
michael@0 645 ; | A0 B0 | |
michael@0 646 ; | A1 B1 | C0 C1 |
michael@0 647 ; | A3 B3 | D0 D1 |
michael@0 648 ; | A5 B5 | |
michael@0 649 ; | A7 B7 | |
michael@0 650
michael@0 651 ; -- Odd part
michael@0 652
michael@0 653 packssdw mm2,mm4 ; mm2=(A1 A3 B1 B3)
michael@0 654 packssdw mm5,mm3 ; mm5=(A5 A7 B5 B7)
michael@0 655 pmaddwd mm2,[GOTOFF(ebx,PW_F362_MF127)]
michael@0 656 pmaddwd mm5,[GOTOFF(ebx,PW_F085_MF072)]
michael@0 657
michael@0 658 paddd mm2,mm5 ; mm2=tmp0[row0 row1]
michael@0 659
michael@0 660 ; -- Even part
michael@0 661
michael@0 662 pslld mm1,(CONST_BITS+2) ; mm1=tmp10[row0 row1]
michael@0 663
michael@0 664 ; -- Final output stage
michael@0 665
michael@0 666 movq mm0,[GOTOFF(ebx,PD_DESCALE_P2_2)] ; mm0=[PD_DESCALE_P2_2]
michael@0 667
michael@0 668 movq mm6,mm1
michael@0 669 paddd mm1,mm2 ; mm1=data0[row0 row1]=(C0 C1)
michael@0 670 psubd mm6,mm2 ; mm6=data1[row0 row1]=(D0 D1)
michael@0 671
michael@0 672 paddd mm1,mm0
michael@0 673 paddd mm6,mm0
michael@0 674 psrad mm1,DESCALE_P2_2
michael@0 675 psrad mm6,DESCALE_P2_2
michael@0 676
michael@0 677 movq mm7,mm1 ; transpose coefficients
michael@0 678 punpckldq mm1,mm6 ; mm1=(C0 D0)
michael@0 679 punpckhdq mm7,mm6 ; mm7=(C1 D1)
michael@0 680
michael@0 681 packssdw mm1,mm7 ; mm1=(C0 D0 C1 D1)
michael@0 682 packsswb mm1,mm1 ; mm1=(C0 D0 C1 D1 C0 D0 C1 D1)
michael@0 683 paddb mm1,[GOTOFF(ebx,PB_CENTERJSAMP)]
michael@0 684
michael@0 685 movd ecx,mm1
michael@0 686 movd ebx,mm1 ; ebx=(C0 D0 C1 D1)
michael@0 687 shr ecx,2*BYTE_BIT ; ecx=(C1 D1 -- --)
michael@0 688
michael@0 689 mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0 690 mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0 691 mov WORD [edx+eax*SIZEOF_JSAMPLE], bx
michael@0 692 mov WORD [esi+eax*SIZEOF_JSAMPLE], cx
michael@0 693
michael@0 694 emms ; empty MMX state
michael@0 695
michael@0 696 pop edi
michael@0 697 pop esi
michael@0 698 ; pop edx ; need not be preserved
michael@0 699 ; pop ecx ; need not be preserved
michael@0 700 pop ebx
michael@0 701 pop ebp
michael@0 702 ret
michael@0 703
michael@0 704 ; For some reason, the OS X linker does not honor the request to align the
michael@0 705 ; segment unless we do this.
michael@0 706 align 16

Mercurial Repository: The Tor Browser

Europalab SCM Repository Server

mercurial