1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jiss2fst-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,492 @@
1.4 +;
1.5 +; jiss2fst-64.asm - fast integer IDCT (64-bit SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/projecpt/showfiles.php?group_id=6208
1.20 +;
1.21 +; This file contains a fast, not so accurate integer implementation of
1.22 +; the inverse DCT (Discrete Cosine Transform). The following code is
1.23 +; based directly on the IJG's original jidctfst.c; see the jidctfst.c
1.24 +; for more details.
1.25 +;
1.26 +; [TAB8]
1.27 +
1.28 +%include "jsimdext.inc"
1.29 +%include "jdct.inc"
1.30 +
1.31 +; --------------------------------------------------------------------------
1.32 +
1.33 +%define CONST_BITS 8 ; 14 is also OK.
1.34 +%define PASS1_BITS 2
1.35 +
1.36 +%if IFAST_SCALE_BITS != PASS1_BITS
1.37 +%error "'IFAST_SCALE_BITS' must be equal to 'PASS1_BITS'."
1.38 +%endif
1.39 +
1.40 +%if CONST_BITS == 8
1.41 +F_1_082 equ 277 ; FIX(1.082392200)
1.42 +F_1_414 equ 362 ; FIX(1.414213562)
1.43 +F_1_847 equ 473 ; FIX(1.847759065)
1.44 +F_2_613 equ 669 ; FIX(2.613125930)
1.45 +F_1_613 equ (F_2_613 - 256) ; FIX(2.613125930) - FIX(1)
1.46 +%else
1.47 +; NASM cannot do compile-time arithmetic on floating-point constants.
1.48 +%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
1.49 +F_1_082 equ DESCALE(1162209775,30-CONST_BITS) ; FIX(1.082392200)
1.50 +F_1_414 equ DESCALE(1518500249,30-CONST_BITS) ; FIX(1.414213562)
1.51 +F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
1.52 +F_2_613 equ DESCALE(2805822602,30-CONST_BITS) ; FIX(2.613125930)
1.53 +F_1_613 equ (F_2_613 - (1 << CONST_BITS)) ; FIX(2.613125930) - FIX(1)
1.54 +%endif
1.55 +
1.56 +; --------------------------------------------------------------------------
1.57 + SECTION SEG_CONST
1.58 +
1.59 +; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
1.60 +; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
1.61 +
1.62 +%define PRE_MULTIPLY_SCALE_BITS 2
1.63 +%define CONST_SHIFT (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
1.64 +
1.65 + alignz 16
1.66 + global EXTN(jconst_idct_ifast_sse2)
1.67 +
1.68 +EXTN(jconst_idct_ifast_sse2):
1.69 +
1.70 +PW_F1414 times 8 dw F_1_414 << CONST_SHIFT
1.71 +PW_F1847 times 8 dw F_1_847 << CONST_SHIFT
1.72 +PW_MF1613 times 8 dw -F_1_613 << CONST_SHIFT
1.73 +PW_F1082 times 8 dw F_1_082 << CONST_SHIFT
1.74 +PB_CENTERJSAMP times 16 db CENTERJSAMPLE
1.75 +
1.76 + alignz 16
1.77 +
1.78 +; --------------------------------------------------------------------------
1.79 + SECTION SEG_TEXT
1.80 + BITS 64
1.81 +;
1.82 +; Perform dequantization and inverse DCT on one block of coefficients.
1.83 +;
1.84 +; GLOBAL(void)
1.85 +; jsimd_idct_ifast_sse2 (void * dct_table, JCOEFPTR coef_block,
1.86 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.87 +;
1.88 +
1.89 +; r10 = jpeg_component_info * compptr
1.90 +; r11 = JCOEFPTR coef_block
1.91 +; r12 = JSAMPARRAY output_buf
1.92 +; r13 = JDIMENSION output_col
1.93 +
1.94 +%define original_rbp rbp+0
1.95 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.96 +%define WK_NUM 2
1.97 +
1.98 + align 16
1.99 + global EXTN(jsimd_idct_ifast_sse2)
1.100 +
1.101 +EXTN(jsimd_idct_ifast_sse2):
1.102 + push rbp
1.103 + mov rax,rsp ; rax = original rbp
1.104 + sub rsp, byte 4
1.105 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.106 + mov [rsp],rax
1.107 + mov rbp,rsp ; rbp = aligned rbp
1.108 + lea rsp, [wk(0)]
1.109 + collect_args
1.110 +
1.111 + ; ---- Pass 1: process columns from input.
1.112 +
1.113 + mov rdx, r10 ; quantptr
1.114 + mov rsi, r11 ; inptr
1.115 +
1.116 +%ifndef NO_ZERO_COLUMN_TEST_IFAST_SSE2
1.117 + mov eax, DWORD [DWBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.118 + or eax, DWORD [DWBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.119 + jnz near .columnDCT
1.120 +
1.121 + movdqa xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.122 + movdqa xmm1, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.123 + por xmm0, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
1.124 + por xmm1, XMMWORD [XMMBLOCK(4,0,rsi,SIZEOF_JCOEF)]
1.125 + por xmm0, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
1.126 + por xmm1, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
1.127 + por xmm0, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
1.128 + por xmm1,xmm0
1.129 + packsswb xmm1,xmm1
1.130 + packsswb xmm1,xmm1
1.131 + movd eax,xmm1
1.132 + test rax,rax
1.133 + jnz short .columnDCT
1.134 +
1.135 + ; -- AC terms all zero
1.136 +
1.137 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
1.138 + pmullw xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
1.139 +
1.140 + movdqa xmm7,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07)
1.141 + punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
1.142 + punpckhwd xmm7,xmm7 ; xmm7=(04 04 05 05 06 06 07 07)
1.143 +
1.144 + pshufd xmm6,xmm0,0x00 ; xmm6=col0=(00 00 00 00 00 00 00 00)
1.145 + pshufd xmm2,xmm0,0x55 ; xmm2=col1=(01 01 01 01 01 01 01 01)
1.146 + pshufd xmm5,xmm0,0xAA ; xmm5=col2=(02 02 02 02 02 02 02 02)
1.147 + pshufd xmm0,xmm0,0xFF ; xmm0=col3=(03 03 03 03 03 03 03 03)
1.148 + pshufd xmm1,xmm7,0x00 ; xmm1=col4=(04 04 04 04 04 04 04 04)
1.149 + pshufd xmm4,xmm7,0x55 ; xmm4=col5=(05 05 05 05 05 05 05 05)
1.150 + pshufd xmm3,xmm7,0xAA ; xmm3=col6=(06 06 06 06 06 06 06 06)
1.151 + pshufd xmm7,xmm7,0xFF ; xmm7=col7=(07 07 07 07 07 07 07 07)
1.152 +
1.153 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=col1
1.154 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=col3
1.155 + jmp near .column_end
1.156 +%endif
1.157 +.columnDCT:
1.158 +
1.159 + ; -- Even part
1.160 +
1.161 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
1.162 + movdqa xmm1, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
1.163 + pmullw xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.164 + pmullw xmm1, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.165 + movdqa xmm2, XMMWORD [XMMBLOCK(4,0,rsi,SIZEOF_JCOEF)]
1.166 + movdqa xmm3, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
1.167 + pmullw xmm2, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.168 + pmullw xmm3, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.169 +
1.170 + movdqa xmm4,xmm0
1.171 + movdqa xmm5,xmm1
1.172 + psubw xmm0,xmm2 ; xmm0=tmp11
1.173 + psubw xmm1,xmm3
1.174 + paddw xmm4,xmm2 ; xmm4=tmp10
1.175 + paddw xmm5,xmm3 ; xmm5=tmp13
1.176 +
1.177 + psllw xmm1,PRE_MULTIPLY_SCALE_BITS
1.178 + pmulhw xmm1,[rel PW_F1414]
1.179 + psubw xmm1,xmm5 ; xmm1=tmp12
1.180 +
1.181 + movdqa xmm6,xmm4
1.182 + movdqa xmm7,xmm0
1.183 + psubw xmm4,xmm5 ; xmm4=tmp3
1.184 + psubw xmm0,xmm1 ; xmm0=tmp2
1.185 + paddw xmm6,xmm5 ; xmm6=tmp0
1.186 + paddw xmm7,xmm1 ; xmm7=tmp1
1.187 +
1.188 + movdqa XMMWORD [wk(1)], xmm4 ; wk(1)=tmp3
1.189 + movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=tmp2
1.190 +
1.191 + ; -- Odd part
1.192 +
1.193 + movdqa xmm2, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
1.194 + movdqa xmm3, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
1.195 + pmullw xmm2, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.196 + pmullw xmm3, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.197 + movdqa xmm5, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
1.198 + movdqa xmm1, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
1.199 + pmullw xmm5, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.200 + pmullw xmm1, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_IFAST_MULT_TYPE)]
1.201 +
1.202 + movdqa xmm4,xmm2
1.203 + movdqa xmm0,xmm5
1.204 + psubw xmm2,xmm1 ; xmm2=z12
1.205 + psubw xmm5,xmm3 ; xmm5=z10
1.206 + paddw xmm4,xmm1 ; xmm4=z11
1.207 + paddw xmm0,xmm3 ; xmm0=z13
1.208 +
1.209 + movdqa xmm1,xmm5 ; xmm1=z10(unscaled)
1.210 + psllw xmm2,PRE_MULTIPLY_SCALE_BITS
1.211 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.212 +
1.213 + movdqa xmm3,xmm4
1.214 + psubw xmm4,xmm0
1.215 + paddw xmm3,xmm0 ; xmm3=tmp7
1.216 +
1.217 + psllw xmm4,PRE_MULTIPLY_SCALE_BITS
1.218 + pmulhw xmm4,[rel PW_F1414] ; xmm4=tmp11
1.219 +
1.220 + ; To avoid overflow...
1.221 + ;
1.222 + ; (Original)
1.223 + ; tmp12 = -2.613125930 * z10 + z5;
1.224 + ;
1.225 + ; (This implementation)
1.226 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.227 + ; = -1.613125930 * z10 - z10 + z5;
1.228 +
1.229 + movdqa xmm0,xmm5
1.230 + paddw xmm5,xmm2
1.231 + pmulhw xmm5,[rel PW_F1847] ; xmm5=z5
1.232 + pmulhw xmm0,[rel PW_MF1613]
1.233 + pmulhw xmm2,[rel PW_F1082]
1.234 + psubw xmm0,xmm1
1.235 + psubw xmm2,xmm5 ; xmm2=tmp10
1.236 + paddw xmm0,xmm5 ; xmm0=tmp12
1.237 +
1.238 + ; -- Final output stage
1.239 +
1.240 + psubw xmm0,xmm3 ; xmm0=tmp6
1.241 + movdqa xmm1,xmm6
1.242 + movdqa xmm5,xmm7
1.243 + paddw xmm6,xmm3 ; xmm6=data0=(00 01 02 03 04 05 06 07)
1.244 + paddw xmm7,xmm0 ; xmm7=data1=(10 11 12 13 14 15 16 17)
1.245 + psubw xmm1,xmm3 ; xmm1=data7=(70 71 72 73 74 75 76 77)
1.246 + psubw xmm5,xmm0 ; xmm5=data6=(60 61 62 63 64 65 66 67)
1.247 + psubw xmm4,xmm0 ; xmm4=tmp5
1.248 +
1.249 + movdqa xmm3,xmm6 ; transpose coefficients(phase 1)
1.250 + punpcklwd xmm6,xmm7 ; xmm6=(00 10 01 11 02 12 03 13)
1.251 + punpckhwd xmm3,xmm7 ; xmm3=(04 14 05 15 06 16 07 17)
1.252 + movdqa xmm0,xmm5 ; transpose coefficients(phase 1)
1.253 + punpcklwd xmm5,xmm1 ; xmm5=(60 70 61 71 62 72 63 73)
1.254 + punpckhwd xmm0,xmm1 ; xmm0=(64 74 65 75 66 76 67 77)
1.255 +
1.256 + movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp2
1.257 + movdqa xmm1, XMMWORD [wk(1)] ; xmm1=tmp3
1.258 +
1.259 + movdqa XMMWORD [wk(0)], xmm5 ; wk(0)=(60 70 61 71 62 72 63 73)
1.260 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=(64 74 65 75 66 76 67 77)
1.261 +
1.262 + paddw xmm2,xmm4 ; xmm2=tmp4
1.263 + movdqa xmm5,xmm7
1.264 + movdqa xmm0,xmm1
1.265 + paddw xmm7,xmm4 ; xmm7=data2=(20 21 22 23 24 25 26 27)
1.266 + paddw xmm1,xmm2 ; xmm1=data4=(40 41 42 43 44 45 46 47)
1.267 + psubw xmm5,xmm4 ; xmm5=data5=(50 51 52 53 54 55 56 57)
1.268 + psubw xmm0,xmm2 ; xmm0=data3=(30 31 32 33 34 35 36 37)
1.269 +
1.270 + movdqa xmm4,xmm7 ; transpose coefficients(phase 1)
1.271 + punpcklwd xmm7,xmm0 ; xmm7=(20 30 21 31 22 32 23 33)
1.272 + punpckhwd xmm4,xmm0 ; xmm4=(24 34 25 35 26 36 27 37)
1.273 + movdqa xmm2,xmm1 ; transpose coefficients(phase 1)
1.274 + punpcklwd xmm1,xmm5 ; xmm1=(40 50 41 51 42 52 43 53)
1.275 + punpckhwd xmm2,xmm5 ; xmm2=(44 54 45 55 46 56 47 57)
1.276 +
1.277 + movdqa xmm0,xmm3 ; transpose coefficients(phase 2)
1.278 + punpckldq xmm3,xmm4 ; xmm3=(04 14 24 34 05 15 25 35)
1.279 + punpckhdq xmm0,xmm4 ; xmm0=(06 16 26 36 07 17 27 37)
1.280 + movdqa xmm5,xmm6 ; transpose coefficients(phase 2)
1.281 + punpckldq xmm6,xmm7 ; xmm6=(00 10 20 30 01 11 21 31)
1.282 + punpckhdq xmm5,xmm7 ; xmm5=(02 12 22 32 03 13 23 33)
1.283 +
1.284 + movdqa xmm4, XMMWORD [wk(0)] ; xmm4=(60 70 61 71 62 72 63 73)
1.285 + movdqa xmm7, XMMWORD [wk(1)] ; xmm7=(64 74 65 75 66 76 67 77)
1.286 +
1.287 + movdqa XMMWORD [wk(0)], xmm3 ; wk(0)=(04 14 24 34 05 15 25 35)
1.288 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=(06 16 26 36 07 17 27 37)
1.289 +
1.290 + movdqa xmm3,xmm1 ; transpose coefficients(phase 2)
1.291 + punpckldq xmm1,xmm4 ; xmm1=(40 50 60 70 41 51 61 71)
1.292 + punpckhdq xmm3,xmm4 ; xmm3=(42 52 62 72 43 53 63 73)
1.293 + movdqa xmm0,xmm2 ; transpose coefficients(phase 2)
1.294 + punpckldq xmm2,xmm7 ; xmm2=(44 54 64 74 45 55 65 75)
1.295 + punpckhdq xmm0,xmm7 ; xmm0=(46 56 66 76 47 57 67 77)
1.296 +
1.297 + movdqa xmm4,xmm6 ; transpose coefficients(phase 3)
1.298 + punpcklqdq xmm6,xmm1 ; xmm6=col0=(00 10 20 30 40 50 60 70)
1.299 + punpckhqdq xmm4,xmm1 ; xmm4=col1=(01 11 21 31 41 51 61 71)
1.300 + movdqa xmm7,xmm5 ; transpose coefficients(phase 3)
1.301 + punpcklqdq xmm5,xmm3 ; xmm5=col2=(02 12 22 32 42 52 62 72)
1.302 + punpckhqdq xmm7,xmm3 ; xmm7=col3=(03 13 23 33 43 53 63 73)
1.303 +
1.304 + movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(04 14 24 34 05 15 25 35)
1.305 + movdqa xmm3, XMMWORD [wk(1)] ; xmm3=(06 16 26 36 07 17 27 37)
1.306 +
1.307 + movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=col1
1.308 + movdqa XMMWORD [wk(1)], xmm7 ; wk(1)=col3
1.309 +
1.310 + movdqa xmm4,xmm1 ; transpose coefficients(phase 3)
1.311 + punpcklqdq xmm1,xmm2 ; xmm1=col4=(04 14 24 34 44 54 64 74)
1.312 + punpckhqdq xmm4,xmm2 ; xmm4=col5=(05 15 25 35 45 55 65 75)
1.313 + movdqa xmm7,xmm3 ; transpose coefficients(phase 3)
1.314 + punpcklqdq xmm3,xmm0 ; xmm3=col6=(06 16 26 36 46 56 66 76)
1.315 + punpckhqdq xmm7,xmm0 ; xmm7=col7=(07 17 27 37 47 57 67 77)
1.316 +.column_end:
1.317 +
1.318 + ; -- Prefetch the next coefficient block
1.319 +
1.320 + prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
1.321 + prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
1.322 + prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
1.323 + prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
1.324 +
1.325 + ; ---- Pass 2: process rows from work array, store into output array.
1.326 +
1.327 + mov rax, [original_rbp]
1.328 + mov rdi, r12 ; (JSAMPROW *)
1.329 + mov rax, r13
1.330 +
1.331 + ; -- Even part
1.332 +
1.333 + ; xmm6=col0, xmm5=col2, xmm1=col4, xmm3=col6
1.334 +
1.335 + movdqa xmm2,xmm6
1.336 + movdqa xmm0,xmm5
1.337 + psubw xmm6,xmm1 ; xmm6=tmp11
1.338 + psubw xmm5,xmm3
1.339 + paddw xmm2,xmm1 ; xmm2=tmp10
1.340 + paddw xmm0,xmm3 ; xmm0=tmp13
1.341 +
1.342 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.343 + pmulhw xmm5,[rel PW_F1414]
1.344 + psubw xmm5,xmm0 ; xmm5=tmp12
1.345 +
1.346 + movdqa xmm1,xmm2
1.347 + movdqa xmm3,xmm6
1.348 + psubw xmm2,xmm0 ; xmm2=tmp3
1.349 + psubw xmm6,xmm5 ; xmm6=tmp2
1.350 + paddw xmm1,xmm0 ; xmm1=tmp0
1.351 + paddw xmm3,xmm5 ; xmm3=tmp1
1.352 +
1.353 + movdqa xmm0, XMMWORD [wk(0)] ; xmm0=col1
1.354 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=col3
1.355 +
1.356 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp3
1.357 + movdqa XMMWORD [wk(1)], xmm6 ; wk(1)=tmp2
1.358 +
1.359 + ; -- Odd part
1.360 +
1.361 + ; xmm0=col1, xmm5=col3, xmm4=col5, xmm7=col7
1.362 +
1.363 + movdqa xmm2,xmm0
1.364 + movdqa xmm6,xmm4
1.365 + psubw xmm0,xmm7 ; xmm0=z12
1.366 + psubw xmm4,xmm5 ; xmm4=z10
1.367 + paddw xmm2,xmm7 ; xmm2=z11
1.368 + paddw xmm6,xmm5 ; xmm6=z13
1.369 +
1.370 + movdqa xmm7,xmm4 ; xmm7=z10(unscaled)
1.371 + psllw xmm0,PRE_MULTIPLY_SCALE_BITS
1.372 + psllw xmm4,PRE_MULTIPLY_SCALE_BITS
1.373 +
1.374 + movdqa xmm5,xmm2
1.375 + psubw xmm2,xmm6
1.376 + paddw xmm5,xmm6 ; xmm5=tmp7
1.377 +
1.378 + psllw xmm2,PRE_MULTIPLY_SCALE_BITS
1.379 + pmulhw xmm2,[rel PW_F1414] ; xmm2=tmp11
1.380 +
1.381 + ; To avoid overflow...
1.382 + ;
1.383 + ; (Original)
1.384 + ; tmp12 = -2.613125930 * z10 + z5;
1.385 + ;
1.386 + ; (This implementation)
1.387 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.388 + ; = -1.613125930 * z10 - z10 + z5;
1.389 +
1.390 + movdqa xmm6,xmm4
1.391 + paddw xmm4,xmm0
1.392 + pmulhw xmm4,[rel PW_F1847] ; xmm4=z5
1.393 + pmulhw xmm6,[rel PW_MF1613]
1.394 + pmulhw xmm0,[rel PW_F1082]
1.395 + psubw xmm6,xmm7
1.396 + psubw xmm0,xmm4 ; xmm0=tmp10
1.397 + paddw xmm6,xmm4 ; xmm6=tmp12
1.398 +
1.399 + ; -- Final output stage
1.400 +
1.401 + psubw xmm6,xmm5 ; xmm6=tmp6
1.402 + movdqa xmm7,xmm1
1.403 + movdqa xmm4,xmm3
1.404 + paddw xmm1,xmm5 ; xmm1=data0=(00 10 20 30 40 50 60 70)
1.405 + paddw xmm3,xmm6 ; xmm3=data1=(01 11 21 31 41 51 61 71)
1.406 + psraw xmm1,(PASS1_BITS+3) ; descale
1.407 + psraw xmm3,(PASS1_BITS+3) ; descale
1.408 + psubw xmm7,xmm5 ; xmm7=data7=(07 17 27 37 47 57 67 77)
1.409 + psubw xmm4,xmm6 ; xmm4=data6=(06 16 26 36 46 56 66 76)
1.410 + psraw xmm7,(PASS1_BITS+3) ; descale
1.411 + psraw xmm4,(PASS1_BITS+3) ; descale
1.412 + psubw xmm2,xmm6 ; xmm2=tmp5
1.413 +
1.414 + packsswb xmm1,xmm4 ; xmm1=(00 10 20 30 40 50 60 70 06 16 26 36 46 56 66 76)
1.415 + packsswb xmm3,xmm7 ; xmm3=(01 11 21 31 41 51 61 71 07 17 27 37 47 57 67 77)
1.416 +
1.417 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp2
1.418 + movdqa xmm6, XMMWORD [wk(0)] ; xmm6=tmp3
1.419 +
1.420 + paddw xmm0,xmm2 ; xmm0=tmp4
1.421 + movdqa xmm4,xmm5
1.422 + movdqa xmm7,xmm6
1.423 + paddw xmm5,xmm2 ; xmm5=data2=(02 12 22 32 42 52 62 72)
1.424 + paddw xmm6,xmm0 ; xmm6=data4=(04 14 24 34 44 54 64 74)
1.425 + psraw xmm5,(PASS1_BITS+3) ; descale
1.426 + psraw xmm6,(PASS1_BITS+3) ; descale
1.427 + psubw xmm4,xmm2 ; xmm4=data5=(05 15 25 35 45 55 65 75)
1.428 + psubw xmm7,xmm0 ; xmm7=data3=(03 13 23 33 43 53 63 73)
1.429 + psraw xmm4,(PASS1_BITS+3) ; descale
1.430 + psraw xmm7,(PASS1_BITS+3) ; descale
1.431 +
1.432 + movdqa xmm2,[rel PB_CENTERJSAMP] ; xmm2=[rel PB_CENTERJSAMP]
1.433 +
1.434 + packsswb xmm5,xmm6 ; xmm5=(02 12 22 32 42 52 62 72 04 14 24 34 44 54 64 74)
1.435 + packsswb xmm7,xmm4 ; xmm7=(03 13 23 33 43 53 63 73 05 15 25 35 45 55 65 75)
1.436 +
1.437 + paddb xmm1,xmm2
1.438 + paddb xmm3,xmm2
1.439 + paddb xmm5,xmm2
1.440 + paddb xmm7,xmm2
1.441 +
1.442 + movdqa xmm0,xmm1 ; transpose coefficients(phase 1)
1.443 + punpcklbw xmm1,xmm3 ; xmm1=(00 01 10 11 20 21 30 31 40 41 50 51 60 61 70 71)
1.444 + punpckhbw xmm0,xmm3 ; xmm0=(06 07 16 17 26 27 36 37 46 47 56 57 66 67 76 77)
1.445 + movdqa xmm6,xmm5 ; transpose coefficients(phase 1)
1.446 + punpcklbw xmm5,xmm7 ; xmm5=(02 03 12 13 22 23 32 33 42 43 52 53 62 63 72 73)
1.447 + punpckhbw xmm6,xmm7 ; xmm6=(04 05 14 15 24 25 34 35 44 45 54 55 64 65 74 75)
1.448 +
1.449 + movdqa xmm4,xmm1 ; transpose coefficients(phase 2)
1.450 + punpcklwd xmm1,xmm5 ; xmm1=(00 01 02 03 10 11 12 13 20 21 22 23 30 31 32 33)
1.451 + punpckhwd xmm4,xmm5 ; xmm4=(40 41 42 43 50 51 52 53 60 61 62 63 70 71 72 73)
1.452 + movdqa xmm2,xmm6 ; transpose coefficients(phase 2)
1.453 + punpcklwd xmm6,xmm0 ; xmm6=(04 05 06 07 14 15 16 17 24 25 26 27 34 35 36 37)
1.454 + punpckhwd xmm2,xmm0 ; xmm2=(44 45 46 47 54 55 56 57 64 65 66 67 74 75 76 77)
1.455 +
1.456 + movdqa xmm3,xmm1 ; transpose coefficients(phase 3)
1.457 + punpckldq xmm1,xmm6 ; xmm1=(00 01 02 03 04 05 06 07 10 11 12 13 14 15 16 17)
1.458 + punpckhdq xmm3,xmm6 ; xmm3=(20 21 22 23 24 25 26 27 30 31 32 33 34 35 36 37)
1.459 + movdqa xmm7,xmm4 ; transpose coefficients(phase 3)
1.460 + punpckldq xmm4,xmm2 ; xmm4=(40 41 42 43 44 45 46 47 50 51 52 53 54 55 56 57)
1.461 + punpckhdq xmm7,xmm2 ; xmm7=(60 61 62 63 64 65 66 67 70 71 72 73 74 75 76 77)
1.462 +
1.463 + pshufd xmm5,xmm1,0x4E ; xmm5=(10 11 12 13 14 15 16 17 00 01 02 03 04 05 06 07)
1.464 + pshufd xmm0,xmm3,0x4E ; xmm0=(30 31 32 33 34 35 36 37 20 21 22 23 24 25 26 27)
1.465 + pshufd xmm6,xmm4,0x4E ; xmm6=(50 51 52 53 54 55 56 57 40 41 42 43 44 45 46 47)
1.466 + pshufd xmm2,xmm7,0x4E ; xmm2=(70 71 72 73 74 75 76 77 60 61 62 63 64 65 66 67)
1.467 +
1.468 + mov rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW]
1.469 + mov rsi, JSAMPROW [rdi+2*SIZEOF_JSAMPROW]
1.470 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm1
1.471 + movq XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm3
1.472 + mov rdx, JSAMPROW [rdi+4*SIZEOF_JSAMPROW]
1.473 + mov rsi, JSAMPROW [rdi+6*SIZEOF_JSAMPROW]
1.474 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm4
1.475 + movq XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm7
1.476 +
1.477 + mov rdx, JSAMPROW [rdi+1*SIZEOF_JSAMPROW]
1.478 + mov rsi, JSAMPROW [rdi+3*SIZEOF_JSAMPROW]
1.479 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm5
1.480 + movq XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm0
1.481 + mov rdx, JSAMPROW [rdi+5*SIZEOF_JSAMPROW]
1.482 + mov rsi, JSAMPROW [rdi+7*SIZEOF_JSAMPROW]
1.483 + movq XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm6
1.484 + movq XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm2
1.485 +
1.486 + uncollect_args
1.487 + mov rsp,rbp ; rsp <- aligned rbp
1.488 + pop rsp ; rsp <- original rbp
1.489 + pop rbp
1.490 + ret
1.491 + ret
1.492 +
1.493 +; For some reason, the OS X linker does not honor the request to align the
1.494 +; segment unless we do this.
1.495 + align 16
