1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jiss2flt-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,483 @@
1.4 +;
1.5 +; jiss2flt-64.asm - floating-point IDCT (64-bit SSE & SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; This file contains a floating-point implementation of the inverse DCT
1.22 +; (Discrete Cosine Transform). The following code is based directly on
1.23 +; the IJG's original jidctflt.c; see the jidctflt.c for more details.
1.24 +;
1.25 +; [TAB8]
1.26 +
1.27 +%include "jsimdext.inc"
1.28 +%include "jdct.inc"
1.29 +
1.30 +; --------------------------------------------------------------------------
1.31 +
1.32 +%macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5)
1.33 + shufps %1,%2,0x44
1.34 +%endmacro
1.35 +
1.36 +%macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7)
1.37 + shufps %1,%2,0xEE
1.38 +%endmacro
1.39 +
1.40 +; --------------------------------------------------------------------------
1.41 + SECTION SEG_CONST
1.42 +
1.43 + alignz 16
1.44 + global EXTN(jconst_idct_float_sse2)
1.45 +
1.46 +EXTN(jconst_idct_float_sse2):
1.47 +
1.48 +PD_1_414 times 4 dd 1.414213562373095048801689
1.49 +PD_1_847 times 4 dd 1.847759065022573512256366
1.50 +PD_1_082 times 4 dd 1.082392200292393968799446
1.51 +PD_M2_613 times 4 dd -2.613125929752753055713286
1.52 +PD_RNDINT_MAGIC times 4 dd 100663296.0 ; (float)(0x00C00000 << 3)
1.53 +PB_CENTERJSAMP times 16 db CENTERJSAMPLE
1.54 +
1.55 + alignz 16
1.56 +
1.57 +; --------------------------------------------------------------------------
1.58 + SECTION SEG_TEXT
1.59 + BITS 64
1.60 +;
1.61 +; Perform dequantization and inverse DCT on one block of coefficients.
1.62 +;
1.63 +; GLOBAL(void)
1.64 +; jsimd_idct_float_sse2 (void * dct_table, JCOEFPTR coef_block,
1.65 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.66 +;
1.67 +
1.68 +; r10 = void * dct_table
1.69 +; r11 = JCOEFPTR coef_block
1.70 +; r12 = JSAMPARRAY output_buf
1.71 +; r13 = JDIMENSION output_col
1.72 +
1.73 +%define original_rbp rbp+0
1.74 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.75 +%define WK_NUM 2
1.76 +%define workspace wk(0)-DCTSIZE2*SIZEOF_FAST_FLOAT
1.77 + ; FAST_FLOAT workspace[DCTSIZE2]
1.78 +
1.79 + align 16
1.80 + global EXTN(jsimd_idct_float_sse2)
1.81 +
1.82 +EXTN(jsimd_idct_float_sse2):
1.83 + push rbp
1.84 + mov rax,rsp ; rax = original rbp
1.85 + sub rsp, byte 4
1.86 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.87 + mov [rsp],rax
1.88 + mov rbp,rsp ; rbp = aligned rbp
1.89 + lea rsp, [workspace]
1.90 + collect_args
1.91 + push rbx
1.92 +
1.93 + ; ---- Pass 1: process columns from input, store into work array.
1.94 +
1.95 + mov rdx, r10 ; quantptr
1.96 + mov rsi, r11 ; inptr
1.97 + lea rdi, [workspace] ; FAST_FLOAT * wsptr
1.98 + mov rcx, DCTSIZE/4 ; ctr
1.99 +.columnloop:
1.100 +%ifndef NO_ZERO_COLUMN_TEST_FLOAT_SSE
1.101 + mov eax, DWORD [DWBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.102 + or eax, DWORD [DWBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.103 + jnz near .columnDCT
1.104 +
1.105 + movq xmm1, XMM_MMWORD [MMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.106 + movq xmm2, XMM_MMWORD [MMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.107 + movq xmm3, XMM_MMWORD [MMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
1.108 + movq xmm4, XMM_MMWORD [MMBLOCK(4,0,rsi,SIZEOF_JCOEF)]
1.109 + movq xmm5, XMM_MMWORD [MMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
1.110 + movq xmm6, XMM_MMWORD [MMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
1.111 + movq xmm7, XMM_MMWORD [MMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
1.112 + por xmm1,xmm2
1.113 + por xmm3,xmm4
1.114 + por xmm5,xmm6
1.115 + por xmm1,xmm3
1.116 + por xmm5,xmm7
1.117 + por xmm1,xmm5
1.118 + packsswb xmm1,xmm1
1.119 + movd eax,xmm1
1.120 + test rax,rax
1.121 + jnz short .columnDCT
1.122 +
1.123 + ; -- AC terms all zero
1.124 +
1.125 + movq xmm0, XMM_MMWORD [MMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
1.126 +
1.127 + punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
1.128 + psrad xmm0,(DWORD_BIT-WORD_BIT) ; xmm0=in0=(00 01 02 03)
1.129 + cvtdq2ps xmm0,xmm0 ; xmm0=in0=(00 01 02 03)
1.130 +
1.131 + mulps xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.132 +
1.133 + movaps xmm1,xmm0
1.134 + movaps xmm2,xmm0
1.135 + movaps xmm3,xmm0
1.136 +
1.137 + shufps xmm0,xmm0,0x00 ; xmm0=(00 00 00 00)
1.138 + shufps xmm1,xmm1,0x55 ; xmm1=(01 01 01 01)
1.139 + shufps xmm2,xmm2,0xAA ; xmm2=(02 02 02 02)
1.140 + shufps xmm3,xmm3,0xFF ; xmm3=(03 03 03 03)
1.141 +
1.142 + movaps XMMWORD [XMMBLOCK(0,0,rdi,SIZEOF_FAST_FLOAT)], xmm0
1.143 + movaps XMMWORD [XMMBLOCK(0,1,rdi,SIZEOF_FAST_FLOAT)], xmm0
1.144 + movaps XMMWORD [XMMBLOCK(1,0,rdi,SIZEOF_FAST_FLOAT)], xmm1
1.145 + movaps XMMWORD [XMMBLOCK(1,1,rdi,SIZEOF_FAST_FLOAT)], xmm1
1.146 + movaps XMMWORD [XMMBLOCK(2,0,rdi,SIZEOF_FAST_FLOAT)], xmm2
1.147 + movaps XMMWORD [XMMBLOCK(2,1,rdi,SIZEOF_FAST_FLOAT)], xmm2
1.148 + movaps XMMWORD [XMMBLOCK(3,0,rdi,SIZEOF_FAST_FLOAT)], xmm3
1.149 + movaps XMMWORD [XMMBLOCK(3,1,rdi,SIZEOF_FAST_FLOAT)], xmm3
1.150 + jmp near .nextcolumn
1.151 +%endif
1.152 +.columnDCT:
1.153 +
1.154 + ; -- Even part
1.155 +
1.156 + movq xmm0, XMM_MMWORD [MMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
1.157 + movq xmm1, XMM_MMWORD [MMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.158 + movq xmm2, XMM_MMWORD [MMBLOCK(4,0,rsi,SIZEOF_JCOEF)]
1.159 + movq xmm3, XMM_MMWORD [MMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
1.160 +
1.161 + punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
1.162 + punpcklwd xmm1,xmm1 ; xmm1=(20 20 21 21 22 22 23 23)
1.163 + psrad xmm0,(DWORD_BIT-WORD_BIT) ; xmm0=in0=(00 01 02 03)
1.164 + psrad xmm1,(DWORD_BIT-WORD_BIT) ; xmm1=in2=(20 21 22 23)
1.165 + cvtdq2ps xmm0,xmm0 ; xmm0=in0=(00 01 02 03)
1.166 + cvtdq2ps xmm1,xmm1 ; xmm1=in2=(20 21 22 23)
1.167 +
1.168 + punpcklwd xmm2,xmm2 ; xmm2=(40 40 41 41 42 42 43 43)
1.169 + punpcklwd xmm3,xmm3 ; xmm3=(60 60 61 61 62 62 63 63)
1.170 + psrad xmm2,(DWORD_BIT-WORD_BIT) ; xmm2=in4=(40 41 42 43)
1.171 + psrad xmm3,(DWORD_BIT-WORD_BIT) ; xmm3=in6=(60 61 62 63)
1.172 + cvtdq2ps xmm2,xmm2 ; xmm2=in4=(40 41 42 43)
1.173 + cvtdq2ps xmm3,xmm3 ; xmm3=in6=(60 61 62 63)
1.174 +
1.175 + mulps xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.176 + mulps xmm1, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.177 + mulps xmm2, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.178 + mulps xmm3, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.179 +
1.180 + movaps xmm4,xmm0
1.181 + movaps xmm5,xmm1
1.182 + subps xmm0,xmm2 ; xmm0=tmp11
1.183 + subps xmm1,xmm3
1.184 + addps xmm4,xmm2 ; xmm4=tmp10
1.185 + addps xmm5,xmm3 ; xmm5=tmp13
1.186 +
1.187 + mulps xmm1,[rel PD_1_414]
1.188 + subps xmm1,xmm5 ; xmm1=tmp12
1.189 +
1.190 + movaps xmm6,xmm4
1.191 + movaps xmm7,xmm0
1.192 + subps xmm4,xmm5 ; xmm4=tmp3
1.193 + subps xmm0,xmm1 ; xmm0=tmp2
1.194 + addps xmm6,xmm5 ; xmm6=tmp0
1.195 + addps xmm7,xmm1 ; xmm7=tmp1
1.196 +
1.197 + movaps XMMWORD [wk(1)], xmm4 ; tmp3
1.198 + movaps XMMWORD [wk(0)], xmm0 ; tmp2
1.199 +
1.200 + ; -- Odd part
1.201 +
1.202 + movq xmm2, XMM_MMWORD [MMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.203 + movq xmm3, XMM_MMWORD [MMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
1.204 + movq xmm5, XMM_MMWORD [MMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
1.205 + movq xmm1, XMM_MMWORD [MMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
1.206 +
1.207 + punpcklwd xmm2,xmm2 ; xmm2=(10 10 11 11 12 12 13 13)
1.208 + punpcklwd xmm3,xmm3 ; xmm3=(30 30 31 31 32 32 33 33)
1.209 + psrad xmm2,(DWORD_BIT-WORD_BIT) ; xmm2=in1=(10 11 12 13)
1.210 + psrad xmm3,(DWORD_BIT-WORD_BIT) ; xmm3=in3=(30 31 32 33)
1.211 + cvtdq2ps xmm2,xmm2 ; xmm2=in1=(10 11 12 13)
1.212 + cvtdq2ps xmm3,xmm3 ; xmm3=in3=(30 31 32 33)
1.213 +
1.214 + punpcklwd xmm5,xmm5 ; xmm5=(50 50 51 51 52 52 53 53)
1.215 + punpcklwd xmm1,xmm1 ; xmm1=(70 70 71 71 72 72 73 73)
1.216 + psrad xmm5,(DWORD_BIT-WORD_BIT) ; xmm5=in5=(50 51 52 53)
1.217 + psrad xmm1,(DWORD_BIT-WORD_BIT) ; xmm1=in7=(70 71 72 73)
1.218 + cvtdq2ps xmm5,xmm5 ; xmm5=in5=(50 51 52 53)
1.219 + cvtdq2ps xmm1,xmm1 ; xmm1=in7=(70 71 72 73)
1.220 +
1.221 + mulps xmm2, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.222 + mulps xmm3, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.223 + mulps xmm5, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.224 + mulps xmm1, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_FLOAT_MULT_TYPE)]
1.225 +
1.226 + movaps xmm4,xmm2
1.227 + movaps xmm0,xmm5
1.228 + addps xmm2,xmm1 ; xmm2=z11
1.229 + addps xmm5,xmm3 ; xmm5=z13
1.230 + subps xmm4,xmm1 ; xmm4=z12
1.231 + subps xmm0,xmm3 ; xmm0=z10
1.232 +
1.233 + movaps xmm1,xmm2
1.234 + subps xmm2,xmm5
1.235 + addps xmm1,xmm5 ; xmm1=tmp7
1.236 +
1.237 + mulps xmm2,[rel PD_1_414] ; xmm2=tmp11
1.238 +
1.239 + movaps xmm3,xmm0
1.240 + addps xmm0,xmm4
1.241 + mulps xmm0,[rel PD_1_847] ; xmm0=z5
1.242 + mulps xmm3,[rel PD_M2_613] ; xmm3=(z10 * -2.613125930)
1.243 + mulps xmm4,[rel PD_1_082] ; xmm4=(z12 * 1.082392200)
1.244 + addps xmm3,xmm0 ; xmm3=tmp12
1.245 + subps xmm4,xmm0 ; xmm4=tmp10
1.246 +
1.247 + ; -- Final output stage
1.248 +
1.249 + subps xmm3,xmm1 ; xmm3=tmp6
1.250 + movaps xmm5,xmm6
1.251 + movaps xmm0,xmm7
1.252 + addps xmm6,xmm1 ; xmm6=data0=(00 01 02 03)
1.253 + addps xmm7,xmm3 ; xmm7=data1=(10 11 12 13)
1.254 + subps xmm5,xmm1 ; xmm5=data7=(70 71 72 73)
1.255 + subps xmm0,xmm3 ; xmm0=data6=(60 61 62 63)
1.256 + subps xmm2,xmm3 ; xmm2=tmp5
1.257 +
1.258 + movaps xmm1,xmm6 ; transpose coefficients(phase 1)
1.259 + unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11)
1.260 + unpckhps xmm1,xmm7 ; xmm1=(02 12 03 13)
1.261 + movaps xmm3,xmm0 ; transpose coefficients(phase 1)
1.262 + unpcklps xmm0,xmm5 ; xmm0=(60 70 61 71)
1.263 + unpckhps xmm3,xmm5 ; xmm3=(62 72 63 73)
1.264 +
1.265 + movaps xmm7, XMMWORD [wk(0)] ; xmm7=tmp2
1.266 + movaps xmm5, XMMWORD [wk(1)] ; xmm5=tmp3
1.267 +
1.268 + movaps XMMWORD [wk(0)], xmm0 ; wk(0)=(60 70 61 71)
1.269 + movaps XMMWORD [wk(1)], xmm3 ; wk(1)=(62 72 63 73)
1.270 +
1.271 + addps xmm4,xmm2 ; xmm4=tmp4
1.272 + movaps xmm0,xmm7
1.273 + movaps xmm3,xmm5
1.274 + addps xmm7,xmm2 ; xmm7=data2=(20 21 22 23)
1.275 + addps xmm5,xmm4 ; xmm5=data4=(40 41 42 43)
1.276 + subps xmm0,xmm2 ; xmm0=data5=(50 51 52 53)
1.277 + subps xmm3,xmm4 ; xmm3=data3=(30 31 32 33)
1.278 +
1.279 + movaps xmm2,xmm7 ; transpose coefficients(phase 1)
1.280 + unpcklps xmm7,xmm3 ; xmm7=(20 30 21 31)
1.281 + unpckhps xmm2,xmm3 ; xmm2=(22 32 23 33)
1.282 + movaps xmm4,xmm5 ; transpose coefficients(phase 1)
1.283 + unpcklps xmm5,xmm0 ; xmm5=(40 50 41 51)
1.284 + unpckhps xmm4,xmm0 ; xmm4=(42 52 43 53)
1.285 +
1.286 + movaps xmm3,xmm6 ; transpose coefficients(phase 2)
1.287 + unpcklps2 xmm6,xmm7 ; xmm6=(00 10 20 30)
1.288 + unpckhps2 xmm3,xmm7 ; xmm3=(01 11 21 31)
1.289 + movaps xmm0,xmm1 ; transpose coefficients(phase 2)
1.290 + unpcklps2 xmm1,xmm2 ; xmm1=(02 12 22 32)
1.291 + unpckhps2 xmm0,xmm2 ; xmm0=(03 13 23 33)
1.292 +
1.293 + movaps xmm7, XMMWORD [wk(0)] ; xmm7=(60 70 61 71)
1.294 + movaps xmm2, XMMWORD [wk(1)] ; xmm2=(62 72 63 73)
1.295 +
1.296 + movaps XMMWORD [XMMBLOCK(0,0,rdi,SIZEOF_FAST_FLOAT)], xmm6
1.297 + movaps XMMWORD [XMMBLOCK(1,0,rdi,SIZEOF_FAST_FLOAT)], xmm3
1.298 + movaps XMMWORD [XMMBLOCK(2,0,rdi,SIZEOF_FAST_FLOAT)], xmm1
1.299 + movaps XMMWORD [XMMBLOCK(3,0,rdi,SIZEOF_FAST_FLOAT)], xmm0
1.300 +
1.301 + movaps xmm6,xmm5 ; transpose coefficients(phase 2)
1.302 + unpcklps2 xmm5,xmm7 ; xmm5=(40 50 60 70)
1.303 + unpckhps2 xmm6,xmm7 ; xmm6=(41 51 61 71)
1.304 + movaps xmm3,xmm4 ; transpose coefficients(phase 2)
1.305 + unpcklps2 xmm4,xmm2 ; xmm4=(42 52 62 72)
1.306 + unpckhps2 xmm3,xmm2 ; xmm3=(43 53 63 73)
1.307 +
1.308 + movaps XMMWORD [XMMBLOCK(0,1,rdi,SIZEOF_FAST_FLOAT)], xmm5
1.309 + movaps XMMWORD [XMMBLOCK(1,1,rdi,SIZEOF_FAST_FLOAT)], xmm6
1.310 + movaps XMMWORD [XMMBLOCK(2,1,rdi,SIZEOF_FAST_FLOAT)], xmm4
1.311 + movaps XMMWORD [XMMBLOCK(3,1,rdi,SIZEOF_FAST_FLOAT)], xmm3
1.312 +
1.313 +.nextcolumn:
1.314 + add rsi, byte 4*SIZEOF_JCOEF ; coef_block
1.315 + add rdx, byte 4*SIZEOF_FLOAT_MULT_TYPE ; quantptr
1.316 + add rdi, 4*DCTSIZE*SIZEOF_FAST_FLOAT ; wsptr
1.317 + dec rcx ; ctr
1.318 + jnz near .columnloop
1.319 +
1.320 + ; -- Prefetch the next coefficient block
1.321 +
1.322 + prefetchnta [rsi + (DCTSIZE2-8)*SIZEOF_JCOEF + 0*32]
1.323 + prefetchnta [rsi + (DCTSIZE2-8)*SIZEOF_JCOEF + 1*32]
1.324 + prefetchnta [rsi + (DCTSIZE2-8)*SIZEOF_JCOEF + 2*32]
1.325 + prefetchnta [rsi + (DCTSIZE2-8)*SIZEOF_JCOEF + 3*32]
1.326 +
1.327 + ; ---- Pass 2: process rows from work array, store into output array.
1.328 +
1.329 + mov rax, [original_rbp]
1.330 + lea rsi, [workspace] ; FAST_FLOAT * wsptr
1.331 + mov rdi, r12 ; (JSAMPROW *)
1.332 + mov rax, r13
1.333 + mov rcx, DCTSIZE/4 ; ctr
1.334 +.rowloop:
1.335 +
1.336 + ; -- Even part
1.337 +
1.338 + movaps xmm0, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_FAST_FLOAT)]
1.339 + movaps xmm1, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_FAST_FLOAT)]
1.340 + movaps xmm2, XMMWORD [XMMBLOCK(4,0,rsi,SIZEOF_FAST_FLOAT)]
1.341 + movaps xmm3, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_FAST_FLOAT)]
1.342 +
1.343 + movaps xmm4,xmm0
1.344 + movaps xmm5,xmm1
1.345 + subps xmm0,xmm2 ; xmm0=tmp11
1.346 + subps xmm1,xmm3
1.347 + addps xmm4,xmm2 ; xmm4=tmp10
1.348 + addps xmm5,xmm3 ; xmm5=tmp13
1.349 +
1.350 + mulps xmm1,[rel PD_1_414]
1.351 + subps xmm1,xmm5 ; xmm1=tmp12
1.352 +
1.353 + movaps xmm6,xmm4
1.354 + movaps xmm7,xmm0
1.355 + subps xmm4,xmm5 ; xmm4=tmp3
1.356 + subps xmm0,xmm1 ; xmm0=tmp2
1.357 + addps xmm6,xmm5 ; xmm6=tmp0
1.358 + addps xmm7,xmm1 ; xmm7=tmp1
1.359 +
1.360 + movaps XMMWORD [wk(1)], xmm4 ; tmp3
1.361 + movaps XMMWORD [wk(0)], xmm0 ; tmp2
1.362 +
1.363 + ; -- Odd part
1.364 +
1.365 + movaps xmm2, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_FAST_FLOAT)]
1.366 + movaps xmm3, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_FAST_FLOAT)]
1.367 + movaps xmm5, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_FAST_FLOAT)]
1.368 + movaps xmm1, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_FAST_FLOAT)]
1.369 +
1.370 + movaps xmm4,xmm2
1.371 + movaps xmm0,xmm5
1.372 + addps xmm2,xmm1 ; xmm2=z11
1.373 + addps xmm5,xmm3 ; xmm5=z13
1.374 + subps xmm4,xmm1 ; xmm4=z12
1.375 + subps xmm0,xmm3 ; xmm0=z10
1.376 +
1.377 + movaps xmm1,xmm2
1.378 + subps xmm2,xmm5
1.379 + addps xmm1,xmm5 ; xmm1=tmp7
1.380 +
1.381 + mulps xmm2,[rel PD_1_414] ; xmm2=tmp11
1.382 +
1.383 + movaps xmm3,xmm0
1.384 + addps xmm0,xmm4
1.385 + mulps xmm0,[rel PD_1_847] ; xmm0=z5
1.386 + mulps xmm3,[rel PD_M2_613] ; xmm3=(z10 * -2.613125930)
1.387 + mulps xmm4,[rel PD_1_082] ; xmm4=(z12 * 1.082392200)
1.388 + addps xmm3,xmm0 ; xmm3=tmp12
1.389 + subps xmm4,xmm0 ; xmm4=tmp10
1.390 +
1.391 + ; -- Final output stage
1.392 +
1.393 + subps xmm3,xmm1 ; xmm3=tmp6
1.394 + movaps xmm5,xmm6
1.395 + movaps xmm0,xmm7
1.396 + addps xmm6,xmm1 ; xmm6=data0=(00 10 20 30)
1.397 + addps xmm7,xmm3 ; xmm7=data1=(01 11 21 31)
1.398 + subps xmm5,xmm1 ; xmm5=data7=(07 17 27 37)
1.399 + subps xmm0,xmm3 ; xmm0=data6=(06 16 26 36)
1.400 + subps xmm2,xmm3 ; xmm2=tmp5
1.401 +
1.402 + movaps xmm1,[rel PD_RNDINT_MAGIC] ; xmm1=[rel PD_RNDINT_MAGIC]
1.403 + pcmpeqd xmm3,xmm3
1.404 + psrld xmm3,WORD_BIT ; xmm3={0xFFFF 0x0000 0xFFFF 0x0000 ..}
1.405 +
1.406 + addps xmm6,xmm1 ; xmm6=roundint(data0/8)=(00 ** 10 ** 20 ** 30 **)
1.407 + addps xmm7,xmm1 ; xmm7=roundint(data1/8)=(01 ** 11 ** 21 ** 31 **)
1.408 + addps xmm0,xmm1 ; xmm0=roundint(data6/8)=(06 ** 16 ** 26 ** 36 **)
1.409 + addps xmm5,xmm1 ; xmm5=roundint(data7/8)=(07 ** 17 ** 27 ** 37 **)
1.410 +
1.411 + pand xmm6,xmm3 ; xmm6=(00 -- 10 -- 20 -- 30 --)
1.412 + pslld xmm7,WORD_BIT ; xmm7=(-- 01 -- 11 -- 21 -- 31)
1.413 + pand xmm0,xmm3 ; xmm0=(06 -- 16 -- 26 -- 36 --)
1.414 + pslld xmm5,WORD_BIT ; xmm5=(-- 07 -- 17 -- 27 -- 37)
1.415 + por xmm6,xmm7 ; xmm6=(00 01 10 11 20 21 30 31)
1.416 + por xmm0,xmm5 ; xmm0=(06 07 16 17 26 27 36 37)
1.417 +
1.418 + movaps xmm1, XMMWORD [wk(0)] ; xmm1=tmp2
1.419 + movaps xmm3, XMMWORD [wk(1)] ; xmm3=tmp3
1.420 +
1.421 + addps xmm4,xmm2 ; xmm4=tmp4
1.422 + movaps xmm7,xmm1
1.423 + movaps xmm5,xmm3
1.424 + addps xmm1,xmm2 ; xmm1=data2=(02 12 22 32)
1.425 + addps xmm3,xmm4 ; xmm3=data4=(04 14 24 34)
1.426 + subps xmm7,xmm2 ; xmm7=data5=(05 15 25 35)
1.427 + subps xmm5,xmm4 ; xmm5=data3=(03 13 23 33)
1.428 +
1.429 + movaps xmm2,[rel PD_RNDINT_MAGIC] ; xmm2=[rel PD_RNDINT_MAGIC]
1.430 + pcmpeqd xmm4,xmm4
1.431 + psrld xmm4,WORD_BIT ; xmm4={0xFFFF 0x0000 0xFFFF 0x0000 ..}
1.432 +
1.433 + addps xmm3,xmm2 ; xmm3=roundint(data4/8)=(04 ** 14 ** 24 ** 34 **)
1.434 + addps xmm7,xmm2 ; xmm7=roundint(data5/8)=(05 ** 15 ** 25 ** 35 **)
1.435 + addps xmm1,xmm2 ; xmm1=roundint(data2/8)=(02 ** 12 ** 22 ** 32 **)
1.436 + addps xmm5,xmm2 ; xmm5=roundint(data3/8)=(03 ** 13 ** 23 ** 33 **)
1.437 +
1.438 + pand xmm3,xmm4 ; xmm3=(04 -- 14 -- 24 -- 34 --)
1.439 + pslld xmm7,WORD_BIT ; xmm7=(-- 05 -- 15 -- 25 -- 35)
1.440 + pand xmm1,xmm4 ; xmm1=(02 -- 12 -- 22 -- 32 --)
1.441 + pslld xmm5,WORD_BIT ; xmm5=(-- 03 -- 13 -- 23 -- 33)
1.442 + por xmm3,xmm7 ; xmm3=(04 05 14 15 24 25 34 35)
1.443 + por xmm1,xmm5 ; xmm1=(02 03 12 13 22 23 32 33)
1.444 +
1.445 + movdqa xmm2,[rel PB_CENTERJSAMP] ; xmm2=[rel PB_CENTERJSAMP]
1.446 +
1.447 + packsswb xmm6,xmm3 ; xmm6=(00 01 10 11 20 21 30 31 04 05 14 15 24 25 34 35)
1.448 + packsswb xmm1,xmm0 ; xmm1=(02 03 12 13 22 23 32 33 06 07 16 17 26 27 36 37)
1.449 + paddb xmm6,xmm2
1.450 + paddb xmm1,xmm2
1.451 +
1.452 + movdqa xmm4,xmm6 ; transpose coefficients(phase 2)
1.453 + punpcklwd xmm6,xmm1 ; xmm6=(00 01 02 03 10 11 12 13 20 21 22 23 30 31 32 33)
1.454 + punpckhwd xmm4,xmm1 ; xmm4=(04 05 06 07 14 15 16 17 24 25 26 27 34 35 36 37)
1.455 +
1.456 + movdqa xmm7,xmm6 ; transpose coefficients(phase 3)
1.457 + punpckldq xmm6,xmm4 ; xmm6=(00 01 02 03 04 05 06 07 10 11 12 13 14 15 16 17)
1.458 + punpckhdq xmm7,xmm4 ; xmm7=(20 21 22 23 24 25 26 27 30 31 32 33 34 35 36 37)
1.459 +
1.460 + pshufd xmm5,xmm6,0x4E ; xmm5=(10 11 12 13 14 15 16 17 00 01 02 03 04 05 06 07)
1.461 + pshufd xmm3,xmm7,0x4E ; xmm3=(30 31 32 33 34 35 36 37 20 21 22 23 24 25 26 27)
1.462 +
1.463 + mov rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW]
1.464 + mov rbx, JSAMPROW [rdi+2*SIZEOF_JSAMPROW]
1.465 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm6
1.466 + movq XMM_MMWORD [rbx+rax*SIZEOF_JSAMPLE], xmm7
1.467 + mov rdx, JSAMPROW [rdi+1*SIZEOF_JSAMPROW]
1.468 + mov rbx, JSAMPROW [rdi+3*SIZEOF_JSAMPROW]
1.469 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm5
1.470 + movq XMM_MMWORD [rbx+rax*SIZEOF_JSAMPLE], xmm3
1.471 +
1.472 + add rsi, byte 4*SIZEOF_FAST_FLOAT ; wsptr
1.473 + add rdi, byte 4*SIZEOF_JSAMPROW
1.474 + dec rcx ; ctr
1.475 + jnz near .rowloop
1.476 +
1.477 + pop rbx
1.478 + uncollect_args
1.479 + mov rsp,rbp ; rsp <- aligned rbp
1.480 + pop rsp ; rsp <- original rbp
1.481 + pop rbp
1.482 + ret
1.483 +
1.484 +; For some reason, the OS X linker does not honor the request to align the
1.485 +; segment unless we do this.
1.486 + align 16
