1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jfsseflt.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,370 @@
1.4 +;
1.5 +; jfsseflt.asm - floating-point FDCT (SSE)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +;
1.9 +; Based on
1.10 +; x86 SIMD extension for IJG JPEG library
1.11 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.12 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.13 +;
1.14 +; This file should be assembled with NASM (Netwide Assembler),
1.15 +; can *not* be assembled with Microsoft's MASM or any compatible
1.16 +; assembler (including Borland's Turbo Assembler).
1.17 +; NASM is available from http://nasm.sourceforge.net/ or
1.18 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.19 +;
1.20 +; This file contains a floating-point implementation of the forward DCT
1.21 +; (Discrete Cosine Transform). The following code is based directly on
1.22 +; the IJG's original jfdctflt.c; see the jfdctflt.c for more details.
1.23 +;
1.24 +; [TAB8]
1.25 +
1.26 +%include "jsimdext.inc"
1.27 +%include "jdct.inc"
1.28 +
1.29 +; --------------------------------------------------------------------------
1.30 +
1.31 +%macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5)
1.32 + shufps %1,%2,0x44
1.33 +%endmacro
1.34 +
1.35 +%macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7)
1.36 + shufps %1,%2,0xEE
1.37 +%endmacro
1.38 +
1.39 +; --------------------------------------------------------------------------
1.40 + SECTION SEG_CONST
1.41 +
1.42 + alignz 16
1.43 + global EXTN(jconst_fdct_float_sse)
1.44 +
1.45 +EXTN(jconst_fdct_float_sse):
1.46 +
1.47 +PD_0_382 times 4 dd 0.382683432365089771728460
1.48 +PD_0_707 times 4 dd 0.707106781186547524400844
1.49 +PD_0_541 times 4 dd 0.541196100146196984399723
1.50 +PD_1_306 times 4 dd 1.306562964876376527856643
1.51 +
1.52 + alignz 16
1.53 +
1.54 +; --------------------------------------------------------------------------
1.55 + SECTION SEG_TEXT
1.56 + BITS 32
1.57 +;
1.58 +; Perform the forward DCT on one block of samples.
1.59 +;
1.60 +; GLOBAL(void)
1.61 +; jsimd_fdct_float_sse (FAST_FLOAT * data)
1.62 +;
1.63 +
1.64 +%define data(b) (b)+8 ; FAST_FLOAT * data
1.65 +
1.66 +%define original_ebp ebp+0
1.67 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.68 +%define WK_NUM 2
1.69 +
1.70 + align 16
1.71 + global EXTN(jsimd_fdct_float_sse)
1.72 +
1.73 +EXTN(jsimd_fdct_float_sse):
1.74 + push ebp
1.75 + mov eax,esp ; eax = original ebp
1.76 + sub esp, byte 4
1.77 + and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.78 + mov [esp],eax
1.79 + mov ebp,esp ; ebp = aligned ebp
1.80 + lea esp, [wk(0)]
1.81 + pushpic ebx
1.82 +; push ecx ; need not be preserved
1.83 +; push edx ; need not be preserved
1.84 +; push esi ; unused
1.85 +; push edi ; unused
1.86 +
1.87 + get_GOT ebx ; get GOT address
1.88 +
1.89 + ; ---- Pass 1: process rows.
1.90 +
1.91 + mov edx, POINTER [data(eax)] ; (FAST_FLOAT *)
1.92 + mov ecx, DCTSIZE/4
1.93 + alignx 16,7
1.94 +.rowloop:
1.95 +
1.96 + movaps xmm0, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)]
1.97 + movaps xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)]
1.98 + movaps xmm2, XMMWORD [XMMBLOCK(2,1,edx,SIZEOF_FAST_FLOAT)]
1.99 + movaps xmm3, XMMWORD [XMMBLOCK(3,1,edx,SIZEOF_FAST_FLOAT)]
1.100 +
1.101 + ; xmm0=(20 21 22 23), xmm2=(24 25 26 27)
1.102 + ; xmm1=(30 31 32 33), xmm3=(34 35 36 37)
1.103 +
1.104 + movaps xmm4,xmm0 ; transpose coefficients(phase 1)
1.105 + unpcklps xmm0,xmm1 ; xmm0=(20 30 21 31)
1.106 + unpckhps xmm4,xmm1 ; xmm4=(22 32 23 33)
1.107 + movaps xmm5,xmm2 ; transpose coefficients(phase 1)
1.108 + unpcklps xmm2,xmm3 ; xmm2=(24 34 25 35)
1.109 + unpckhps xmm5,xmm3 ; xmm5=(26 36 27 37)
1.110 +
1.111 + movaps xmm6, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
1.112 + movaps xmm7, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
1.113 + movaps xmm1, XMMWORD [XMMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
1.114 + movaps xmm3, XMMWORD [XMMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
1.115 +
1.116 + ; xmm6=(00 01 02 03), xmm1=(04 05 06 07)
1.117 + ; xmm7=(10 11 12 13), xmm3=(14 15 16 17)
1.118 +
1.119 + movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 32 23 33)
1.120 + movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(24 34 25 35)
1.121 +
1.122 + movaps xmm4,xmm6 ; transpose coefficients(phase 1)
1.123 + unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11)
1.124 + unpckhps xmm4,xmm7 ; xmm4=(02 12 03 13)
1.125 + movaps xmm2,xmm1 ; transpose coefficients(phase 1)
1.126 + unpcklps xmm1,xmm3 ; xmm1=(04 14 05 15)
1.127 + unpckhps xmm2,xmm3 ; xmm2=(06 16 07 17)
1.128 +
1.129 + movaps xmm7,xmm6 ; transpose coefficients(phase 2)
1.130 + unpcklps2 xmm6,xmm0 ; xmm6=(00 10 20 30)=data0
1.131 + unpckhps2 xmm7,xmm0 ; xmm7=(01 11 21 31)=data1
1.132 + movaps xmm3,xmm2 ; transpose coefficients(phase 2)
1.133 + unpcklps2 xmm2,xmm5 ; xmm2=(06 16 26 36)=data6
1.134 + unpckhps2 xmm3,xmm5 ; xmm3=(07 17 27 37)=data7
1.135 +
1.136 + movaps xmm0,xmm7
1.137 + movaps xmm5,xmm6
1.138 + subps xmm7,xmm2 ; xmm7=data1-data6=tmp6
1.139 + subps xmm6,xmm3 ; xmm6=data0-data7=tmp7
1.140 + addps xmm0,xmm2 ; xmm0=data1+data6=tmp1
1.141 + addps xmm5,xmm3 ; xmm5=data0+data7=tmp0
1.142 +
1.143 + movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 32 23 33)
1.144 + movaps xmm3, XMMWORD [wk(1)] ; xmm3=(24 34 25 35)
1.145 + movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6
1.146 + movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
1.147 +
1.148 + movaps xmm7,xmm4 ; transpose coefficients(phase 2)
1.149 + unpcklps2 xmm4,xmm2 ; xmm4=(02 12 22 32)=data2
1.150 + unpckhps2 xmm7,xmm2 ; xmm7=(03 13 23 33)=data3
1.151 + movaps xmm6,xmm1 ; transpose coefficients(phase 2)
1.152 + unpcklps2 xmm1,xmm3 ; xmm1=(04 14 24 34)=data4
1.153 + unpckhps2 xmm6,xmm3 ; xmm6=(05 15 25 35)=data5
1.154 +
1.155 + movaps xmm2,xmm7
1.156 + movaps xmm3,xmm4
1.157 + addps xmm7,xmm1 ; xmm7=data3+data4=tmp3
1.158 + addps xmm4,xmm6 ; xmm4=data2+data5=tmp2
1.159 + subps xmm2,xmm1 ; xmm2=data3-data4=tmp4
1.160 + subps xmm3,xmm6 ; xmm3=data2-data5=tmp5
1.161 +
1.162 + ; -- Even part
1.163 +
1.164 + movaps xmm1,xmm5
1.165 + movaps xmm6,xmm0
1.166 + subps xmm5,xmm7 ; xmm5=tmp13
1.167 + subps xmm0,xmm4 ; xmm0=tmp12
1.168 + addps xmm1,xmm7 ; xmm1=tmp10
1.169 + addps xmm6,xmm4 ; xmm6=tmp11
1.170 +
1.171 + addps xmm0,xmm5
1.172 + mulps xmm0,[GOTOFF(ebx,PD_0_707)] ; xmm0=z1
1.173 +
1.174 + movaps xmm7,xmm1
1.175 + movaps xmm4,xmm5
1.176 + subps xmm1,xmm6 ; xmm1=data4
1.177 + subps xmm5,xmm0 ; xmm5=data6
1.178 + addps xmm7,xmm6 ; xmm7=data0
1.179 + addps xmm4,xmm0 ; xmm4=data2
1.180 +
1.181 + movaps XMMWORD [XMMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)], xmm1
1.182 + movaps XMMWORD [XMMBLOCK(2,1,edx,SIZEOF_FAST_FLOAT)], xmm5
1.183 + movaps XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], xmm7
1.184 + movaps XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)], xmm4
1.185 +
1.186 + ; -- Odd part
1.187 +
1.188 + movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6
1.189 + movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7
1.190 +
1.191 + addps xmm2,xmm3 ; xmm2=tmp10
1.192 + addps xmm3,xmm6 ; xmm3=tmp11
1.193 + addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7
1.194 +
1.195 + mulps xmm3,[GOTOFF(ebx,PD_0_707)] ; xmm3=z3
1.196 +
1.197 + movaps xmm1,xmm2 ; xmm1=tmp10
1.198 + subps xmm2,xmm6
1.199 + mulps xmm2,[GOTOFF(ebx,PD_0_382)] ; xmm2=z5
1.200 + mulps xmm1,[GOTOFF(ebx,PD_0_541)] ; xmm1=MULTIPLY(tmp10,FIX_0_541196)
1.201 + mulps xmm6,[GOTOFF(ebx,PD_1_306)] ; xmm6=MULTIPLY(tmp12,FIX_1_306562)
1.202 + addps xmm1,xmm2 ; xmm1=z2
1.203 + addps xmm6,xmm2 ; xmm6=z4
1.204 +
1.205 + movaps xmm5,xmm0
1.206 + subps xmm0,xmm3 ; xmm0=z13
1.207 + addps xmm5,xmm3 ; xmm5=z11
1.208 +
1.209 + movaps xmm7,xmm0
1.210 + movaps xmm4,xmm5
1.211 + subps xmm0,xmm1 ; xmm0=data3
1.212 + subps xmm5,xmm6 ; xmm5=data7
1.213 + addps xmm7,xmm1 ; xmm7=data5
1.214 + addps xmm4,xmm6 ; xmm4=data1
1.215 +
1.216 + movaps XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)], xmm0
1.217 + movaps XMMWORD [XMMBLOCK(3,1,edx,SIZEOF_FAST_FLOAT)], xmm5
1.218 + movaps XMMWORD [XMMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)], xmm7
1.219 + movaps XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], xmm4
1.220 +
1.221 + add edx, 4*DCTSIZE*SIZEOF_FAST_FLOAT
1.222 + dec ecx
1.223 + jnz near .rowloop
1.224 +
1.225 + ; ---- Pass 2: process columns.
1.226 +
1.227 + mov edx, POINTER [data(eax)] ; (FAST_FLOAT *)
1.228 + mov ecx, DCTSIZE/4
1.229 + alignx 16,7
1.230 +.columnloop:
1.231 +
1.232 + movaps xmm0, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)]
1.233 + movaps xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)]
1.234 + movaps xmm2, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)]
1.235 + movaps xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)]
1.236 +
1.237 + ; xmm0=(02 12 22 32), xmm2=(42 52 62 72)
1.238 + ; xmm1=(03 13 23 33), xmm3=(43 53 63 73)
1.239 +
1.240 + movaps xmm4,xmm0 ; transpose coefficients(phase 1)
1.241 + unpcklps xmm0,xmm1 ; xmm0=(02 03 12 13)
1.242 + unpckhps xmm4,xmm1 ; xmm4=(22 23 32 33)
1.243 + movaps xmm5,xmm2 ; transpose coefficients(phase 1)
1.244 + unpcklps xmm2,xmm3 ; xmm2=(42 43 52 53)
1.245 + unpckhps xmm5,xmm3 ; xmm5=(62 63 72 73)
1.246 +
1.247 + movaps xmm6, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
1.248 + movaps xmm7, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
1.249 + movaps xmm1, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)]
1.250 + movaps xmm3, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)]
1.251 +
1.252 + ; xmm6=(00 10 20 30), xmm1=(40 50 60 70)
1.253 + ; xmm7=(01 11 21 31), xmm3=(41 51 61 71)
1.254 +
1.255 + movaps XMMWORD [wk(0)], xmm4 ; wk(0)=(22 23 32 33)
1.256 + movaps XMMWORD [wk(1)], xmm2 ; wk(1)=(42 43 52 53)
1.257 +
1.258 + movaps xmm4,xmm6 ; transpose coefficients(phase 1)
1.259 + unpcklps xmm6,xmm7 ; xmm6=(00 01 10 11)
1.260 + unpckhps xmm4,xmm7 ; xmm4=(20 21 30 31)
1.261 + movaps xmm2,xmm1 ; transpose coefficients(phase 1)
1.262 + unpcklps xmm1,xmm3 ; xmm1=(40 41 50 51)
1.263 + unpckhps xmm2,xmm3 ; xmm2=(60 61 70 71)
1.264 +
1.265 + movaps xmm7,xmm6 ; transpose coefficients(phase 2)
1.266 + unpcklps2 xmm6,xmm0 ; xmm6=(00 01 02 03)=data0
1.267 + unpckhps2 xmm7,xmm0 ; xmm7=(10 11 12 13)=data1
1.268 + movaps xmm3,xmm2 ; transpose coefficients(phase 2)
1.269 + unpcklps2 xmm2,xmm5 ; xmm2=(60 61 62 63)=data6
1.270 + unpckhps2 xmm3,xmm5 ; xmm3=(70 71 72 73)=data7
1.271 +
1.272 + movaps xmm0,xmm7
1.273 + movaps xmm5,xmm6
1.274 + subps xmm7,xmm2 ; xmm7=data1-data6=tmp6
1.275 + subps xmm6,xmm3 ; xmm6=data0-data7=tmp7
1.276 + addps xmm0,xmm2 ; xmm0=data1+data6=tmp1
1.277 + addps xmm5,xmm3 ; xmm5=data0+data7=tmp0
1.278 +
1.279 + movaps xmm2, XMMWORD [wk(0)] ; xmm2=(22 23 32 33)
1.280 + movaps xmm3, XMMWORD [wk(1)] ; xmm3=(42 43 52 53)
1.281 + movaps XMMWORD [wk(0)], xmm7 ; wk(0)=tmp6
1.282 + movaps XMMWORD [wk(1)], xmm6 ; wk(1)=tmp7
1.283 +
1.284 + movaps xmm7,xmm4 ; transpose coefficients(phase 2)
1.285 + unpcklps2 xmm4,xmm2 ; xmm4=(20 21 22 23)=data2
1.286 + unpckhps2 xmm7,xmm2 ; xmm7=(30 31 32 33)=data3
1.287 + movaps xmm6,xmm1 ; transpose coefficients(phase 2)
1.288 + unpcklps2 xmm1,xmm3 ; xmm1=(40 41 42 43)=data4
1.289 + unpckhps2 xmm6,xmm3 ; xmm6=(50 51 52 53)=data5
1.290 +
1.291 + movaps xmm2,xmm7
1.292 + movaps xmm3,xmm4
1.293 + addps xmm7,xmm1 ; xmm7=data3+data4=tmp3
1.294 + addps xmm4,xmm6 ; xmm4=data2+data5=tmp2
1.295 + subps xmm2,xmm1 ; xmm2=data3-data4=tmp4
1.296 + subps xmm3,xmm6 ; xmm3=data2-data5=tmp5
1.297 +
1.298 + ; -- Even part
1.299 +
1.300 + movaps xmm1,xmm5
1.301 + movaps xmm6,xmm0
1.302 + subps xmm5,xmm7 ; xmm5=tmp13
1.303 + subps xmm0,xmm4 ; xmm0=tmp12
1.304 + addps xmm1,xmm7 ; xmm1=tmp10
1.305 + addps xmm6,xmm4 ; xmm6=tmp11
1.306 +
1.307 + addps xmm0,xmm5
1.308 + mulps xmm0,[GOTOFF(ebx,PD_0_707)] ; xmm0=z1
1.309 +
1.310 + movaps xmm7,xmm1
1.311 + movaps xmm4,xmm5
1.312 + subps xmm1,xmm6 ; xmm1=data4
1.313 + subps xmm5,xmm0 ; xmm5=data6
1.314 + addps xmm7,xmm6 ; xmm7=data0
1.315 + addps xmm4,xmm0 ; xmm4=data2
1.316 +
1.317 + movaps XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)], xmm1
1.318 + movaps XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)], xmm5
1.319 + movaps XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], xmm7
1.320 + movaps XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)], xmm4
1.321 +
1.322 + ; -- Odd part
1.323 +
1.324 + movaps xmm6, XMMWORD [wk(0)] ; xmm6=tmp6
1.325 + movaps xmm0, XMMWORD [wk(1)] ; xmm0=tmp7
1.326 +
1.327 + addps xmm2,xmm3 ; xmm2=tmp10
1.328 + addps xmm3,xmm6 ; xmm3=tmp11
1.329 + addps xmm6,xmm0 ; xmm6=tmp12, xmm0=tmp7
1.330 +
1.331 + mulps xmm3,[GOTOFF(ebx,PD_0_707)] ; xmm3=z3
1.332 +
1.333 + movaps xmm1,xmm2 ; xmm1=tmp10
1.334 + subps xmm2,xmm6
1.335 + mulps xmm2,[GOTOFF(ebx,PD_0_382)] ; xmm2=z5
1.336 + mulps xmm1,[GOTOFF(ebx,PD_0_541)] ; xmm1=MULTIPLY(tmp10,FIX_0_541196)
1.337 + mulps xmm6,[GOTOFF(ebx,PD_1_306)] ; xmm6=MULTIPLY(tmp12,FIX_1_306562)
1.338 + addps xmm1,xmm2 ; xmm1=z2
1.339 + addps xmm6,xmm2 ; xmm6=z4
1.340 +
1.341 + movaps xmm5,xmm0
1.342 + subps xmm0,xmm3 ; xmm0=z13
1.343 + addps xmm5,xmm3 ; xmm5=z11
1.344 +
1.345 + movaps xmm7,xmm0
1.346 + movaps xmm4,xmm5
1.347 + subps xmm0,xmm1 ; xmm0=data3
1.348 + subps xmm5,xmm6 ; xmm5=data7
1.349 + addps xmm7,xmm1 ; xmm7=data5
1.350 + addps xmm4,xmm6 ; xmm4=data1
1.351 +
1.352 + movaps XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)], xmm0
1.353 + movaps XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)], xmm5
1.354 + movaps XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)], xmm7
1.355 + movaps XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], xmm4
1.356 +
1.357 + add edx, byte 4*SIZEOF_FAST_FLOAT
1.358 + dec ecx
1.359 + jnz near .columnloop
1.360 +
1.361 +; pop edi ; unused
1.362 +; pop esi ; unused
1.363 +; pop edx ; need not be preserved
1.364 +; pop ecx ; need not be preserved
1.365 + poppic ebx
1.366 + mov esp,ebp ; esp <- aligned ebp
1.367 + pop esp ; esp <- original ebp
1.368 + pop ebp
1.369 + ret
1.370 +
1.371 +; For some reason, the OS X linker does not honor the request to align the
1.372 +; segment unless we do this.
1.373 + align 16
