1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jiss2red.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,594 @@
1.4 +;
1.5 +; jiss2red.asm - reduced-size IDCT (SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +;
1.9 +; Based on
1.10 +; x86 SIMD extension for IJG JPEG library
1.11 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.12 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.13 +;
1.14 +; This file should be assembled with NASM (Netwide Assembler),
1.15 +; can *not* be assembled with Microsoft's MASM or any compatible
1.16 +; assembler (including Borland's Turbo Assembler).
1.17 +; NASM is available from http://nasm.sourceforge.net/ or
1.18 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.19 +;
1.20 +; This file contains inverse-DCT routines that produce reduced-size
1.21 +; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.
1.22 +; The following code is based directly on the IJG's original jidctred.c;
1.23 +; see the jidctred.c for more details.
1.24 +;
1.25 +; [TAB8]
1.26 +
1.27 +%include "jsimdext.inc"
1.28 +%include "jdct.inc"
1.29 +
1.30 +; --------------------------------------------------------------------------
1.31 +
1.32 +%define CONST_BITS 13
1.33 +%define PASS1_BITS 2
1.34 +
1.35 +%define DESCALE_P1_4 (CONST_BITS-PASS1_BITS+1)
1.36 +%define DESCALE_P2_4 (CONST_BITS+PASS1_BITS+3+1)
1.37 +%define DESCALE_P1_2 (CONST_BITS-PASS1_BITS+2)
1.38 +%define DESCALE_P2_2 (CONST_BITS+PASS1_BITS+3+2)
1.39 +
1.40 +%if CONST_BITS == 13
1.41 +F_0_211 equ 1730 ; FIX(0.211164243)
1.42 +F_0_509 equ 4176 ; FIX(0.509795579)
1.43 +F_0_601 equ 4926 ; FIX(0.601344887)
1.44 +F_0_720 equ 5906 ; FIX(0.720959822)
1.45 +F_0_765 equ 6270 ; FIX(0.765366865)
1.46 +F_0_850 equ 6967 ; FIX(0.850430095)
1.47 +F_0_899 equ 7373 ; FIX(0.899976223)
1.48 +F_1_061 equ 8697 ; FIX(1.061594337)
1.49 +F_1_272 equ 10426 ; FIX(1.272758580)
1.50 +F_1_451 equ 11893 ; FIX(1.451774981)
1.51 +F_1_847 equ 15137 ; FIX(1.847759065)
1.52 +F_2_172 equ 17799 ; FIX(2.172734803)
1.53 +F_2_562 equ 20995 ; FIX(2.562915447)
1.54 +F_3_624 equ 29692 ; FIX(3.624509785)
1.55 +%else
1.56 +; NASM cannot do compile-time arithmetic on floating-point constants.
1.57 +%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
1.58 +F_0_211 equ DESCALE( 226735879,30-CONST_BITS) ; FIX(0.211164243)
1.59 +F_0_509 equ DESCALE( 547388834,30-CONST_BITS) ; FIX(0.509795579)
1.60 +F_0_601 equ DESCALE( 645689155,30-CONST_BITS) ; FIX(0.601344887)
1.61 +F_0_720 equ DESCALE( 774124714,30-CONST_BITS) ; FIX(0.720959822)
1.62 +F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)
1.63 +F_0_850 equ DESCALE( 913142361,30-CONST_BITS) ; FIX(0.850430095)
1.64 +F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)
1.65 +F_1_061 equ DESCALE(1139878239,30-CONST_BITS) ; FIX(1.061594337)
1.66 +F_1_272 equ DESCALE(1366614119,30-CONST_BITS) ; FIX(1.272758580)
1.67 +F_1_451 equ DESCALE(1558831516,30-CONST_BITS) ; FIX(1.451774981)
1.68 +F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
1.69 +F_2_172 equ DESCALE(2332956230,30-CONST_BITS) ; FIX(2.172734803)
1.70 +F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)
1.71 +F_3_624 equ DESCALE(3891787747,30-CONST_BITS) ; FIX(3.624509785)
1.72 +%endif
1.73 +
1.74 +; --------------------------------------------------------------------------
1.75 + SECTION SEG_CONST
1.76 +
1.77 + alignz 16
1.78 + global EXTN(jconst_idct_red_sse2)
1.79 +
1.80 +EXTN(jconst_idct_red_sse2):
1.81 +
1.82 +PW_F184_MF076 times 4 dw F_1_847,-F_0_765
1.83 +PW_F256_F089 times 4 dw F_2_562, F_0_899
1.84 +PW_F106_MF217 times 4 dw F_1_061,-F_2_172
1.85 +PW_MF060_MF050 times 4 dw -F_0_601,-F_0_509
1.86 +PW_F145_MF021 times 4 dw F_1_451,-F_0_211
1.87 +PW_F362_MF127 times 4 dw F_3_624,-F_1_272
1.88 +PW_F085_MF072 times 4 dw F_0_850,-F_0_720
1.89 +PD_DESCALE_P1_4 times 4 dd 1 << (DESCALE_P1_4-1)
1.90 +PD_DESCALE_P2_4 times 4 dd 1 << (DESCALE_P2_4-1)
1.91 +PD_DESCALE_P1_2 times 4 dd 1 << (DESCALE_P1_2-1)
1.92 +PD_DESCALE_P2_2 times 4 dd 1 << (DESCALE_P2_2-1)
1.93 +PB_CENTERJSAMP times 16 db CENTERJSAMPLE
1.94 +
1.95 + alignz 16
1.96 +
1.97 +; --------------------------------------------------------------------------
1.98 + SECTION SEG_TEXT
1.99 + BITS 32
1.100 +;
1.101 +; Perform dequantization and inverse DCT on one block of coefficients,
1.102 +; producing a reduced-size 4x4 output block.
1.103 +;
1.104 +; GLOBAL(void)
1.105 +; jsimd_idct_4x4_sse2 (void * dct_table, JCOEFPTR coef_block,
1.106 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.107 +;
1.108 +
1.109 +%define dct_table(b) (b)+8 ; void * dct_table
1.110 +%define coef_block(b) (b)+12 ; JCOEFPTR coef_block
1.111 +%define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
1.112 +%define output_col(b) (b)+20 ; JDIMENSION output_col
1.113 +
1.114 +%define original_ebp ebp+0
1.115 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.116 +%define WK_NUM 2
1.117 +
1.118 + align 16
1.119 + global EXTN(jsimd_idct_4x4_sse2)
1.120 +
1.121 +EXTN(jsimd_idct_4x4_sse2):
1.122 + push ebp
1.123 + mov eax,esp ; eax = original ebp
1.124 + sub esp, byte 4
1.125 + and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.126 + mov [esp],eax
1.127 + mov ebp,esp ; ebp = aligned ebp
1.128 + lea esp, [wk(0)]
1.129 + pushpic ebx
1.130 +; push ecx ; unused
1.131 +; push edx ; need not be preserved
1.132 + push esi
1.133 + push edi
1.134 +
1.135 + get_GOT ebx ; get GOT address
1.136 +
1.137 + ; ---- Pass 1: process columns from input.
1.138 +
1.139 +; mov eax, [original_ebp]
1.140 + mov edx, POINTER [dct_table(eax)] ; quantptr
1.141 + mov esi, JCOEFPTR [coef_block(eax)] ; inptr
1.142 +
1.143 +%ifndef NO_ZERO_COLUMN_TEST_4X4_SSE2
1.144 + mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.145 + or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.146 + jnz short .columnDCT
1.147 +
1.148 + movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.149 + movdqa xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.150 + por xmm0, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.151 + por xmm1, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.152 + por xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.153 + por xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.154 + por xmm0,xmm1
1.155 + packsswb xmm0,xmm0
1.156 + packsswb xmm0,xmm0
1.157 + movd eax,xmm0
1.158 + test eax,eax
1.159 + jnz short .columnDCT
1.160 +
1.161 + ; -- AC terms all zero
1.162 +
1.163 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.164 + pmullw xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.165 +
1.166 + psllw xmm0,PASS1_BITS
1.167 +
1.168 + movdqa xmm3,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07)
1.169 + punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
1.170 + punpckhwd xmm3,xmm3 ; xmm3=(04 04 05 05 06 06 07 07)
1.171 +
1.172 + pshufd xmm1,xmm0,0x50 ; xmm1=[col0 col1]=(00 00 00 00 01 01 01 01)
1.173 + pshufd xmm0,xmm0,0xFA ; xmm0=[col2 col3]=(02 02 02 02 03 03 03 03)
1.174 + pshufd xmm6,xmm3,0x50 ; xmm6=[col4 col5]=(04 04 04 04 05 05 05 05)
1.175 + pshufd xmm3,xmm3,0xFA ; xmm3=[col6 col7]=(06 06 06 06 07 07 07 07)
1.176 +
1.177 + jmp near .column_end
1.178 + alignx 16,7
1.179 +%endif
1.180 +.columnDCT:
1.181 +
1.182 + ; -- Odd part
1.183 +
1.184 + movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.185 + movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.186 + pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.187 + pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.188 + movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.189 + movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.190 + pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.191 + pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.192 +
1.193 + movdqa xmm4,xmm0
1.194 + movdqa xmm5,xmm0
1.195 + punpcklwd xmm4,xmm1
1.196 + punpckhwd xmm5,xmm1
1.197 + movdqa xmm0,xmm4
1.198 + movdqa xmm1,xmm5
1.199 + pmaddwd xmm4,[GOTOFF(ebx,PW_F256_F089)] ; xmm4=(tmp2L)
1.200 + pmaddwd xmm5,[GOTOFF(ebx,PW_F256_F089)] ; xmm5=(tmp2H)
1.201 + pmaddwd xmm0,[GOTOFF(ebx,PW_F106_MF217)] ; xmm0=(tmp0L)
1.202 + pmaddwd xmm1,[GOTOFF(ebx,PW_F106_MF217)] ; xmm1=(tmp0H)
1.203 +
1.204 + movdqa xmm6,xmm2
1.205 + movdqa xmm7,xmm2
1.206 + punpcklwd xmm6,xmm3
1.207 + punpckhwd xmm7,xmm3
1.208 + movdqa xmm2,xmm6
1.209 + movdqa xmm3,xmm7
1.210 + pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2L)
1.211 + pmaddwd xmm7,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm7=(tmp2H)
1.212 + pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0L)
1.213 + pmaddwd xmm3,[GOTOFF(ebx,PW_F145_MF021)] ; xmm3=(tmp0H)
1.214 +
1.215 + paddd xmm6,xmm4 ; xmm6=tmp2L
1.216 + paddd xmm7,xmm5 ; xmm7=tmp2H
1.217 + paddd xmm2,xmm0 ; xmm2=tmp0L
1.218 + paddd xmm3,xmm1 ; xmm3=tmp0H
1.219 +
1.220 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp0L
1.221 + movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=tmp0H
1.222 +
1.223 + ; -- Even part
1.224 +
1.225 + movdqa xmm4, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.226 + movdqa xmm5, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.227 + movdqa xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.228 + pmullw xmm4, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.229 + pmullw xmm5, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.230 + pmullw xmm0, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.231 +
1.232 + pxor xmm1,xmm1
1.233 + pxor xmm2,xmm2
1.234 + punpcklwd xmm1,xmm4 ; xmm1=tmp0L
1.235 + punpckhwd xmm2,xmm4 ; xmm2=tmp0H
1.236 + psrad xmm1,(16-CONST_BITS-1) ; psrad xmm1,16 & pslld xmm1,CONST_BITS+1
1.237 + psrad xmm2,(16-CONST_BITS-1) ; psrad xmm2,16 & pslld xmm2,CONST_BITS+1
1.238 +
1.239 + movdqa xmm3,xmm5 ; xmm5=in2=z2
1.240 + punpcklwd xmm5,xmm0 ; xmm0=in6=z3
1.241 + punpckhwd xmm3,xmm0
1.242 + pmaddwd xmm5,[GOTOFF(ebx,PW_F184_MF076)] ; xmm5=tmp2L
1.243 + pmaddwd xmm3,[GOTOFF(ebx,PW_F184_MF076)] ; xmm3=tmp2H
1.244 +
1.245 + movdqa xmm4,xmm1
1.246 + movdqa xmm0,xmm2
1.247 + paddd xmm1,xmm5 ; xmm1=tmp10L
1.248 + paddd xmm2,xmm3 ; xmm2=tmp10H
1.249 + psubd xmm4,xmm5 ; xmm4=tmp12L
1.250 + psubd xmm0,xmm3 ; xmm0=tmp12H
1.251 +
1.252 + ; -- Final output stage
1.253 +
1.254 + movdqa xmm5,xmm1
1.255 + movdqa xmm3,xmm2
1.256 + paddd xmm1,xmm6 ; xmm1=data0L
1.257 + paddd xmm2,xmm7 ; xmm2=data0H
1.258 + psubd xmm5,xmm6 ; xmm5=data3L
1.259 + psubd xmm3,xmm7 ; xmm3=data3H
1.260 +
1.261 + movdqa xmm6,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm6=[PD_DESCALE_P1_4]
1.262 +
1.263 + paddd xmm1,xmm6
1.264 + paddd xmm2,xmm6
1.265 + psrad xmm1,DESCALE_P1_4
1.266 + psrad xmm2,DESCALE_P1_4
1.267 + paddd xmm5,xmm6
1.268 + paddd xmm3,xmm6
1.269 + psrad xmm5,DESCALE_P1_4
1.270 + psrad xmm3,DESCALE_P1_4
1.271 +
1.272 + packssdw xmm1,xmm2 ; xmm1=data0=(00 01 02 03 04 05 06 07)
1.273 + packssdw xmm5,xmm3 ; xmm5=data3=(30 31 32 33 34 35 36 37)
1.274 +
1.275 + movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp0L
1.276 + movdqa xmm6, XMMWORD [wk(1)] ; xmm6=tmp0H
1.277 +
1.278 + movdqa xmm2,xmm4
1.279 + movdqa xmm3,xmm0
1.280 + paddd xmm4,xmm7 ; xmm4=data1L
1.281 + paddd xmm0,xmm6 ; xmm0=data1H
1.282 + psubd xmm2,xmm7 ; xmm2=data2L
1.283 + psubd xmm3,xmm6 ; xmm3=data2H
1.284 +
1.285 + movdqa xmm7,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm7=[PD_DESCALE_P1_4]
1.286 +
1.287 + paddd xmm4,xmm7
1.288 + paddd xmm0,xmm7
1.289 + psrad xmm4,DESCALE_P1_4
1.290 + psrad xmm0,DESCALE_P1_4
1.291 + paddd xmm2,xmm7
1.292 + paddd xmm3,xmm7
1.293 + psrad xmm2,DESCALE_P1_4
1.294 + psrad xmm3,DESCALE_P1_4
1.295 +
1.296 + packssdw xmm4,xmm0 ; xmm4=data1=(10 11 12 13 14 15 16 17)
1.297 + packssdw xmm2,xmm3 ; xmm2=data2=(20 21 22 23 24 25 26 27)
1.298 +
1.299 + movdqa xmm6,xmm1 ; transpose coefficients(phase 1)
1.300 + punpcklwd xmm1,xmm4 ; xmm1=(00 10 01 11 02 12 03 13)
1.301 + punpckhwd xmm6,xmm4 ; xmm6=(04 14 05 15 06 16 07 17)
1.302 + movdqa xmm7,xmm2 ; transpose coefficients(phase 1)
1.303 + punpcklwd xmm2,xmm5 ; xmm2=(20 30 21 31 22 32 23 33)
1.304 + punpckhwd xmm7,xmm5 ; xmm7=(24 34 25 35 26 36 27 37)
1.305 +
1.306 + movdqa xmm0,xmm1 ; transpose coefficients(phase 2)
1.307 + punpckldq xmm1,xmm2 ; xmm1=[col0 col1]=(00 10 20 30 01 11 21 31)
1.308 + punpckhdq xmm0,xmm2 ; xmm0=[col2 col3]=(02 12 22 32 03 13 23 33)
1.309 + movdqa xmm3,xmm6 ; transpose coefficients(phase 2)
1.310 + punpckldq xmm6,xmm7 ; xmm6=[col4 col5]=(04 14 24 34 05 15 25 35)
1.311 + punpckhdq xmm3,xmm7 ; xmm3=[col6 col7]=(06 16 26 36 07 17 27 37)
1.312 +.column_end:
1.313 +
1.314 + ; -- Prefetch the next coefficient block
1.315 +
1.316 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
1.317 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
1.318 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
1.319 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
1.320 +
1.321 + ; ---- Pass 2: process rows, store into output array.
1.322 +
1.323 + mov eax, [original_ebp]
1.324 + mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
1.325 + mov eax, JDIMENSION [output_col(eax)]
1.326 +
1.327 + ; -- Even part
1.328 +
1.329 + pxor xmm4,xmm4
1.330 + punpcklwd xmm4,xmm1 ; xmm4=tmp0
1.331 + psrad xmm4,(16-CONST_BITS-1) ; psrad xmm4,16 & pslld xmm4,CONST_BITS+1
1.332 +
1.333 + ; -- Odd part
1.334 +
1.335 + punpckhwd xmm1,xmm0
1.336 + punpckhwd xmm6,xmm3
1.337 + movdqa xmm5,xmm1
1.338 + movdqa xmm2,xmm6
1.339 + pmaddwd xmm1,[GOTOFF(ebx,PW_F256_F089)] ; xmm1=(tmp2)
1.340 + pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2)
1.341 + pmaddwd xmm5,[GOTOFF(ebx,PW_F106_MF217)] ; xmm5=(tmp0)
1.342 + pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0)
1.343 +
1.344 + paddd xmm6,xmm1 ; xmm6=tmp2
1.345 + paddd xmm2,xmm5 ; xmm2=tmp0
1.346 +
1.347 + ; -- Even part
1.348 +
1.349 + punpcklwd xmm0,xmm3
1.350 + pmaddwd xmm0,[GOTOFF(ebx,PW_F184_MF076)] ; xmm0=tmp2
1.351 +
1.352 + movdqa xmm7,xmm4
1.353 + paddd xmm4,xmm0 ; xmm4=tmp10
1.354 + psubd xmm7,xmm0 ; xmm7=tmp12
1.355 +
1.356 + ; -- Final output stage
1.357 +
1.358 + movdqa xmm1,[GOTOFF(ebx,PD_DESCALE_P2_4)] ; xmm1=[PD_DESCALE_P2_4]
1.359 +
1.360 + movdqa xmm5,xmm4
1.361 + movdqa xmm3,xmm7
1.362 + paddd xmm4,xmm6 ; xmm4=data0=(00 10 20 30)
1.363 + paddd xmm7,xmm2 ; xmm7=data1=(01 11 21 31)
1.364 + psubd xmm5,xmm6 ; xmm5=data3=(03 13 23 33)
1.365 + psubd xmm3,xmm2 ; xmm3=data2=(02 12 22 32)
1.366 +
1.367 + paddd xmm4,xmm1
1.368 + paddd xmm7,xmm1
1.369 + psrad xmm4,DESCALE_P2_4
1.370 + psrad xmm7,DESCALE_P2_4
1.371 + paddd xmm5,xmm1
1.372 + paddd xmm3,xmm1
1.373 + psrad xmm5,DESCALE_P2_4
1.374 + psrad xmm3,DESCALE_P2_4
1.375 +
1.376 + packssdw xmm4,xmm3 ; xmm4=(00 10 20 30 02 12 22 32)
1.377 + packssdw xmm7,xmm5 ; xmm7=(01 11 21 31 03 13 23 33)
1.378 +
1.379 + movdqa xmm0,xmm4 ; transpose coefficients(phase 1)
1.380 + punpcklwd xmm4,xmm7 ; xmm4=(00 01 10 11 20 21 30 31)
1.381 + punpckhwd xmm0,xmm7 ; xmm0=(02 03 12 13 22 23 32 33)
1.382 +
1.383 + movdqa xmm6,xmm4 ; transpose coefficients(phase 2)
1.384 + punpckldq xmm4,xmm0 ; xmm4=(00 01 02 03 10 11 12 13)
1.385 + punpckhdq xmm6,xmm0 ; xmm6=(20 21 22 23 30 31 32 33)
1.386 +
1.387 + packsswb xmm4,xmm6 ; xmm4=(00 01 02 03 10 11 12 13 20 ..)
1.388 + paddb xmm4,[GOTOFF(ebx,PB_CENTERJSAMP)]
1.389 +
1.390 + pshufd xmm2,xmm4,0x39 ; xmm2=(10 11 12 13 20 21 22 23 30 ..)
1.391 + pshufd xmm1,xmm4,0x4E ; xmm1=(20 21 22 23 30 31 32 33 00 ..)
1.392 + pshufd xmm3,xmm4,0x93 ; xmm3=(30 31 32 33 00 01 02 03 10 ..)
1.393 +
1.394 + mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
1.395 + mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
1.396 + movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm4
1.397 + movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm2
1.398 + mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
1.399 + mov esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
1.400 + movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm1
1.401 + movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm3
1.402 +
1.403 + pop edi
1.404 + pop esi
1.405 +; pop edx ; need not be preserved
1.406 +; pop ecx ; unused
1.407 + poppic ebx
1.408 + mov esp,ebp ; esp <- aligned ebp
1.409 + pop esp ; esp <- original ebp
1.410 + pop ebp
1.411 + ret
1.412 +
1.413 +
1.414 +; --------------------------------------------------------------------------
1.415 +;
1.416 +; Perform dequantization and inverse DCT on one block of coefficients,
1.417 +; producing a reduced-size 2x2 output block.
1.418 +;
1.419 +; GLOBAL(void)
1.420 +; jsimd_idct_2x2_sse2 (void * dct_table, JCOEFPTR coef_block,
1.421 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.422 +;
1.423 +
1.424 +%define dct_table(b) (b)+8 ; void * dct_table
1.425 +%define coef_block(b) (b)+12 ; JCOEFPTR coef_block
1.426 +%define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
1.427 +%define output_col(b) (b)+20 ; JDIMENSION output_col
1.428 +
1.429 + align 16
1.430 + global EXTN(jsimd_idct_2x2_sse2)
1.431 +
1.432 +EXTN(jsimd_idct_2x2_sse2):
1.433 + push ebp
1.434 + mov ebp,esp
1.435 + push ebx
1.436 +; push ecx ; need not be preserved
1.437 +; push edx ; need not be preserved
1.438 + push esi
1.439 + push edi
1.440 +
1.441 + get_GOT ebx ; get GOT address
1.442 +
1.443 + ; ---- Pass 1: process columns from input.
1.444 +
1.445 + mov edx, POINTER [dct_table(ebp)] ; quantptr
1.446 + mov esi, JCOEFPTR [coef_block(ebp)] ; inptr
1.447 +
1.448 + ; | input: | result: |
1.449 + ; | 00 01 ** 03 ** 05 ** 07 | |
1.450 + ; | 10 11 ** 13 ** 15 ** 17 | |
1.451 + ; | ** ** ** ** ** ** ** ** | |
1.452 + ; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 |
1.453 + ; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 |
1.454 + ; | 50 51 ** 53 ** 55 ** 57 | |
1.455 + ; | ** ** ** ** ** ** ** ** | |
1.456 + ; | 70 71 ** 73 ** 75 ** 77 | |
1.457 +
1.458 + ; -- Odd part
1.459 +
1.460 + movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.461 + movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.462 + pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.463 + pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.464 + movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.465 + movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.466 + pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.467 + pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.468 +
1.469 + ; xmm0=(10 11 ** 13 ** 15 ** 17), xmm1=(30 31 ** 33 ** 35 ** 37)
1.470 + ; xmm2=(50 51 ** 53 ** 55 ** 57), xmm3=(70 71 ** 73 ** 75 ** 77)
1.471 +
1.472 + pcmpeqd xmm7,xmm7
1.473 + pslld xmm7,WORD_BIT ; xmm7={0x0000 0xFFFF 0x0000 0xFFFF ..}
1.474 +
1.475 + movdqa xmm4,xmm0 ; xmm4=(10 11 ** 13 ** 15 ** 17)
1.476 + movdqa xmm5,xmm2 ; xmm5=(50 51 ** 53 ** 55 ** 57)
1.477 + punpcklwd xmm4,xmm1 ; xmm4=(10 30 11 31 ** ** 13 33)
1.478 + punpcklwd xmm5,xmm3 ; xmm5=(50 70 51 71 ** ** 53 73)
1.479 + pmaddwd xmm4,[GOTOFF(ebx,PW_F362_MF127)]
1.480 + pmaddwd xmm5,[GOTOFF(ebx,PW_F085_MF072)]
1.481 +
1.482 + psrld xmm0,WORD_BIT ; xmm0=(11 -- 13 -- 15 -- 17 --)
1.483 + pand xmm1,xmm7 ; xmm1=(-- 31 -- 33 -- 35 -- 37)
1.484 + psrld xmm2,WORD_BIT ; xmm2=(51 -- 53 -- 55 -- 57 --)
1.485 + pand xmm3,xmm7 ; xmm3=(-- 71 -- 73 -- 75 -- 77)
1.486 + por xmm0,xmm1 ; xmm0=(11 31 13 33 15 35 17 37)
1.487 + por xmm2,xmm3 ; xmm2=(51 71 53 73 55 75 57 77)
1.488 + pmaddwd xmm0,[GOTOFF(ebx,PW_F362_MF127)]
1.489 + pmaddwd xmm2,[GOTOFF(ebx,PW_F085_MF072)]
1.490 +
1.491 + paddd xmm4,xmm5 ; xmm4=tmp0[col0 col1 **** col3]
1.492 + paddd xmm0,xmm2 ; xmm0=tmp0[col1 col3 col5 col7]
1.493 +
1.494 + ; -- Even part
1.495 +
1.496 + movdqa xmm6, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.497 + pmullw xmm6, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.498 +
1.499 + ; xmm6=(00 01 ** 03 ** 05 ** 07)
1.500 +
1.501 + movdqa xmm1,xmm6 ; xmm1=(00 01 ** 03 ** 05 ** 07)
1.502 + pslld xmm6,WORD_BIT ; xmm6=(-- 00 -- ** -- ** -- **)
1.503 + pand xmm1,xmm7 ; xmm1=(-- 01 -- 03 -- 05 -- 07)
1.504 + psrad xmm6,(WORD_BIT-CONST_BITS-2) ; xmm6=tmp10[col0 **** **** ****]
1.505 + psrad xmm1,(WORD_BIT-CONST_BITS-2) ; xmm1=tmp10[col1 col3 col5 col7]
1.506 +
1.507 + ; -- Final output stage
1.508 +
1.509 + movdqa xmm3,xmm6
1.510 + movdqa xmm5,xmm1
1.511 + paddd xmm6,xmm4 ; xmm6=data0[col0 **** **** ****]=(A0 ** ** **)
1.512 + paddd xmm1,xmm0 ; xmm1=data0[col1 col3 col5 col7]=(A1 A3 A5 A7)
1.513 + psubd xmm3,xmm4 ; xmm3=data1[col0 **** **** ****]=(B0 ** ** **)
1.514 + psubd xmm5,xmm0 ; xmm5=data1[col1 col3 col5 col7]=(B1 B3 B5 B7)
1.515 +
1.516 + movdqa xmm2,[GOTOFF(ebx,PD_DESCALE_P1_2)] ; xmm2=[PD_DESCALE_P1_2]
1.517 +
1.518 + punpckldq xmm6,xmm3 ; xmm6=(A0 B0 ** **)
1.519 +
1.520 + movdqa xmm7,xmm1
1.521 + punpcklqdq xmm1,xmm5 ; xmm1=(A1 A3 B1 B3)
1.522 + punpckhqdq xmm7,xmm5 ; xmm7=(A5 A7 B5 B7)
1.523 +
1.524 + paddd xmm6,xmm2
1.525 + psrad xmm6,DESCALE_P1_2
1.526 +
1.527 + paddd xmm1,xmm2
1.528 + paddd xmm7,xmm2
1.529 + psrad xmm1,DESCALE_P1_2
1.530 + psrad xmm7,DESCALE_P1_2
1.531 +
1.532 + ; -- Prefetch the next coefficient block
1.533 +
1.534 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
1.535 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
1.536 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
1.537 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
1.538 +
1.539 + ; ---- Pass 2: process rows, store into output array.
1.540 +
1.541 + mov edi, JSAMPARRAY [output_buf(ebp)] ; (JSAMPROW *)
1.542 + mov eax, JDIMENSION [output_col(ebp)]
1.543 +
1.544 + ; | input:| result:|
1.545 + ; | A0 B0 | |
1.546 + ; | A1 B1 | C0 C1 |
1.547 + ; | A3 B3 | D0 D1 |
1.548 + ; | A5 B5 | |
1.549 + ; | A7 B7 | |
1.550 +
1.551 + ; -- Odd part
1.552 +
1.553 + packssdw xmm1,xmm1 ; xmm1=(A1 A3 B1 B3 A1 A3 B1 B3)
1.554 + packssdw xmm7,xmm7 ; xmm7=(A5 A7 B5 B7 A5 A7 B5 B7)
1.555 + pmaddwd xmm1,[GOTOFF(ebx,PW_F362_MF127)]
1.556 + pmaddwd xmm7,[GOTOFF(ebx,PW_F085_MF072)]
1.557 +
1.558 + paddd xmm1,xmm7 ; xmm1=tmp0[row0 row1 row0 row1]
1.559 +
1.560 + ; -- Even part
1.561 +
1.562 + pslld xmm6,(CONST_BITS+2) ; xmm6=tmp10[row0 row1 **** ****]
1.563 +
1.564 + ; -- Final output stage
1.565 +
1.566 + movdqa xmm4,xmm6
1.567 + paddd xmm6,xmm1 ; xmm6=data0[row0 row1 **** ****]=(C0 C1 ** **)
1.568 + psubd xmm4,xmm1 ; xmm4=data1[row0 row1 **** ****]=(D0 D1 ** **)
1.569 +
1.570 + punpckldq xmm6,xmm4 ; xmm6=(C0 D0 C1 D1)
1.571 +
1.572 + paddd xmm6,[GOTOFF(ebx,PD_DESCALE_P2_2)]
1.573 + psrad xmm6,DESCALE_P2_2
1.574 +
1.575 + packssdw xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1)
1.576 + packsswb xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1 ..)
1.577 + paddb xmm6,[GOTOFF(ebx,PB_CENTERJSAMP)]
1.578 +
1.579 + pextrw ebx,xmm6,0x00 ; ebx=(C0 D0 -- --)
1.580 + pextrw ecx,xmm6,0x01 ; ecx=(C1 D1 -- --)
1.581 +
1.582 + mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
1.583 + mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
1.584 + mov WORD [edx+eax*SIZEOF_JSAMPLE], bx
1.585 + mov WORD [esi+eax*SIZEOF_JSAMPLE], cx
1.586 +
1.587 + pop edi
1.588 + pop esi
1.589 +; pop edx ; need not be preserved
1.590 +; pop ecx ; need not be preserved
1.591 + pop ebx
1.592 + pop ebp
1.593 + ret
1.594 +
1.595 +; For some reason, the OS X linker does not honor the request to align the
1.596 +; segment unless we do this.
1.597 + align 16
