1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jdmrgss2-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,538 @@
1.4 +;
1.5 +; jdmrgss2-64.asm - merged upsampling/color conversion (64-bit SSE2)
1.6 +;
1.7 +; Copyright 2009, 2012 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009, 2012 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; [TAB8]
1.22 +
1.23 +%include "jcolsamp.inc"
1.24 +
1.25 +; --------------------------------------------------------------------------
1.26 +;
1.27 +; Upsample and color convert for the case of 2:1 horizontal and 1:1 vertical.
1.28 +;
1.29 +; GLOBAL(void)
1.30 +; jsimd_h2v1_merged_upsample_sse2 (JDIMENSION output_width,
1.31 +; JSAMPIMAGE input_buf,
1.32 +; JDIMENSION in_row_group_ctr,
1.33 +; JSAMPARRAY output_buf);
1.34 +;
1.35 +
1.36 +; r10 = JDIMENSION output_width
1.37 +; r11 = JSAMPIMAGE input_buf
1.38 +; r12 = JDIMENSION in_row_group_ctr
1.39 +; r13 = JSAMPARRAY output_buf
1.40 +
1.41 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.42 +%define WK_NUM 3
1.43 +
1.44 + align 16
1.45 + global EXTN(jsimd_h2v1_merged_upsample_sse2)
1.46 +
1.47 +EXTN(jsimd_h2v1_merged_upsample_sse2):
1.48 + push rbp
1.49 + mov rax,rsp ; rax = original rbp
1.50 + sub rsp, byte 4
1.51 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.52 + mov [rsp],rax
1.53 + mov rbp,rsp ; rbp = aligned rbp
1.54 + lea rsp, [wk(0)]
1.55 + collect_args
1.56 + push rbx
1.57 +
1.58 + mov rcx, r10 ; col
1.59 + test rcx,rcx
1.60 + jz near .return
1.61 +
1.62 + push rcx
1.63 +
1.64 + mov rdi, r11
1.65 + mov rcx, r12
1.66 + mov rsi, JSAMPARRAY [rdi+0*SIZEOF_JSAMPARRAY]
1.67 + mov rbx, JSAMPARRAY [rdi+1*SIZEOF_JSAMPARRAY]
1.68 + mov rdx, JSAMPARRAY [rdi+2*SIZEOF_JSAMPARRAY]
1.69 + mov rdi, r13
1.70 + mov rsi, JSAMPROW [rsi+rcx*SIZEOF_JSAMPROW] ; inptr0
1.71 + mov rbx, JSAMPROW [rbx+rcx*SIZEOF_JSAMPROW] ; inptr1
1.72 + mov rdx, JSAMPROW [rdx+rcx*SIZEOF_JSAMPROW] ; inptr2
1.73 + mov rdi, JSAMPROW [rdi] ; outptr
1.74 +
1.75 + pop rcx ; col
1.76 +
1.77 +.columnloop:
1.78 +
1.79 + movdqa xmm6, XMMWORD [rbx] ; xmm6=Cb(0123456789ABCDEF)
1.80 + movdqa xmm7, XMMWORD [rdx] ; xmm7=Cr(0123456789ABCDEF)
1.81 +
1.82 + pxor xmm1,xmm1 ; xmm1=(all 0's)
1.83 + pcmpeqw xmm3,xmm3
1.84 + psllw xmm3,7 ; xmm3={0xFF80 0xFF80 0xFF80 0xFF80 ..}
1.85 +
1.86 + movdqa xmm4,xmm6
1.87 + punpckhbw xmm6,xmm1 ; xmm6=Cb(89ABCDEF)=CbH
1.88 + punpcklbw xmm4,xmm1 ; xmm4=Cb(01234567)=CbL
1.89 + movdqa xmm0,xmm7
1.90 + punpckhbw xmm7,xmm1 ; xmm7=Cr(89ABCDEF)=CrH
1.91 + punpcklbw xmm0,xmm1 ; xmm0=Cr(01234567)=CrL
1.92 +
1.93 + paddw xmm6,xmm3
1.94 + paddw xmm4,xmm3
1.95 + paddw xmm7,xmm3
1.96 + paddw xmm0,xmm3
1.97 +
1.98 + ; (Original)
1.99 + ; R = Y + 1.40200 * Cr
1.100 + ; G = Y - 0.34414 * Cb - 0.71414 * Cr
1.101 + ; B = Y + 1.77200 * Cb
1.102 + ;
1.103 + ; (This implementation)
1.104 + ; R = Y + 0.40200 * Cr + Cr
1.105 + ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
1.106 + ; B = Y - 0.22800 * Cb + Cb + Cb
1.107 +
1.108 + movdqa xmm5,xmm6 ; xmm5=CbH
1.109 + movdqa xmm2,xmm4 ; xmm2=CbL
1.110 + paddw xmm6,xmm6 ; xmm6=2*CbH
1.111 + paddw xmm4,xmm4 ; xmm4=2*CbL
1.112 + movdqa xmm1,xmm7 ; xmm1=CrH
1.113 + movdqa xmm3,xmm0 ; xmm3=CrL
1.114 + paddw xmm7,xmm7 ; xmm7=2*CrH
1.115 + paddw xmm0,xmm0 ; xmm0=2*CrL
1.116 +
1.117 + pmulhw xmm6,[rel PW_MF0228] ; xmm6=(2*CbH * -FIX(0.22800))
1.118 + pmulhw xmm4,[rel PW_MF0228] ; xmm4=(2*CbL * -FIX(0.22800))
1.119 + pmulhw xmm7,[rel PW_F0402] ; xmm7=(2*CrH * FIX(0.40200))
1.120 + pmulhw xmm0,[rel PW_F0402] ; xmm0=(2*CrL * FIX(0.40200))
1.121 +
1.122 + paddw xmm6,[rel PW_ONE]
1.123 + paddw xmm4,[rel PW_ONE]
1.124 + psraw xmm6,1 ; xmm6=(CbH * -FIX(0.22800))
1.125 + psraw xmm4,1 ; xmm4=(CbL * -FIX(0.22800))
1.126 + paddw xmm7,[rel PW_ONE]
1.127 + paddw xmm0,[rel PW_ONE]
1.128 + psraw xmm7,1 ; xmm7=(CrH * FIX(0.40200))
1.129 + psraw xmm0,1 ; xmm0=(CrL * FIX(0.40200))
1.130 +
1.131 + paddw xmm6,xmm5
1.132 + paddw xmm4,xmm2
1.133 + paddw xmm6,xmm5 ; xmm6=(CbH * FIX(1.77200))=(B-Y)H
1.134 + paddw xmm4,xmm2 ; xmm4=(CbL * FIX(1.77200))=(B-Y)L
1.135 + paddw xmm7,xmm1 ; xmm7=(CrH * FIX(1.40200))=(R-Y)H
1.136 + paddw xmm0,xmm3 ; xmm0=(CrL * FIX(1.40200))=(R-Y)L
1.137 +
1.138 + movdqa XMMWORD [wk(0)], xmm6 ; wk(0)=(B-Y)H
1.139 + movdqa XMMWORD [wk(1)], xmm7 ; wk(1)=(R-Y)H
1.140 +
1.141 + movdqa xmm6,xmm5
1.142 + movdqa xmm7,xmm2
1.143 + punpcklwd xmm5,xmm1
1.144 + punpckhwd xmm6,xmm1
1.145 + pmaddwd xmm5,[rel PW_MF0344_F0285]
1.146 + pmaddwd xmm6,[rel PW_MF0344_F0285]
1.147 + punpcklwd xmm2,xmm3
1.148 + punpckhwd xmm7,xmm3
1.149 + pmaddwd xmm2,[rel PW_MF0344_F0285]
1.150 + pmaddwd xmm7,[rel PW_MF0344_F0285]
1.151 +
1.152 + paddd xmm5,[rel PD_ONEHALF]
1.153 + paddd xmm6,[rel PD_ONEHALF]
1.154 + psrad xmm5,SCALEBITS
1.155 + psrad xmm6,SCALEBITS
1.156 + paddd xmm2,[rel PD_ONEHALF]
1.157 + paddd xmm7,[rel PD_ONEHALF]
1.158 + psrad xmm2,SCALEBITS
1.159 + psrad xmm7,SCALEBITS
1.160 +
1.161 + packssdw xmm5,xmm6 ; xmm5=CbH*-FIX(0.344)+CrH*FIX(0.285)
1.162 + packssdw xmm2,xmm7 ; xmm2=CbL*-FIX(0.344)+CrL*FIX(0.285)
1.163 + psubw xmm5,xmm1 ; xmm5=CbH*-FIX(0.344)+CrH*-FIX(0.714)=(G-Y)H
1.164 + psubw xmm2,xmm3 ; xmm2=CbL*-FIX(0.344)+CrL*-FIX(0.714)=(G-Y)L
1.165 +
1.166 + movdqa XMMWORD [wk(2)], xmm5 ; wk(2)=(G-Y)H
1.167 +
1.168 + mov al,2 ; Yctr
1.169 + jmp short .Yloop_1st
1.170 +
1.171 +.Yloop_2nd:
1.172 + movdqa xmm0, XMMWORD [wk(1)] ; xmm0=(R-Y)H
1.173 + movdqa xmm2, XMMWORD [wk(2)] ; xmm2=(G-Y)H
1.174 + movdqa xmm4, XMMWORD [wk(0)] ; xmm4=(B-Y)H
1.175 +
1.176 +.Yloop_1st:
1.177 + movdqa xmm7, XMMWORD [rsi] ; xmm7=Y(0123456789ABCDEF)
1.178 +
1.179 + pcmpeqw xmm6,xmm6
1.180 + psrlw xmm6,BYTE_BIT ; xmm6={0xFF 0x00 0xFF 0x00 ..}
1.181 + pand xmm6,xmm7 ; xmm6=Y(02468ACE)=YE
1.182 + psrlw xmm7,BYTE_BIT ; xmm7=Y(13579BDF)=YO
1.183 +
1.184 + movdqa xmm1,xmm0 ; xmm1=xmm0=(R-Y)(L/H)
1.185 + movdqa xmm3,xmm2 ; xmm3=xmm2=(G-Y)(L/H)
1.186 + movdqa xmm5,xmm4 ; xmm5=xmm4=(B-Y)(L/H)
1.187 +
1.188 + paddw xmm0,xmm6 ; xmm0=((R-Y)+YE)=RE=R(02468ACE)
1.189 + paddw xmm1,xmm7 ; xmm1=((R-Y)+YO)=RO=R(13579BDF)
1.190 + packuswb xmm0,xmm0 ; xmm0=R(02468ACE********)
1.191 + packuswb xmm1,xmm1 ; xmm1=R(13579BDF********)
1.192 +
1.193 + paddw xmm2,xmm6 ; xmm2=((G-Y)+YE)=GE=G(02468ACE)
1.194 + paddw xmm3,xmm7 ; xmm3=((G-Y)+YO)=GO=G(13579BDF)
1.195 + packuswb xmm2,xmm2 ; xmm2=G(02468ACE********)
1.196 + packuswb xmm3,xmm3 ; xmm3=G(13579BDF********)
1.197 +
1.198 + paddw xmm4,xmm6 ; xmm4=((B-Y)+YE)=BE=B(02468ACE)
1.199 + paddw xmm5,xmm7 ; xmm5=((B-Y)+YO)=BO=B(13579BDF)
1.200 + packuswb xmm4,xmm4 ; xmm4=B(02468ACE********)
1.201 + packuswb xmm5,xmm5 ; xmm5=B(13579BDF********)
1.202 +
1.203 +%if RGB_PIXELSIZE == 3 ; ---------------
1.204 +
1.205 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.206 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.207 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.208 + ; xmmG=(** ** ** ** ** ** ** ** **), xmmH=(** ** ** ** ** ** ** ** **)
1.209 +
1.210 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.211 + punpcklbw xmmE,xmmB ; xmmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F)
1.212 + punpcklbw xmmD,xmmF ; xmmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F)
1.213 +
1.214 + movdqa xmmG,xmmA
1.215 + movdqa xmmH,xmmA
1.216 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07)
1.217 + punpckhwd xmmG,xmmE ; xmmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F)
1.218 +
1.219 + psrldq xmmH,2 ; xmmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E -- --)
1.220 + psrldq xmmE,2 ; xmmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F -- --)
1.221 +
1.222 + movdqa xmmC,xmmD
1.223 + movdqa xmmB,xmmD
1.224 + punpcklwd xmmD,xmmH ; xmmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18)
1.225 + punpckhwd xmmC,xmmH ; xmmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F -- --)
1.226 +
1.227 + psrldq xmmB,2 ; xmmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F -- --)
1.228 +
1.229 + movdqa xmmF,xmmE
1.230 + punpcklwd xmmE,xmmB ; xmmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29)
1.231 + punpckhwd xmmF,xmmB ; xmmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F -- -- -- --)
1.232 +
1.233 + pshufd xmmH,xmmA,0x4E; xmmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03)
1.234 + movdqa xmmB,xmmE
1.235 + punpckldq xmmA,xmmD ; xmmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14)
1.236 + punpckldq xmmE,xmmH ; xmmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07)
1.237 + punpckhdq xmmD,xmmB ; xmmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29)
1.238 +
1.239 + pshufd xmmH,xmmG,0x4E; xmmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B)
1.240 + movdqa xmmB,xmmF
1.241 + punpckldq xmmG,xmmC ; xmmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C)
1.242 + punpckldq xmmF,xmmH ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F)
1.243 + punpckhdq xmmC,xmmB ; xmmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F -- -- -- -- -- --)
1.244 +
1.245 + punpcklqdq xmmA,xmmE ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
1.246 + punpcklqdq xmmD,xmmG ; xmmD=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
1.247 + punpcklqdq xmmF,xmmC ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
1.248 +
1.249 + cmp rcx, byte SIZEOF_XMMWORD
1.250 + jb short .column_st32
1.251 +
1.252 + test rdi, SIZEOF_XMMWORD-1
1.253 + jnz short .out1
1.254 + ; --(aligned)-------------------
1.255 + movntdq XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.256 + movntdq XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.257 + movntdq XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmF
1.258 + jmp short .out0
1.259 +.out1: ; --(unaligned)-----------------
1.260 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.261 + movdqu XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.262 + movdqu XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmF
1.263 +.out0:
1.264 + add rdi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.265 + sub rcx, byte SIZEOF_XMMWORD
1.266 + jz near .endcolumn
1.267 +
1.268 + add rsi, byte SIZEOF_XMMWORD ; inptr0
1.269 + dec al ; Yctr
1.270 + jnz near .Yloop_2nd
1.271 +
1.272 + add rbx, byte SIZEOF_XMMWORD ; inptr1
1.273 + add rdx, byte SIZEOF_XMMWORD ; inptr2
1.274 + jmp near .columnloop
1.275 +
1.276 +.column_st32:
1.277 + lea rcx, [rcx+rcx*2] ; imul ecx, RGB_PIXELSIZE
1.278 + cmp rcx, byte 2*SIZEOF_XMMWORD
1.279 + jb short .column_st16
1.280 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.281 + movdqu XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.282 + add rdi, byte 2*SIZEOF_XMMWORD ; outptr
1.283 + movdqa xmmA,xmmF
1.284 + sub rcx, byte 2*SIZEOF_XMMWORD
1.285 + jmp short .column_st15
1.286 +.column_st16:
1.287 + cmp rcx, byte SIZEOF_XMMWORD
1.288 + jb short .column_st15
1.289 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.290 + add rdi, byte SIZEOF_XMMWORD ; outptr
1.291 + movdqa xmmA,xmmD
1.292 + sub rcx, byte SIZEOF_XMMWORD
1.293 +.column_st15:
1.294 + ; Store the lower 8 bytes of xmmA to the output when it has enough
1.295 + ; space.
1.296 + cmp rcx, byte SIZEOF_MMWORD
1.297 + jb short .column_st7
1.298 + movq XMM_MMWORD [rdi], xmmA
1.299 + add rdi, byte SIZEOF_MMWORD
1.300 + sub rcx, byte SIZEOF_MMWORD
1.301 + psrldq xmmA, SIZEOF_MMWORD
1.302 +.column_st7:
1.303 + ; Store the lower 4 bytes of xmmA to the output when it has enough
1.304 + ; space.
1.305 + cmp rcx, byte SIZEOF_DWORD
1.306 + jb short .column_st3
1.307 + movd XMM_DWORD [rdi], xmmA
1.308 + add rdi, byte SIZEOF_DWORD
1.309 + sub rcx, byte SIZEOF_DWORD
1.310 + psrldq xmmA, SIZEOF_DWORD
1.311 +.column_st3:
1.312 + ; Store the lower 2 bytes of rax to the output when it has enough
1.313 + ; space.
1.314 + movd eax, xmmA
1.315 + cmp rcx, byte SIZEOF_WORD
1.316 + jb short .column_st1
1.317 + mov WORD [rdi], ax
1.318 + add rdi, byte SIZEOF_WORD
1.319 + sub rcx, byte SIZEOF_WORD
1.320 + shr rax, 16
1.321 +.column_st1:
1.322 + ; Store the lower 1 byte of rax to the output when it has enough
1.323 + ; space.
1.324 + test rcx, rcx
1.325 + jz short .endcolumn
1.326 + mov BYTE [rdi], al
1.327 +
1.328 +%else ; RGB_PIXELSIZE == 4 ; -----------
1.329 +
1.330 +%ifdef RGBX_FILLER_0XFF
1.331 + pcmpeqb xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.332 + pcmpeqb xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.333 +%else
1.334 + pxor xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.335 + pxor xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.336 +%endif
1.337 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.338 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.339 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.340 + ; xmmG=(30 32 34 36 38 3A 3C 3E **), xmmH=(31 33 35 37 39 3B 3D 3F **)
1.341 +
1.342 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.343 + punpcklbw xmmE,xmmG ; xmmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E)
1.344 + punpcklbw xmmB,xmmD ; xmmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F)
1.345 + punpcklbw xmmF,xmmH ; xmmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F)
1.346 +
1.347 + movdqa xmmC,xmmA
1.348 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36)
1.349 + punpckhwd xmmC,xmmE ; xmmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E)
1.350 + movdqa xmmG,xmmB
1.351 + punpcklwd xmmB,xmmF ; xmmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37)
1.352 + punpckhwd xmmG,xmmF ; xmmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F)
1.353 +
1.354 + movdqa xmmD,xmmA
1.355 + punpckldq xmmA,xmmB ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
1.356 + punpckhdq xmmD,xmmB ; xmmD=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
1.357 + movdqa xmmH,xmmC
1.358 + punpckldq xmmC,xmmG ; xmmC=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
1.359 + punpckhdq xmmH,xmmG ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
1.360 +
1.361 + cmp rcx, byte SIZEOF_XMMWORD
1.362 + jb short .column_st32
1.363 +
1.364 + test rdi, SIZEOF_XMMWORD-1
1.365 + jnz short .out1
1.366 + ; --(aligned)-------------------
1.367 + movntdq XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.368 + movntdq XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.369 + movntdq XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmC
1.370 + movntdq XMMWORD [rdi+3*SIZEOF_XMMWORD], xmmH
1.371 + jmp short .out0
1.372 +.out1: ; --(unaligned)-----------------
1.373 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.374 + movdqu XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.375 + movdqu XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmC
1.376 + movdqu XMMWORD [rdi+3*SIZEOF_XMMWORD], xmmH
1.377 +.out0:
1.378 + add rdi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.379 + sub rcx, byte SIZEOF_XMMWORD
1.380 + jz near .endcolumn
1.381 +
1.382 + add rsi, byte SIZEOF_XMMWORD ; inptr0
1.383 + dec al ; Yctr
1.384 + jnz near .Yloop_2nd
1.385 +
1.386 + add rbx, byte SIZEOF_XMMWORD ; inptr1
1.387 + add rdx, byte SIZEOF_XMMWORD ; inptr2
1.388 + jmp near .columnloop
1.389 +
1.390 +.column_st32:
1.391 + cmp rcx, byte SIZEOF_XMMWORD/2
1.392 + jb short .column_st16
1.393 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.394 + movdqu XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
1.395 + add rdi, byte 2*SIZEOF_XMMWORD ; outptr
1.396 + movdqa xmmA,xmmC
1.397 + movdqa xmmD,xmmH
1.398 + sub rcx, byte SIZEOF_XMMWORD/2
1.399 +.column_st16:
1.400 + cmp rcx, byte SIZEOF_XMMWORD/4
1.401 + jb short .column_st15
1.402 + movdqu XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
1.403 + add rdi, byte SIZEOF_XMMWORD ; outptr
1.404 + movdqa xmmA,xmmD
1.405 + sub rcx, byte SIZEOF_XMMWORD/4
1.406 +.column_st15:
1.407 + ; Store two pixels (8 bytes) of xmmA to the output when it has enough
1.408 + ; space.
1.409 + cmp rcx, byte SIZEOF_XMMWORD/8
1.410 + jb short .column_st7
1.411 + movq XMM_MMWORD [rdi], xmmA
1.412 + add rdi, byte SIZEOF_XMMWORD/8*4
1.413 + sub rcx, byte SIZEOF_XMMWORD/8
1.414 + psrldq xmmA, SIZEOF_XMMWORD/8*4
1.415 +.column_st7:
1.416 + ; Store one pixel (4 bytes) of xmmA to the output when it has enough
1.417 + ; space.
1.418 + test rcx, rcx
1.419 + jz short .endcolumn
1.420 + movd XMM_DWORD [rdi], xmmA
1.421 +
1.422 +%endif ; RGB_PIXELSIZE ; ---------------
1.423 +
1.424 +.endcolumn:
1.425 + sfence ; flush the write buffer
1.426 +
1.427 +.return:
1.428 + pop rbx
1.429 + uncollect_args
1.430 + mov rsp,rbp ; rsp <- aligned rbp
1.431 + pop rsp ; rsp <- original rbp
1.432 + pop rbp
1.433 + ret
1.434 +
1.435 +; --------------------------------------------------------------------------
1.436 +;
1.437 +; Upsample and color convert for the case of 2:1 horizontal and 2:1 vertical.
1.438 +;
1.439 +; GLOBAL(void)
1.440 +; jsimd_h2v2_merged_upsample_sse2 (JDIMENSION output_width,
1.441 +; JSAMPIMAGE input_buf,
1.442 +; JDIMENSION in_row_group_ctr,
1.443 +; JSAMPARRAY output_buf);
1.444 +;
1.445 +
1.446 +; r10 = JDIMENSION output_width
1.447 +; r11 = JSAMPIMAGE input_buf
1.448 +; r12 = JDIMENSION in_row_group_ctr
1.449 +; r13 = JSAMPARRAY output_buf
1.450 +
1.451 + align 16
1.452 + global EXTN(jsimd_h2v2_merged_upsample_sse2)
1.453 +
1.454 +EXTN(jsimd_h2v2_merged_upsample_sse2):
1.455 + push rbp
1.456 + mov rax,rsp
1.457 + mov rbp,rsp
1.458 + collect_args
1.459 + push rbx
1.460 +
1.461 + mov rax, r10
1.462 +
1.463 + mov rdi, r11
1.464 + mov rcx, r12
1.465 + mov rsi, JSAMPARRAY [rdi+0*SIZEOF_JSAMPARRAY]
1.466 + mov rbx, JSAMPARRAY [rdi+1*SIZEOF_JSAMPARRAY]
1.467 + mov rdx, JSAMPARRAY [rdi+2*SIZEOF_JSAMPARRAY]
1.468 + mov rdi, r13
1.469 + lea rsi, [rsi+rcx*SIZEOF_JSAMPROW]
1.470 +
1.471 + push rdx ; inptr2
1.472 + push rbx ; inptr1
1.473 + push rsi ; inptr00
1.474 + mov rbx,rsp
1.475 +
1.476 + push rdi
1.477 + push rcx
1.478 + push rax
1.479 +
1.480 + %ifdef WIN64
1.481 + mov r8, rcx
1.482 + mov r9, rdi
1.483 + mov rcx, rax
1.484 + mov rdx, rbx
1.485 + %else
1.486 + mov rdx, rcx
1.487 + mov rcx, rdi
1.488 + mov rdi, rax
1.489 + mov rsi, rbx
1.490 + %endif
1.491 +
1.492 + call EXTN(jsimd_h2v1_merged_upsample_sse2)
1.493 +
1.494 + pop rax
1.495 + pop rcx
1.496 + pop rdi
1.497 + pop rsi
1.498 + pop rbx
1.499 + pop rdx
1.500 +
1.501 + add rdi, byte SIZEOF_JSAMPROW ; outptr1
1.502 + add rsi, byte SIZEOF_JSAMPROW ; inptr01
1.503 +
1.504 + push rdx ; inptr2
1.505 + push rbx ; inptr1
1.506 + push rsi ; inptr00
1.507 + mov rbx,rsp
1.508 +
1.509 + push rdi
1.510 + push rcx
1.511 + push rax
1.512 +
1.513 + %ifdef WIN64
1.514 + mov r8, rcx
1.515 + mov r9, rdi
1.516 + mov rcx, rax
1.517 + mov rdx, rbx
1.518 + %else
1.519 + mov rdx, rcx
1.520 + mov rcx, rdi
1.521 + mov rdi, rax
1.522 + mov rsi, rbx
1.523 + %endif
1.524 +
1.525 + call EXTN(jsimd_h2v1_merged_upsample_sse2)
1.526 +
1.527 + pop rax
1.528 + pop rcx
1.529 + pop rdi
1.530 + pop rsi
1.531 + pop rbx
1.532 + pop rdx
1.533 +
1.534 + pop rbx
1.535 + uncollect_args
1.536 + pop rbp
1.537 + ret
1.538 +
1.539 +; For some reason, the OS X linker does not honor the request to align the
1.540 +; segment unless we do this.
1.541 + align 16
