1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jcclrss2-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,485 @@
1.4 +;
1.5 +; jcclrss2-64.asm - colorspace conversion (64-bit SSE2)
1.6 +;
1.7 +; x86 SIMD extension for IJG JPEG library
1.8 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.9 +; Copyright (C) 2009, D. R. Commander.
1.10 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.11 +;
1.12 +; This file should be assembled with NASM (Netwide Assembler),
1.13 +; can *not* be assembled with Microsoft's MASM or any compatible
1.14 +; assembler (including Borland's Turbo Assembler).
1.15 +; NASM is available from http://nasm.sourceforge.net/ or
1.16 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.17 +;
1.18 +; [TAB8]
1.19 +
1.20 +%include "jcolsamp.inc"
1.21 +
1.22 +; --------------------------------------------------------------------------
1.23 +;
1.24 +; Convert some rows of samples to the output colorspace.
1.25 +;
1.26 +; GLOBAL(void)
1.27 +; jsimd_rgb_ycc_convert_sse2 (JDIMENSION img_width,
1.28 +; JSAMPARRAY input_buf, JSAMPIMAGE output_buf,
1.29 +; JDIMENSION output_row, int num_rows);
1.30 +;
1.31 +
1.32 +; r10 = JDIMENSION img_width
1.33 +; r11 = JSAMPARRAY input_buf
1.34 +; r12 = JSAMPIMAGE output_buf
1.35 +; r13 = JDIMENSION output_row
1.36 +; r14 = int num_rows
1.37 +
1.38 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.39 +%define WK_NUM 8
1.40 +
1.41 + align 16
1.42 +
1.43 + global EXTN(jsimd_rgb_ycc_convert_sse2)
1.44 +
1.45 +EXTN(jsimd_rgb_ycc_convert_sse2):
1.46 + push rbp
1.47 + mov rax,rsp ; rax = original rbp
1.48 + sub rsp, byte 4
1.49 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.50 + mov [rsp],rax
1.51 + mov rbp,rsp ; rbp = aligned rbp
1.52 + lea rsp, [wk(0)]
1.53 + collect_args
1.54 + push rbx
1.55 +
1.56 + mov rcx, r10
1.57 + test rcx,rcx
1.58 + jz near .return
1.59 +
1.60 + push rcx
1.61 +
1.62 + mov rsi, r12
1.63 + mov rcx, r13
1.64 + mov rdi, JSAMPARRAY [rsi+0*SIZEOF_JSAMPARRAY]
1.65 + mov rbx, JSAMPARRAY [rsi+1*SIZEOF_JSAMPARRAY]
1.66 + mov rdx, JSAMPARRAY [rsi+2*SIZEOF_JSAMPARRAY]
1.67 + lea rdi, [rdi+rcx*SIZEOF_JSAMPROW]
1.68 + lea rbx, [rbx+rcx*SIZEOF_JSAMPROW]
1.69 + lea rdx, [rdx+rcx*SIZEOF_JSAMPROW]
1.70 +
1.71 + pop rcx
1.72 +
1.73 + mov rsi, r11
1.74 + mov eax, r14d
1.75 + test rax,rax
1.76 + jle near .return
1.77 +.rowloop:
1.78 + push rdx
1.79 + push rbx
1.80 + push rdi
1.81 + push rsi
1.82 + push rcx ; col
1.83 +
1.84 + mov rsi, JSAMPROW [rsi] ; inptr
1.85 + mov rdi, JSAMPROW [rdi] ; outptr0
1.86 + mov rbx, JSAMPROW [rbx] ; outptr1
1.87 + mov rdx, JSAMPROW [rdx] ; outptr2
1.88 +
1.89 + cmp rcx, byte SIZEOF_XMMWORD
1.90 + jae near .columnloop
1.91 +
1.92 +%if RGB_PIXELSIZE == 3 ; ---------------
1.93 +
1.94 +.column_ld1:
1.95 + push rax
1.96 + push rdx
1.97 + lea rcx,[rcx+rcx*2] ; imul ecx,RGB_PIXELSIZE
1.98 + test cl, SIZEOF_BYTE
1.99 + jz short .column_ld2
1.100 + sub rcx, byte SIZEOF_BYTE
1.101 + movzx rax, BYTE [rsi+rcx]
1.102 +.column_ld2:
1.103 + test cl, SIZEOF_WORD
1.104 + jz short .column_ld4
1.105 + sub rcx, byte SIZEOF_WORD
1.106 + movzx rdx, WORD [rsi+rcx]
1.107 + shl rax, WORD_BIT
1.108 + or rax,rdx
1.109 +.column_ld4:
1.110 + movd xmmA,eax
1.111 + pop rdx
1.112 + pop rax
1.113 + test cl, SIZEOF_DWORD
1.114 + jz short .column_ld8
1.115 + sub rcx, byte SIZEOF_DWORD
1.116 + movd xmmF, XMM_DWORD [rsi+rcx]
1.117 + pslldq xmmA, SIZEOF_DWORD
1.118 + por xmmA,xmmF
1.119 +.column_ld8:
1.120 + test cl, SIZEOF_MMWORD
1.121 + jz short .column_ld16
1.122 + sub rcx, byte SIZEOF_MMWORD
1.123 + movq xmmB, XMM_MMWORD [rsi+rcx]
1.124 + pslldq xmmA, SIZEOF_MMWORD
1.125 + por xmmA,xmmB
1.126 +.column_ld16:
1.127 + test cl, SIZEOF_XMMWORD
1.128 + jz short .column_ld32
1.129 + movdqa xmmF,xmmA
1.130 + movdqu xmmA, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.131 + mov rcx, SIZEOF_XMMWORD
1.132 + jmp short .rgb_ycc_cnv
1.133 +.column_ld32:
1.134 + test cl, 2*SIZEOF_XMMWORD
1.135 + mov rcx, SIZEOF_XMMWORD
1.136 + jz short .rgb_ycc_cnv
1.137 + movdqa xmmB,xmmA
1.138 + movdqu xmmA, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.139 + movdqu xmmF, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.140 + jmp short .rgb_ycc_cnv
1.141 +
1.142 +.columnloop:
1.143 + movdqu xmmA, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.144 + movdqu xmmF, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.145 + movdqu xmmB, XMMWORD [rsi+2*SIZEOF_XMMWORD]
1.146 +
1.147 +.rgb_ycc_cnv:
1.148 + ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
1.149 + ; xmmF=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
1.150 + ; xmmB=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
1.151 +
1.152 + movdqa xmmG,xmmA
1.153 + pslldq xmmA,8 ; xmmA=(-- -- -- -- -- -- -- -- 00 10 20 01 11 21 02 12)
1.154 + psrldq xmmG,8 ; xmmG=(22 03 13 23 04 14 24 05 -- -- -- -- -- -- -- --)
1.155 +
1.156 + punpckhbw xmmA,xmmF ; xmmA=(00 08 10 18 20 28 01 09 11 19 21 29 02 0A 12 1A)
1.157 + pslldq xmmF,8 ; xmmF=(-- -- -- -- -- -- -- -- 15 25 06 16 26 07 17 27)
1.158 +
1.159 + punpcklbw xmmG,xmmB ; xmmG=(22 2A 03 0B 13 1B 23 2B 04 0C 14 1C 24 2C 05 0D)
1.160 + punpckhbw xmmF,xmmB ; xmmF=(15 1D 25 2D 06 0E 16 1E 26 2E 07 0F 17 1F 27 2F)
1.161 +
1.162 + movdqa xmmD,xmmA
1.163 + pslldq xmmA,8 ; xmmA=(-- -- -- -- -- -- -- -- 00 08 10 18 20 28 01 09)
1.164 + psrldq xmmD,8 ; xmmD=(11 19 21 29 02 0A 12 1A -- -- -- -- -- -- -- --)
1.165 +
1.166 + punpckhbw xmmA,xmmG ; xmmA=(00 04 08 0C 10 14 18 1C 20 24 28 2C 01 05 09 0D)
1.167 + pslldq xmmG,8 ; xmmG=(-- -- -- -- -- -- -- -- 22 2A 03 0B 13 1B 23 2B)
1.168 +
1.169 + punpcklbw xmmD,xmmF ; xmmD=(11 15 19 1D 21 25 29 2D 02 06 0A 0E 12 16 1A 1E)
1.170 + punpckhbw xmmG,xmmF ; xmmG=(22 26 2A 2E 03 07 0B 0F 13 17 1B 1F 23 27 2B 2F)
1.171 +
1.172 + movdqa xmmE,xmmA
1.173 + pslldq xmmA,8 ; xmmA=(-- -- -- -- -- -- -- -- 00 04 08 0C 10 14 18 1C)
1.174 + psrldq xmmE,8 ; xmmE=(20 24 28 2C 01 05 09 0D -- -- -- -- -- -- -- --)
1.175 +
1.176 + punpckhbw xmmA,xmmD ; xmmA=(00 02 04 06 08 0A 0C 0E 10 12 14 16 18 1A 1C 1E)
1.177 + pslldq xmmD,8 ; xmmD=(-- -- -- -- -- -- -- -- 11 15 19 1D 21 25 29 2D)
1.178 +
1.179 + punpcklbw xmmE,xmmG ; xmmE=(20 22 24 26 28 2A 2C 2E 01 03 05 07 09 0B 0D 0F)
1.180 + punpckhbw xmmD,xmmG ; xmmD=(11 13 15 17 19 1B 1D 1F 21 23 25 27 29 2B 2D 2F)
1.181 +
1.182 + pxor xmmH,xmmH
1.183 +
1.184 + movdqa xmmC,xmmA
1.185 + punpcklbw xmmA,xmmH ; xmmA=(00 02 04 06 08 0A 0C 0E)
1.186 + punpckhbw xmmC,xmmH ; xmmC=(10 12 14 16 18 1A 1C 1E)
1.187 +
1.188 + movdqa xmmB,xmmE
1.189 + punpcklbw xmmE,xmmH ; xmmE=(20 22 24 26 28 2A 2C 2E)
1.190 + punpckhbw xmmB,xmmH ; xmmB=(01 03 05 07 09 0B 0D 0F)
1.191 +
1.192 + movdqa xmmF,xmmD
1.193 + punpcklbw xmmD,xmmH ; xmmD=(11 13 15 17 19 1B 1D 1F)
1.194 + punpckhbw xmmF,xmmH ; xmmF=(21 23 25 27 29 2B 2D 2F)
1.195 +
1.196 +%else ; RGB_PIXELSIZE == 4 ; -----------
1.197 +
1.198 +.column_ld1:
1.199 + test cl, SIZEOF_XMMWORD/16
1.200 + jz short .column_ld2
1.201 + sub rcx, byte SIZEOF_XMMWORD/16
1.202 + movd xmmA, XMM_DWORD [rsi+rcx*RGB_PIXELSIZE]
1.203 +.column_ld2:
1.204 + test cl, SIZEOF_XMMWORD/8
1.205 + jz short .column_ld4
1.206 + sub rcx, byte SIZEOF_XMMWORD/8
1.207 + movq xmmE, XMM_MMWORD [rsi+rcx*RGB_PIXELSIZE]
1.208 + pslldq xmmA, SIZEOF_MMWORD
1.209 + por xmmA,xmmE
1.210 +.column_ld4:
1.211 + test cl, SIZEOF_XMMWORD/4
1.212 + jz short .column_ld8
1.213 + sub rcx, byte SIZEOF_XMMWORD/4
1.214 + movdqa xmmE,xmmA
1.215 + movdqu xmmA, XMMWORD [rsi+rcx*RGB_PIXELSIZE]
1.216 +.column_ld8:
1.217 + test cl, SIZEOF_XMMWORD/2
1.218 + mov rcx, SIZEOF_XMMWORD
1.219 + jz short .rgb_ycc_cnv
1.220 + movdqa xmmF,xmmA
1.221 + movdqa xmmH,xmmE
1.222 + movdqu xmmA, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.223 + movdqu xmmE, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.224 + jmp short .rgb_ycc_cnv
1.225 +
1.226 +.columnloop:
1.227 + movdqu xmmA, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.228 + movdqu xmmE, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.229 + movdqu xmmF, XMMWORD [rsi+2*SIZEOF_XMMWORD]
1.230 + movdqu xmmH, XMMWORD [rsi+3*SIZEOF_XMMWORD]
1.231 +
1.232 +.rgb_ycc_cnv:
1.233 + ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
1.234 + ; xmmE=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
1.235 + ; xmmF=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
1.236 + ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
1.237 +
1.238 + movdqa xmmD,xmmA
1.239 + punpcklbw xmmA,xmmE ; xmmA=(00 04 10 14 20 24 30 34 01 05 11 15 21 25 31 35)
1.240 + punpckhbw xmmD,xmmE ; xmmD=(02 06 12 16 22 26 32 36 03 07 13 17 23 27 33 37)
1.241 +
1.242 + movdqa xmmC,xmmF
1.243 + punpcklbw xmmF,xmmH ; xmmF=(08 0C 18 1C 28 2C 38 3C 09 0D 19 1D 29 2D 39 3D)
1.244 + punpckhbw xmmC,xmmH ; xmmC=(0A 0E 1A 1E 2A 2E 3A 3E 0B 0F 1B 1F 2B 2F 3B 3F)
1.245 +
1.246 + movdqa xmmB,xmmA
1.247 + punpcklwd xmmA,xmmF ; xmmA=(00 04 08 0C 10 14 18 1C 20 24 28 2C 30 34 38 3C)
1.248 + punpckhwd xmmB,xmmF ; xmmB=(01 05 09 0D 11 15 19 1D 21 25 29 2D 31 35 39 3D)
1.249 +
1.250 + movdqa xmmG,xmmD
1.251 + punpcklwd xmmD,xmmC ; xmmD=(02 06 0A 0E 12 16 1A 1E 22 26 2A 2E 32 36 3A 3E)
1.252 + punpckhwd xmmG,xmmC ; xmmG=(03 07 0B 0F 13 17 1B 1F 23 27 2B 2F 33 37 3B 3F)
1.253 +
1.254 + movdqa xmmE,xmmA
1.255 + punpcklbw xmmA,xmmD ; xmmA=(00 02 04 06 08 0A 0C 0E 10 12 14 16 18 1A 1C 1E)
1.256 + punpckhbw xmmE,xmmD ; xmmE=(20 22 24 26 28 2A 2C 2E 30 32 34 36 38 3A 3C 3E)
1.257 +
1.258 + movdqa xmmH,xmmB
1.259 + punpcklbw xmmB,xmmG ; xmmB=(01 03 05 07 09 0B 0D 0F 11 13 15 17 19 1B 1D 1F)
1.260 + punpckhbw xmmH,xmmG ; xmmH=(21 23 25 27 29 2B 2D 2F 31 33 35 37 39 3B 3D 3F)
1.261 +
1.262 + pxor xmmF,xmmF
1.263 +
1.264 + movdqa xmmC,xmmA
1.265 + punpcklbw xmmA,xmmF ; xmmA=(00 02 04 06 08 0A 0C 0E)
1.266 + punpckhbw xmmC,xmmF ; xmmC=(10 12 14 16 18 1A 1C 1E)
1.267 +
1.268 + movdqa xmmD,xmmB
1.269 + punpcklbw xmmB,xmmF ; xmmB=(01 03 05 07 09 0B 0D 0F)
1.270 + punpckhbw xmmD,xmmF ; xmmD=(11 13 15 17 19 1B 1D 1F)
1.271 +
1.272 + movdqa xmmG,xmmE
1.273 + punpcklbw xmmE,xmmF ; xmmE=(20 22 24 26 28 2A 2C 2E)
1.274 + punpckhbw xmmG,xmmF ; xmmG=(30 32 34 36 38 3A 3C 3E)
1.275 +
1.276 + punpcklbw xmmF,xmmH
1.277 + punpckhbw xmmH,xmmH
1.278 + psrlw xmmF,BYTE_BIT ; xmmF=(21 23 25 27 29 2B 2D 2F)
1.279 + psrlw xmmH,BYTE_BIT ; xmmH=(31 33 35 37 39 3B 3D 3F)
1.280 +
1.281 +%endif ; RGB_PIXELSIZE ; ---------------
1.282 +
1.283 + ; xmm0=R(02468ACE)=RE, xmm2=G(02468ACE)=GE, xmm4=B(02468ACE)=BE
1.284 + ; xmm1=R(13579BDF)=RO, xmm3=G(13579BDF)=GO, xmm5=B(13579BDF)=BO
1.285 +
1.286 + ; (Original)
1.287 + ; Y = 0.29900 * R + 0.58700 * G + 0.11400 * B
1.288 + ; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
1.289 + ; Cr = 0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
1.290 + ;
1.291 + ; (This implementation)
1.292 + ; Y = 0.29900 * R + 0.33700 * G + 0.11400 * B + 0.25000 * G
1.293 + ; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
1.294 + ; Cr = 0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
1.295 +
1.296 + movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=RE
1.297 + movdqa XMMWORD [wk(1)], xmm1 ; wk(1)=RO
1.298 + movdqa XMMWORD [wk(2)], xmm4 ; wk(2)=BE
1.299 + movdqa XMMWORD [wk(3)], xmm5 ; wk(3)=BO
1.300 +
1.301 + movdqa xmm6,xmm1
1.302 + punpcklwd xmm1,xmm3
1.303 + punpckhwd xmm6,xmm3
1.304 + movdqa xmm7,xmm1
1.305 + movdqa xmm4,xmm6
1.306 + pmaddwd xmm1,[rel PW_F0299_F0337] ; xmm1=ROL*FIX(0.299)+GOL*FIX(0.337)
1.307 + pmaddwd xmm6,[rel PW_F0299_F0337] ; xmm6=ROH*FIX(0.299)+GOH*FIX(0.337)
1.308 + pmaddwd xmm7,[rel PW_MF016_MF033] ; xmm7=ROL*-FIX(0.168)+GOL*-FIX(0.331)
1.309 + pmaddwd xmm4,[rel PW_MF016_MF033] ; xmm4=ROH*-FIX(0.168)+GOH*-FIX(0.331)
1.310 +
1.311 + movdqa XMMWORD [wk(4)], xmm1 ; wk(4)=ROL*FIX(0.299)+GOL*FIX(0.337)
1.312 + movdqa XMMWORD [wk(5)], xmm6 ; wk(5)=ROH*FIX(0.299)+GOH*FIX(0.337)
1.313 +
1.314 + pxor xmm1,xmm1
1.315 + pxor xmm6,xmm6
1.316 + punpcklwd xmm1,xmm5 ; xmm1=BOL
1.317 + punpckhwd xmm6,xmm5 ; xmm6=BOH
1.318 + psrld xmm1,1 ; xmm1=BOL*FIX(0.500)
1.319 + psrld xmm6,1 ; xmm6=BOH*FIX(0.500)
1.320 +
1.321 + movdqa xmm5,[rel PD_ONEHALFM1_CJ] ; xmm5=[PD_ONEHALFM1_CJ]
1.322 +
1.323 + paddd xmm7,xmm1
1.324 + paddd xmm4,xmm6
1.325 + paddd xmm7,xmm5
1.326 + paddd xmm4,xmm5
1.327 + psrld xmm7,SCALEBITS ; xmm7=CbOL
1.328 + psrld xmm4,SCALEBITS ; xmm4=CbOH
1.329 + packssdw xmm7,xmm4 ; xmm7=CbO
1.330 +
1.331 + movdqa xmm1, XMMWORD [wk(2)] ; xmm1=BE
1.332 +
1.333 + movdqa xmm6,xmm0
1.334 + punpcklwd xmm0,xmm2
1.335 + punpckhwd xmm6,xmm2
1.336 + movdqa xmm5,xmm0
1.337 + movdqa xmm4,xmm6
1.338 + pmaddwd xmm0,[rel PW_F0299_F0337] ; xmm0=REL*FIX(0.299)+GEL*FIX(0.337)
1.339 + pmaddwd xmm6,[rel PW_F0299_F0337] ; xmm6=REH*FIX(0.299)+GEH*FIX(0.337)
1.340 + pmaddwd xmm5,[rel PW_MF016_MF033] ; xmm5=REL*-FIX(0.168)+GEL*-FIX(0.331)
1.341 + pmaddwd xmm4,[rel PW_MF016_MF033] ; xmm4=REH*-FIX(0.168)+GEH*-FIX(0.331)
1.342 +
1.343 + movdqa XMMWORD [wk(6)], xmm0 ; wk(6)=REL*FIX(0.299)+GEL*FIX(0.337)
1.344 + movdqa XMMWORD [wk(7)], xmm6 ; wk(7)=REH*FIX(0.299)+GEH*FIX(0.337)
1.345 +
1.346 + pxor xmm0,xmm0
1.347 + pxor xmm6,xmm6
1.348 + punpcklwd xmm0,xmm1 ; xmm0=BEL
1.349 + punpckhwd xmm6,xmm1 ; xmm6=BEH
1.350 + psrld xmm0,1 ; xmm0=BEL*FIX(0.500)
1.351 + psrld xmm6,1 ; xmm6=BEH*FIX(0.500)
1.352 +
1.353 + movdqa xmm1,[rel PD_ONEHALFM1_CJ] ; xmm1=[PD_ONEHALFM1_CJ]
1.354 +
1.355 + paddd xmm5,xmm0
1.356 + paddd xmm4,xmm6
1.357 + paddd xmm5,xmm1
1.358 + paddd xmm4,xmm1
1.359 + psrld xmm5,SCALEBITS ; xmm5=CbEL
1.360 + psrld xmm4,SCALEBITS ; xmm4=CbEH
1.361 + packssdw xmm5,xmm4 ; xmm5=CbE
1.362 +
1.363 + psllw xmm7,BYTE_BIT
1.364 + por xmm5,xmm7 ; xmm5=Cb
1.365 + movdqa XMMWORD [rbx], xmm5 ; Save Cb
1.366 +
1.367 + movdqa xmm0, XMMWORD [wk(3)] ; xmm0=BO
1.368 + movdqa xmm6, XMMWORD [wk(2)] ; xmm6=BE
1.369 + movdqa xmm1, XMMWORD [wk(1)] ; xmm1=RO
1.370 +
1.371 + movdqa xmm4,xmm0
1.372 + punpcklwd xmm0,xmm3
1.373 + punpckhwd xmm4,xmm3
1.374 + movdqa xmm7,xmm0
1.375 + movdqa xmm5,xmm4
1.376 + pmaddwd xmm0,[rel PW_F0114_F0250] ; xmm0=BOL*FIX(0.114)+GOL*FIX(0.250)
1.377 + pmaddwd xmm4,[rel PW_F0114_F0250] ; xmm4=BOH*FIX(0.114)+GOH*FIX(0.250)
1.378 + pmaddwd xmm7,[rel PW_MF008_MF041] ; xmm7=BOL*-FIX(0.081)+GOL*-FIX(0.418)
1.379 + pmaddwd xmm5,[rel PW_MF008_MF041] ; xmm5=BOH*-FIX(0.081)+GOH*-FIX(0.418)
1.380 +
1.381 + movdqa xmm3,[rel PD_ONEHALF] ; xmm3=[PD_ONEHALF]
1.382 +
1.383 + paddd xmm0, XMMWORD [wk(4)]
1.384 + paddd xmm4, XMMWORD [wk(5)]
1.385 + paddd xmm0,xmm3
1.386 + paddd xmm4,xmm3
1.387 + psrld xmm0,SCALEBITS ; xmm0=YOL
1.388 + psrld xmm4,SCALEBITS ; xmm4=YOH
1.389 + packssdw xmm0,xmm4 ; xmm0=YO
1.390 +
1.391 + pxor xmm3,xmm3
1.392 + pxor xmm4,xmm4
1.393 + punpcklwd xmm3,xmm1 ; xmm3=ROL
1.394 + punpckhwd xmm4,xmm1 ; xmm4=ROH
1.395 + psrld xmm3,1 ; xmm3=ROL*FIX(0.500)
1.396 + psrld xmm4,1 ; xmm4=ROH*FIX(0.500)
1.397 +
1.398 + movdqa xmm1,[rel PD_ONEHALFM1_CJ] ; xmm1=[PD_ONEHALFM1_CJ]
1.399 +
1.400 + paddd xmm7,xmm3
1.401 + paddd xmm5,xmm4
1.402 + paddd xmm7,xmm1
1.403 + paddd xmm5,xmm1
1.404 + psrld xmm7,SCALEBITS ; xmm7=CrOL
1.405 + psrld xmm5,SCALEBITS ; xmm5=CrOH
1.406 + packssdw xmm7,xmm5 ; xmm7=CrO
1.407 +
1.408 + movdqa xmm3, XMMWORD [wk(0)] ; xmm3=RE
1.409 +
1.410 + movdqa xmm4,xmm6
1.411 + punpcklwd xmm6,xmm2
1.412 + punpckhwd xmm4,xmm2
1.413 + movdqa xmm1,xmm6
1.414 + movdqa xmm5,xmm4
1.415 + pmaddwd xmm6,[rel PW_F0114_F0250] ; xmm6=BEL*FIX(0.114)+GEL*FIX(0.250)
1.416 + pmaddwd xmm4,[rel PW_F0114_F0250] ; xmm4=BEH*FIX(0.114)+GEH*FIX(0.250)
1.417 + pmaddwd xmm1,[rel PW_MF008_MF041] ; xmm1=BEL*-FIX(0.081)+GEL*-FIX(0.418)
1.418 + pmaddwd xmm5,[rel PW_MF008_MF041] ; xmm5=BEH*-FIX(0.081)+GEH*-FIX(0.418)
1.419 +
1.420 + movdqa xmm2,[rel PD_ONEHALF] ; xmm2=[PD_ONEHALF]
1.421 +
1.422 + paddd xmm6, XMMWORD [wk(6)]
1.423 + paddd xmm4, XMMWORD [wk(7)]
1.424 + paddd xmm6,xmm2
1.425 + paddd xmm4,xmm2
1.426 + psrld xmm6,SCALEBITS ; xmm6=YEL
1.427 + psrld xmm4,SCALEBITS ; xmm4=YEH
1.428 + packssdw xmm6,xmm4 ; xmm6=YE
1.429 +
1.430 + psllw xmm0,BYTE_BIT
1.431 + por xmm6,xmm0 ; xmm6=Y
1.432 + movdqa XMMWORD [rdi], xmm6 ; Save Y
1.433 +
1.434 + pxor xmm2,xmm2
1.435 + pxor xmm4,xmm4
1.436 + punpcklwd xmm2,xmm3 ; xmm2=REL
1.437 + punpckhwd xmm4,xmm3 ; xmm4=REH
1.438 + psrld xmm2,1 ; xmm2=REL*FIX(0.500)
1.439 + psrld xmm4,1 ; xmm4=REH*FIX(0.500)
1.440 +
1.441 + movdqa xmm0,[rel PD_ONEHALFM1_CJ] ; xmm0=[PD_ONEHALFM1_CJ]
1.442 +
1.443 + paddd xmm1,xmm2
1.444 + paddd xmm5,xmm4
1.445 + paddd xmm1,xmm0
1.446 + paddd xmm5,xmm0
1.447 + psrld xmm1,SCALEBITS ; xmm1=CrEL
1.448 + psrld xmm5,SCALEBITS ; xmm5=CrEH
1.449 + packssdw xmm1,xmm5 ; xmm1=CrE
1.450 +
1.451 + psllw xmm7,BYTE_BIT
1.452 + por xmm1,xmm7 ; xmm1=Cr
1.453 + movdqa XMMWORD [rdx], xmm1 ; Save Cr
1.454 +
1.455 + sub rcx, byte SIZEOF_XMMWORD
1.456 + add rsi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; inptr
1.457 + add rdi, byte SIZEOF_XMMWORD ; outptr0
1.458 + add rbx, byte SIZEOF_XMMWORD ; outptr1
1.459 + add rdx, byte SIZEOF_XMMWORD ; outptr2
1.460 + cmp rcx, byte SIZEOF_XMMWORD
1.461 + jae near .columnloop
1.462 + test rcx,rcx
1.463 + jnz near .column_ld1
1.464 +
1.465 + pop rcx ; col
1.466 + pop rsi
1.467 + pop rdi
1.468 + pop rbx
1.469 + pop rdx
1.470 +
1.471 + add rsi, byte SIZEOF_JSAMPROW ; input_buf
1.472 + add rdi, byte SIZEOF_JSAMPROW
1.473 + add rbx, byte SIZEOF_JSAMPROW
1.474 + add rdx, byte SIZEOF_JSAMPROW
1.475 + dec rax ; num_rows
1.476 + jg near .rowloop
1.477 +
1.478 +.return:
1.479 + pop rbx
1.480 + uncollect_args
1.481 + mov rsp,rbp ; rsp <- aligned rbp
1.482 + pop rsp ; rsp <- original rbp
1.483 + pop rbp
1.484 + ret
1.485 +
1.486 +; For some reason, the OS X linker does not honor the request to align the
1.487 +; segment unless we do this.
1.488 + align 16
