michael@0: ;
michael@0: ; jcqnt3dn.asm - sample data conversion and quantization (3DNow! & MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Load data into workspace, applying unsigned->signed conversion
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_convsamp_float_3dnow (JSAMPARRAY sample_data, JDIMENSION start_col,
michael@0: ;                             FAST_FLOAT * workspace);
michael@0: ;
michael@0: 
michael@0: %define sample_data	ebp+8		; JSAMPARRAY sample_data
michael@0: %define start_col	ebp+12		; JDIMENSION start_col
michael@0: %define workspace	ebp+16		; FAST_FLOAT * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_convsamp_float_3dnow)
michael@0: 
michael@0: EXTN(jsimd_convsamp_float_3dnow):
michael@0: 	push	ebp
michael@0: 	mov	ebp,esp
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	pcmpeqw  mm7,mm7
michael@0: 	psllw    mm7,7
michael@0: 	packsswb mm7,mm7		; mm7 = PB_CENTERJSAMPLE (0x808080..)
michael@0: 
michael@0: 	mov	esi, JSAMPARRAY [sample_data]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [start_col]
michael@0: 	mov	edi, POINTER [workspace]	; (DCTELEM *)
michael@0: 	mov	ecx, DCTSIZE/2
michael@0: 	alignx	16,7
michael@0: .convloop:
michael@0: 	mov	ebx, JSAMPROW [esi+0*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 	mov	edx, JSAMPROW [esi+1*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 
michael@0: 	movq	mm0, MMWORD [ebx+eax*SIZEOF_JSAMPLE]
michael@0: 	movq	mm1, MMWORD [edx+eax*SIZEOF_JSAMPLE]
michael@0: 
michael@0: 	psubb	mm0,mm7				; mm0=(01234567)
michael@0: 	psubb	mm1,mm7				; mm1=(89ABCDEF)
michael@0: 
michael@0: 	punpcklbw mm2,mm0			; mm2=(*0*1*2*3)
michael@0: 	punpckhbw mm0,mm0			; mm0=(*4*5*6*7)
michael@0: 	punpcklbw mm3,mm1			; mm3=(*8*9*A*B)
michael@0: 	punpckhbw mm1,mm1			; mm1=(*C*D*E*F)
michael@0: 
michael@0: 	punpcklwd mm4,mm2			; mm4=(***0***1)
michael@0: 	punpckhwd mm2,mm2			; mm2=(***2***3)
michael@0: 	punpcklwd mm5,mm0			; mm5=(***4***5)
michael@0: 	punpckhwd mm0,mm0			; mm0=(***6***7)
michael@0: 
michael@0: 	psrad	mm4,(DWORD_BIT-BYTE_BIT)	; mm4=(01)
michael@0: 	psrad	mm2,(DWORD_BIT-BYTE_BIT)	; mm2=(23)
michael@0: 	pi2fd	mm4,mm4
michael@0: 	pi2fd	mm2,mm2
michael@0: 	psrad	mm5,(DWORD_BIT-BYTE_BIT)	; mm5=(45)
michael@0: 	psrad	mm0,(DWORD_BIT-BYTE_BIT)	; mm0=(67)
michael@0: 	pi2fd	mm5,mm5
michael@0: 	pi2fd	mm0,mm0
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(0,2,edi,SIZEOF_FAST_FLOAT)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(0,3,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 
michael@0: 	punpcklwd mm6,mm3			; mm6=(***8***9)
michael@0: 	punpckhwd mm3,mm3			; mm3=(***A***B)
michael@0: 	punpcklwd mm4,mm1			; mm4=(***C***D)
michael@0: 	punpckhwd mm1,mm1			; mm1=(***E***F)
michael@0: 
michael@0: 	psrad	mm6,(DWORD_BIT-BYTE_BIT)	; mm6=(89)
michael@0: 	psrad	mm3,(DWORD_BIT-BYTE_BIT)	; mm3=(AB)
michael@0: 	pi2fd	mm6,mm6
michael@0: 	pi2fd	mm3,mm3
michael@0: 	psrad	mm4,(DWORD_BIT-BYTE_BIT)	; mm4=(CD)
michael@0: 	psrad	mm1,(DWORD_BIT-BYTE_BIT)	; mm1=(EF)
michael@0: 	pi2fd	mm4,mm4
michael@0: 	pi2fd	mm1,mm1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], mm3
michael@0: 	movq	MMWORD [MMBLOCK(1,2,edi,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(1,3,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 
michael@0: 	add	esi, byte 2*SIZEOF_JSAMPROW
michael@0: 	add	edi, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0: 	dec	ecx
michael@0: 	jnz	near .convloop
michael@0: 
michael@0: 	femms		; empty MMX/3DNow! state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Quantize/descale the coefficients, and store into coef_block
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_quantize_float_3dnow (JCOEFPTR coef_block, FAST_FLOAT * divisors,
michael@0: ;                             FAST_FLOAT * workspace);
michael@0: ;
michael@0: 
michael@0: %define coef_block	ebp+8		; JCOEFPTR coef_block
michael@0: %define divisors	ebp+12		; FAST_FLOAT * divisors
michael@0: %define workspace	ebp+16		; FAST_FLOAT * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_quantize_float_3dnow)
michael@0: 
michael@0: EXTN(jsimd_quantize_float_3dnow):
michael@0: 	push	ebp
michael@0: 	mov	ebp,esp
michael@0: ;	push	ebx		; unused
michael@0: ;	push	ecx		; unused
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	mov       eax, 0x4B400000	; (float)0x00C00000 (rndint_magic)
michael@0: 	movd      mm7,eax
michael@0: 	punpckldq mm7,mm7		; mm7={12582912.0F 12582912.0F}
michael@0: 
michael@0: 	mov	esi, POINTER [workspace]
michael@0: 	mov	edx, POINTER [divisors]
michael@0: 	mov	edi, JCOEFPTR [coef_block]
michael@0: 	mov	eax, DCTSIZE2/16
michael@0: 	alignx	16,7
michael@0: .quantloop:
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(0,1,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm1, MMWORD [MMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(0,2,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(0,3,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm2, MMWORD [MMBLOCK(0,2,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm3, MMWORD [MMBLOCK(0,3,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	pfadd	mm0,mm7			; mm0=(00 ** 01 **)
michael@0: 	pfadd	mm1,mm7			; mm1=(02 ** 03 **)
michael@0: 	pfadd	mm2,mm7			; mm0=(04 ** 05 **)
michael@0: 	pfadd	mm3,mm7			; mm1=(06 ** 07 **)
michael@0: 
michael@0: 	movq      mm4,mm0
michael@0: 	punpcklwd mm0,mm1		; mm0=(00 02 ** **)
michael@0: 	punpckhwd mm4,mm1		; mm4=(01 03 ** **)
michael@0: 	movq      mm5,mm2
michael@0: 	punpcklwd mm2,mm3		; mm2=(04 06 ** **)
michael@0: 	punpckhwd mm5,mm3		; mm5=(05 07 ** **)
michael@0: 
michael@0: 	punpcklwd mm0,mm4		; mm0=(00 01 02 03)
michael@0: 	punpcklwd mm2,mm5		; mm2=(04 05 06 07)
michael@0: 
michael@0: 	movq	mm6, MMWORD [MMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(1,1,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm6, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm1, MMWORD [MMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(1,2,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm4, MMWORD [MMBLOCK(1,3,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm3, MMWORD [MMBLOCK(1,2,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	pfmul	mm4, MMWORD [MMBLOCK(1,3,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	pfadd	mm6,mm7			; mm0=(10 ** 11 **)
michael@0: 	pfadd	mm1,mm7			; mm4=(12 ** 13 **)
michael@0: 	pfadd	mm3,mm7			; mm0=(14 ** 15 **)
michael@0: 	pfadd	mm4,mm7			; mm4=(16 ** 17 **)
michael@0: 
michael@0: 	movq      mm5,mm6
michael@0: 	punpcklwd mm6,mm1		; mm6=(10 12 ** **)
michael@0: 	punpckhwd mm5,mm1		; mm5=(11 13 ** **)
michael@0: 	movq      mm1,mm3
michael@0: 	punpcklwd mm3,mm4		; mm3=(14 16 ** **)
michael@0: 	punpckhwd mm1,mm4		; mm1=(15 17 ** **)
michael@0: 
michael@0: 	punpcklwd mm6,mm5		; mm6=(10 11 12 13)
michael@0: 	punpcklwd mm3,mm1		; mm3=(14 15 16 17)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm3
michael@0: 
michael@0: 	add	esi, byte 16*SIZEOF_FAST_FLOAT
michael@0: 	add	edx, byte 16*SIZEOF_FAST_FLOAT
michael@0: 	add	edi, byte 16*SIZEOF_JCOEF
michael@0: 	dec	eax
michael@0: 	jnz	near .quantloop
michael@0: 
michael@0: 	femms		; empty MMX/3DNow! state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; unused
michael@0: ;	pop	ebx		; unused
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16