The Tor Browser: media/webrtc/trunk/testing/gtest/configure.ac@8bccb770b82d

     1 m4_include(m4/acx_pthread.m4)

     3 # At this point, the Xcode project assumes the version string will be three

     4 # integers separated by periods and surrounded by square brackets (e.g.

     5 # "[1.0.1]"). It also asumes that there won't be any closing parenthesis

     6 # between "AC_INIT(" and the closing ")" including comments and strings.

     7 AC_INIT([Google C++ Testing Framework],

     8         [1.6.0],

     9         [googletestframework@googlegroups.com],

    10         [gtest])

    12 # Provide various options to initialize the Autoconf and configure processes.

    13 AC_PREREQ([2.59])

    14 AC_CONFIG_SRCDIR([./LICENSE])

    15 AC_CONFIG_MACRO_DIR([m4])

    16 AC_CONFIG_AUX_DIR([build-aux])

    17 AC_CONFIG_HEADERS([build-aux/config.h])

    18 AC_CONFIG_FILES([Makefile])

    19 AC_CONFIG_FILES([scripts/gtest-config], [chmod +x scripts/gtest-config])

    21 # Initialize Automake with various options. We require at least v1.9, prevent

    22 # pedantic complaints about package files, and enable various distribution

    23 # targets.

    24 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-zip foreign subdir-objects])

    26 # Check for programs used in building Google Test.

    27 AC_PROG_CC

    28 AC_PROG_CXX

    29 AC_LANG([C++])

    30 AC_PROG_LIBTOOL

    32 # TODO(chandlerc@google.com): Currently we aren't running the Python tests

    33 # against the interpreter detected by AM_PATH_PYTHON, and so we condition

    34 # HAVE_PYTHON by requiring "python" to be in the PATH, and that interpreter's

    35 # version to be >= 2.3. This will allow the scripts to use a "/usr/bin/env"

    36 # hashbang.

    37 PYTHON=  # We *do not* allow the user to specify a python interpreter

    38 AC_PATH_PROG([PYTHON],[python],[:])

    39 AS_IF([test "$PYTHON" != ":"],

    40       [AM_PYTHON_CHECK_VERSION([$PYTHON],[2.3],[:],[PYTHON=":"])])

    41 AM_CONDITIONAL([HAVE_PYTHON],[test "$PYTHON" != ":"])

    43 # Configure pthreads.

    44 AC_ARG_WITH([pthreads],

    45             [AS_HELP_STRING([--with-pthreads],

    46                [use pthreads (default is yes)])],

    47             [with_pthreads=$withval],

    48             [with_pthreads=check])

    50 have_pthreads=no

    51 AS_IF([test "x$with_pthreads" != "xno"],

    52       [ACX_PTHREAD(

    53         [],

    54         [AS_IF([test "x$with_pthreads" != "xcheck"],

    55                [AC_MSG_FAILURE(

    56                  [--with-pthreads was specified, but unable to be used])])])

    57        have_pthreads="$acx_pthread_ok"])

    58 AM_CONDITIONAL([HAVE_PTHREADS],[test "x$have_pthreads" == "xyes"])

    59 AC_SUBST(PTHREAD_CFLAGS)

    60 AC_SUBST(PTHREAD_LIBS)

    62 # TODO(chandlerc@google.com) Check for the necessary system headers.

    64 # TODO(chandlerc@google.com) Check the types, structures, and other compiler

    65 # and architecture characteristics.

    67 # Output the generated files. No further autoconf macros may be used.

    68 AC_OUTPUT

The Tor Browser / file revision