michael@0: ;
michael@0: ; jcqnts2i-64.asm - sample data conversion and quantization (64-bit SSE2)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ; Copyright 2009 D. R. Commander
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	64
michael@0: ;
michael@0: ; Load data into workspace, applying unsigned->signed conversion
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_convsamp_sse2 (JSAMPARRAY sample_data, JDIMENSION start_col,
michael@0: ;                      DCTELEM * workspace);
michael@0: ;
michael@0: 
michael@0: ; r10 = JSAMPARRAY sample_data
michael@0: ; r11 = JDIMENSION start_col
michael@0: ; r12 = DCTELEM * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_convsamp_sse2)
michael@0: 
michael@0: EXTN(jsimd_convsamp_sse2):
michael@0: 	push	rbp
michael@0: 	mov	rax,rsp
michael@0: 	mov	rbp,rsp
michael@0: 	collect_args
michael@0: 	push	rbx
michael@0: 
michael@0: 	pxor	xmm6,xmm6		; xmm6=(all 0's)
michael@0: 	pcmpeqw	xmm7,xmm7
michael@0: 	psllw	xmm7,7			; xmm7={0xFF80 0xFF80 0xFF80 0xFF80 ..}
michael@0: 
michael@0: 	mov rsi, r10
michael@0: 	mov rax, r11
michael@0: 	mov rdi, r12
michael@0: 	mov	rcx, DCTSIZE/4
michael@0: .convloop:
michael@0: 	mov	rbx, JSAMPROW [rsi+0*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 	mov rdx, JSAMPROW [rsi+1*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 
michael@0: 	movq	xmm0, XMM_MMWORD [rbx+rax*SIZEOF_JSAMPLE]	; xmm0=(01234567)
michael@0: 	movq	xmm1, XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE]	; xmm1=(89ABCDEF)
michael@0: 
michael@0: 	mov	rbx, JSAMPROW [rsi+2*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 	mov	rdx, JSAMPROW [rsi+3*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 
michael@0: 	movq	xmm2, XMM_MMWORD [rbx+rax*SIZEOF_JSAMPLE]	; xmm2=(GHIJKLMN)
michael@0: 	movq	xmm3, XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE]	; xmm3=(OPQRSTUV)
michael@0: 
michael@0: 	punpcklbw xmm0,xmm6		; xmm0=(01234567)
michael@0: 	punpcklbw xmm1,xmm6		; xmm1=(89ABCDEF)
michael@0: 	paddw     xmm0,xmm7
michael@0: 	paddw     xmm1,xmm7
michael@0: 	punpcklbw xmm2,xmm6		; xmm2=(GHIJKLMN)
michael@0: 	punpcklbw xmm3,xmm6		; xmm3=(OPQRSTUV)
michael@0: 	paddw     xmm2,xmm7
michael@0: 	paddw     xmm3,xmm7
michael@0: 
michael@0: 	movdqa	XMMWORD [XMMBLOCK(0,0,rdi,SIZEOF_DCTELEM)], xmm0
michael@0: 	movdqa	XMMWORD [XMMBLOCK(1,0,rdi,SIZEOF_DCTELEM)], xmm1
michael@0: 	movdqa	XMMWORD [XMMBLOCK(2,0,rdi,SIZEOF_DCTELEM)], xmm2
michael@0: 	movdqa	XMMWORD [XMMBLOCK(3,0,rdi,SIZEOF_DCTELEM)], xmm3
michael@0: 
michael@0: 	add	rsi, byte 4*SIZEOF_JSAMPROW
michael@0: 	add	rdi, byte 4*DCTSIZE*SIZEOF_DCTELEM
michael@0: 	dec	rcx
michael@0: 	jnz	short .convloop
michael@0: 
michael@0: 	pop	rbx
michael@0: 	uncollect_args
michael@0: 	pop	rbp
michael@0: 	ret
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Quantize/descale the coefficients, and store into coef_block
michael@0: ;
michael@0: ; This implementation is based on an algorithm described in
michael@0: ;   "How to optimize for the Pentium family of microprocessors"
michael@0: ;   (http://www.agner.org/assem/).
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_quantize_sse2 (JCOEFPTR coef_block, DCTELEM * divisors,
michael@0: ;                      DCTELEM * workspace);
michael@0: ;
michael@0: 
michael@0: %define RECIPROCAL(m,n,b) XMMBLOCK(DCTSIZE*0+(m),(n),(b),SIZEOF_DCTELEM)
michael@0: %define CORRECTION(m,n,b) XMMBLOCK(DCTSIZE*1+(m),(n),(b),SIZEOF_DCTELEM)
michael@0: %define SCALE(m,n,b)      XMMBLOCK(DCTSIZE*2+(m),(n),(b),SIZEOF_DCTELEM)
michael@0: 
michael@0: ; r10 = JCOEFPTR coef_block
michael@0: ; r11 = DCTELEM * divisors
michael@0: ; r12 = DCTELEM * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_quantize_sse2)
michael@0: 
michael@0: EXTN(jsimd_quantize_sse2):
michael@0: 	push	rbp
michael@0: 	mov	rax,rsp
michael@0: 	mov	rbp,rsp
michael@0: 	collect_args
michael@0: 
michael@0: 	mov rsi, r12
michael@0: 	mov rdx, r11
michael@0: 	mov rdi, r10
michael@0: 	mov	rax, DCTSIZE2/32
michael@0: .quantloop:
michael@0: 	movdqa	xmm4, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_DCTELEM)]
michael@0: 	movdqa	xmm5, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_DCTELEM)]
michael@0: 	movdqa	xmm6, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_DCTELEM)]
michael@0: 	movdqa	xmm7, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_DCTELEM)]
michael@0: 	movdqa	xmm0,xmm4
michael@0: 	movdqa	xmm1,xmm5
michael@0: 	movdqa	xmm2,xmm6
michael@0: 	movdqa	xmm3,xmm7
michael@0: 	psraw	xmm4,(WORD_BIT-1)
michael@0: 	psraw	xmm5,(WORD_BIT-1)
michael@0: 	psraw	xmm6,(WORD_BIT-1)
michael@0: 	psraw	xmm7,(WORD_BIT-1)
michael@0: 	pxor	xmm0,xmm4
michael@0: 	pxor	xmm1,xmm5
michael@0: 	pxor	xmm2,xmm6
michael@0: 	pxor	xmm3,xmm7
michael@0: 	psubw	xmm0,xmm4		; if (xmm0 < 0) xmm0 = -xmm0;
michael@0: 	psubw	xmm1,xmm5		; if (xmm1 < 0) xmm1 = -xmm1;
michael@0: 	psubw	xmm2,xmm6		; if (xmm2 < 0) xmm2 = -xmm2;
michael@0: 	psubw	xmm3,xmm7		; if (xmm3 < 0) xmm3 = -xmm3;
michael@0: 
michael@0: 	paddw	xmm0, XMMWORD [CORRECTION(0,0,rdx)]  ; correction + roundfactor
michael@0: 	paddw	xmm1, XMMWORD [CORRECTION(1,0,rdx)]
michael@0: 	paddw	xmm2, XMMWORD [CORRECTION(2,0,rdx)]
michael@0: 	paddw	xmm3, XMMWORD [CORRECTION(3,0,rdx)]
michael@0: 	pmulhuw	xmm0, XMMWORD [RECIPROCAL(0,0,rdx)]  ; reciprocal
michael@0: 	pmulhuw	xmm1, XMMWORD [RECIPROCAL(1,0,rdx)]
michael@0: 	pmulhuw	xmm2, XMMWORD [RECIPROCAL(2,0,rdx)]
michael@0: 	pmulhuw	xmm3, XMMWORD [RECIPROCAL(3,0,rdx)]
michael@0: 	pmulhuw	xmm0, XMMWORD [SCALE(0,0,rdx)]	; scale
michael@0: 	pmulhuw	xmm1, XMMWORD [SCALE(1,0,rdx)]
michael@0: 	pmulhuw	xmm2, XMMWORD [SCALE(2,0,rdx)]
michael@0: 	pmulhuw	xmm3, XMMWORD [SCALE(3,0,rdx)]
michael@0: 
michael@0: 	pxor	xmm0,xmm4
michael@0: 	pxor	xmm1,xmm5
michael@0: 	pxor	xmm2,xmm6
michael@0: 	pxor	xmm3,xmm7
michael@0: 	psubw	xmm0,xmm4
michael@0: 	psubw	xmm1,xmm5
michael@0: 	psubw	xmm2,xmm6
michael@0: 	psubw	xmm3,xmm7
michael@0: 	movdqa	XMMWORD [XMMBLOCK(0,0,rdi,SIZEOF_DCTELEM)], xmm0
michael@0: 	movdqa	XMMWORD [XMMBLOCK(1,0,rdi,SIZEOF_DCTELEM)], xmm1
michael@0: 	movdqa	XMMWORD [XMMBLOCK(2,0,rdi,SIZEOF_DCTELEM)], xmm2
michael@0: 	movdqa	XMMWORD [XMMBLOCK(3,0,rdi,SIZEOF_DCTELEM)], xmm3
michael@0: 
michael@0: 	add	rsi, byte 32*SIZEOF_DCTELEM
michael@0: 	add	rdx, byte 32*SIZEOF_DCTELEM
michael@0: 	add	rdi, byte 32*SIZEOF_JCOEF
michael@0: 	dec	rax
michael@0: 	jnz	near .quantloop
michael@0: 
michael@0: 	uncollect_args
michael@0: 	pop	rbp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16