michael@0: ;
michael@0: ; jcclrmmx.asm - colorspace conversion (MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jcolsamp.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Convert some rows of samples to the output colorspace.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_rgb_ycc_convert_mmx (JDIMENSION img_width,
michael@0: ;                           JSAMPARRAY input_buf, JSAMPIMAGE output_buf,
michael@0: ;                           JDIMENSION output_row, int num_rows);
michael@0: ;
michael@0: 
michael@0: %define img_width(b)	(b)+8			; JDIMENSION img_width
michael@0: %define input_buf(b)	(b)+12		; JSAMPARRAY input_buf
michael@0: %define output_buf(b)	(b)+16		; JSAMPIMAGE output_buf
michael@0: %define output_row(b)	(b)+20		; JDIMENSION output_row
michael@0: %define num_rows(b)	(b)+24		; int num_rows
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		8
michael@0: %define gotptr		wk(0)-SIZEOF_POINTER	; void * gotptr
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_rgb_ycc_convert_mmx)
michael@0: 
michael@0: EXTN(jsimd_rgb_ycc_convert_mmx):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [wk(0)]
michael@0: 	pushpic	eax		; make a room for GOT address
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx			; get GOT address
michael@0: 	movpic	POINTER [gotptr], ebx	; save GOT address
michael@0: 
michael@0: 	mov	ecx, JDIMENSION [img_width(eax)]	; num_cols
michael@0: 	test	ecx,ecx
michael@0: 	jz	near .return
michael@0: 
michael@0: 	push	ecx
michael@0: 
michael@0: 	mov	esi, JSAMPIMAGE [output_buf(eax)]
michael@0: 	mov	ecx, JDIMENSION [output_row(eax)]
michael@0: 	mov	edi, JSAMPARRAY [esi+0*SIZEOF_JSAMPARRAY]
michael@0: 	mov	ebx, JSAMPARRAY [esi+1*SIZEOF_JSAMPARRAY]
michael@0: 	mov	edx, JSAMPARRAY [esi+2*SIZEOF_JSAMPARRAY]
michael@0: 	lea	edi, [edi+ecx*SIZEOF_JSAMPROW]
michael@0: 	lea	ebx, [ebx+ecx*SIZEOF_JSAMPROW]
michael@0: 	lea	edx, [edx+ecx*SIZEOF_JSAMPROW]
michael@0: 
michael@0: 	pop	ecx
michael@0: 
michael@0: 	mov	esi, JSAMPARRAY [input_buf(eax)]
michael@0: 	mov	eax, INT [num_rows(eax)]
michael@0: 	test	eax,eax
michael@0: 	jle	near .return
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 	pushpic	eax
michael@0: 	push	edx
michael@0: 	push	ebx
michael@0: 	push	edi
michael@0: 	push	esi
michael@0: 	push	ecx			; col
michael@0: 
michael@0: 	mov	esi, JSAMPROW [esi]	; inptr
michael@0: 	mov	edi, JSAMPROW [edi]	; outptr0
michael@0: 	mov	ebx, JSAMPROW [ebx]	; outptr1
michael@0: 	mov	edx, JSAMPROW [edx]	; outptr2
michael@0: 	movpic	eax, POINTER [gotptr]	; load GOT address (eax)
michael@0: 
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD
michael@0: 	jae	short .columnloop
michael@0: 	alignx	16,7
michael@0: 
michael@0: %if RGB_PIXELSIZE == 3 ; ---------------
michael@0: 
michael@0: .column_ld1:
michael@0: 	push	eax
michael@0: 	push	edx
michael@0: 	lea	ecx,[ecx+ecx*2]		; imul ecx,RGB_PIXELSIZE
michael@0: 	test	cl, SIZEOF_BYTE
michael@0: 	jz	short .column_ld2
michael@0: 	sub	ecx, byte SIZEOF_BYTE
michael@0: 	xor	eax,eax
michael@0: 	mov	al, BYTE [esi+ecx]
michael@0: .column_ld2:
michael@0: 	test	cl, SIZEOF_WORD
michael@0: 	jz	short .column_ld4
michael@0: 	sub	ecx, byte SIZEOF_WORD
michael@0: 	xor	edx,edx
michael@0: 	mov	dx, WORD [esi+ecx]
michael@0: 	shl	eax, WORD_BIT
michael@0: 	or	eax,edx
michael@0: .column_ld4:
michael@0: 	movd	mmA,eax
michael@0: 	pop	edx
michael@0: 	pop	eax
michael@0: 	test	cl, SIZEOF_DWORD
michael@0: 	jz	short .column_ld8
michael@0: 	sub	ecx, byte SIZEOF_DWORD
michael@0: 	movd	mmG, DWORD [esi+ecx]
michael@0: 	psllq	mmA, DWORD_BIT
michael@0: 	por	mmA,mmG
michael@0: .column_ld8:
michael@0: 	test	cl, SIZEOF_MMWORD
michael@0: 	jz	short .column_ld16
michael@0: 	movq	mmG,mmA
michael@0: 	movq	mmA, MMWORD [esi+0*SIZEOF_MMWORD]
michael@0: 	mov	ecx, SIZEOF_MMWORD
michael@0: 	jmp	short .rgb_ycc_cnv
michael@0: .column_ld16:
michael@0: 	test	cl, 2*SIZEOF_MMWORD
michael@0: 	mov	ecx, SIZEOF_MMWORD
michael@0: 	jz	short .rgb_ycc_cnv
michael@0: 	movq	mmF,mmA
michael@0: 	movq	mmA, MMWORD [esi+0*SIZEOF_MMWORD]
michael@0: 	movq	mmG, MMWORD [esi+1*SIZEOF_MMWORD]
michael@0: 	jmp	short .rgb_ycc_cnv
michael@0: 	alignx	16,7
michael@0: 
michael@0: .columnloop:
michael@0: 	movq	mmA, MMWORD [esi+0*SIZEOF_MMWORD]
michael@0: 	movq	mmG, MMWORD [esi+1*SIZEOF_MMWORD]
michael@0: 	movq	mmF, MMWORD [esi+2*SIZEOF_MMWORD]
michael@0: 
michael@0: .rgb_ycc_cnv:
michael@0: 	; mmA=(00 10 20 01 11 21 02 12)
michael@0: 	; mmG=(22 03 13 23 04 14 24 05)
michael@0: 	; mmF=(15 25 06 16 26 07 17 27)
michael@0: 
michael@0: 	movq      mmD,mmA
michael@0: 	psllq     mmA,4*BYTE_BIT	; mmA=(-- -- -- -- 00 10 20 01)
michael@0: 	psrlq     mmD,4*BYTE_BIT	; mmD=(11 21 02 12 -- -- -- --)
michael@0: 
michael@0: 	punpckhbw mmA,mmG		; mmA=(00 04 10 14 20 24 01 05)
michael@0: 	psllq     mmG,4*BYTE_BIT	; mmG=(-- -- -- -- 22 03 13 23)
michael@0: 
michael@0: 	punpcklbw mmD,mmF		; mmD=(11 15 21 25 02 06 12 16)
michael@0: 	punpckhbw mmG,mmF		; mmG=(22 26 03 07 13 17 23 27)
michael@0: 
michael@0: 	movq      mmE,mmA
michael@0: 	psllq     mmA,4*BYTE_BIT	; mmA=(-- -- -- -- 00 04 10 14)
michael@0: 	psrlq     mmE,4*BYTE_BIT	; mmE=(20 24 01 05 -- -- -- --)
michael@0: 
michael@0: 	punpckhbw mmA,mmD		; mmA=(00 02 04 06 10 12 14 16)
michael@0: 	psllq     mmD,4*BYTE_BIT	; mmD=(-- -- -- -- 11 15 21 25)
michael@0: 
michael@0: 	punpcklbw mmE,mmG		; mmE=(20 22 24 26 01 03 05 07)
michael@0: 	punpckhbw mmD,mmG		; mmD=(11 13 15 17 21 23 25 27)
michael@0: 
michael@0: 	pxor      mmH,mmH
michael@0: 
michael@0: 	movq      mmC,mmA
michael@0: 	punpcklbw mmA,mmH		; mmA=(00 02 04 06)
michael@0: 	punpckhbw mmC,mmH		; mmC=(10 12 14 16)
michael@0: 
michael@0: 	movq      mmB,mmE
michael@0: 	punpcklbw mmE,mmH		; mmE=(20 22 24 26)
michael@0: 	punpckhbw mmB,mmH		; mmB=(01 03 05 07)
michael@0: 
michael@0: 	movq      mmF,mmD
michael@0: 	punpcklbw mmD,mmH		; mmD=(11 13 15 17)
michael@0: 	punpckhbw mmF,mmH		; mmF=(21 23 25 27)
michael@0: 
michael@0: %else ; RGB_PIXELSIZE == 4 ; -----------
michael@0: 
michael@0: .column_ld1:
michael@0: 	test	cl, SIZEOF_MMWORD/8
michael@0: 	jz	short .column_ld2
michael@0: 	sub	ecx, byte SIZEOF_MMWORD/8
michael@0: 	movd	mmA, DWORD [esi+ecx*RGB_PIXELSIZE]
michael@0: .column_ld2:
michael@0: 	test	cl, SIZEOF_MMWORD/4
michael@0: 	jz	short .column_ld4
michael@0: 	sub	ecx, byte SIZEOF_MMWORD/4
michael@0: 	movq	mmF,mmA
michael@0: 	movq	mmA, MMWORD [esi+ecx*RGB_PIXELSIZE]
michael@0: .column_ld4:
michael@0: 	test	cl, SIZEOF_MMWORD/2
michael@0: 	mov	ecx, SIZEOF_MMWORD
michael@0: 	jz	short .rgb_ycc_cnv
michael@0: 	movq	mmD,mmA
michael@0: 	movq	mmC,mmF
michael@0: 	movq	mmA, MMWORD [esi+0*SIZEOF_MMWORD]
michael@0: 	movq	mmF, MMWORD [esi+1*SIZEOF_MMWORD]
michael@0: 	jmp	short .rgb_ycc_cnv
michael@0: 	alignx	16,7
michael@0: 
michael@0: .columnloop:
michael@0: 	movq	mmA, MMWORD [esi+0*SIZEOF_MMWORD]
michael@0: 	movq	mmF, MMWORD [esi+1*SIZEOF_MMWORD]
michael@0: 	movq	mmD, MMWORD [esi+2*SIZEOF_MMWORD]
michael@0: 	movq	mmC, MMWORD [esi+3*SIZEOF_MMWORD]
michael@0: 
michael@0: .rgb_ycc_cnv:
michael@0: 	; mmA=(00 10 20 30 01 11 21 31)
michael@0: 	; mmF=(02 12 22 32 03 13 23 33)
michael@0: 	; mmD=(04 14 24 34 05 15 25 35)
michael@0: 	; mmC=(06 16 26 36 07 17 27 37)
michael@0: 
michael@0: 	movq      mmB,mmA
michael@0: 	punpcklbw mmA,mmF		; mmA=(00 02 10 12 20 22 30 32)
michael@0: 	punpckhbw mmB,mmF		; mmB=(01 03 11 13 21 23 31 33)
michael@0: 
michael@0: 	movq      mmG,mmD
michael@0: 	punpcklbw mmD,mmC		; mmD=(04 06 14 16 24 26 34 36)
michael@0: 	punpckhbw mmG,mmC		; mmG=(05 07 15 17 25 27 35 37)
michael@0: 
michael@0: 	movq      mmE,mmA
michael@0: 	punpcklwd mmA,mmD		; mmA=(00 02 04 06 10 12 14 16)
michael@0: 	punpckhwd mmE,mmD		; mmE=(20 22 24 26 30 32 34 36)
michael@0: 
michael@0: 	movq      mmH,mmB
michael@0: 	punpcklwd mmB,mmG		; mmB=(01 03 05 07 11 13 15 17)
michael@0: 	punpckhwd mmH,mmG		; mmH=(21 23 25 27 31 33 35 37)
michael@0: 
michael@0: 	pxor      mmF,mmF
michael@0: 
michael@0: 	movq      mmC,mmA
michael@0: 	punpcklbw mmA,mmF		; mmA=(00 02 04 06)
michael@0: 	punpckhbw mmC,mmF		; mmC=(10 12 14 16)
michael@0: 
michael@0: 	movq      mmD,mmB
michael@0: 	punpcklbw mmB,mmF		; mmB=(01 03 05 07)
michael@0: 	punpckhbw mmD,mmF		; mmD=(11 13 15 17)
michael@0: 
michael@0: 	movq      mmG,mmE
michael@0: 	punpcklbw mmE,mmF		; mmE=(20 22 24 26)
michael@0: 	punpckhbw mmG,mmF		; mmG=(30 32 34 36)
michael@0: 
michael@0: 	punpcklbw mmF,mmH
michael@0: 	punpckhbw mmH,mmH
michael@0: 	psrlw     mmF,BYTE_BIT		; mmF=(21 23 25 27)
michael@0: 	psrlw     mmH,BYTE_BIT		; mmH=(31 33 35 37)
michael@0: 
michael@0: %endif ; RGB_PIXELSIZE ; ---------------
michael@0: 
michael@0: 	; mm0=(R0 R2 R4 R6)=RE, mm2=(G0 G2 G4 G6)=GE, mm4=(B0 B2 B4 B6)=BE
michael@0: 	; mm1=(R1 R3 R5 R7)=RO, mm3=(G1 G3 G5 G7)=GO, mm5=(B1 B3 B5 B7)=BO
michael@0: 
michael@0: 	; (Original)
michael@0: 	; Y  =  0.29900 * R + 0.58700 * G + 0.11400 * B
michael@0: 	; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
michael@0: 	; Cr =  0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
michael@0: 	;
michael@0: 	; (This implementation)
michael@0: 	; Y  =  0.29900 * R + 0.33700 * G + 0.11400 * B + 0.25000 * G
michael@0: 	; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
michael@0: 	; Cr =  0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
michael@0: 
michael@0: 	movq      MMWORD [wk(0)], mm0	; wk(0)=RE
michael@0: 	movq      MMWORD [wk(1)], mm1	; wk(1)=RO
michael@0: 	movq      MMWORD [wk(2)], mm4	; wk(2)=BE
michael@0: 	movq      MMWORD [wk(3)], mm5	; wk(3)=BO
michael@0: 
michael@0: 	movq      mm6,mm1
michael@0: 	punpcklwd mm1,mm3
michael@0: 	punpckhwd mm6,mm3
michael@0: 	movq      mm7,mm1
michael@0: 	movq      mm4,mm6
michael@0: 	pmaddwd   mm1,[GOTOFF(eax,PW_F0299_F0337)] ; mm1=ROL*FIX(0.299)+GOL*FIX(0.337)
michael@0: 	pmaddwd   mm6,[GOTOFF(eax,PW_F0299_F0337)] ; mm6=ROH*FIX(0.299)+GOH*FIX(0.337)
michael@0: 	pmaddwd   mm7,[GOTOFF(eax,PW_MF016_MF033)] ; mm7=ROL*-FIX(0.168)+GOL*-FIX(0.331)
michael@0: 	pmaddwd   mm4,[GOTOFF(eax,PW_MF016_MF033)] ; mm4=ROH*-FIX(0.168)+GOH*-FIX(0.331)
michael@0: 
michael@0: 	movq      MMWORD [wk(4)], mm1	; wk(4)=ROL*FIX(0.299)+GOL*FIX(0.337)
michael@0: 	movq      MMWORD [wk(5)], mm6	; wk(5)=ROH*FIX(0.299)+GOH*FIX(0.337)
michael@0: 
michael@0: 	pxor      mm1,mm1
michael@0: 	pxor      mm6,mm6
michael@0: 	punpcklwd mm1,mm5		; mm1=BOL
michael@0: 	punpckhwd mm6,mm5		; mm6=BOH
michael@0: 	psrld     mm1,1			; mm1=BOL*FIX(0.500)
michael@0: 	psrld     mm6,1			; mm6=BOH*FIX(0.500)
michael@0: 
michael@0: 	movq      mm5,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm5=[PD_ONEHALFM1_CJ]
michael@0: 
michael@0: 	paddd     mm7,mm1
michael@0: 	paddd     mm4,mm6
michael@0: 	paddd     mm7,mm5
michael@0: 	paddd     mm4,mm5
michael@0: 	psrld     mm7,SCALEBITS		; mm7=CbOL
michael@0: 	psrld     mm4,SCALEBITS		; mm4=CbOH
michael@0: 	packssdw  mm7,mm4		; mm7=CbO
michael@0: 
michael@0: 	movq      mm1, MMWORD [wk(2)]	; mm1=BE
michael@0: 
michael@0: 	movq      mm6,mm0
michael@0: 	punpcklwd mm0,mm2
michael@0: 	punpckhwd mm6,mm2
michael@0: 	movq      mm5,mm0
michael@0: 	movq      mm4,mm6
michael@0: 	pmaddwd   mm0,[GOTOFF(eax,PW_F0299_F0337)] ; mm0=REL*FIX(0.299)+GEL*FIX(0.337)
michael@0: 	pmaddwd   mm6,[GOTOFF(eax,PW_F0299_F0337)] ; mm6=REH*FIX(0.299)+GEH*FIX(0.337)
michael@0: 	pmaddwd   mm5,[GOTOFF(eax,PW_MF016_MF033)] ; mm5=REL*-FIX(0.168)+GEL*-FIX(0.331)
michael@0: 	pmaddwd   mm4,[GOTOFF(eax,PW_MF016_MF033)] ; mm4=REH*-FIX(0.168)+GEH*-FIX(0.331)
michael@0: 
michael@0: 	movq      MMWORD [wk(6)], mm0	; wk(6)=REL*FIX(0.299)+GEL*FIX(0.337)
michael@0: 	movq      MMWORD [wk(7)], mm6	; wk(7)=REH*FIX(0.299)+GEH*FIX(0.337)
michael@0: 
michael@0: 	pxor      mm0,mm0
michael@0: 	pxor      mm6,mm6
michael@0: 	punpcklwd mm0,mm1		; mm0=BEL
michael@0: 	punpckhwd mm6,mm1		; mm6=BEH
michael@0: 	psrld     mm0,1			; mm0=BEL*FIX(0.500)
michael@0: 	psrld     mm6,1			; mm6=BEH*FIX(0.500)
michael@0: 
michael@0: 	movq      mm1,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm1=[PD_ONEHALFM1_CJ]
michael@0: 
michael@0: 	paddd     mm5,mm0
michael@0: 	paddd     mm4,mm6
michael@0: 	paddd     mm5,mm1
michael@0: 	paddd     mm4,mm1
michael@0: 	psrld     mm5,SCALEBITS		; mm5=CbEL
michael@0: 	psrld     mm4,SCALEBITS		; mm4=CbEH
michael@0: 	packssdw  mm5,mm4		; mm5=CbE
michael@0: 
michael@0: 	psllw     mm7,BYTE_BIT
michael@0: 	por       mm5,mm7		; mm5=Cb
michael@0: 	movq      MMWORD [ebx], mm5	; Save Cb
michael@0: 
michael@0: 	movq      mm0, MMWORD [wk(3)]	; mm0=BO
michael@0: 	movq      mm6, MMWORD [wk(2)]	; mm6=BE
michael@0: 	movq      mm1, MMWORD [wk(1)]	; mm1=RO
michael@0: 
michael@0: 	movq      mm4,mm0
michael@0: 	punpcklwd mm0,mm3
michael@0: 	punpckhwd mm4,mm3
michael@0: 	movq      mm7,mm0
michael@0: 	movq      mm5,mm4
michael@0: 	pmaddwd   mm0,[GOTOFF(eax,PW_F0114_F0250)] ; mm0=BOL*FIX(0.114)+GOL*FIX(0.250)
michael@0: 	pmaddwd   mm4,[GOTOFF(eax,PW_F0114_F0250)] ; mm4=BOH*FIX(0.114)+GOH*FIX(0.250)
michael@0: 	pmaddwd   mm7,[GOTOFF(eax,PW_MF008_MF041)] ; mm7=BOL*-FIX(0.081)+GOL*-FIX(0.418)
michael@0: 	pmaddwd   mm5,[GOTOFF(eax,PW_MF008_MF041)] ; mm5=BOH*-FIX(0.081)+GOH*-FIX(0.418)
michael@0: 
michael@0: 	movq      mm3,[GOTOFF(eax,PD_ONEHALF)]	; mm3=[PD_ONEHALF]
michael@0: 
michael@0: 	paddd     mm0, MMWORD [wk(4)]
michael@0: 	paddd     mm4, MMWORD [wk(5)]
michael@0: 	paddd     mm0,mm3
michael@0: 	paddd     mm4,mm3
michael@0: 	psrld     mm0,SCALEBITS		; mm0=YOL
michael@0: 	psrld     mm4,SCALEBITS		; mm4=YOH
michael@0: 	packssdw  mm0,mm4		; mm0=YO
michael@0: 
michael@0: 	pxor      mm3,mm3
michael@0: 	pxor      mm4,mm4
michael@0: 	punpcklwd mm3,mm1		; mm3=ROL
michael@0: 	punpckhwd mm4,mm1		; mm4=ROH
michael@0: 	psrld     mm3,1			; mm3=ROL*FIX(0.500)
michael@0: 	psrld     mm4,1			; mm4=ROH*FIX(0.500)
michael@0: 
michael@0: 	movq      mm1,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm1=[PD_ONEHALFM1_CJ]
michael@0: 
michael@0: 	paddd     mm7,mm3
michael@0: 	paddd     mm5,mm4
michael@0: 	paddd     mm7,mm1
michael@0: 	paddd     mm5,mm1
michael@0: 	psrld     mm7,SCALEBITS		; mm7=CrOL
michael@0: 	psrld     mm5,SCALEBITS		; mm5=CrOH
michael@0: 	packssdw  mm7,mm5		; mm7=CrO
michael@0: 
michael@0: 	movq      mm3, MMWORD [wk(0)]	; mm3=RE
michael@0: 
michael@0: 	movq      mm4,mm6
michael@0: 	punpcklwd mm6,mm2
michael@0: 	punpckhwd mm4,mm2
michael@0: 	movq      mm1,mm6
michael@0: 	movq      mm5,mm4
michael@0: 	pmaddwd   mm6,[GOTOFF(eax,PW_F0114_F0250)] ; mm6=BEL*FIX(0.114)+GEL*FIX(0.250)
michael@0: 	pmaddwd   mm4,[GOTOFF(eax,PW_F0114_F0250)] ; mm4=BEH*FIX(0.114)+GEH*FIX(0.250)
michael@0: 	pmaddwd   mm1,[GOTOFF(eax,PW_MF008_MF041)] ; mm1=BEL*-FIX(0.081)+GEL*-FIX(0.418)
michael@0: 	pmaddwd   mm5,[GOTOFF(eax,PW_MF008_MF041)] ; mm5=BEH*-FIX(0.081)+GEH*-FIX(0.418)
michael@0: 
michael@0: 	movq      mm2,[GOTOFF(eax,PD_ONEHALF)]	; mm2=[PD_ONEHALF]
michael@0: 
michael@0: 	paddd     mm6, MMWORD [wk(6)]
michael@0: 	paddd     mm4, MMWORD [wk(7)]
michael@0: 	paddd     mm6,mm2
michael@0: 	paddd     mm4,mm2
michael@0: 	psrld     mm6,SCALEBITS		; mm6=YEL
michael@0: 	psrld     mm4,SCALEBITS		; mm4=YEH
michael@0: 	packssdw  mm6,mm4		; mm6=YE
michael@0: 
michael@0: 	psllw     mm0,BYTE_BIT
michael@0: 	por       mm6,mm0		; mm6=Y
michael@0: 	movq      MMWORD [edi], mm6	; Save Y
michael@0: 
michael@0: 	pxor      mm2,mm2
michael@0: 	pxor      mm4,mm4
michael@0: 	punpcklwd mm2,mm3		; mm2=REL
michael@0: 	punpckhwd mm4,mm3		; mm4=REH
michael@0: 	psrld     mm2,1			; mm2=REL*FIX(0.500)
michael@0: 	psrld     mm4,1			; mm4=REH*FIX(0.500)
michael@0: 
michael@0: 	movq      mm0,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm0=[PD_ONEHALFM1_CJ]
michael@0: 
michael@0: 	paddd     mm1,mm2
michael@0: 	paddd     mm5,mm4
michael@0: 	paddd     mm1,mm0
michael@0: 	paddd     mm5,mm0
michael@0: 	psrld     mm1,SCALEBITS		; mm1=CrEL
michael@0: 	psrld     mm5,SCALEBITS		; mm5=CrEH
michael@0: 	packssdw  mm1,mm5		; mm1=CrE
michael@0: 
michael@0: 	psllw     mm7,BYTE_BIT
michael@0: 	por       mm1,mm7		; mm1=Cr
michael@0: 	movq      MMWORD [edx], mm1	; Save Cr
michael@0: 
michael@0: 	sub	ecx, byte SIZEOF_MMWORD
michael@0: 	add	esi, byte RGB_PIXELSIZE*SIZEOF_MMWORD	; inptr
michael@0: 	add	edi, byte SIZEOF_MMWORD			; outptr0
michael@0: 	add	ebx, byte SIZEOF_MMWORD			; outptr1
michael@0: 	add	edx, byte SIZEOF_MMWORD			; outptr2
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD
michael@0: 	jae	near .columnloop
michael@0: 	test	ecx,ecx
michael@0: 	jnz	near .column_ld1
michael@0: 
michael@0: 	pop	ecx			; col
michael@0: 	pop	esi
michael@0: 	pop	edi
michael@0: 	pop	ebx
michael@0: 	pop	edx
michael@0: 	poppic	eax
michael@0: 
michael@0: 	add	esi, byte SIZEOF_JSAMPROW	; input_buf
michael@0: 	add	edi, byte SIZEOF_JSAMPROW
michael@0: 	add	ebx, byte SIZEOF_JSAMPROW
michael@0: 	add	edx, byte SIZEOF_JSAMPROW
michael@0: 	dec	eax				; num_rows
michael@0: 	jg	near .rowloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: .return:
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16