1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libvpx/vp8/encoder/arm/neon/fastquantizeb_neon.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,258 @@
1.4 +;
1.5 +; Copyright (c) 2011 The WebM project authors. All Rights Reserved.
1.6 +;
1.7 +; Use of this source code is governed by a BSD-style license
1.8 +; that can be found in the LICENSE file in the root of the source
1.9 +; tree. An additional intellectual property rights grant can be found
1.10 +; in the file PATENTS. All contributing project authors may
1.11 +; be found in the AUTHORS file in the root of the source tree.
1.12 +;
1.13 +
1.14 +
1.15 + EXPORT |vp8_fast_quantize_b_neon|
1.16 + EXPORT |vp8_fast_quantize_b_pair_neon|
1.17 +
1.18 + INCLUDE vp8_asm_enc_offsets.asm
1.19 +
1.20 + ARM
1.21 + REQUIRE8
1.22 + PRESERVE8
1.23 +
1.24 + AREA ||.text||, CODE, READONLY, ALIGN=4
1.25 +
1.26 +;vp8_fast_quantize_b_pair_neon(BLOCK *b1, BLOCK *b2, BLOCKD *d1, BLOCKD *d2);
1.27 +|vp8_fast_quantize_b_pair_neon| PROC
1.28 +
1.29 + stmfd sp!, {r4-r9}
1.30 + vstmdb sp!, {q4-q7}
1.31 +
1.32 + ldr r4, [r0, #vp8_block_coeff]
1.33 + ldr r5, [r0, #vp8_block_quant_fast]
1.34 + ldr r6, [r0, #vp8_block_round]
1.35 +
1.36 + vld1.16 {q0, q1}, [r4@128] ; load z
1.37 +
1.38 + ldr r7, [r2, #vp8_blockd_qcoeff]
1.39 +
1.40 + vabs.s16 q4, q0 ; calculate x = abs(z)
1.41 + vabs.s16 q5, q1
1.42 +
1.43 + ;right shift 15 to get sign, all 0 if it is positive, all 1 if it is negative
1.44 + vshr.s16 q2, q0, #15 ; sz
1.45 + vshr.s16 q3, q1, #15
1.46 +
1.47 + vld1.s16 {q6, q7}, [r6@128] ; load round_ptr [0-15]
1.48 + vld1.s16 {q8, q9}, [r5@128] ; load quant_ptr [0-15]
1.49 +
1.50 + ldr r4, [r1, #vp8_block_coeff]
1.51 +
1.52 + vadd.s16 q4, q6 ; x + Round
1.53 + vadd.s16 q5, q7
1.54 +
1.55 + vld1.16 {q0, q1}, [r4@128] ; load z2
1.56 +
1.57 + vqdmulh.s16 q4, q8 ; y = ((Round+abs(z)) * Quant) >> 16
1.58 + vqdmulh.s16 q5, q9
1.59 +
1.60 + vabs.s16 q10, q0 ; calculate x2 = abs(z_2)
1.61 + vabs.s16 q11, q1
1.62 + vshr.s16 q12, q0, #15 ; sz2
1.63 + vshr.s16 q13, q1, #15
1.64 +
1.65 + ;modify data to have its original sign
1.66 + veor.s16 q4, q2 ; y^sz
1.67 + veor.s16 q5, q3
1.68 +
1.69 + vadd.s16 q10, q6 ; x2 + Round
1.70 + vadd.s16 q11, q7
1.71 +
1.72 + ldr r8, [r2, #vp8_blockd_dequant]
1.73 +
1.74 + vqdmulh.s16 q10, q8 ; y2 = ((Round+abs(z)) * Quant) >> 16
1.75 + vqdmulh.s16 q11, q9
1.76 +
1.77 + vshr.s16 q4, #1 ; right shift 1 after vqdmulh
1.78 + vshr.s16 q5, #1
1.79 +
1.80 + vld1.s16 {q6, q7}, [r8@128] ;load dequant_ptr[i]
1.81 +
1.82 + vsub.s16 q4, q2 ; x1=(y^sz)-sz = (y^sz)-(-1) (2's complement)
1.83 + vsub.s16 q5, q3
1.84 +
1.85 + vshr.s16 q10, #1 ; right shift 1 after vqdmulh
1.86 + vshr.s16 q11, #1
1.87 +
1.88 + ldr r9, [r2, #vp8_blockd_dqcoeff]
1.89 +
1.90 + veor.s16 q10, q12 ; y2^sz2
1.91 + veor.s16 q11, q13
1.92 +
1.93 + vst1.s16 {q4, q5}, [r7] ; store: qcoeff = x1
1.94 +
1.95 +
1.96 + vsub.s16 q10, q12 ; x2=(y^sz)-sz = (y^sz)-(-1) (2's complement)
1.97 + vsub.s16 q11, q13
1.98 +
1.99 + ldr r6, [r3, #vp8_blockd_qcoeff]
1.100 +
1.101 + vmul.s16 q2, q6, q4 ; x * Dequant
1.102 + vmul.s16 q3, q7, q5
1.103 +
1.104 + adr r0, inv_zig_zag ; load ptr of inverse zigzag table
1.105 +
1.106 + vceq.s16 q8, q8 ; set q8 to all 1
1.107 +
1.108 + vst1.s16 {q10, q11}, [r6] ; store: qcoeff = x2
1.109 +
1.110 + vmul.s16 q12, q6, q10 ; x2 * Dequant
1.111 + vmul.s16 q13, q7, q11
1.112 +
1.113 + vld1.16 {q6, q7}, [r0@128] ; load inverse scan order
1.114 +
1.115 + vtst.16 q14, q4, q8 ; now find eob
1.116 + vtst.16 q15, q5, q8 ; non-zero element is set to all 1
1.117 +
1.118 + vst1.s16 {q2, q3}, [r9] ; store dqcoeff = x * Dequant
1.119 +
1.120 + ldr r7, [r3, #vp8_blockd_dqcoeff]
1.121 +
1.122 + vand q0, q6, q14 ; get all valid numbers from scan array
1.123 + vand q1, q7, q15
1.124 +
1.125 + vst1.s16 {q12, q13}, [r7] ; store dqcoeff = x * Dequant
1.126 +
1.127 + vtst.16 q2, q10, q8 ; now find eob
1.128 + vtst.16 q3, q11, q8 ; non-zero element is set to all 1
1.129 +
1.130 + vmax.u16 q0, q0, q1 ; find maximum value in q0, q1
1.131 +
1.132 + vand q10, q6, q2 ; get all valid numbers from scan array
1.133 + vand q11, q7, q3
1.134 + vmax.u16 q10, q10, q11 ; find maximum value in q10, q11
1.135 +
1.136 + vmax.u16 d0, d0, d1
1.137 + vmax.u16 d20, d20, d21
1.138 + vmovl.u16 q0, d0
1.139 + vmovl.u16 q10, d20
1.140 +
1.141 + vmax.u32 d0, d0, d1
1.142 + vmax.u32 d20, d20, d21
1.143 + vpmax.u32 d0, d0, d0
1.144 + vpmax.u32 d20, d20, d20
1.145 +
1.146 + ldr r4, [r2, #vp8_blockd_eob]
1.147 + ldr r5, [r3, #vp8_blockd_eob]
1.148 +
1.149 + vst1.8 {d0[0]}, [r4] ; store eob
1.150 + vst1.8 {d20[0]}, [r5] ; store eob
1.151 +
1.152 + vldmia sp!, {q4-q7}
1.153 + ldmfd sp!, {r4-r9}
1.154 + bx lr
1.155 +
1.156 + ENDP
1.157 +
1.158 +;void vp8_fast_quantize_b_c(BLOCK *b, BLOCKD *d)
1.159 +|vp8_fast_quantize_b_neon| PROC
1.160 +
1.161 + stmfd sp!, {r4-r7}
1.162 +
1.163 + ldr r3, [r0, #vp8_block_coeff]
1.164 + ldr r4, [r0, #vp8_block_quant_fast]
1.165 + ldr r5, [r0, #vp8_block_round]
1.166 +
1.167 + vld1.16 {q0, q1}, [r3@128] ; load z
1.168 + vorr.s16 q14, q0, q1 ; check if all zero (step 1)
1.169 + ldr r6, [r1, #vp8_blockd_qcoeff]
1.170 + ldr r7, [r1, #vp8_blockd_dqcoeff]
1.171 + vorr.s16 d28, d28, d29 ; check if all zero (step 2)
1.172 +
1.173 + vabs.s16 q12, q0 ; calculate x = abs(z)
1.174 + vabs.s16 q13, q1
1.175 +
1.176 + ;right shift 15 to get sign, all 0 if it is positive, all 1 if it is negative
1.177 + vshr.s16 q2, q0, #15 ; sz
1.178 + vmov r2, r3, d28 ; check if all zero (step 3)
1.179 + vshr.s16 q3, q1, #15
1.180 +
1.181 + vld1.s16 {q14, q15}, [r5@128]; load round_ptr [0-15]
1.182 + vld1.s16 {q8, q9}, [r4@128] ; load quant_ptr [0-15]
1.183 +
1.184 + vadd.s16 q12, q14 ; x + Round
1.185 + vadd.s16 q13, q15
1.186 +
1.187 + adr r0, inv_zig_zag ; load ptr of inverse zigzag table
1.188 +
1.189 + vqdmulh.s16 q12, q8 ; y = ((Round+abs(z)) * Quant) >> 16
1.190 + vqdmulh.s16 q13, q9
1.191 +
1.192 + vld1.16 {q10, q11}, [r0@128]; load inverse scan order
1.193 +
1.194 + vceq.s16 q8, q8 ; set q8 to all 1
1.195 +
1.196 + ldr r4, [r1, #vp8_blockd_dequant]
1.197 +
1.198 + vshr.s16 q12, #1 ; right shift 1 after vqdmulh
1.199 + vshr.s16 q13, #1
1.200 +
1.201 + ldr r5, [r1, #vp8_blockd_eob]
1.202 +
1.203 + orr r2, r2, r3 ; check if all zero (step 4)
1.204 + cmp r2, #0 ; check if all zero (step 5)
1.205 + beq zero_output ; check if all zero (step 6)
1.206 +
1.207 + ;modify data to have its original sign
1.208 + veor.s16 q12, q2 ; y^sz
1.209 + veor.s16 q13, q3
1.210 +
1.211 + vsub.s16 q12, q2 ; x1=(y^sz)-sz = (y^sz)-(-1) (2's complement)
1.212 + vsub.s16 q13, q3
1.213 +
1.214 + vld1.s16 {q2, q3}, [r4@128] ; load dequant_ptr[i]
1.215 +
1.216 + vtst.16 q14, q12, q8 ; now find eob
1.217 + vtst.16 q15, q13, q8 ; non-zero element is set to all 1
1.218 +
1.219 + vst1.s16 {q12, q13}, [r6@128]; store: qcoeff = x1
1.220 +
1.221 + vand q10, q10, q14 ; get all valid numbers from scan array
1.222 + vand q11, q11, q15
1.223 +
1.224 +
1.225 + vmax.u16 q0, q10, q11 ; find maximum value in q0, q1
1.226 + vmax.u16 d0, d0, d1
1.227 + vmovl.u16 q0, d0
1.228 +
1.229 + vmul.s16 q2, q12 ; x * Dequant
1.230 + vmul.s16 q3, q13
1.231 +
1.232 + vmax.u32 d0, d0, d1
1.233 + vpmax.u32 d0, d0, d0
1.234 +
1.235 + vst1.s16 {q2, q3}, [r7@128] ; store dqcoeff = x * Dequant
1.236 +
1.237 + vst1.8 {d0[0]}, [r5] ; store eob
1.238 +
1.239 + ldmfd sp!, {r4-r7}
1.240 + bx lr
1.241 +
1.242 +zero_output
1.243 + strb r2, [r5] ; store eob
1.244 + vst1.s16 {q0, q1}, [r6@128] ; qcoeff = 0
1.245 + vst1.s16 {q0, q1}, [r7@128] ; dqcoeff = 0
1.246 +
1.247 + ldmfd sp!, {r4-r7}
1.248 + bx lr
1.249 +
1.250 + ENDP
1.251 +
1.252 +; default inverse zigzag table is defined in vp8/common/entropy.c
1.253 + ALIGN 16 ; enable use of @128 bit aligned loads
1.254 +inv_zig_zag
1.255 + DCW 0x0001, 0x0002, 0x0006, 0x0007
1.256 + DCW 0x0003, 0x0005, 0x0008, 0x000d
1.257 + DCW 0x0004, 0x0009, 0x000c, 0x000e
1.258 + DCW 0x000a, 0x000b, 0x000f, 0x0010
1.259 +
1.260 + END
1.261 +
