1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jdmrgss2.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,519 @@
1.4 +;
1.5 +; jdmrgss2.asm - merged upsampling/color conversion (SSE2)
1.6 +;
1.7 +; Copyright 2009, 2012 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2012 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; [TAB8]
1.22 +
1.23 +%include "jcolsamp.inc"
1.24 +
1.25 +; --------------------------------------------------------------------------
1.26 +;
1.27 +; Upsample and color convert for the case of 2:1 horizontal and 1:1 vertical.
1.28 +;
1.29 +; GLOBAL(void)
1.30 +; jsimd_h2v1_merged_upsample_sse2 (JDIMENSION output_width,
1.31 +; JSAMPIMAGE input_buf,
1.32 +; JDIMENSION in_row_group_ctr,
1.33 +; JSAMPARRAY output_buf);
1.34 +;
1.35 +
1.36 +%define output_width(b) (b)+8 ; JDIMENSION output_width
1.37 +%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
1.38 +%define in_row_group_ctr(b) (b)+16 ; JDIMENSION in_row_group_ctr
1.39 +%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
1.40 +
1.41 +%define original_ebp ebp+0
1.42 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.43 +%define WK_NUM 3
1.44 +%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
1.45 +
1.46 + align 16
1.47 + global EXTN(jsimd_h2v1_merged_upsample_sse2)
1.48 +
1.49 +EXTN(jsimd_h2v1_merged_upsample_sse2):
1.50 + push ebp
1.51 + mov eax,esp ; eax = original ebp
1.52 + sub esp, byte 4
1.53 + and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.54 + mov [esp],eax
1.55 + mov ebp,esp ; ebp = aligned ebp
1.56 + lea esp, [wk(0)]
1.57 + pushpic eax ; make a room for GOT address
1.58 + push ebx
1.59 +; push ecx ; need not be preserved
1.60 +; push edx ; need not be preserved
1.61 + push esi
1.62 + push edi
1.63 +
1.64 + get_GOT ebx ; get GOT address
1.65 + movpic POINTER [gotptr], ebx ; save GOT address
1.66 +
1.67 + mov ecx, JDIMENSION [output_width(eax)] ; col
1.68 + test ecx,ecx
1.69 + jz near .return
1.70 +
1.71 + push ecx
1.72 +
1.73 + mov edi, JSAMPIMAGE [input_buf(eax)]
1.74 + mov ecx, JDIMENSION [in_row_group_ctr(eax)]
1.75 + mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
1.76 + mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
1.77 + mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
1.78 + mov edi, JSAMPARRAY [output_buf(eax)]
1.79 + mov esi, JSAMPROW [esi+ecx*SIZEOF_JSAMPROW] ; inptr0
1.80 + mov ebx, JSAMPROW [ebx+ecx*SIZEOF_JSAMPROW] ; inptr1
1.81 + mov edx, JSAMPROW [edx+ecx*SIZEOF_JSAMPROW] ; inptr2
1.82 + mov edi, JSAMPROW [edi] ; outptr
1.83 +
1.84 + pop ecx ; col
1.85 +
1.86 + alignx 16,7
1.87 +.columnloop:
1.88 + movpic eax, POINTER [gotptr] ; load GOT address (eax)
1.89 +
1.90 + movdqa xmm6, XMMWORD [ebx] ; xmm6=Cb(0123456789ABCDEF)
1.91 + movdqa xmm7, XMMWORD [edx] ; xmm7=Cr(0123456789ABCDEF)
1.92 +
1.93 + pxor xmm1,xmm1 ; xmm1=(all 0's)
1.94 + pcmpeqw xmm3,xmm3
1.95 + psllw xmm3,7 ; xmm3={0xFF80 0xFF80 0xFF80 0xFF80 ..}
1.96 +
1.97 + movdqa xmm4,xmm6
1.98 + punpckhbw xmm6,xmm1 ; xmm6=Cb(89ABCDEF)=CbH
1.99 + punpcklbw xmm4,xmm1 ; xmm4=Cb(01234567)=CbL
1.100 + movdqa xmm0,xmm7
1.101 + punpckhbw xmm7,xmm1 ; xmm7=Cr(89ABCDEF)=CrH
1.102 + punpcklbw xmm0,xmm1 ; xmm0=Cr(01234567)=CrL
1.103 +
1.104 + paddw xmm6,xmm3
1.105 + paddw xmm4,xmm3
1.106 + paddw xmm7,xmm3
1.107 + paddw xmm0,xmm3
1.108 +
1.109 + ; (Original)
1.110 + ; R = Y + 1.40200 * Cr
1.111 + ; G = Y - 0.34414 * Cb - 0.71414 * Cr
1.112 + ; B = Y + 1.77200 * Cb
1.113 + ;
1.114 + ; (This implementation)
1.115 + ; R = Y + 0.40200 * Cr + Cr
1.116 + ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
1.117 + ; B = Y - 0.22800 * Cb + Cb + Cb
1.118 +
1.119 + movdqa xmm5,xmm6 ; xmm5=CbH
1.120 + movdqa xmm2,xmm4 ; xmm2=CbL
1.121 + paddw xmm6,xmm6 ; xmm6=2*CbH
1.122 + paddw xmm4,xmm4 ; xmm4=2*CbL
1.123 + movdqa xmm1,xmm7 ; xmm1=CrH
1.124 + movdqa xmm3,xmm0 ; xmm3=CrL
1.125 + paddw xmm7,xmm7 ; xmm7=2*CrH
1.126 + paddw xmm0,xmm0 ; xmm0=2*CrL
1.127 +
1.128 + pmulhw xmm6,[GOTOFF(eax,PW_MF0228)] ; xmm6=(2*CbH * -FIX(0.22800))
1.129 + pmulhw xmm4,[GOTOFF(eax,PW_MF0228)] ; xmm4=(2*CbL * -FIX(0.22800))
1.130 + pmulhw xmm7,[GOTOFF(eax,PW_F0402)] ; xmm7=(2*CrH * FIX(0.40200))
1.131 + pmulhw xmm0,[GOTOFF(eax,PW_F0402)] ; xmm0=(2*CrL * FIX(0.40200))
1.132 +
1.133 + paddw xmm6,[GOTOFF(eax,PW_ONE)]
1.134 + paddw xmm4,[GOTOFF(eax,PW_ONE)]
1.135 + psraw xmm6,1 ; xmm6=(CbH * -FIX(0.22800))
1.136 + psraw xmm4,1 ; xmm4=(CbL * -FIX(0.22800))
1.137 + paddw xmm7,[GOTOFF(eax,PW_ONE)]
1.138 + paddw xmm0,[GOTOFF(eax,PW_ONE)]
1.139 + psraw xmm7,1 ; xmm7=(CrH * FIX(0.40200))
1.140 + psraw xmm0,1 ; xmm0=(CrL * FIX(0.40200))
1.141 +
1.142 + paddw xmm6,xmm5
1.143 + paddw xmm4,xmm2
1.144 + paddw xmm6,xmm5 ; xmm6=(CbH * FIX(1.77200))=(B-Y)H
1.145 + paddw xmm4,xmm2 ; xmm4=(CbL * FIX(1.77200))=(B-Y)L
1.146 + paddw xmm7,xmm1 ; xmm7=(CrH * FIX(1.40200))=(R-Y)H
1.147 + paddw xmm0,xmm3 ; xmm0=(CrL * FIX(1.40200))=(R-Y)L
1.148 +
1.149 + movdqa XMMWORD [wk(0)], xmm6 ; wk(0)=(B-Y)H
1.150 + movdqa XMMWORD [wk(1)], xmm7 ; wk(1)=(R-Y)H
1.151 +
1.152 + movdqa xmm6,xmm5
1.153 + movdqa xmm7,xmm2
1.154 + punpcklwd xmm5,xmm1
1.155 + punpckhwd xmm6,xmm1
1.156 + pmaddwd xmm5,[GOTOFF(eax,PW_MF0344_F0285)]
1.157 + pmaddwd xmm6,[GOTOFF(eax,PW_MF0344_F0285)]
1.158 + punpcklwd xmm2,xmm3
1.159 + punpckhwd xmm7,xmm3
1.160 + pmaddwd xmm2,[GOTOFF(eax,PW_MF0344_F0285)]
1.161 + pmaddwd xmm7,[GOTOFF(eax,PW_MF0344_F0285)]
1.162 +
1.163 + paddd xmm5,[GOTOFF(eax,PD_ONEHALF)]
1.164 + paddd xmm6,[GOTOFF(eax,PD_ONEHALF)]
1.165 + psrad xmm5,SCALEBITS
1.166 + psrad xmm6,SCALEBITS
1.167 + paddd xmm2,[GOTOFF(eax,PD_ONEHALF)]
1.168 + paddd xmm7,[GOTOFF(eax,PD_ONEHALF)]
1.169 + psrad xmm2,SCALEBITS
1.170 + psrad xmm7,SCALEBITS
1.171 +
1.172 + packssdw xmm5,xmm6 ; xmm5=CbH*-FIX(0.344)+CrH*FIX(0.285)
1.173 + packssdw xmm2,xmm7 ; xmm2=CbL*-FIX(0.344)+CrL*FIX(0.285)
1.174 + psubw xmm5,xmm1 ; xmm5=CbH*-FIX(0.344)+CrH*-FIX(0.714)=(G-Y)H
1.175 + psubw xmm2,xmm3 ; xmm2=CbL*-FIX(0.344)+CrL*-FIX(0.714)=(G-Y)L
1.176 +
1.177 + movdqa XMMWORD [wk(2)], xmm5 ; wk(2)=(G-Y)H
1.178 +
1.179 + mov al,2 ; Yctr
1.180 + jmp short .Yloop_1st
1.181 + alignx 16,7
1.182 +
1.183 +.Yloop_2nd:
1.184 + movdqa xmm0, XMMWORD [wk(1)] ; xmm0=(R-Y)H
1.185 + movdqa xmm2, XMMWORD [wk(2)] ; xmm2=(G-Y)H
1.186 + movdqa xmm4, XMMWORD [wk(0)] ; xmm4=(B-Y)H
1.187 + alignx 16,7
1.188 +
1.189 +.Yloop_1st:
1.190 + movdqa xmm7, XMMWORD [esi] ; xmm7=Y(0123456789ABCDEF)
1.191 +
1.192 + pcmpeqw xmm6,xmm6
1.193 + psrlw xmm6,BYTE_BIT ; xmm6={0xFF 0x00 0xFF 0x00 ..}
1.194 + pand xmm6,xmm7 ; xmm6=Y(02468ACE)=YE
1.195 + psrlw xmm7,BYTE_BIT ; xmm7=Y(13579BDF)=YO
1.196 +
1.197 + movdqa xmm1,xmm0 ; xmm1=xmm0=(R-Y)(L/H)
1.198 + movdqa xmm3,xmm2 ; xmm3=xmm2=(G-Y)(L/H)
1.199 + movdqa xmm5,xmm4 ; xmm5=xmm4=(B-Y)(L/H)
1.200 +
1.201 + paddw xmm0,xmm6 ; xmm0=((R-Y)+YE)=RE=R(02468ACE)
1.202 + paddw xmm1,xmm7 ; xmm1=((R-Y)+YO)=RO=R(13579BDF)
1.203 + packuswb xmm0,xmm0 ; xmm0=R(02468ACE********)
1.204 + packuswb xmm1,xmm1 ; xmm1=R(13579BDF********)
1.205 +
1.206 + paddw xmm2,xmm6 ; xmm2=((G-Y)+YE)=GE=G(02468ACE)
1.207 + paddw xmm3,xmm7 ; xmm3=((G-Y)+YO)=GO=G(13579BDF)
1.208 + packuswb xmm2,xmm2 ; xmm2=G(02468ACE********)
1.209 + packuswb xmm3,xmm3 ; xmm3=G(13579BDF********)
1.210 +
1.211 + paddw xmm4,xmm6 ; xmm4=((B-Y)+YE)=BE=B(02468ACE)
1.212 + paddw xmm5,xmm7 ; xmm5=((B-Y)+YO)=BO=B(13579BDF)
1.213 + packuswb xmm4,xmm4 ; xmm4=B(02468ACE********)
1.214 + packuswb xmm5,xmm5 ; xmm5=B(13579BDF********)
1.215 +
1.216 +%if RGB_PIXELSIZE == 3 ; ---------------
1.217 +
1.218 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.219 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.220 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.221 + ; xmmG=(** ** ** ** ** ** ** ** **), xmmH=(** ** ** ** ** ** ** ** **)
1.222 +
1.223 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.224 + punpcklbw xmmE,xmmB ; xmmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F)
1.225 + punpcklbw xmmD,xmmF ; xmmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F)
1.226 +
1.227 + movdqa xmmG,xmmA
1.228 + movdqa xmmH,xmmA
1.229 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07)
1.230 + punpckhwd xmmG,xmmE ; xmmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F)
1.231 +
1.232 + psrldq xmmH,2 ; xmmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E -- --)
1.233 + psrldq xmmE,2 ; xmmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F -- --)
1.234 +
1.235 + movdqa xmmC,xmmD
1.236 + movdqa xmmB,xmmD
1.237 + punpcklwd xmmD,xmmH ; xmmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18)
1.238 + punpckhwd xmmC,xmmH ; xmmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F -- --)
1.239 +
1.240 + psrldq xmmB,2 ; xmmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F -- --)
1.241 +
1.242 + movdqa xmmF,xmmE
1.243 + punpcklwd xmmE,xmmB ; xmmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29)
1.244 + punpckhwd xmmF,xmmB ; xmmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F -- -- -- --)
1.245 +
1.246 + pshufd xmmH,xmmA,0x4E; xmmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03)
1.247 + movdqa xmmB,xmmE
1.248 + punpckldq xmmA,xmmD ; xmmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14)
1.249 + punpckldq xmmE,xmmH ; xmmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07)
1.250 + punpckhdq xmmD,xmmB ; xmmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29)
1.251 +
1.252 + pshufd xmmH,xmmG,0x4E; xmmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B)
1.253 + movdqa xmmB,xmmF
1.254 + punpckldq xmmG,xmmC ; xmmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C)
1.255 + punpckldq xmmF,xmmH ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F)
1.256 + punpckhdq xmmC,xmmB ; xmmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F -- -- -- -- -- --)
1.257 +
1.258 + punpcklqdq xmmA,xmmE ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
1.259 + punpcklqdq xmmD,xmmG ; xmmD=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
1.260 + punpcklqdq xmmF,xmmC ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
1.261 +
1.262 + cmp ecx, byte SIZEOF_XMMWORD
1.263 + jb short .column_st32
1.264 +
1.265 + test edi, SIZEOF_XMMWORD-1
1.266 + jnz short .out1
1.267 + ; --(aligned)-------------------
1.268 + movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.269 + movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.270 + movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmF
1.271 + jmp short .out0
1.272 +.out1: ; --(unaligned)-----------------
1.273 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.274 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.275 + movdqu XMMWORD [edi+2*SIZEOF_XMMWORD], xmmF
1.276 +.out0:
1.277 + add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.278 + sub ecx, byte SIZEOF_XMMWORD
1.279 + jz near .endcolumn
1.280 +
1.281 + add esi, byte SIZEOF_XMMWORD ; inptr0
1.282 + dec al ; Yctr
1.283 + jnz near .Yloop_2nd
1.284 +
1.285 + add ebx, byte SIZEOF_XMMWORD ; inptr1
1.286 + add edx, byte SIZEOF_XMMWORD ; inptr2
1.287 + jmp near .columnloop
1.288 + alignx 16,7
1.289 +
1.290 +.column_st32:
1.291 + lea ecx, [ecx+ecx*2] ; imul ecx, RGB_PIXELSIZE
1.292 + cmp ecx, byte 2*SIZEOF_XMMWORD
1.293 + jb short .column_st16
1.294 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.295 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.296 + add edi, byte 2*SIZEOF_XMMWORD ; outptr
1.297 + movdqa xmmA,xmmF
1.298 + sub ecx, byte 2*SIZEOF_XMMWORD
1.299 + jmp short .column_st15
1.300 +.column_st16:
1.301 + cmp ecx, byte SIZEOF_XMMWORD
1.302 + jb short .column_st15
1.303 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.304 + add edi, byte SIZEOF_XMMWORD ; outptr
1.305 + movdqa xmmA,xmmD
1.306 + sub ecx, byte SIZEOF_XMMWORD
1.307 +.column_st15:
1.308 + ; Store the lower 8 bytes of xmmA to the output when it has enough
1.309 + ; space.
1.310 + cmp ecx, byte SIZEOF_MMWORD
1.311 + jb short .column_st7
1.312 + movq XMM_MMWORD [edi], xmmA
1.313 + add edi, byte SIZEOF_MMWORD
1.314 + sub ecx, byte SIZEOF_MMWORD
1.315 + psrldq xmmA, SIZEOF_MMWORD
1.316 +.column_st7:
1.317 + ; Store the lower 4 bytes of xmmA to the output when it has enough
1.318 + ; space.
1.319 + cmp ecx, byte SIZEOF_DWORD
1.320 + jb short .column_st3
1.321 + movd XMM_DWORD [edi], xmmA
1.322 + add edi, byte SIZEOF_DWORD
1.323 + sub ecx, byte SIZEOF_DWORD
1.324 + psrldq xmmA, SIZEOF_DWORD
1.325 +.column_st3:
1.326 + ; Store the lower 2 bytes of eax to the output when it has enough
1.327 + ; space.
1.328 + movd eax, xmmA
1.329 + cmp ecx, byte SIZEOF_WORD
1.330 + jb short .column_st1
1.331 + mov WORD [edi], ax
1.332 + add edi, byte SIZEOF_WORD
1.333 + sub ecx, byte SIZEOF_WORD
1.334 + shr eax, 16
1.335 +.column_st1:
1.336 + ; Store the lower 1 byte of eax to the output when it has enough
1.337 + ; space.
1.338 + test ecx, ecx
1.339 + jz short .endcolumn
1.340 + mov BYTE [edi], al
1.341 +
1.342 +%else ; RGB_PIXELSIZE == 4 ; -----------
1.343 +
1.344 +%ifdef RGBX_FILLER_0XFF
1.345 + pcmpeqb xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.346 + pcmpeqb xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.347 +%else
1.348 + pxor xmm6,xmm6 ; xmm6=XE=X(02468ACE********)
1.349 + pxor xmm7,xmm7 ; xmm7=XO=X(13579BDF********)
1.350 +%endif
1.351 + ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
1.352 + ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
1.353 + ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
1.354 + ; xmmG=(30 32 34 36 38 3A 3C 3E **), xmmH=(31 33 35 37 39 3B 3D 3F **)
1.355 +
1.356 + punpcklbw xmmA,xmmC ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
1.357 + punpcklbw xmmE,xmmG ; xmmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E)
1.358 + punpcklbw xmmB,xmmD ; xmmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F)
1.359 + punpcklbw xmmF,xmmH ; xmmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F)
1.360 +
1.361 + movdqa xmmC,xmmA
1.362 + punpcklwd xmmA,xmmE ; xmmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36)
1.363 + punpckhwd xmmC,xmmE ; xmmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E)
1.364 + movdqa xmmG,xmmB
1.365 + punpcklwd xmmB,xmmF ; xmmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37)
1.366 + punpckhwd xmmG,xmmF ; xmmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F)
1.367 +
1.368 + movdqa xmmD,xmmA
1.369 + punpckldq xmmA,xmmB ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
1.370 + punpckhdq xmmD,xmmB ; xmmD=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
1.371 + movdqa xmmH,xmmC
1.372 + punpckldq xmmC,xmmG ; xmmC=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
1.373 + punpckhdq xmmH,xmmG ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
1.374 +
1.375 + cmp ecx, byte SIZEOF_XMMWORD
1.376 + jb short .column_st32
1.377 +
1.378 + test edi, SIZEOF_XMMWORD-1
1.379 + jnz short .out1
1.380 + ; --(aligned)-------------------
1.381 + movntdq XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.382 + movntdq XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.383 + movntdq XMMWORD [edi+2*SIZEOF_XMMWORD], xmmC
1.384 + movntdq XMMWORD [edi+3*SIZEOF_XMMWORD], xmmH
1.385 + jmp short .out0
1.386 +.out1: ; --(unaligned)-----------------
1.387 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.388 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.389 + movdqu XMMWORD [edi+2*SIZEOF_XMMWORD], xmmC
1.390 + movdqu XMMWORD [edi+3*SIZEOF_XMMWORD], xmmH
1.391 +.out0:
1.392 + add edi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD ; outptr
1.393 + sub ecx, byte SIZEOF_XMMWORD
1.394 + jz near .endcolumn
1.395 +
1.396 + add esi, byte SIZEOF_XMMWORD ; inptr0
1.397 + dec al ; Yctr
1.398 + jnz near .Yloop_2nd
1.399 +
1.400 + add ebx, byte SIZEOF_XMMWORD ; inptr1
1.401 + add edx, byte SIZEOF_XMMWORD ; inptr2
1.402 + jmp near .columnloop
1.403 + alignx 16,7
1.404 +
1.405 +.column_st32:
1.406 + cmp ecx, byte SIZEOF_XMMWORD/2
1.407 + jb short .column_st16
1.408 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.409 + movdqu XMMWORD [edi+1*SIZEOF_XMMWORD], xmmD
1.410 + add edi, byte 2*SIZEOF_XMMWORD ; outptr
1.411 + movdqa xmmA,xmmC
1.412 + movdqa xmmD,xmmH
1.413 + sub ecx, byte SIZEOF_XMMWORD/2
1.414 +.column_st16:
1.415 + cmp ecx, byte SIZEOF_XMMWORD/4
1.416 + jb short .column_st15
1.417 + movdqu XMMWORD [edi+0*SIZEOF_XMMWORD], xmmA
1.418 + add edi, byte SIZEOF_XMMWORD ; outptr
1.419 + movdqa xmmA,xmmD
1.420 + sub ecx, byte SIZEOF_XMMWORD/4
1.421 +.column_st15:
1.422 + ; Store two pixels (8 bytes) of xmmA to the output when it has enough
1.423 + ; space.
1.424 + cmp ecx, byte SIZEOF_XMMWORD/8
1.425 + jb short .column_st7
1.426 + movq XMM_MMWORD [edi], xmmA
1.427 + add edi, byte SIZEOF_XMMWORD/8*4
1.428 + sub ecx, byte SIZEOF_XMMWORD/8
1.429 + psrldq xmmA, SIZEOF_XMMWORD/8*4
1.430 +.column_st7:
1.431 + ; Store one pixel (4 bytes) of xmmA to the output when it has enough
1.432 + ; space.
1.433 + test ecx, ecx
1.434 + jz short .endcolumn
1.435 + movd XMM_DWORD [edi], xmmA
1.436 +
1.437 +%endif ; RGB_PIXELSIZE ; ---------------
1.438 +
1.439 +.endcolumn:
1.440 + sfence ; flush the write buffer
1.441 +
1.442 +.return:
1.443 + pop edi
1.444 + pop esi
1.445 +; pop edx ; need not be preserved
1.446 +; pop ecx ; need not be preserved
1.447 + pop ebx
1.448 + mov esp,ebp ; esp <- aligned ebp
1.449 + pop esp ; esp <- original ebp
1.450 + pop ebp
1.451 + ret
1.452 +
1.453 +; --------------------------------------------------------------------------
1.454 +;
1.455 +; Upsample and color convert for the case of 2:1 horizontal and 2:1 vertical.
1.456 +;
1.457 +; GLOBAL(void)
1.458 +; jsimd_h2v2_merged_upsample_sse2 (JDIMENSION output_width,
1.459 +; JSAMPIMAGE input_buf,
1.460 +; JDIMENSION in_row_group_ctr,
1.461 +; JSAMPARRAY output_buf);
1.462 +;
1.463 +
1.464 +%define output_width(b) (b)+8 ; JDIMENSION output_width
1.465 +%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
1.466 +%define in_row_group_ctr(b) (b)+16 ; JDIMENSION in_row_group_ctr
1.467 +%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
1.468 +
1.469 + align 16
1.470 + global EXTN(jsimd_h2v2_merged_upsample_sse2)
1.471 +
1.472 +EXTN(jsimd_h2v2_merged_upsample_sse2):
1.473 + push ebp
1.474 + mov ebp,esp
1.475 + push ebx
1.476 +; push ecx ; need not be preserved
1.477 +; push edx ; need not be preserved
1.478 + push esi
1.479 + push edi
1.480 +
1.481 + mov eax, POINTER [output_width(ebp)]
1.482 +
1.483 + mov edi, JSAMPIMAGE [input_buf(ebp)]
1.484 + mov ecx, JDIMENSION [in_row_group_ctr(ebp)]
1.485 + mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
1.486 + mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
1.487 + mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
1.488 + mov edi, JSAMPARRAY [output_buf(ebp)]
1.489 + lea esi, [esi+ecx*SIZEOF_JSAMPROW]
1.490 +
1.491 + push edx ; inptr2
1.492 + push ebx ; inptr1
1.493 + push esi ; inptr00
1.494 + mov ebx,esp
1.495 +
1.496 + push edi ; output_buf (outptr0)
1.497 + push ecx ; in_row_group_ctr
1.498 + push ebx ; input_buf
1.499 + push eax ; output_width
1.500 +
1.501 + call near EXTN(jsimd_h2v1_merged_upsample_sse2)
1.502 +
1.503 + add esi, byte SIZEOF_JSAMPROW ; inptr01
1.504 + add edi, byte SIZEOF_JSAMPROW ; outptr1
1.505 + mov POINTER [ebx+0*SIZEOF_POINTER], esi
1.506 + mov POINTER [ebx-1*SIZEOF_POINTER], edi
1.507 +
1.508 + call near EXTN(jsimd_h2v1_merged_upsample_sse2)
1.509 +
1.510 + add esp, byte 7*SIZEOF_DWORD
1.511 +
1.512 + pop edi
1.513 + pop esi
1.514 +; pop edx ; need not be preserved
1.515 +; pop ecx ; need not be preserved
1.516 + pop ebx
1.517 + pop ebp
1.518 + ret
1.519 +
1.520 +; For some reason, the OS X linker does not honor the request to align the
1.521 +; segment unless we do this.
1.522 + align 16
