1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jimmxfst.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,500 @@
1.4 +;
1.5 +; jimmxfst.asm - fast integer IDCT (MMX)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +;
1.9 +; Based on
1.10 +; x86 SIMD extension for IJG JPEG library
1.11 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.12 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.13 +;
1.14 +; This file should be assembled with NASM (Netwide Assembler),
1.15 +; can *not* be assembled with Microsoft's MASM or any compatible
1.16 +; assembler (including Borland's Turbo Assembler).
1.17 +; NASM is available from http://nasm.sourceforge.net/ or
1.18 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.19 +;
1.20 +; This file contains a fast, not so accurate integer implementation of
1.21 +; the inverse DCT (Discrete Cosine Transform). The following code is
1.22 +; based directly on the IJG's original jidctfst.c; see the jidctfst.c
1.23 +; for more details.
1.24 +;
1.25 +; [TAB8]
1.26 +
1.27 +%include "jsimdext.inc"
1.28 +%include "jdct.inc"
1.29 +
1.30 +; --------------------------------------------------------------------------
1.31 +
1.32 +%define CONST_BITS 8 ; 14 is also OK.
1.33 +%define PASS1_BITS 2
1.34 +
1.35 +%if IFAST_SCALE_BITS != PASS1_BITS
1.36 +%error "'IFAST_SCALE_BITS' must be equal to 'PASS1_BITS'."
1.37 +%endif
1.38 +
1.39 +%if CONST_BITS == 8
1.40 +F_1_082 equ 277 ; FIX(1.082392200)
1.41 +F_1_414 equ 362 ; FIX(1.414213562)
1.42 +F_1_847 equ 473 ; FIX(1.847759065)
1.43 +F_2_613 equ 669 ; FIX(2.613125930)
1.44 +F_1_613 equ (F_2_613 - 256) ; FIX(2.613125930) - FIX(1)
1.45 +%else
1.46 +; NASM cannot do compile-time arithmetic on floating-point constants.
1.47 +%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
1.48 +F_1_082 equ DESCALE(1162209775,30-CONST_BITS) ; FIX(1.082392200)
1.49 +F_1_414 equ DESCALE(1518500249,30-CONST_BITS) ; FIX(1.414213562)
1.50 +F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
1.51 +F_2_613 equ DESCALE(2805822602,30-CONST_BITS) ; FIX(2.613125930)
1.52 +F_1_613 equ (F_2_613 - (1 << CONST_BITS)) ; FIX(2.613125930) - FIX(1)
1.53 +%endif
1.54 +
1.55 +; --------------------------------------------------------------------------
1.56 + SECTION SEG_CONST
1.57 +
1.58 +; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
1.59 +; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
1.60 +
1.61 +%define PRE_MULTIPLY_SCALE_BITS 2
1.62 +%define CONST_SHIFT (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
1.63 +
1.64 + alignz 16
1.65 + global EXTN(jconst_idct_ifast_mmx)
1.66 +
1.67 +EXTN(jconst_idct_ifast_mmx):
1.68 +
1.69 +PW_F1414 times 4 dw F_1_414 << CONST_SHIFT
1.70 +PW_F1847 times 4 dw F_1_847 << CONST_SHIFT
1.71 +PW_MF1613 times 4 dw -F_1_613 << CONST_SHIFT
1.72 +PW_F1082 times 4 dw F_1_082 << CONST_SHIFT
1.73 +PB_CENTERJSAMP times 8 db CENTERJSAMPLE
1.74 +
1.75 + alignz 16
1.76 +
1.77 +; --------------------------------------------------------------------------
1.78 + SECTION SEG_TEXT
1.79 + BITS 32
1.80 +;
1.81 +; Perform dequantization and inverse DCT on one block of coefficients.
1.82 +;
1.83 +; GLOBAL(void)
1.84 +; jsimd_idct_ifast_mmx (void * dct_table, JCOEFPTR coef_block,
1.85 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.86 +;
1.87 +
1.88 +%define dct_table(b) (b)+8 ; jpeg_component_info * compptr
1.89 +%define coef_block(b) (b)+12 ; JCOEFPTR coef_block
1.90 +%define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
1.91 +%define output_col(b) (b)+20 ; JDIMENSION output_col
1.92 +
1.93 +%define original_ebp ebp+0
1.94 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
1.95 +%define WK_NUM 2
1.96 +%define workspace wk(0)-DCTSIZE2*SIZEOF_JCOEF
1.97 + ; JCOEF workspace[DCTSIZE2]
1.98 +
1.99 + align 16
1.100 + global EXTN(jsimd_idct_ifast_mmx)
1.101 +
1.102 +EXTN(jsimd_idct_ifast_mmx):
1.103 + push ebp
1.104 + mov eax,esp ; eax = original ebp
1.105 + sub esp, byte 4
1.106 + and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
1.107 + mov [esp],eax
1.108 + mov ebp,esp ; ebp = aligned ebp
1.109 + lea esp, [workspace]
1.110 + push ebx
1.111 +; push ecx ; need not be preserved
1.112 +; push edx ; need not be preserved
1.113 + push esi
1.114 + push edi
1.115 +
1.116 + get_GOT ebx ; get GOT address
1.117 +
1.118 + ; ---- Pass 1: process columns from input, store into work array.
1.119 +
1.120 +; mov eax, [original_ebp]
1.121 + mov edx, POINTER [dct_table(eax)] ; quantptr
1.122 + mov esi, JCOEFPTR [coef_block(eax)] ; inptr
1.123 + lea edi, [workspace] ; JCOEF * wsptr
1.124 + mov ecx, DCTSIZE/4 ; ctr
1.125 + alignx 16,7
1.126 +.columnloop:
1.127 +%ifndef NO_ZERO_COLUMN_TEST_IFAST_MMX
1.128 + mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.129 + or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.130 + jnz short .columnDCT
1.131 +
1.132 + movq mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.133 + movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.134 + por mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.135 + por mm1, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
1.136 + por mm0, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.137 + por mm1, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.138 + por mm0, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.139 + por mm1,mm0
1.140 + packsswb mm1,mm1
1.141 + movd eax,mm1
1.142 + test eax,eax
1.143 + jnz short .columnDCT
1.144 +
1.145 + ; -- AC terms all zero
1.146 +
1.147 + movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.148 + pmullw mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.149 +
1.150 + movq mm2,mm0 ; mm0=in0=(00 01 02 03)
1.151 + punpcklwd mm0,mm0 ; mm0=(00 00 01 01)
1.152 + punpckhwd mm2,mm2 ; mm2=(02 02 03 03)
1.153 +
1.154 + movq mm1,mm0
1.155 + punpckldq mm0,mm0 ; mm0=(00 00 00 00)
1.156 + punpckhdq mm1,mm1 ; mm1=(01 01 01 01)
1.157 + movq mm3,mm2
1.158 + punpckldq mm2,mm2 ; mm2=(02 02 02 02)
1.159 + punpckhdq mm3,mm3 ; mm3=(03 03 03 03)
1.160 +
1.161 + movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
1.162 + movq MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm0
1.163 + movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1
1.164 + movq MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm1
1.165 + movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2
1.166 + movq MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm2
1.167 + movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
1.168 + movq MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm3
1.169 + jmp near .nextcolumn
1.170 + alignx 16,7
1.171 +%endif
1.172 +.columnDCT:
1.173 +
1.174 + ; -- Even part
1.175 +
1.176 + movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.177 + movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.178 + pmullw mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.179 + pmullw mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.180 + movq mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
1.181 + movq mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.182 + pmullw mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.183 + pmullw mm3, MMWORD [MMBLOCK(6,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.184 +
1.185 + movq mm4,mm0
1.186 + movq mm5,mm1
1.187 + psubw mm0,mm2 ; mm0=tmp11
1.188 + psubw mm1,mm3
1.189 + paddw mm4,mm2 ; mm4=tmp10
1.190 + paddw mm5,mm3 ; mm5=tmp13
1.191 +
1.192 + psllw mm1,PRE_MULTIPLY_SCALE_BITS
1.193 + pmulhw mm1,[GOTOFF(ebx,PW_F1414)]
1.194 + psubw mm1,mm5 ; mm1=tmp12
1.195 +
1.196 + movq mm6,mm4
1.197 + movq mm7,mm0
1.198 + psubw mm4,mm5 ; mm4=tmp3
1.199 + psubw mm0,mm1 ; mm0=tmp2
1.200 + paddw mm6,mm5 ; mm6=tmp0
1.201 + paddw mm7,mm1 ; mm7=tmp1
1.202 +
1.203 + movq MMWORD [wk(1)], mm4 ; wk(1)=tmp3
1.204 + movq MMWORD [wk(0)], mm0 ; wk(0)=tmp2
1.205 +
1.206 + ; -- Odd part
1.207 +
1.208 + movq mm2, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.209 + movq mm3, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.210 + pmullw mm2, MMWORD [MMBLOCK(1,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.211 + pmullw mm3, MMWORD [MMBLOCK(3,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.212 + movq mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.213 + movq mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.214 + pmullw mm5, MMWORD [MMBLOCK(5,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.215 + pmullw mm1, MMWORD [MMBLOCK(7,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.216 +
1.217 + movq mm4,mm2
1.218 + movq mm0,mm5
1.219 + psubw mm2,mm1 ; mm2=z12
1.220 + psubw mm5,mm3 ; mm5=z10
1.221 + paddw mm4,mm1 ; mm4=z11
1.222 + paddw mm0,mm3 ; mm0=z13
1.223 +
1.224 + movq mm1,mm5 ; mm1=z10(unscaled)
1.225 + psllw mm2,PRE_MULTIPLY_SCALE_BITS
1.226 + psllw mm5,PRE_MULTIPLY_SCALE_BITS
1.227 +
1.228 + movq mm3,mm4
1.229 + psubw mm4,mm0
1.230 + paddw mm3,mm0 ; mm3=tmp7
1.231 +
1.232 + psllw mm4,PRE_MULTIPLY_SCALE_BITS
1.233 + pmulhw mm4,[GOTOFF(ebx,PW_F1414)] ; mm4=tmp11
1.234 +
1.235 + ; To avoid overflow...
1.236 + ;
1.237 + ; (Original)
1.238 + ; tmp12 = -2.613125930 * z10 + z5;
1.239 + ;
1.240 + ; (This implementation)
1.241 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.242 + ; = -1.613125930 * z10 - z10 + z5;
1.243 +
1.244 + movq mm0,mm5
1.245 + paddw mm5,mm2
1.246 + pmulhw mm5,[GOTOFF(ebx,PW_F1847)] ; mm5=z5
1.247 + pmulhw mm0,[GOTOFF(ebx,PW_MF1613)]
1.248 + pmulhw mm2,[GOTOFF(ebx,PW_F1082)]
1.249 + psubw mm0,mm1
1.250 + psubw mm2,mm5 ; mm2=tmp10
1.251 + paddw mm0,mm5 ; mm0=tmp12
1.252 +
1.253 + ; -- Final output stage
1.254 +
1.255 + psubw mm0,mm3 ; mm0=tmp6
1.256 + movq mm1,mm6
1.257 + movq mm5,mm7
1.258 + paddw mm6,mm3 ; mm6=data0=(00 01 02 03)
1.259 + paddw mm7,mm0 ; mm7=data1=(10 11 12 13)
1.260 + psubw mm1,mm3 ; mm1=data7=(70 71 72 73)
1.261 + psubw mm5,mm0 ; mm5=data6=(60 61 62 63)
1.262 + psubw mm4,mm0 ; mm4=tmp5
1.263 +
1.264 + movq mm3,mm6 ; transpose coefficients(phase 1)
1.265 + punpcklwd mm6,mm7 ; mm6=(00 10 01 11)
1.266 + punpckhwd mm3,mm7 ; mm3=(02 12 03 13)
1.267 + movq mm0,mm5 ; transpose coefficients(phase 1)
1.268 + punpcklwd mm5,mm1 ; mm5=(60 70 61 71)
1.269 + punpckhwd mm0,mm1 ; mm0=(62 72 63 73)
1.270 +
1.271 + movq mm7, MMWORD [wk(0)] ; mm7=tmp2
1.272 + movq mm1, MMWORD [wk(1)] ; mm1=tmp3
1.273 +
1.274 + movq MMWORD [wk(0)], mm5 ; wk(0)=(60 70 61 71)
1.275 + movq MMWORD [wk(1)], mm0 ; wk(1)=(62 72 63 73)
1.276 +
1.277 + paddw mm2,mm4 ; mm2=tmp4
1.278 + movq mm5,mm7
1.279 + movq mm0,mm1
1.280 + paddw mm7,mm4 ; mm7=data2=(20 21 22 23)
1.281 + paddw mm1,mm2 ; mm1=data4=(40 41 42 43)
1.282 + psubw mm5,mm4 ; mm5=data5=(50 51 52 53)
1.283 + psubw mm0,mm2 ; mm0=data3=(30 31 32 33)
1.284 +
1.285 + movq mm4,mm7 ; transpose coefficients(phase 1)
1.286 + punpcklwd mm7,mm0 ; mm7=(20 30 21 31)
1.287 + punpckhwd mm4,mm0 ; mm4=(22 32 23 33)
1.288 + movq mm2,mm1 ; transpose coefficients(phase 1)
1.289 + punpcklwd mm1,mm5 ; mm1=(40 50 41 51)
1.290 + punpckhwd mm2,mm5 ; mm2=(42 52 43 53)
1.291 +
1.292 + movq mm0,mm6 ; transpose coefficients(phase 2)
1.293 + punpckldq mm6,mm7 ; mm6=(00 10 20 30)
1.294 + punpckhdq mm0,mm7 ; mm0=(01 11 21 31)
1.295 + movq mm5,mm3 ; transpose coefficients(phase 2)
1.296 + punpckldq mm3,mm4 ; mm3=(02 12 22 32)
1.297 + punpckhdq mm5,mm4 ; mm5=(03 13 23 33)
1.298 +
1.299 + movq mm7, MMWORD [wk(0)] ; mm7=(60 70 61 71)
1.300 + movq mm4, MMWORD [wk(1)] ; mm4=(62 72 63 73)
1.301 +
1.302 + movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm6
1.303 + movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm0
1.304 + movq MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm3
1.305 + movq MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm5
1.306 +
1.307 + movq mm6,mm1 ; transpose coefficients(phase 2)
1.308 + punpckldq mm1,mm7 ; mm1=(40 50 60 70)
1.309 + punpckhdq mm6,mm7 ; mm6=(41 51 61 71)
1.310 + movq mm0,mm2 ; transpose coefficients(phase 2)
1.311 + punpckldq mm2,mm4 ; mm2=(42 52 62 72)
1.312 + punpckhdq mm0,mm4 ; mm0=(43 53 63 73)
1.313 +
1.314 + movq MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm1
1.315 + movq MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm6
1.316 + movq MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm2
1.317 + movq MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm0
1.318 +
1.319 +.nextcolumn:
1.320 + add esi, byte 4*SIZEOF_JCOEF ; coef_block
1.321 + add edx, byte 4*SIZEOF_IFAST_MULT_TYPE ; quantptr
1.322 + add edi, byte 4*DCTSIZE*SIZEOF_JCOEF ; wsptr
1.323 + dec ecx ; ctr
1.324 + jnz near .columnloop
1.325 +
1.326 + ; ---- Pass 2: process rows from work array, store into output array.
1.327 +
1.328 + mov eax, [original_ebp]
1.329 + lea esi, [workspace] ; JCOEF * wsptr
1.330 + mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
1.331 + mov eax, JDIMENSION [output_col(eax)]
1.332 + mov ecx, DCTSIZE/4 ; ctr
1.333 + alignx 16,7
1.334 +.rowloop:
1.335 +
1.336 + ; -- Even part
1.337 +
1.338 + movq mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.339 + movq mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.340 + movq mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
1.341 + movq mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.342 +
1.343 + movq mm4,mm0
1.344 + movq mm5,mm1
1.345 + psubw mm0,mm2 ; mm0=tmp11
1.346 + psubw mm1,mm3
1.347 + paddw mm4,mm2 ; mm4=tmp10
1.348 + paddw mm5,mm3 ; mm5=tmp13
1.349 +
1.350 + psllw mm1,PRE_MULTIPLY_SCALE_BITS
1.351 + pmulhw mm1,[GOTOFF(ebx,PW_F1414)]
1.352 + psubw mm1,mm5 ; mm1=tmp12
1.353 +
1.354 + movq mm6,mm4
1.355 + movq mm7,mm0
1.356 + psubw mm4,mm5 ; mm4=tmp3
1.357 + psubw mm0,mm1 ; mm0=tmp2
1.358 + paddw mm6,mm5 ; mm6=tmp0
1.359 + paddw mm7,mm1 ; mm7=tmp1
1.360 +
1.361 + movq MMWORD [wk(1)], mm4 ; wk(1)=tmp3
1.362 + movq MMWORD [wk(0)], mm0 ; wk(0)=tmp2
1.363 +
1.364 + ; -- Odd part
1.365 +
1.366 + movq mm2, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.367 + movq mm3, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.368 + movq mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.369 + movq mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.370 +
1.371 + movq mm4,mm2
1.372 + movq mm0,mm5
1.373 + psubw mm2,mm1 ; mm2=z12
1.374 + psubw mm5,mm3 ; mm5=z10
1.375 + paddw mm4,mm1 ; mm4=z11
1.376 + paddw mm0,mm3 ; mm0=z13
1.377 +
1.378 + movq mm1,mm5 ; mm1=z10(unscaled)
1.379 + psllw mm2,PRE_MULTIPLY_SCALE_BITS
1.380 + psllw mm5,PRE_MULTIPLY_SCALE_BITS
1.381 +
1.382 + movq mm3,mm4
1.383 + psubw mm4,mm0
1.384 + paddw mm3,mm0 ; mm3=tmp7
1.385 +
1.386 + psllw mm4,PRE_MULTIPLY_SCALE_BITS
1.387 + pmulhw mm4,[GOTOFF(ebx,PW_F1414)] ; mm4=tmp11
1.388 +
1.389 + ; To avoid overflow...
1.390 + ;
1.391 + ; (Original)
1.392 + ; tmp12 = -2.613125930 * z10 + z5;
1.393 + ;
1.394 + ; (This implementation)
1.395 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.396 + ; = -1.613125930 * z10 - z10 + z5;
1.397 +
1.398 + movq mm0,mm5
1.399 + paddw mm5,mm2
1.400 + pmulhw mm5,[GOTOFF(ebx,PW_F1847)] ; mm5=z5
1.401 + pmulhw mm0,[GOTOFF(ebx,PW_MF1613)]
1.402 + pmulhw mm2,[GOTOFF(ebx,PW_F1082)]
1.403 + psubw mm0,mm1
1.404 + psubw mm2,mm5 ; mm2=tmp10
1.405 + paddw mm0,mm5 ; mm0=tmp12
1.406 +
1.407 + ; -- Final output stage
1.408 +
1.409 + psubw mm0,mm3 ; mm0=tmp6
1.410 + movq mm1,mm6
1.411 + movq mm5,mm7
1.412 + paddw mm6,mm3 ; mm6=data0=(00 10 20 30)
1.413 + paddw mm7,mm0 ; mm7=data1=(01 11 21 31)
1.414 + psraw mm6,(PASS1_BITS+3) ; descale
1.415 + psraw mm7,(PASS1_BITS+3) ; descale
1.416 + psubw mm1,mm3 ; mm1=data7=(07 17 27 37)
1.417 + psubw mm5,mm0 ; mm5=data6=(06 16 26 36)
1.418 + psraw mm1,(PASS1_BITS+3) ; descale
1.419 + psraw mm5,(PASS1_BITS+3) ; descale
1.420 + psubw mm4,mm0 ; mm4=tmp5
1.421 +
1.422 + packsswb mm6,mm5 ; mm6=(00 10 20 30 06 16 26 36)
1.423 + packsswb mm7,mm1 ; mm7=(01 11 21 31 07 17 27 37)
1.424 +
1.425 + movq mm3, MMWORD [wk(0)] ; mm3=tmp2
1.426 + movq mm0, MMWORD [wk(1)] ; mm0=tmp3
1.427 +
1.428 + paddw mm2,mm4 ; mm2=tmp4
1.429 + movq mm5,mm3
1.430 + movq mm1,mm0
1.431 + paddw mm3,mm4 ; mm3=data2=(02 12 22 32)
1.432 + paddw mm0,mm2 ; mm0=data4=(04 14 24 34)
1.433 + psraw mm3,(PASS1_BITS+3) ; descale
1.434 + psraw mm0,(PASS1_BITS+3) ; descale
1.435 + psubw mm5,mm4 ; mm5=data5=(05 15 25 35)
1.436 + psubw mm1,mm2 ; mm1=data3=(03 13 23 33)
1.437 + psraw mm5,(PASS1_BITS+3) ; descale
1.438 + psraw mm1,(PASS1_BITS+3) ; descale
1.439 +
1.440 + movq mm4,[GOTOFF(ebx,PB_CENTERJSAMP)] ; mm4=[PB_CENTERJSAMP]
1.441 +
1.442 + packsswb mm3,mm0 ; mm3=(02 12 22 32 04 14 24 34)
1.443 + packsswb mm1,mm5 ; mm1=(03 13 23 33 05 15 25 35)
1.444 +
1.445 + paddb mm6,mm4
1.446 + paddb mm7,mm4
1.447 + paddb mm3,mm4
1.448 + paddb mm1,mm4
1.449 +
1.450 + movq mm2,mm6 ; transpose coefficients(phase 1)
1.451 + punpcklbw mm6,mm7 ; mm6=(00 01 10 11 20 21 30 31)
1.452 + punpckhbw mm2,mm7 ; mm2=(06 07 16 17 26 27 36 37)
1.453 + movq mm0,mm3 ; transpose coefficients(phase 1)
1.454 + punpcklbw mm3,mm1 ; mm3=(02 03 12 13 22 23 32 33)
1.455 + punpckhbw mm0,mm1 ; mm0=(04 05 14 15 24 25 34 35)
1.456 +
1.457 + movq mm5,mm6 ; transpose coefficients(phase 2)
1.458 + punpcklwd mm6,mm3 ; mm6=(00 01 02 03 10 11 12 13)
1.459 + punpckhwd mm5,mm3 ; mm5=(20 21 22 23 30 31 32 33)
1.460 + movq mm4,mm0 ; transpose coefficients(phase 2)
1.461 + punpcklwd mm0,mm2 ; mm0=(04 05 06 07 14 15 16 17)
1.462 + punpckhwd mm4,mm2 ; mm4=(24 25 26 27 34 35 36 37)
1.463 +
1.464 + movq mm7,mm6 ; transpose coefficients(phase 3)
1.465 + punpckldq mm6,mm0 ; mm6=(00 01 02 03 04 05 06 07)
1.466 + punpckhdq mm7,mm0 ; mm7=(10 11 12 13 14 15 16 17)
1.467 + movq mm1,mm5 ; transpose coefficients(phase 3)
1.468 + punpckldq mm5,mm4 ; mm5=(20 21 22 23 24 25 26 27)
1.469 + punpckhdq mm1,mm4 ; mm1=(30 31 32 33 34 35 36 37)
1.470 +
1.471 + pushpic ebx ; save GOT address
1.472 +
1.473 + mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
1.474 + mov ebx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
1.475 + movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm6
1.476 + movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm7
1.477 + mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
1.478 + mov ebx, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
1.479 + movq MMWORD [edx+eax*SIZEOF_JSAMPLE], mm5
1.480 + movq MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm1
1.481 +
1.482 + poppic ebx ; restore GOT address
1.483 +
1.484 + add esi, byte 4*SIZEOF_JCOEF ; wsptr
1.485 + add edi, byte 4*SIZEOF_JSAMPROW
1.486 + dec ecx ; ctr
1.487 + jnz near .rowloop
1.488 +
1.489 + emms ; empty MMX state
1.490 +
1.491 + pop edi
1.492 + pop esi
1.493 +; pop edx ; need not be preserved
1.494 +; pop ecx ; need not be preserved
1.495 + pop ebx
1.496 + mov esp,ebp ; esp <- aligned ebp
1.497 + pop esp ; esp <- original ebp
1.498 + pop ebp
1.499 + ret
1.500 +
1.501 +; For some reason, the OS X linker does not honor the request to align the
1.502 +; segment unless we do this.
1.503 + align 16
