1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jcsamss2-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,330 @@
1.4 +;
1.5 +; jcsamss2-64.asm - downsampling (64-bit SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; [TAB8]
1.22 +
1.23 +%include "jsimdext.inc"
1.24 +
1.25 +; --------------------------------------------------------------------------
1.26 + SECTION SEG_TEXT
1.27 + BITS 64
1.28 +;
1.29 +; Downsample pixel values of a single component.
1.30 +; This version handles the common case of 2:1 horizontal and 1:1 vertical,
1.31 +; without smoothing.
1.32 +;
1.33 +; GLOBAL(void)
1.34 +; jsimd_h2v1_downsample_sse2 (JDIMENSION image_width, int max_v_samp_factor,
1.35 +; JDIMENSION v_samp_factor, JDIMENSION width_blocks,
1.36 +; JSAMPARRAY input_data, JSAMPARRAY output_data);
1.37 +;
1.38 +
1.39 +; r10 = JDIMENSION image_width
1.40 +; r11 = int max_v_samp_factor
1.41 +; r12 = JDIMENSION v_samp_factor
1.42 +; r13 = JDIMENSION width_blocks
1.43 +; r14 = JSAMPARRAY input_data
1.44 +; r15 = JSAMPARRAY output_data
1.45 +
1.46 + align 16
1.47 + global EXTN(jsimd_h2v1_downsample_sse2)
1.48 +
1.49 +EXTN(jsimd_h2v1_downsample_sse2):
1.50 + push rbp
1.51 + mov rax,rsp
1.52 + mov rbp,rsp
1.53 + collect_args
1.54 +
1.55 + mov rcx, r13
1.56 + shl rcx,3 ; imul rcx,DCTSIZE (rcx = output_cols)
1.57 + jz near .return
1.58 +
1.59 + mov rdx, r10
1.60 +
1.61 + ; -- expand_right_edge
1.62 +
1.63 + push rcx
1.64 + shl rcx,1 ; output_cols * 2
1.65 + sub rcx,rdx
1.66 + jle short .expand_end
1.67 +
1.68 + mov rax, r11
1.69 + test rax,rax
1.70 + jle short .expand_end
1.71 +
1.72 + cld
1.73 + mov rsi, r14 ; input_data
1.74 +.expandloop:
1.75 + push rax
1.76 + push rcx
1.77 +
1.78 + mov rdi, JSAMPROW [rsi]
1.79 + add rdi,rdx
1.80 + mov al, JSAMPLE [rdi-1]
1.81 +
1.82 + rep stosb
1.83 +
1.84 + pop rcx
1.85 + pop rax
1.86 +
1.87 + add rsi, byte SIZEOF_JSAMPROW
1.88 + dec rax
1.89 + jg short .expandloop
1.90 +
1.91 +.expand_end:
1.92 + pop rcx ; output_cols
1.93 +
1.94 + ; -- h2v1_downsample
1.95 +
1.96 + mov rax, r12 ; rowctr
1.97 + test eax,eax
1.98 + jle near .return
1.99 +
1.100 + mov rdx, 0x00010000 ; bias pattern
1.101 + movd xmm7,edx
1.102 + pcmpeqw xmm6,xmm6
1.103 + pshufd xmm7,xmm7,0x00 ; xmm7={0, 1, 0, 1, 0, 1, 0, 1}
1.104 + psrlw xmm6,BYTE_BIT ; xmm6={0xFF 0x00 0xFF 0x00 ..}
1.105 +
1.106 + mov rsi, r14 ; input_data
1.107 + mov rdi, r15 ; output_data
1.108 +.rowloop:
1.109 + push rcx
1.110 + push rdi
1.111 + push rsi
1.112 +
1.113 + mov rsi, JSAMPROW [rsi] ; inptr
1.114 + mov rdi, JSAMPROW [rdi] ; outptr
1.115 +
1.116 + cmp rcx, byte SIZEOF_XMMWORD
1.117 + jae short .columnloop
1.118 +
1.119 +.columnloop_r8:
1.120 + movdqa xmm0, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.121 + pxor xmm1,xmm1
1.122 + mov rcx, SIZEOF_XMMWORD
1.123 + jmp short .downsample
1.124 +
1.125 +.columnloop:
1.126 + movdqa xmm0, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.127 + movdqa xmm1, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.128 +
1.129 +.downsample:
1.130 + movdqa xmm2,xmm0
1.131 + movdqa xmm3,xmm1
1.132 +
1.133 + pand xmm0,xmm6
1.134 + psrlw xmm2,BYTE_BIT
1.135 + pand xmm1,xmm6
1.136 + psrlw xmm3,BYTE_BIT
1.137 +
1.138 + paddw xmm0,xmm2
1.139 + paddw xmm1,xmm3
1.140 + paddw xmm0,xmm7
1.141 + paddw xmm1,xmm7
1.142 + psrlw xmm0,1
1.143 + psrlw xmm1,1
1.144 +
1.145 + packuswb xmm0,xmm1
1.146 +
1.147 + movdqa XMMWORD [rdi+0*SIZEOF_XMMWORD], xmm0
1.148 +
1.149 + sub rcx, byte SIZEOF_XMMWORD ; outcol
1.150 + add rsi, byte 2*SIZEOF_XMMWORD ; inptr
1.151 + add rdi, byte 1*SIZEOF_XMMWORD ; outptr
1.152 + cmp rcx, byte SIZEOF_XMMWORD
1.153 + jae short .columnloop
1.154 + test rcx,rcx
1.155 + jnz short .columnloop_r8
1.156 +
1.157 + pop rsi
1.158 + pop rdi
1.159 + pop rcx
1.160 +
1.161 + add rsi, byte SIZEOF_JSAMPROW ; input_data
1.162 + add rdi, byte SIZEOF_JSAMPROW ; output_data
1.163 + dec rax ; rowctr
1.164 + jg near .rowloop
1.165 +
1.166 +.return:
1.167 + uncollect_args
1.168 + pop rbp
1.169 + ret
1.170 +
1.171 +; --------------------------------------------------------------------------
1.172 +;
1.173 +; Downsample pixel values of a single component.
1.174 +; This version handles the standard case of 2:1 horizontal and 2:1 vertical,
1.175 +; without smoothing.
1.176 +;
1.177 +; GLOBAL(void)
1.178 +; jsimd_h2v2_downsample_sse2 (JDIMENSION image_width, int max_v_samp_factor,
1.179 +; JDIMENSION v_samp_factor, JDIMENSION width_blocks,
1.180 +; JSAMPARRAY input_data, JSAMPARRAY output_data);
1.181 +;
1.182 +
1.183 +; r10 = JDIMENSION image_width
1.184 +; r11 = int max_v_samp_factor
1.185 +; r12 = JDIMENSION v_samp_factor
1.186 +; r13 = JDIMENSION width_blocks
1.187 +; r14 = JSAMPARRAY input_data
1.188 +; r15 = JSAMPARRAY output_data
1.189 +
1.190 + align 16
1.191 + global EXTN(jsimd_h2v2_downsample_sse2)
1.192 +
1.193 +EXTN(jsimd_h2v2_downsample_sse2):
1.194 + push rbp
1.195 + mov rax,rsp
1.196 + mov rbp,rsp
1.197 + collect_args
1.198 +
1.199 + mov rcx, r13
1.200 + shl rcx,3 ; imul rcx,DCTSIZE (rcx = output_cols)
1.201 + jz near .return
1.202 +
1.203 + mov rdx, r10
1.204 +
1.205 + ; -- expand_right_edge
1.206 +
1.207 + push rcx
1.208 + shl rcx,1 ; output_cols * 2
1.209 + sub rcx,rdx
1.210 + jle short .expand_end
1.211 +
1.212 + mov rax, r11
1.213 + test rax,rax
1.214 + jle short .expand_end
1.215 +
1.216 + cld
1.217 + mov rsi, r14 ; input_data
1.218 +.expandloop:
1.219 + push rax
1.220 + push rcx
1.221 +
1.222 + mov rdi, JSAMPROW [rsi]
1.223 + add rdi,rdx
1.224 + mov al, JSAMPLE [rdi-1]
1.225 +
1.226 + rep stosb
1.227 +
1.228 + pop rcx
1.229 + pop rax
1.230 +
1.231 + add rsi, byte SIZEOF_JSAMPROW
1.232 + dec rax
1.233 + jg short .expandloop
1.234 +
1.235 +.expand_end:
1.236 + pop rcx ; output_cols
1.237 +
1.238 + ; -- h2v2_downsample
1.239 +
1.240 + mov rax, r12 ; rowctr
1.241 + test rax,rax
1.242 + jle near .return
1.243 +
1.244 + mov rdx, 0x00020001 ; bias pattern
1.245 + movd xmm7,edx
1.246 + pcmpeqw xmm6,xmm6
1.247 + pshufd xmm7,xmm7,0x00 ; xmm7={1, 2, 1, 2, 1, 2, 1, 2}
1.248 + psrlw xmm6,BYTE_BIT ; xmm6={0xFF 0x00 0xFF 0x00 ..}
1.249 +
1.250 + mov rsi, r14 ; input_data
1.251 + mov rdi, r15 ; output_data
1.252 +.rowloop:
1.253 + push rcx
1.254 + push rdi
1.255 + push rsi
1.256 +
1.257 + mov rdx, JSAMPROW [rsi+0*SIZEOF_JSAMPROW] ; inptr0
1.258 + mov rsi, JSAMPROW [rsi+1*SIZEOF_JSAMPROW] ; inptr1
1.259 + mov rdi, JSAMPROW [rdi] ; outptr
1.260 +
1.261 + cmp rcx, byte SIZEOF_XMMWORD
1.262 + jae short .columnloop
1.263 +
1.264 +.columnloop_r8:
1.265 + movdqa xmm0, XMMWORD [rdx+0*SIZEOF_XMMWORD]
1.266 + movdqa xmm1, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.267 + pxor xmm2,xmm2
1.268 + pxor xmm3,xmm3
1.269 + mov rcx, SIZEOF_XMMWORD
1.270 + jmp short .downsample
1.271 +
1.272 +.columnloop:
1.273 + movdqa xmm0, XMMWORD [rdx+0*SIZEOF_XMMWORD]
1.274 + movdqa xmm1, XMMWORD [rsi+0*SIZEOF_XMMWORD]
1.275 + movdqa xmm2, XMMWORD [rdx+1*SIZEOF_XMMWORD]
1.276 + movdqa xmm3, XMMWORD [rsi+1*SIZEOF_XMMWORD]
1.277 +
1.278 +.downsample:
1.279 + movdqa xmm4,xmm0
1.280 + movdqa xmm5,xmm1
1.281 + pand xmm0,xmm6
1.282 + psrlw xmm4,BYTE_BIT
1.283 + pand xmm1,xmm6
1.284 + psrlw xmm5,BYTE_BIT
1.285 + paddw xmm0,xmm4
1.286 + paddw xmm1,xmm5
1.287 +
1.288 + movdqa xmm4,xmm2
1.289 + movdqa xmm5,xmm3
1.290 + pand xmm2,xmm6
1.291 + psrlw xmm4,BYTE_BIT
1.292 + pand xmm3,xmm6
1.293 + psrlw xmm5,BYTE_BIT
1.294 + paddw xmm2,xmm4
1.295 + paddw xmm3,xmm5
1.296 +
1.297 + paddw xmm0,xmm1
1.298 + paddw xmm2,xmm3
1.299 + paddw xmm0,xmm7
1.300 + paddw xmm2,xmm7
1.301 + psrlw xmm0,2
1.302 + psrlw xmm2,2
1.303 +
1.304 + packuswb xmm0,xmm2
1.305 +
1.306 + movdqa XMMWORD [rdi+0*SIZEOF_XMMWORD], xmm0
1.307 +
1.308 + sub rcx, byte SIZEOF_XMMWORD ; outcol
1.309 + add rdx, byte 2*SIZEOF_XMMWORD ; inptr0
1.310 + add rsi, byte 2*SIZEOF_XMMWORD ; inptr1
1.311 + add rdi, byte 1*SIZEOF_XMMWORD ; outptr
1.312 + cmp rcx, byte SIZEOF_XMMWORD
1.313 + jae near .columnloop
1.314 + test rcx,rcx
1.315 + jnz near .columnloop_r8
1.316 +
1.317 + pop rsi
1.318 + pop rdi
1.319 + pop rcx
1.320 +
1.321 + add rsi, byte 2*SIZEOF_JSAMPROW ; input_data
1.322 + add rdi, byte 1*SIZEOF_JSAMPROW ; output_data
1.323 + dec rax ; rowctr
1.324 + jg near .rowloop
1.325 +
1.326 +.return:
1.327 + uncollect_args
1.328 + pop rbp
1.329 + ret
1.330 +
1.331 +; For some reason, the OS X linker does not honor the request to align the
1.332 +; segment unless we do this.
1.333 + align 16
