1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jfsseflt-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,358 @@
1.4 +;
1.5 +; jfsseflt-64.asm - floating-point FDCT (64-bit SSE)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; This file contains a floating-point implementation of the forward DCT
1.22 +; (Discrete Cosine Transform). The following code is based directly on
1.23 +; the IJG's original jfdctflt.c; see the jfdctflt.c for more details.
1.24 +;
1.25 +; [TAB8]
1.26 +
1.27 +%include "jsimdext.inc"
1.28 +%include "jdct.inc"
1.29 +
1.30 +; --------------------------------------------------------------------------
1.31 +
1.32 +%macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5)
1.33 + shufps %1,%2,0x44
1.34 +%endmacro
1.35 +
1.36 +%macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7)
1.37 + shufps %1,%2,0xEE
1.38 +%endmacro
1.39 +
1.40 +; --------------------------------------------------------------------------
1.41 + SECTION SEG_CONST
1.42 +
1.43 + alignz 16
1.44 + global EXTN(jconst_fdct_float_sse)
1.45 +
1.46 +EXTN(jconst_fdct_float_sse):
1.47 +
1.48 +PD_0_382 times 4 dd 0.382683432365089771728460
1.49 +PD_0_707 times 4 dd 0.707106781186547524400844
1.50 +PD_0_541 times 4 dd 0.541196100146196984399723
1.51 +PD_1_306 times 4 dd 1.306562964876376527856643
1.52 +
1.53 + alignz 16
1.54 +
1.55 +; --------------------------------------------------------------------------
1.56 + SECTION SEG_TEXT
1.57 + BITS 64
1.58 +;
1.59 +; Perform the forward DCT on one block of samples.
1.60 +;
1.61 +; GLOBAL(void)
1.62 +; jsimd_fdct_float_sse (FAST_FLOAT * data)
1.63 +;
1.64 +
1.65 +; r10 = FAST_FLOAT * data
1.66 +
1.67 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.68 +%define WK_NUM 2
1.69 +
1.70 + align 16
1.71 + global EXTN(jsimd_fdct_float_sse)
1.72 +
1.73 +EXTN(jsimd_fdct_float_sse):
1.74 + push rbp
1.75 + mov rax,rsp ; rax = original rbp
1.76 + sub rsp, byte 4
1.77 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.78 + mov [rsp],rax
1.79 + mov rbp,rsp ; rbp = aligned rbp
1.80 + lea rsp, [wk(0)]
1.81 + collect_args
1.82 +
1.83 + ; ---- Pass 1: process rows.
1.84 +
1.85 + mov rdx, r10 ; (FAST_FLOAT *)
1.86 + mov rcx, DCTSIZE/4
1.87 +.rowloop:
1.88 +
1.89 + movaps xmm0, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)]
1.90 + movaps xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)]
1.91 + movaps xmm2, XMMWORD [XMMBLOCK(2,1,rdx,SIZEOF_FAST_FLOAT)]
1.92 + movaps xmm3, XMMWORD [XMMBLOCK(3,1,rdx,SIZEOF_FAST_FLOAT)]
1.93 +
1.94 + ; xmm0=(20 21 22 23), xmm2=(24 25 26 27)
1.95 + ; xmm1=(30 31 32 33), xmm3=(34 35 36 37)
1.96 +
1.97 + movaps xmm4,xmm0 ; transpose coefficients(phase 1)
1.98 + unpcklps xmm0,xmm1 ; xmm0=(20 30 21 31)
1.99 + unpckhps xmm4,xmm1 ; xmm4=(22 32 23 33)
1.100 + movaps xmm5,xmm2 ; transpose coefficients(phase 1)
1.101 + unpcklps xmm2,xmm3 ; xmm2=(24 34 25 35)
1.102 + unpckhps xmm5,xmm3 ; xmm5=(26 36 27 37)
1.103 +
1.104 + movaps xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)]
1.105 + movaps xmm7, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)]
1.106 + movaps xmm1, XMMWORD [XMMBLOCK(0,1,rdx,SIZEOF_FAST_FLOAT)]
1.107 + movaps xmm3, XMMWORD [XMMBLOCK(1,1,rdx,SIZEOF_FAST_FLOAT)]
1.108 +
1.109 + ; xmm6=(00 01 02 03), xmm1=(04 05 06 07)
1.110 + ; xmm7=(10 11 12 13), xmm3=(14 15 16 17)
1.111 +
1.112 + movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 32 23 33)
1.113 + movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(24 34 25 35)
1.114 +
1.115 + movaps xmm4,xmm6 ; transpose coefficients(phase 1)
1.116 + unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11)
1.117 + unpckhps xmm4,xmm7 ; xmm4=(02 12 03 13)
1.118 + movaps xmm2,xmm1 ; transpose coefficients(phase 1)
1.119 + unpcklps xmm1,xmm3 ; xmm1=(04 14 05 15)
1.120 + unpckhps xmm2,xmm3 ; xmm2=(06 16 07 17)
1.121 +
1.122 + movaps xmm7,xmm6 ; transpose coefficients(phase 2)
1.123 + unpcklps2 xmm6,xmm0 ; xmm6=(00 10 20 30)=data0
1.124 + unpckhps2 xmm7,xmm0 ; xmm7=(01 11 21 31)=data1
1.125 + movaps xmm3,xmm2 ; transpose coefficients(phase 2)
1.126 + unpcklps2 xmm2,xmm5 ; xmm2=(06 16 26 36)=data6
1.127 + unpckhps2 xmm3,xmm5 ; xmm3=(07 17 27 37)=data7
1.128 +
1.129 + movaps xmm0,xmm7
1.130 + movaps xmm5,xmm6
1.131 + subps xmm7,xmm2 ; xmm7=data1-data6=tmp6
1.132 + subps xmm6,xmm3 ; xmm6=data0-data7=tmp7
1.133 + addps xmm0,xmm2 ; xmm0=data1+data6=tmp1
1.134 + addps xmm5,xmm3 ; xmm5=data0+data7=tmp0
1.135 +
1.136 + movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 32 23 33)
1.137 + movaps xmm3, XMMWORD [wk(1)] ; xmm3=(24 34 25 35)
1.138 + movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6
1.139 + movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
1.140 +
1.141 + movaps xmm7,xmm4 ; transpose coefficients(phase 2)
1.142 + unpcklps2 xmm4,xmm2 ; xmm4=(02 12 22 32)=data2
1.143 + unpckhps2 xmm7,xmm2 ; xmm7=(03 13 23 33)=data3
1.144 + movaps xmm6,xmm1 ; transpose coefficients(phase 2)
1.145 + unpcklps2 xmm1,xmm3 ; xmm1=(04 14 24 34)=data4
1.146 + unpckhps2 xmm6,xmm3 ; xmm6=(05 15 25 35)=data5
1.147 +
1.148 + movaps xmm2,xmm7
1.149 + movaps xmm3,xmm4
1.150 + addps xmm7,xmm1 ; xmm7=data3+data4=tmp3
1.151 + addps xmm4,xmm6 ; xmm4=data2+data5=tmp2
1.152 + subps xmm2,xmm1 ; xmm2=data3-data4=tmp4
1.153 + subps xmm3,xmm6 ; xmm3=data2-data5=tmp5
1.154 +
1.155 + ; -- Even part
1.156 +
1.157 + movaps xmm1,xmm5
1.158 + movaps xmm6,xmm0
1.159 + subps xmm5,xmm7 ; xmm5=tmp13
1.160 + subps xmm0,xmm4 ; xmm0=tmp12
1.161 + addps xmm1,xmm7 ; xmm1=tmp10
1.162 + addps xmm6,xmm4 ; xmm6=tmp11
1.163 +
1.164 + addps xmm0,xmm5
1.165 + mulps xmm0,[rel PD_0_707] ; xmm0=z1
1.166 +
1.167 + movaps xmm7,xmm1
1.168 + movaps xmm4,xmm5
1.169 + subps xmm1,xmm6 ; xmm1=data4
1.170 + subps xmm5,xmm0 ; xmm5=data6
1.171 + addps xmm7,xmm6 ; xmm7=data0
1.172 + addps xmm4,xmm0 ; xmm4=data2
1.173 +
1.174 + movaps XMMWORD [XMMBLOCK(0,1,rdx,SIZEOF_FAST_FLOAT)], xmm1
1.175 + movaps XMMWORD [XMMBLOCK(2,1,rdx,SIZEOF_FAST_FLOAT)], xmm5
1.176 + movaps XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)], xmm7
1.177 + movaps XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)], xmm4
1.178 +
1.179 + ; -- Odd part
1.180 +
1.181 + movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6
1.182 + movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7
1.183 +
1.184 + addps xmm2,xmm3 ; xmm2=tmp10
1.185 + addps xmm3,xmm6 ; xmm3=tmp11
1.186 + addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7
1.187 +
1.188 + mulps xmm3,[rel PD_0_707] ; xmm3=z3
1.189 +
1.190 + movaps xmm1,xmm2 ; xmm1=tmp10
1.191 + subps xmm2,xmm6
1.192 + mulps xmm2,[rel PD_0_382] ; xmm2=z5
1.193 + mulps xmm1,[rel PD_0_541] ; xmm1=MULTIPLY(tmp10,FIX_0_541196)
1.194 + mulps xmm6,[rel PD_1_306] ; xmm6=MULTIPLY(tmp12,FIX_1_306562)
1.195 + addps xmm1,xmm2 ; xmm1=z2
1.196 + addps xmm6,xmm2 ; xmm6=z4
1.197 +
1.198 + movaps xmm5,xmm0
1.199 + subps xmm0,xmm3 ; xmm0=z13
1.200 + addps xmm5,xmm3 ; xmm5=z11
1.201 +
1.202 + movaps xmm7,xmm0
1.203 + movaps xmm4,xmm5
1.204 + subps xmm0,xmm1 ; xmm0=data3
1.205 + subps xmm5,xmm6 ; xmm5=data7
1.206 + addps xmm7,xmm1 ; xmm7=data5
1.207 + addps xmm4,xmm6 ; xmm4=data1
1.208 +
1.209 + movaps XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)], xmm0
1.210 + movaps XMMWORD [XMMBLOCK(3,1,rdx,SIZEOF_FAST_FLOAT)], xmm5
1.211 + movaps XMMWORD [XMMBLOCK(1,1,rdx,SIZEOF_FAST_FLOAT)], xmm7
1.212 + movaps XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)], xmm4
1.213 +
1.214 + add rdx, 4*DCTSIZE*SIZEOF_FAST_FLOAT
1.215 + dec rcx
1.216 + jnz near .rowloop
1.217 +
1.218 + ; ---- Pass 2: process columns.
1.219 +
1.220 + mov rdx, r10 ; (FAST_FLOAT *)
1.221 + mov rcx, DCTSIZE/4
1.222 +.columnloop:
1.223 +
1.224 + movaps xmm0, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)]
1.225 + movaps xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)]
1.226 + movaps xmm2, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_FAST_FLOAT)]
1.227 + movaps xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_FAST_FLOAT)]
1.228 +
1.229 + ; xmm0=(02 12 22 32), xmm2=(42 52 62 72)
1.230 + ; xmm1=(03 13 23 33), xmm3=(43 53 63 73)
1.231 +
1.232 + movaps xmm4,xmm0 ; transpose coefficients(phase 1)
1.233 + unpcklps xmm0,xmm1 ; xmm0=(02 03 12 13)
1.234 + unpckhps xmm4,xmm1 ; xmm4=(22 23 32 33)
1.235 + movaps xmm5,xmm2 ; transpose coefficients(phase 1)
1.236 + unpcklps xmm2,xmm3 ; xmm2=(42 43 52 53)
1.237 + unpckhps xmm5,xmm3 ; xmm5=(62 63 72 73)
1.238 +
1.239 + movaps xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)]
1.240 + movaps xmm7, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)]
1.241 + movaps xmm1, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_FAST_FLOAT)]
1.242 + movaps xmm3, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_FAST_FLOAT)]
1.243 +
1.244 + ; xmm6=(00 10 20 30), xmm1=(40 50 60 70)
1.245 + ; xmm7=(01 11 21 31), xmm3=(41 51 61 71)
1.246 +
1.247 + movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 23 32 33)
1.248 + movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(42 43 52 53)
1.249 +
1.250 + movaps xmm4,xmm6 ; transpose coefficients(phase 1)
1.251 + unpcklps xmm6,xmm7 ; xmm6=(00 01 10 11)
1.252 + unpckhps xmm4,xmm7 ; xmm4=(20 21 30 31)
1.253 + movaps xmm2,xmm1 ; transpose coefficients(phase 1)
1.254 + unpcklps xmm1,xmm3 ; xmm1=(40 41 50 51)
1.255 + unpckhps xmm2,xmm3 ; xmm2=(60 61 70 71)
1.256 +
1.257 + movaps xmm7,xmm6 ; transpose coefficients(phase 2)
1.258 + unpcklps2 xmm6,xmm0 ; xmm6=(00 01 02 03)=data0
1.259 + unpckhps2 xmm7,xmm0 ; xmm7=(10 11 12 13)=data1
1.260 + movaps xmm3,xmm2 ; transpose coefficients(phase 2)
1.261 + unpcklps2 xmm2,xmm5 ; xmm2=(60 61 62 63)=data6
1.262 + unpckhps2 xmm3,xmm5 ; xmm3=(70 71 72 73)=data7
1.263 +
1.264 + movaps xmm0,xmm7
1.265 + movaps xmm5,xmm6
1.266 + subps xmm7,xmm2 ; xmm7=data1-data6=tmp6
1.267 + subps xmm6,xmm3 ; xmm6=data0-data7=tmp7
1.268 + addps xmm0,xmm2 ; xmm0=data1+data6=tmp1
1.269 + addps xmm5,xmm3 ; xmm5=data0+data7=tmp0
1.270 +
1.271 + movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 23 32 33)
1.272 + movaps xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53)
1.273 + movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6
1.274 + movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
1.275 +
1.276 + movaps xmm7,xmm4 ; transpose coefficients(phase 2)
1.277 + unpcklps2 xmm4,xmm2 ; xmm4=(20 21 22 23)=data2
1.278 + unpckhps2 xmm7,xmm2 ; xmm7=(30 31 32 33)=data3
1.279 + movaps xmm6,xmm1 ; transpose coefficients(phase 2)
1.280 + unpcklps2 xmm1,xmm3 ; xmm1=(40 41 42 43)=data4
1.281 + unpckhps2 xmm6,xmm3 ; xmm6=(50 51 52 53)=data5
1.282 +
1.283 + movaps xmm2,xmm7
1.284 + movaps xmm3,xmm4
1.285 + addps xmm7,xmm1 ; xmm7=data3+data4=tmp3
1.286 + addps xmm4,xmm6 ; xmm4=data2+data5=tmp2
1.287 + subps xmm2,xmm1 ; xmm2=data3-data4=tmp4
1.288 + subps xmm3,xmm6 ; xmm3=data2-data5=tmp5
1.289 +
1.290 + ; -- Even part
1.291 +
1.292 + movaps xmm1,xmm5
1.293 + movaps xmm6,xmm0
1.294 + subps xmm5,xmm7 ; xmm5=tmp13
1.295 + subps xmm0,xmm4 ; xmm0=tmp12
1.296 + addps xmm1,xmm7 ; xmm1=tmp10
1.297 + addps xmm6,xmm4 ; xmm6=tmp11
1.298 +
1.299 + addps xmm0,xmm5
1.300 + mulps xmm0,[rel PD_0_707] ; xmm0=z1
1.301 +
1.302 + movaps xmm7,xmm1
1.303 + movaps xmm4,xmm5
1.304 + subps xmm1,xmm6 ; xmm1=data4
1.305 + subps xmm5,xmm0 ; xmm5=data6
1.306 + addps xmm7,xmm6 ; xmm7=data0
1.307 + addps xmm4,xmm0 ; xmm4=data2
1.308 +
1.309 + movaps XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_FAST_FLOAT)], xmm1
1.310 + movaps XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_FAST_FLOAT)], xmm5
1.311 + movaps XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FAST_FLOAT)], xmm7
1.312 + movaps XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FAST_FLOAT)], xmm4
1.313 +
1.314 + ; -- Odd part
1.315 +
1.316 + movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6
1.317 + movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7
1.318 +
1.319 + addps xmm2,xmm3 ; xmm2=tmp10
1.320 + addps xmm3,xmm6 ; xmm3=tmp11
1.321 + addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7
1.322 +
1.323 + mulps xmm3,[rel PD_0_707] ; xmm3=z3
1.324 +
1.325 + movaps xmm1,xmm2 ; xmm1=tmp10
1.326 + subps xmm2,xmm6
1.327 + mulps xmm2,[rel PD_0_382] ; xmm2=z5
1.328 + mulps xmm1,[rel PD_0_541] ; xmm1=MULTIPLY(tmp10,FIX_0_541196)
1.329 + mulps xmm6,[rel PD_1_306] ; xmm6=MULTIPLY(tmp12,FIX_1_306562)
1.330 + addps xmm1,xmm2 ; xmm1=z2
1.331 + addps xmm6,xmm2 ; xmm6=z4
1.332 +
1.333 + movaps xmm5,xmm0
1.334 + subps xmm0,xmm3 ; xmm0=z13
1.335 + addps xmm5,xmm3 ; xmm5=z11
1.336 +
1.337 + movaps xmm7,xmm0
1.338 + movaps xmm4,xmm5
1.339 + subps xmm0,xmm1 ; xmm0=data3
1.340 + subps xmm5,xmm6 ; xmm5=data7
1.341 + addps xmm7,xmm1 ; xmm7=data5
1.342 + addps xmm4,xmm6 ; xmm4=data1
1.343 +
1.344 + movaps XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FAST_FLOAT)], xmm0
1.345 + movaps XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_FAST_FLOAT)], xmm5
1.346 + movaps XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_FAST_FLOAT)], xmm7
1.347 + movaps XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FAST_FLOAT)], xmm4
1.348 +
1.349 + add rdx, byte 4*SIZEOF_FAST_FLOAT
1.350 + dec rcx
1.351 + jnz near .columnloop
1.352 +
1.353 + uncollect_args
1.354 + mov rsp,rbp ; rsp <- aligned rbp
1.355 + pop rsp ; rsp <- original rbp
1.356 + pop rbp
1.357 + ret
1.358 +
1.359 +; For some reason, the OS X linker does not honor the request to align the
1.360 +; segment unless we do this.
1.361 + align 16
