The Tor Browser: xpcom/reflect/xptcall/src/md/unix/xptcinvoke_asm_ppc

Incorporate requested changes from Mozilla in review:
https://bugzilla.mozilla.org/show_bug.cgi?id=1123480#c6

     1 # -*- Mode: Asm -*-

2 #

     3 # This Source Code Form is subject to the terms of the Mozilla Public

     4 # License, v. 2.0. If a copy of the MPL was not distributed with this

     5 # file, You can obtain one at http://mozilla.org/MPL/2.0/.

     6 .set r0,0; .set sp,1; .set RTOC,2; .set r3,3; .set r4,4

     7 .set r5,5; .set r6,6; .set r7,7; .set r8,8; .set r9,9

     8 .set r10,10; .set r11,11; .set r12,12; .set r13,13; .set r14,14

     9 .set r15,15; .set r16,16; .set r17,17; .set r18,18; .set r19,19

    10 .set r20,20; .set r21,21; .set r22,22; .set r23,23; .set r24,24

    11 .set r25,25; .set r26,26; .set r27,27; .set r28,28; .set r29,29

    12 .set r30,30; .set r31,31

    13 .set f0,0; .set f1,1; .set f2,2; .set f3,3; .set f4,4

    14 .set f5,5; .set f6,6; .set f7,7; .set f8,8; .set f9,9

    15 .set f10,10; .set f11,11; .set f12,12; .set f13,13; .set f14,14

    16 .set f15,15; .set f16,16; .set f17,17; .set f18,18; .set f19,19

    17 .set f20,20; .set f21,21; .set f22,22; .set f23,23; .set f24,24

    18 .set f25,25; .set f26,26; .set f27,27; .set f28,28; .set f29,29

    19 .set f30,30; .set f31,31

    21         .section ".text"

    22 	.align 2

    23 	.globl XPTC_InvokeByIndex

    24 	.type  XPTC_InvokeByIndex,@function

    26 #

    27 # XPTC_InvokeByIndex(nsISupports* that, uint32_t methodIndex,

    28 #                    uint32_t paramCount, nsXPTCVariant* params)

    29 #

    31 XPTC_InvokeByIndex:

    32 	stwu    sp,-32(sp)			# setup standard stack frame

    33 	mflr    r0				# save LR

    34 	stw     r3,8(sp)			# r3 <= that

    35 	stw     r4,12(sp)			# r4 <= methodIndex

    36 	stw     r30,16(sp)

    37 	stw     r31,20(sp)

    39 	stw     r0,36(sp)			# store LR backchain

    40 	mr      r31,sp

    42 	rlwinm  r10,r5,3,0,27			# r10 = (ParamCount * 2 * 4) & ~0x0f

    43 	addi    r0,r10,96			# reserve stack for GPR and FPR register save area r0 = r10 + 96

    44 	lwz     r9,0(sp)			# r9 = backchain

    45 	neg     r0,r0

    46 	stwux   r9,sp,r0			# reserve stack sapce and save SP backchain

    48 	addi    r3,sp,8				# r3 <= args

    49 	mr      r4,r5				# r4 <= paramCount

    50 	mr      r5,r6				# r5 <= params

    51 	add     r6,r3,r10			# r6 <= gpregs ( == args + r10 )

    52 	mr      r30,r6				# store in r30 for use later...

    53 	addi    r7,r6,32			# r7 <= fpregs ( == gpregs + 32 )

    55 	bl      invoke_copy_to_stack@local	# (args, paramCount, params, gpregs, fpregs)

    57 	lfd     f1,32(r30)			# load FP registers with method parameters

    58 	lfd     f2,40(r30)

    59 	lfd     f3,48(r30)

    60 	lfd     f4,56(r30)

    61 	lfd     f5,64(r30)

    62 	lfd     f6,72(r30)

    63 	lfd     f7,80(r30)

    64 	lfd     f8,88(r30)

    66 	lwz     r3,8(r31)			# r3 <= that

    67 	lwz     r4,12(r31)			# r4 <= methodIndex

    68 	lwz     r5,0(r3)			# r5 <= vtable ( == *that )

    69 	slwi    r4,r4,3				# convert to offset ( *= 8 )

    70 	addi	r4,r4,8				# skip first two vtable entries

    71 	add	r4,r4,r5

    72 	lhz	r0,0(r4)			# virtual base offset

    73 	extsh	r0,r0

    74 	add	r3,r3,r0

    75 	lwz     r0,4(r4)			# r0 <= methodpointer ( == vtable + offset )

    77         lwz     r4,4(r30)			# load GP regs with method parameters

    78 	lwz     r5,8(r30)

    79 	lwz     r6,12(r30)

    80 	lwz     r7,16(r30)

    81 	lwz     r8,20(r30)

    82 	lwz     r9,24(r30)

    83 	lwz     r10,28(r30)

    85 	mtlr    r0				# copy methodpointer to LR

    86 	blrl					# call method

    88 	lwz     r30,16(r31)			# restore r30 & r31

    89 	lwz     r31,20(r31)

    91 	lwz     r11,0(sp)			# clean up the stack

    92 	lwz     r0,4(r11)

    93 	mtlr    r0

    94 	mr      sp,r11

    95 	blr

The Tor Browser / file revision