michael@0: # Helper functions for option handling.                    -*- Autoconf -*-
michael@0: #
michael@0: #   Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
michael@0: #   Written by Gary V. Vaughan, 2004
michael@0: #
michael@0: # This file is free software; the Free Software Foundation gives
michael@0: # unlimited permission to copy and/or distribute it, with or without
michael@0: # modifications, as long as this notice is preserved.
michael@0: 
michael@0: # serial 6 ltoptions.m4
michael@0: 
michael@0: # This is to help aclocal find these macros, as it can't see m4_define.
michael@0: AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
michael@0: 
michael@0: 
michael@0: # _LT_MANGLE_OPTION(MACRO-NAME, OPTION-NAME)
michael@0: # ------------------------------------------
michael@0: m4_define([_LT_MANGLE_OPTION],
michael@0: [[_LT_OPTION_]m4_bpatsubst($1__$2, [[^a-zA-Z0-9_]], [_])])
michael@0: 
michael@0: 
michael@0: # _LT_SET_OPTION(MACRO-NAME, OPTION-NAME)
michael@0: # ---------------------------------------
michael@0: # Set option OPTION-NAME for macro MACRO-NAME, and if there is a
michael@0: # matching handler defined, dispatch to it.  Other OPTION-NAMEs are
michael@0: # saved as a flag.
michael@0: m4_define([_LT_SET_OPTION],
michael@0: [m4_define(_LT_MANGLE_OPTION([$1], [$2]))dnl
michael@0: m4_ifdef(_LT_MANGLE_DEFUN([$1], [$2]),
michael@0:         _LT_MANGLE_DEFUN([$1], [$2]),
michael@0:     [m4_warning([Unknown $1 option `$2'])])[]dnl
michael@0: ])
michael@0: 
michael@0: 
michael@0: # _LT_IF_OPTION(MACRO-NAME, OPTION-NAME, IF-SET, [IF-NOT-SET])
michael@0: # ------------------------------------------------------------
michael@0: # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
michael@0: m4_define([_LT_IF_OPTION],
michael@0: [m4_ifdef(_LT_MANGLE_OPTION([$1], [$2]), [$3], [$4])])
michael@0: 
michael@0: 
michael@0: # _LT_UNLESS_OPTIONS(MACRO-NAME, OPTION-LIST, IF-NOT-SET)
michael@0: # -------------------------------------------------------
michael@0: # Execute IF-NOT-SET unless all options in OPTION-LIST for MACRO-NAME
michael@0: # are set.
michael@0: m4_define([_LT_UNLESS_OPTIONS],
michael@0: [m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
michael@0: 	    [m4_ifdef(_LT_MANGLE_OPTION([$1], _LT_Option),
michael@0: 		      [m4_define([$0_found])])])[]dnl
michael@0: m4_ifdef([$0_found], [m4_undefine([$0_found])], [$3
michael@0: ])[]dnl
michael@0: ])
michael@0: 
michael@0: 
michael@0: # _LT_SET_OPTIONS(MACRO-NAME, OPTION-LIST)
michael@0: # ----------------------------------------
michael@0: # OPTION-LIST is a space-separated list of Libtool options associated
michael@0: # with MACRO-NAME.  If any OPTION has a matching handler declared with
michael@0: # LT_OPTION_DEFINE, dispatch to that macro; otherwise complain about
michael@0: # the unknown option and exit.
michael@0: m4_defun([_LT_SET_OPTIONS],
michael@0: [# Set options
michael@0: m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
michael@0:     [_LT_SET_OPTION([$1], _LT_Option)])
michael@0: 
michael@0: m4_if([$1],[LT_INIT],[
michael@0:   dnl
michael@0:   dnl Simply set some default values (i.e off) if boolean options were not
michael@0:   dnl specified:
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
michael@0:   ])
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
michael@0:   ])
michael@0:   dnl
michael@0:   dnl If no reference was made to various pairs of opposing options, then
michael@0:   dnl we run the default mode handler for the pair.  For example, if neither
michael@0:   dnl `shared' nor `disable-shared' was passed, we enable building of shared
michael@0:   dnl archives by default:
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
michael@0:   _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
michael@0:   		   [_LT_ENABLE_FAST_INSTALL])
michael@0:   ])
michael@0: ])# _LT_SET_OPTIONS
michael@0: 
michael@0: 
michael@0: ## --------------------------------- ##
michael@0: ## Macros to handle LT_INIT options. ##
michael@0: ## --------------------------------- ##
michael@0: 
michael@0: # _LT_MANGLE_DEFUN(MACRO-NAME, OPTION-NAME)
michael@0: # -----------------------------------------
michael@0: m4_define([_LT_MANGLE_DEFUN],
michael@0: [[_LT_OPTION_DEFUN_]m4_bpatsubst(m4_toupper([$1__$2]), [[^A-Z0-9_]], [_])])
michael@0: 
michael@0: 
michael@0: # LT_OPTION_DEFINE(MACRO-NAME, OPTION-NAME, CODE)
michael@0: # -----------------------------------------------
michael@0: m4_define([LT_OPTION_DEFINE],
michael@0: [m4_define(_LT_MANGLE_DEFUN([$1], [$2]), [$3])[]dnl
michael@0: ])# LT_OPTION_DEFINE
michael@0: 
michael@0: 
michael@0: # dlopen
michael@0: # ------
michael@0: LT_OPTION_DEFINE([LT_INIT], [dlopen], [enable_dlopen=yes
michael@0: ])
michael@0: 
michael@0: AU_DEFUN([AC_LIBTOOL_DLOPEN],
michael@0: [_LT_SET_OPTION([LT_INIT], [dlopen])
michael@0: AC_DIAGNOSE([obsolete],
michael@0: [$0: Remove this warning and the call to _LT_SET_OPTION when you
michael@0: put the `dlopen' option into LT_INIT's first parameter.])
michael@0: ])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AC_LIBTOOL_DLOPEN], [])
michael@0: 
michael@0: 
michael@0: # win32-dll
michael@0: # ---------
michael@0: # Declare package support for building win32 dll's.
michael@0: LT_OPTION_DEFINE([LT_INIT], [win32-dll],
michael@0: [enable_win32_dll=yes
michael@0: 
michael@0: case $host in
michael@0: *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-cegcc*)
michael@0:   AC_CHECK_TOOL(AS, as, false)
michael@0:   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
michael@0:   AC_CHECK_TOOL(OBJDUMP, objdump, false)
michael@0:   ;;
michael@0: esac
michael@0: 
michael@0: test -z "$AS" && AS=as
michael@0: _LT_DECL([], [AS],      [0], [Assembler program])dnl
michael@0: 
michael@0: test -z "$DLLTOOL" && DLLTOOL=dlltool
michael@0: _LT_DECL([], [DLLTOOL], [0], [DLL creation program])dnl
michael@0: 
michael@0: test -z "$OBJDUMP" && OBJDUMP=objdump
michael@0: _LT_DECL([], [OBJDUMP], [0], [Object dumper program])dnl
michael@0: ])# win32-dll
michael@0: 
michael@0: AU_DEFUN([AC_LIBTOOL_WIN32_DLL],
michael@0: [AC_REQUIRE([AC_CANONICAL_HOST])dnl
michael@0: _LT_SET_OPTION([LT_INIT], [win32-dll])
michael@0: AC_DIAGNOSE([obsolete],
michael@0: [$0: Remove this warning and the call to _LT_SET_OPTION when you
michael@0: put the `win32-dll' option into LT_INIT's first parameter.])
michael@0: ])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AC_LIBTOOL_WIN32_DLL], [])
michael@0: 
michael@0: 
michael@0: # _LT_ENABLE_SHARED([DEFAULT])
michael@0: # ----------------------------
michael@0: # implement the --enable-shared flag, and supports the `shared' and
michael@0: # `disable-shared' LT_INIT options.
michael@0: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
michael@0: m4_define([_LT_ENABLE_SHARED],
michael@0: [m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
michael@0: AC_ARG_ENABLE([shared],
michael@0:     [AS_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
michael@0: 	[build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
michael@0:     [p=${PACKAGE-default}
michael@0:     case $enableval in
michael@0:     yes) enable_shared=yes ;;
michael@0:     no) enable_shared=no ;;
michael@0:     *)
michael@0:       enable_shared=no
michael@0:       # Look at the argument we got.  We use all the common list separators.
michael@0:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
michael@0:       for pkg in $enableval; do
michael@0: 	IFS="$lt_save_ifs"
michael@0: 	if test "X$pkg" = "X$p"; then
michael@0: 	  enable_shared=yes
michael@0: 	fi
michael@0:       done
michael@0:       IFS="$lt_save_ifs"
michael@0:       ;;
michael@0:     esac],
michael@0:     [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
michael@0: 
michael@0:     _LT_DECL([build_libtool_libs], [enable_shared], [0],
michael@0: 	[Whether or not to build shared libraries])
michael@0: ])# _LT_ENABLE_SHARED
michael@0: 
michael@0: LT_OPTION_DEFINE([LT_INIT], [shared], [_LT_ENABLE_SHARED([yes])])
michael@0: LT_OPTION_DEFINE([LT_INIT], [disable-shared], [_LT_ENABLE_SHARED([no])])
michael@0: 
michael@0: # Old names:
michael@0: AC_DEFUN([AC_ENABLE_SHARED],
michael@0: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[shared])
michael@0: ])
michael@0: 
michael@0: AC_DEFUN([AC_DISABLE_SHARED],
michael@0: [_LT_SET_OPTION([LT_INIT], [disable-shared])
michael@0: ])
michael@0: 
michael@0: AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
michael@0: AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AM_ENABLE_SHARED], [])
michael@0: dnl AC_DEFUN([AM_DISABLE_SHARED], [])
michael@0: 
michael@0: 
michael@0: 
michael@0: # _LT_ENABLE_STATIC([DEFAULT])
michael@0: # ----------------------------
michael@0: # implement the --enable-static flag, and support the `static' and
michael@0: # `disable-static' LT_INIT options.
michael@0: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
michael@0: m4_define([_LT_ENABLE_STATIC],
michael@0: [m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
michael@0: AC_ARG_ENABLE([static],
michael@0:     [AS_HELP_STRING([--enable-static@<:@=PKGS@:>@],
michael@0: 	[build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
michael@0:     [p=${PACKAGE-default}
michael@0:     case $enableval in
michael@0:     yes) enable_static=yes ;;
michael@0:     no) enable_static=no ;;
michael@0:     *)
michael@0:      enable_static=no
michael@0:       # Look at the argument we got.  We use all the common list separators.
michael@0:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
michael@0:       for pkg in $enableval; do
michael@0: 	IFS="$lt_save_ifs"
michael@0: 	if test "X$pkg" = "X$p"; then
michael@0: 	  enable_static=yes
michael@0: 	fi
michael@0:       done
michael@0:       IFS="$lt_save_ifs"
michael@0:       ;;
michael@0:     esac],
michael@0:     [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
michael@0: 
michael@0:     _LT_DECL([build_old_libs], [enable_static], [0],
michael@0: 	[Whether or not to build static libraries])
michael@0: ])# _LT_ENABLE_STATIC
michael@0: 
michael@0: LT_OPTION_DEFINE([LT_INIT], [static], [_LT_ENABLE_STATIC([yes])])
michael@0: LT_OPTION_DEFINE([LT_INIT], [disable-static], [_LT_ENABLE_STATIC([no])])
michael@0: 
michael@0: # Old names:
michael@0: AC_DEFUN([AC_ENABLE_STATIC],
michael@0: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[static])
michael@0: ])
michael@0: 
michael@0: AC_DEFUN([AC_DISABLE_STATIC],
michael@0: [_LT_SET_OPTION([LT_INIT], [disable-static])
michael@0: ])
michael@0: 
michael@0: AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
michael@0: AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AM_ENABLE_STATIC], [])
michael@0: dnl AC_DEFUN([AM_DISABLE_STATIC], [])
michael@0: 
michael@0: 
michael@0: 
michael@0: # _LT_ENABLE_FAST_INSTALL([DEFAULT])
michael@0: # ----------------------------------
michael@0: # implement the --enable-fast-install flag, and support the `fast-install'
michael@0: # and `disable-fast-install' LT_INIT options.
michael@0: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
michael@0: m4_define([_LT_ENABLE_FAST_INSTALL],
michael@0: [m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
michael@0: AC_ARG_ENABLE([fast-install],
michael@0:     [AS_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
michael@0:     [optimize for fast installation @<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
michael@0:     [p=${PACKAGE-default}
michael@0:     case $enableval in
michael@0:     yes) enable_fast_install=yes ;;
michael@0:     no) enable_fast_install=no ;;
michael@0:     *)
michael@0:       enable_fast_install=no
michael@0:       # Look at the argument we got.  We use all the common list separators.
michael@0:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
michael@0:       for pkg in $enableval; do
michael@0: 	IFS="$lt_save_ifs"
michael@0: 	if test "X$pkg" = "X$p"; then
michael@0: 	  enable_fast_install=yes
michael@0: 	fi
michael@0:       done
michael@0:       IFS="$lt_save_ifs"
michael@0:       ;;
michael@0:     esac],
michael@0:     [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
michael@0: 
michael@0: _LT_DECL([fast_install], [enable_fast_install], [0],
michael@0: 	 [Whether or not to optimize for fast installation])dnl
michael@0: ])# _LT_ENABLE_FAST_INSTALL
michael@0: 
michael@0: LT_OPTION_DEFINE([LT_INIT], [fast-install], [_LT_ENABLE_FAST_INSTALL([yes])])
michael@0: LT_OPTION_DEFINE([LT_INIT], [disable-fast-install], [_LT_ENABLE_FAST_INSTALL([no])])
michael@0: 
michael@0: # Old names:
michael@0: AU_DEFUN([AC_ENABLE_FAST_INSTALL],
michael@0: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[fast-install])
michael@0: AC_DIAGNOSE([obsolete],
michael@0: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
michael@0: the `fast-install' option into LT_INIT's first parameter.])
michael@0: ])
michael@0: 
michael@0: AU_DEFUN([AC_DISABLE_FAST_INSTALL],
michael@0: [_LT_SET_OPTION([LT_INIT], [disable-fast-install])
michael@0: AC_DIAGNOSE([obsolete],
michael@0: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
michael@0: the `disable-fast-install' option into LT_INIT's first parameter.])
michael@0: ])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AC_ENABLE_FAST_INSTALL], [])
michael@0: dnl AC_DEFUN([AM_DISABLE_FAST_INSTALL], [])
michael@0: 
michael@0: 
michael@0: # _LT_WITH_PIC([MODE])
michael@0: # --------------------
michael@0: # implement the --with-pic flag, and support the `pic-only' and `no-pic'
michael@0: # LT_INIT options.
michael@0: # MODE is either `yes' or `no'.  If omitted, it defaults to `both'.
michael@0: m4_define([_LT_WITH_PIC],
michael@0: [AC_ARG_WITH([pic],
michael@0:     [AS_HELP_STRING([--with-pic],
michael@0: 	[try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
michael@0:     [pic_mode="$withval"],
michael@0:     [pic_mode=default])
michael@0: 
michael@0: test -z "$pic_mode" && pic_mode=m4_default([$1], [default])
michael@0: 
michael@0: _LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
michael@0: ])# _LT_WITH_PIC
michael@0: 
michael@0: LT_OPTION_DEFINE([LT_INIT], [pic-only], [_LT_WITH_PIC([yes])])
michael@0: LT_OPTION_DEFINE([LT_INIT], [no-pic], [_LT_WITH_PIC([no])])
michael@0: 
michael@0: # Old name:
michael@0: AU_DEFUN([AC_LIBTOOL_PICMODE],
michael@0: [_LT_SET_OPTION([LT_INIT], [pic-only])
michael@0: AC_DIAGNOSE([obsolete],
michael@0: [$0: Remove this warning and the call to _LT_SET_OPTION when you
michael@0: put the `pic-only' option into LT_INIT's first parameter.])
michael@0: ])
michael@0: 
michael@0: dnl aclocal-1.4 backwards compatibility:
michael@0: dnl AC_DEFUN([AC_LIBTOOL_PICMODE], [])
michael@0: 
michael@0: ## ----------------- ##
michael@0: ## LTDL_INIT Options ##
michael@0: ## ----------------- ##
michael@0: 
michael@0: m4_define([_LTDL_MODE], [])
michael@0: LT_OPTION_DEFINE([LTDL_INIT], [nonrecursive],
michael@0: 		 [m4_define([_LTDL_MODE], [nonrecursive])])
michael@0: LT_OPTION_DEFINE([LTDL_INIT], [recursive],
michael@0: 		 [m4_define([_LTDL_MODE], [recursive])])
michael@0: LT_OPTION_DEFINE([LTDL_INIT], [subproject],
michael@0: 		 [m4_define([_LTDL_MODE], [subproject])])
michael@0: 
michael@0: m4_define([_LTDL_TYPE], [])
michael@0: LT_OPTION_DEFINE([LTDL_INIT], [installable],
michael@0: 		 [m4_define([_LTDL_TYPE], [installable])])
michael@0: LT_OPTION_DEFINE([LTDL_INIT], [convenience],
michael@0: 		 [m4_define([_LTDL_TYPE], [convenience])])