1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jdclrss2.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,460 @@
1.4 +;
1.5 +; jdclrss2.asm - colorspace conversion (SSE2)
1.6 +;
1.7 +; Copyright 2009, 2012 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2012 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; [TAB8]
1.22 +
1.23 +%include "jcolsamp.inc"
1.24 +
1.25 +; --------------------------------------------------------------------------
1.26 +;
1.27 +; Convert some rows of samples to the output colorspace.
1.28 +;
1.29 +; GLOBAL(void)
1.30 +; jsimd_ycc_rgb_convert_sse2 (JDIMENSION out_width,
1.31 +; JSAMPIMAGE input_buf, JDIMENSION input_row,
1.32 +; JSAMPARRAY output_buf, int num_rows)
1.33 +;
1.34 +
1.35 +%define out_width(b) (b)+8 ; JDIMENSION out_width
1.36 +%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
1.37 +%define input_row(b) (b)+16 ; JDIMENSION input_row
1.38 +%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
1.39 +%define num_rows(b) (b)+24 ; int num_rows
1.40 +
1.41 +%define original_ebp ebp+0
1.42 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.43 +%define WK_NUM 2
1.44 +%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
1.45 +
1.46 + align 16
1.47 + global EXTN(jsimd_ycc_rgb_convert_sse2)
1.48 +
1.49 +EXTN(jsimd_ycc_rgb_convert_sse2):
1.50 + push ebp
1.51 + mov eax,esp ; eax = original ebp
1.52 + sub esp, byte 4
1.53 + and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.54 + mov [esp],eax
1.55 + mov ebp,esp ; ebp = aligned ebp
1.56 + lea esp, [wk(0)]
1.57 + pushpic eax ; make a room for GOT address
1.58 + push ebx
1.59 +; push ecx ; need not be preserved
1.60 +; push edx ; need not be preserved
1.61 + push esi
1.62 + push edi
1.63 +
1.64 + get_GOT ebx ; get GOT address
1.65 + movpic POINTER [gotptr], ebx ; save GOT address
1.66 +
1.67 + mov ecx, JDIMENSION [out_width(eax)] ; num_cols
1.68 + test ecx,ecx
1.69 + jz near .return
1.70 +
1.71 + push ecx
1.72 +
1.73 + mov edi, JSAMPIMAGE [input_buf(eax)]
1.74 + mov ecx, JDIMENSION [input_row(eax)]
1.75 + mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
1.76 + mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
1.77 + mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
1.78 + lea esi, [esi+ecx*SIZEOF_JSAMPROW]
1.79 + lea ebx, [ebx+ecx*SIZEOF_JSAMPROW]
1.80 + lea edx, [edx+ecx*SIZEOF_JSAMPROW]
1.81 +
1.82 + pop ecx
1.83 +
1.84 + mov edi, JSAMPARRAY [output_buf(eax)]
1.85 + mov eax, INT [num_rows(eax)]
1.86 + test eax,eax
1.87 + jle near .return
1.88 + alignx 16,7
1.89 +.rowloop:
1.90 + push eax
1.91 + push edi
1.92 + push edx
1.93 + push ebx
1.94 + push esi
1.95 + push ecx ; col
1.96 +
1.97 + mov esi, JSAMPROW [esi] ; inptr0
1.98 + mov ebx, JSAMPROW [ebx] ; inptr1
1.99 + mov edx, JSAMPROW [edx] ; inptr2
1.100 + mov edi, JSAMPROW [edi] ; outptr
1.101 + movpic eax, POINTER [gotptr] ; load GOT address (eax)
1.102 + alignx 16,7
1.103 +.columnloop:
1.104 +
1.105 + movdqa xmm5, XMMWORD [ebx] ; xmm5=Cb(0123456789ABCDEF)
1.106 + movdqa xmm1, XMMWORD [edx] ; xmm1=Cr(0123456789ABCDEF)
1.107 +
1.108 + pcmpeqw xmm4,xmm4
1.109 + pcmpeqw xmm7,xmm7
1.110 + psrlw xmm4,BYTE_BIT
1.111 + psllw xmm7,7 ; xmm7={0xFF80 0xFF80 0xFF80 0xFF80 ..}
1.112 + movdqa xmm0,xmm4 ; xmm0=xmm4={0xFF 0x00 0xFF 0x00 ..}
1.113 +
1.114 + pand xmm4,xmm5 ; xmm4=Cb(02468ACE)=CbE
1.115 + psrlw xmm5,BYTE_BIT ; xmm5=Cb(13579BDF)=CbO
1.116 + pand xmm0,xmm1 ; xmm0=Cr(02468ACE)=CrE
1.117 + psrlw xmm1,BYTE_BIT ; xmm1=Cr(13579BDF)=CrO
1.118 +
1.119 + paddw xmm4,xmm7
1.120 + paddw xmm5,xmm7
1.121 + paddw xmm0,xmm7
1.122 + paddw xmm1,xmm7
1.123 +
1.124 + ; (Original)
1.125 + ; R = Y + 1.40200 * Cr
1.126 + ; G = Y - 0.34414 * Cb - 0.71414 * Cr
1.127 + ; B = Y + 1.77200 * Cb
1.128 + ;
1.129 + ; (This implementation)
1.130 + ; R = Y + 0.40200 * Cr + Cr
1.131 + ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
1.132 + ; B = Y - 0.22800 * Cb + Cb + Cb
1.133 +
1.134 + movdqa xmm2,xmm4 ; xmm2=CbE
1.135 + movdqa xmm3,xmm5 ; xmm3=CbO
1.136 + paddw xmm4,xmm4 ; xmm4=2*CbE
1.137 + paddw xmm5,xmm5 ; xmm5=2*CbO
1.138 + movdqa xmm6,xmm0 ; xmm6=CrE
1.139 + movdqa xmm7,xmm1 ; xmm7=CrO
1.140 + paddw xmm0,xmm0 ; xmm0=2*CrE
1.141 + paddw xmm1,xmm1 ; xmm1=2*CrO
1.142 +
1.143 + pmulhw xmm4,[GOTOFF(eax,PW_MF0228)] ; xmm4=(2*CbE * -FIX(0.22800))
1.144 + pmulhw xmm5,[GOTOFF(eax,PW_MF0228)] ; xmm5=(2*CbO * -FIX(0.22800))
1.145 + pmulhw xmm0,[GOTOFF(eax,PW_F0402)] ; xmm0=(2*CrE * FIX(0.40200))
1.146 + pmulhw xmm1,[GOTOFF(eax,PW_F0402)] ; xmm1=(2*CrO * FIX(0.40200))
1.147 +
1.148 + paddw xmm4,[GOTOFF(eax,PW_ONE)]
1.149 + paddw xmm5,[GOTOFF(eax,PW_ONE)]
1.150 + psraw xmm4,1 ; xmm4=(CbE * -FIX(0.22800))
1.151 + psraw xmm5,1 ; xmm5=(CbO * -FIX(0.22800))
1.152 + paddw xmm0,[GOTOFF(eax,PW_ONE)]
1.153 + paddw xmm1,[GOTOFF(eax,PW_ONE)]
1.154 + psraw xmm0,1 ; xmm0=(CrE * FIX(0.40200))
1.155 + psraw xmm1,1 ; xmm1=(CrO * FIX(0.40200))
1.156 +
1.157 + paddw xmm4,xmm2
1.158 + paddw xmm5,xmm3
1.159 + paddw xmm4,xmm2 ; xmm4=(CbE * FIX(1.77200))=(B-Y)E
1.160 + paddw xmm5,xmm3 ; xmm5=(CbO * FIX(1.77200))=(B-Y)O
1.161 + paddw xmm0,xmm6 ; xmm0=(CrE * FIX(1.40200))=(R-Y)E
1.162 + paddw xmm1,xmm7 ; xmm1=(CrO * FIX(1.40200))=(R-Y)O
1.163 +
1.164 + movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=(B-Y)E
1.165 + movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(B-Y)O
1.166 +
1.167 + movdqa xmm4,xmm2
1.168 + movdqa xmm5,xmm3
1.169 + punpcklwd xmm2,xmm6
1.170 + punpckhwd xmm4,xmm6
1.171 + pmaddwd xmm2,[GOTOFF(eax,PW_MF0344_F0285)]
1.172 + pmaddwd xmm4,[GOTOFF(eax,PW_MF0344_F0285)]
1.173 + punpcklwd xmm3,xmm7
1.174 + punpckhwd xmm5,xmm7
1.175 + pmaddwd xmm3,[GOTOFF(eax,PW_MF0344_F0285)]
1.176 + pmaddwd xmm5,[GOTOFF(eax,PW_MF0344_F0285)]
1.177 +
1.178 + paddd xmm2,[GOTOFF(eax,PD_ONEHALF)]
1.179 + paddd xmm4,[GOTOFF(eax,PD_ONEHALF)]
1.180 + psrad xmm2,SCALEBITS
1.181 + psrad xmm4,SCALEBITS
1.182 + paddd xmm3,[GOTOFF(eax,PD_ONEHALF)]
1.183 + paddd xmm5,[GOTOFF(eax,PD_ONEHALF)]
1.184 + psrad xmm3,SCALEBITS
1.185 + psrad xmm5,SCALEBITS
1.186 +
1.187 + packssdw xmm2,xmm4 ; xmm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
1.188 + packssdw xmm3,xmm5 ; xmm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
1.189 + psubw xmm2,xmm6 ; xmm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
1.190 + psubw xmm3,xmm7 ; xmm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
1.191 +
1.192 + movdqa xmm5, XMMWORD [esi] ; xmm5=Y(0123456789ABCDEF)
1.193 +
1.194 + pcmpeqw xmm4,xmm4
1.195 + psrlw xmm4,BYTE_BIT ; xmm4={0xFF 0x00 0xFF 0x00 ..}
1.196 + pand xmm4,xmm5 ; xmm4=Y(02468ACE)=YE
1.197 + psrlw xmm5,BYTE_BIT ; xmm5=Y(13579BDF)=YO
1.198 +
1.199 + paddw xmm0,xmm4 ; xmm0=((R-Y)E+YE)=RE=R(02468ACE)
1.200 + paddw xmm1,xmm5 ; xmm1=((R-Y)O+YO)=RO=R(13579BDF)
1.201 + packuswb xmm0,xmm0 ; xmm0=R(02468ACE********)
1.202 + packuswb xmm1,xmm1 ; xmm1=R(13579BDF********)
1.203 +
1.204 + paddw xmm2,xmm4 ; xmm2=((G-Y)E+YE)=GE=G(02468ACE)
1.205 + paddw xmm3,xmm5 ; xmm3=((G-Y)O+YO)=GO=G(13579BDF)
1.206 + packuswb xmm2,xmm2 ; xmm2=G(02468ACE********)
1.207 + packuswb xmm3,xmm3 ; xmm3=G(13579BDF********)
1.208 +
1.209 + paddw xmm4, XMMWORD [wk(0)] ; xmm4=(YE+(B-Y)E)=BE=B(02468ACE)
1.210 + paddw xmm5, XMMWORD [wk(1)] ; xmm5=(YO+(B-Y)O)=BO=B(13579BDF)
1.211 + packuswb xmm4,xmm4 ; xmm4=B(02468ACE********)
1.212 + packuswb xmm5,xmm5 ; xmm5=B(13579BDF********)
1.213 +
1.214 +%if RGB_PIXELSIZE == 3 ; ---------------
1.215 +
1.216 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.217 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.218 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.219 + ; xmmG=(** ** ** ** ** ** ** ** **), xmmH=(** ** ** ** ** ** ** ** **)
1.220 +
1.221 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.222 + punpcklbw xmmE,xmmB ; xmmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F)
1.223 + punpcklbw xmmD,xmmF ; xmmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F)
1.224 +
1.225 + movdqa xmmG,xmmA
1.226 + movdqa xmmH,xmmA
1.227 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07)
1.228 + punpckhwd xmmG,xmmE ; xmmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F)
1.229 +
1.230 + psrldq xmmH,2 ; xmmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E -- --)
1.231 + psrldq xmmE,2 ; xmmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F -- --)
1.232 +
1.233 + movdqa xmmC,xmmD
1.234 + movdqa xmmB,xmmD
1.235 + punpcklwd xmmD,xmmH ; xmmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18)
1.236 + punpckhwd xmmC,xmmH ; xmmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F -- --)
1.237 +
1.238 + psrldq xmmB,2 ; xmmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F -- --)
1.239 +
1.240 + movdqa xmmF,xmmE
1.241 + punpcklwd xmmE,xmmB ; xmmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29)
1.242 + punpckhwd xmmF,xmmB ; xmmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F -- -- -- --)
1.243 +
1.244 + pshufd xmmH,xmmA,0x4E; xmmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03)
1.245 + movdqa xmmB,xmmE
1.246 + punpckldq xmmA,xmmD ; xmmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14)
1.247 + punpckldq xmmE,xmmH ; xmmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07)
1.248 + punpckhdq xmmD,xmmB ; xmmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29)
1.249 +
1.250 + pshufd xmmH,xmmG,0x4E; xmmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B)
1.251 + movdqa xmmB,xmmF
1.252 + punpckldq xmmG,xmmC ; xmmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C)
1.253 + punpckldq xmmF,xmmH ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F)
1.254 + punpckhdq xmmC,xmmB ; xmmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F -- -- -- -- -- --)
1.255 +
1.256 + punpcklqdq xmmA,xmmE ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
1.257 + punpcklqdq xmmD,xmmG ; xmmD=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
1.258 + punpcklqdq xmmF,xmmC ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
1.259 +
1.260 + cmp ecx, byte SIZEOF_XMMWORD
1.261 + jb short .column_st32
1.262 +
1.263 + test edi, SIZEOF_XMMWORD-1
1.264 + jnz short .out1
1.265 + ; --(aligned)-------------------
1.266 + movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.267 + movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.268 + movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmF
1.269 + jmp short .out0
1.270 +.out1: ; --(unaligned)-----------------
1.271 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.272 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.273 + movdqu XMMWORD [edi+2*SIZEOF_XMMWORD], xmmF
1.274 +.out0:
1.275 + add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.276 + sub ecx, byte SIZEOF_XMMWORD
1.277 + jz near .nextrow
1.278 +
1.279 + add esi, byte SIZEOF_XMMWORD ; inptr0
1.280 + add ebx, byte SIZEOF_XMMWORD ; inptr1
1.281 + add edx, byte SIZEOF_XMMWORD ; inptr2
1.282 + jmp near .columnloop
1.283 + alignx 16,7
1.284 +
1.285 +.column_st32:
1.286 + lea ecx, [ecx+ecx*2] ; imul ecx, RGB_PIXELSIZE
1.287 + cmp ecx, byte 2*SIZEOF_XMMWORD
1.288 + jb short .column_st16
1.289 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.290 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.291 + add edi, byte 2*SIZEOF_XMMWORD ; outptr
1.292 + movdqa xmmA,xmmF
1.293 + sub ecx, byte 2*SIZEOF_XMMWORD
1.294 + jmp short .column_st15
1.295 +.column_st16:
1.296 + cmp ecx, byte SIZEOF_XMMWORD
1.297 + jb short .column_st15
1.298 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.299 + add edi, byte SIZEOF_XMMWORD ; outptr
1.300 + movdqa xmmA,xmmD
1.301 + sub ecx, byte SIZEOF_XMMWORD
1.302 +.column_st15:
1.303 + ; Store the lower 8 bytes of xmmA to the output when it has enough
1.304 + ; space.
1.305 + cmp ecx, byte SIZEOF_MMWORD
1.306 + jb short .column_st7
1.307 + movq XMM_MMWORD [edi], xmmA
1.308 + add edi, byte SIZEOF_MMWORD
1.309 + sub ecx, byte SIZEOF_MMWORD
1.310 + psrldq xmmA, SIZEOF_MMWORD
1.311 +.column_st7:
1.312 + ; Store the lower 4 bytes of xmmA to the output when it has enough
1.313 + ; space.
1.314 + cmp ecx, byte SIZEOF_DWORD
1.315 + jb short .column_st3
1.316 + movd XMM_DWORD [edi], xmmA
1.317 + add edi, byte SIZEOF_DWORD
1.318 + sub ecx, byte SIZEOF_DWORD
1.319 + psrldq xmmA, SIZEOF_DWORD
1.320 +.column_st3:
1.321 + ; Store the lower 2 bytes of eax to the output when it has enough
1.322 + ; space.
1.323 + movd eax, xmmA
1.324 + cmp ecx, byte SIZEOF_WORD
1.325 + jb short .column_st1
1.326 + mov WORD [edi], ax
1.327 + add edi, byte SIZEOF_WORD
1.328 + sub ecx, byte SIZEOF_WORD
1.329 + shr eax, 16
1.330 +.column_st1:
1.331 + ; Store the lower 1 byte of eax to the output when it has enough
1.332 + ; space.
1.333 + test ecx, ecx
1.334 + jz short .nextrow
1.335 + mov BYTE [edi], al
1.336 +
1.337 +%else ; RGB_PIXELSIZE == 4 ; -----------
1.338 +
1.339 +%ifdef RGBX_FILLER_0XFF
1.340 + pcmpeqb xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.341 + pcmpeqb xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.342 +%else
1.343 + pxor xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.344 + pxor xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.345 +%endif
1.346 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.347 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.348 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.349 + ; xmmG=(30 32 34 36 38 3A 3C 3E **), xmmH=(31 33 35 37 39 3B 3D 3F **)
1.350 +
1.351 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.352 + punpcklbw xmmE,xmmG ; xmmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E)
1.353 + punpcklbw xmmB,xmmD ; xmmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F)
1.354 + punpcklbw xmmF,xmmH ; xmmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F)
1.355 +
1.356 + movdqa xmmC,xmmA
1.357 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36)
1.358 + punpckhwd xmmC,xmmE ; xmmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E)
1.359 + movdqa xmmG,xmmB
1.360 + punpcklwd xmmB,xmmF ; xmmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37)
1.361 + punpckhwd xmmG,xmmF ; xmmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F)
1.362 +
1.363 + movdqa xmmD,xmmA
1.364 + punpckldq xmmA,xmmB ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
1.365 + punpckhdq xmmD,xmmB ; xmmD=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
1.366 + movdqa xmmH,xmmC
1.367 + punpckldq xmmC,xmmG ; xmmC=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
1.368 + punpckhdq xmmH,xmmG ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
1.369 +
1.370 + cmp ecx, byte SIZEOF_XMMWORD
1.371 + jb short .column_st32
1.372 +
1.373 + test edi, SIZEOF_XMMWORD-1
1.374 + jnz short .out1
1.375 + ; --(aligned)-------------------
1.376 + movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.377 + movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.378 + movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmC
1.379 + movntdq XMMWORD [edi+3*SIZEOF_XMMWORD], xmmH
1.380 + jmp short .out0
1.381 +.out1: ; --(unaligned)-----------------
1.382 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.383 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.384 + movdqu XMMWORD [edi+2*SIZEOF_XMMWORD], xmmC
1.385 + movdqu XMMWORD [edi+3*SIZEOF_XMMWORD], xmmH
1.386 +.out0:
1.387 + add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.388 + sub ecx, byte SIZEOF_XMMWORD
1.389 + jz near .nextrow
1.390 +
1.391 + add esi, byte SIZEOF_XMMWORD ; inptr0
1.392 + add ebx, byte SIZEOF_XMMWORD ; inptr1
1.393 + add edx, byte SIZEOF_XMMWORD ; inptr2
1.394 + jmp near .columnloop
1.395 + alignx 16,7
1.396 +
1.397 +.column_st32:
1.398 + cmp ecx, byte SIZEOF_XMMWORD/2
1.399 + jb short .column_st16
1.400 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.401 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.402 + add edi, byte 2*SIZEOF_XMMWORD ; outptr
1.403 + movdqa xmmA,xmmC
1.404 + movdqa xmmD,xmmH
1.405 + sub ecx, byte SIZEOF_XMMWORD/2
1.406 +.column_st16:
1.407 + cmp ecx, byte SIZEOF_XMMWORD/4
1.408 + jb short .column_st15
1.409 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.410 + add edi, byte SIZEOF_XMMWORD ; outptr
1.411 + movdqa xmmA,xmmD
1.412 + sub ecx, byte SIZEOF_XMMWORD/4
1.413 +.column_st15:
1.414 + ; Store two pixels (8 bytes) of xmmA to the output when it has enough
1.415 + ; space.
1.416 + cmp ecx, byte SIZEOF_XMMWORD/8
1.417 + jb short .column_st7
1.418 + movq XMM_MMWORD [edi], xmmA
1.419 + add edi, byte SIZEOF_XMMWORD/8*4
1.420 + sub ecx, byte SIZEOF_XMMWORD/8
1.421 + psrldq xmmA, SIZEOF_XMMWORD/8*4
1.422 +.column_st7:
1.423 + ; Store one pixel (4 bytes) of xmmA to the output when it has enough
1.424 + ; space.
1.425 + test ecx, ecx
1.426 + jz short .nextrow
1.427 + movd XMM_DWORD [edi], xmmA
1.428 +
1.429 +%endif ; RGB_PIXELSIZE ; ---------------
1.430 +
1.431 + alignx 16,7
1.432 +
1.433 +.nextrow:
1.434 + pop ecx
1.435 + pop esi
1.436 + pop ebx
1.437 + pop edx
1.438 + pop edi
1.439 + pop eax
1.440 +
1.441 + add esi, byte SIZEOF_JSAMPROW
1.442 + add ebx, byte SIZEOF_JSAMPROW
1.443 + add edx, byte SIZEOF_JSAMPROW
1.444 + add edi, byte SIZEOF_JSAMPROW ; output_buf
1.445 + dec eax ; num_rows
1.446 + jg near .rowloop
1.447 +
1.448 + sfence ; flush the write buffer
1.449 +
1.450 +.return:
1.451 + pop edi
1.452 + pop esi
1.453 +; pop edx ; need not be preserved
1.454 +; pop ecx ; need not be preserved
1.455 + pop ebx
1.456 + mov esp,ebp ; esp <- aligned ebp
1.457 + pop esp ; esp <- original ebp
1.458 + pop ebp
1.459 + ret
1.460 +
1.461 +; For some reason, the OS X linker does not honor the request to align the
1.462 +; segment unless we do this.
1.463 + align 16
