The Tor Browser: xpcom/reflect/xptcall/src/md/unix/xptcinvoke_asm_parisc

Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6

     1 /* -*- Mode: asm; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*-

     2  * Version: MPL 1.1

     3  *

     4  * This Source Code Form is subject to the terms of the Mozilla Public

     5  * License, v. 2.0. If a copy of the MPL was not distributed with this

     6  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */

     8   .LEVEL 1.1

     9   .text

    10   .align 4

    12 framesz:

    13   .equ 128

    15 .globl NS_InvokeByIndex

    16   .type NS_InvokeByIndex, @function

    19 NS_InvokeByIndex:

    20   .PROC

    21   .CALLINFO FRAME=72, CALLER,SAVE_RP, SAVE_SP, ENTRY_GR=3

    22   .ENTRY

    24 ; frame marker takes 48 bytes,

    25 ; register spill area takes 8 bytes,

    26 ; local stack area takes 72 bytes result in 128 bytes total

    28         STW          %rp,-20(%sp)

    29         STW,MA       %r3,128(%sp)

    31         LDO     -framesz(%r30),%r28

    32         STW     %r28,-4(%r30)       ; save previous sp

    33         STW     %r19,-32(%r30)

    35         STW     %r26,-36-framesz(%r30)  ; save argument registers in

    36         STW     %r25,-40-framesz(%r30)  ; in PREVIOUS frame

    37         STW     %r24,-44-framesz(%r30)  ;

    38         STW     %r23,-48-framesz(%r30)  ;

    40         .CALL   ARGW0=GR,ARGW1=GR,ARGW2=GR ;in=24,25,26;out=28

    41         BL    invoke_count_bytes,%r31

    42         COPY    %r31,%r2

    44         CMPIB,>=        0,%r28, .+76

    45         COPY    %r30,%r3            ; copy stack ptr to saved stack ptr

    46         ADD     %r30,%r28,%r30      ; extend stack frame

    47         LDW     -4(%r3),%r28        ; move frame

    48         STW     %r28,-4(%r30)

    49         LDW     -8(%r3),%r28

    50         STW     %r28,-8(%r30)

    51         LDW     -12(%r3),%r28

    52         STW     %r28,-12(%r30)

    53         LDW     -16(%r3),%r28

    54         STW     %r28,-16(%r30)

    55         LDW     -20(%r3),%r28

    56         STW     %r28,-20(%r30)

    57         LDW     -24(%r3),%r28

    58         STW     %r28,-24(%r30)

    59         LDW     -28(%r3),%r28

    60         STW     %r28,-28(%r30)

    61         LDW     -32(%r3),%r28

    62         STW     %r28,-32(%r30)

    64         LDO     -40(%r30),%r26         ; load copy address

    65         LDW     -44-framesz(%r3),%r25  ; load rest of 2 arguments

    66         LDW     -48-framesz(%r3),%r24  ;

    68         LDW     -32(%r30),%r19 ; shared lib call destroys r19; reload

    69         .CALL   ARGW0=GR,ARGW1=GR,ARGW2=GR ;in=24,25,26

    70         BL    invoke_copy_to_stack,%r31

    71         COPY    %r31,%r2

    73         LDO     -48(%r30),%r20

    74         EXTRW,U,= %r28,31,1,%r22

    75         FLDD    0(%r20),%fr7  ; load double arg 1

    76         EXTRW,U,= %r28,30,1,%r22

    77         FLDW    8(%r20),%fr5L ; load float arg 1

    78         EXTRW,U,= %r28,29,1,%r22

    79         FLDW    4(%r20),%fr6L ; load float arg 2

    80         EXTRW,U,= %r28,28,1,%r22

    81         FLDW    0(%r20),%fr7L ; load float arg 3

    83         LDW     -36-framesz(%r3),%r26  ; load ptr to 'that'

    84         LDW     -40(%r30),%r25  ; load the rest of dispatch argument registers

    85         LDW     -44(%r30),%r24

    86         LDW     -48(%r30),%r23

    88         LDW     -36-framesz(%r3),%r20  ; load vtable addr

    89         LDW     -40-framesz(%r3),%r28  ; load index

    90         LDW     0(%r20),%r20    ; follow vtable

    91         SH2ADDL %r28,%r20,%r28  ; add 4*index to vtable entry

    92         LDW     0(%r28),%r22    ; load vtable entry

    94         .CALL ARGW0=GR,ARGW1=GR,ARGW2=GR,ARGW3=GR,RTNVAL=GR ;in=22-26;out=28;

    95         BL    $$dyncall,%r31

    96         COPY    %r31,%r2

    98         LDW     -32(%r30),%r19

    99         COPY    %r3,%r30              ; restore saved stack ptr

   101         LDW          -148(%sp),%rp

   102         LDWM       -128(%sp),%r3

   103         BV,N             (%rp)

   104         NOP

   105   .EXIT

   106   .PROCEND  ;in=23,24,25,26;

   107   .SIZE NS_InvokeByIndex, .-NS_InvokeByIndex

The Tor Browser / file revision