michael@0: ;
michael@0: ; jdclrmmx.asm - colorspace conversion (MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jcolsamp.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Convert some rows of samples to the output colorspace.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_ycc_rgb_convert_mmx (JDIMENSION out_width,
michael@0: ;                            JSAMPIMAGE input_buf, JDIMENSION input_row,
michael@0: ;                            JSAMPARRAY output_buf, int num_rows)
michael@0: ;
michael@0: 
michael@0: %define out_width(b)	(b)+8			; JDIMENSION out_width
michael@0: %define input_buf(b)	(b)+12		; JSAMPIMAGE input_buf
michael@0: %define input_row(b)	(b)+16		; JDIMENSION input_row
michael@0: %define output_buf(b)	(b)+20		; JSAMPARRAY output_buf
michael@0: %define num_rows(b)	(b)+24		; int num_rows
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: %define gotptr		wk(0)-SIZEOF_POINTER	; void * gotptr
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_ycc_rgb_convert_mmx)
michael@0: 
michael@0: EXTN(jsimd_ycc_rgb_convert_mmx):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [wk(0)]
michael@0: 	pushpic	eax		; make a room for GOT address
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx			; get GOT address
michael@0: 	movpic	POINTER [gotptr], ebx	; save GOT address
michael@0: 
michael@0: 	mov	ecx, JDIMENSION [out_width(eax)]	; num_cols
michael@0: 	test	ecx,ecx
michael@0: 	jz	near .return
michael@0: 
michael@0: 	push	ecx
michael@0: 
michael@0: 	mov	edi, JSAMPIMAGE [input_buf(eax)]
michael@0: 	mov	ecx, JDIMENSION [input_row(eax)]
michael@0: 	mov	esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
michael@0: 	mov	ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
michael@0: 	mov	edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
michael@0: 	lea	esi, [esi+ecx*SIZEOF_JSAMPROW]
michael@0: 	lea	ebx, [ebx+ecx*SIZEOF_JSAMPROW]
michael@0: 	lea	edx, [edx+ecx*SIZEOF_JSAMPROW]
michael@0: 
michael@0: 	pop	ecx
michael@0: 
michael@0: 	mov	edi, JSAMPARRAY [output_buf(eax)]
michael@0: 	mov	eax, INT [num_rows(eax)]
michael@0: 	test	eax,eax
michael@0: 	jle	near .return
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 	push	eax
michael@0: 	push	edi
michael@0: 	push	edx
michael@0: 	push	ebx
michael@0: 	push	esi
michael@0: 	push	ecx			; col
michael@0: 
michael@0: 	mov	esi, JSAMPROW [esi]	; inptr0
michael@0: 	mov	ebx, JSAMPROW [ebx]	; inptr1
michael@0: 	mov	edx, JSAMPROW [edx]	; inptr2
michael@0: 	mov	edi, JSAMPROW [edi]	; outptr
michael@0: 	movpic	eax, POINTER [gotptr]	; load GOT address (eax)
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: 
michael@0: 	movq	mm5, MMWORD [ebx]	; mm5=Cb(01234567)
michael@0: 	movq	mm1, MMWORD [edx]	; mm1=Cr(01234567)
michael@0: 
michael@0: 	pcmpeqw	mm4,mm4
michael@0: 	pcmpeqw	mm7,mm7
michael@0: 	psrlw	mm4,BYTE_BIT
michael@0: 	psllw	mm7,7			; mm7={0xFF80 0xFF80 0xFF80 0xFF80}
michael@0: 	movq	mm0,mm4			; mm0=mm4={0xFF 0x00 0xFF 0x00 ..}
michael@0: 
michael@0: 	pand	mm4,mm5			; mm4=Cb(0246)=CbE
michael@0: 	psrlw	mm5,BYTE_BIT		; mm5=Cb(1357)=CbO
michael@0: 	pand	mm0,mm1			; mm0=Cr(0246)=CrE
michael@0: 	psrlw	mm1,BYTE_BIT		; mm1=Cr(1357)=CrO
michael@0: 
michael@0: 	paddw	mm4,mm7
michael@0: 	paddw	mm5,mm7
michael@0: 	paddw	mm0,mm7
michael@0: 	paddw	mm1,mm7
michael@0: 
michael@0: 	; (Original)
michael@0: 	; R = Y                + 1.40200 * Cr
michael@0: 	; G = Y - 0.34414 * Cb - 0.71414 * Cr
michael@0: 	; B = Y + 1.77200 * Cb
michael@0: 	;
michael@0: 	; (This implementation)
michael@0: 	; R = Y                + 0.40200 * Cr + Cr
michael@0: 	; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
michael@0: 	; B = Y - 0.22800 * Cb + Cb + Cb
michael@0: 
michael@0: 	movq	mm2,mm4			; mm2=CbE
michael@0: 	movq	mm3,mm5			; mm3=CbO
michael@0: 	paddw	mm4,mm4			; mm4=2*CbE
michael@0: 	paddw	mm5,mm5			; mm5=2*CbO
michael@0: 	movq	mm6,mm0			; mm6=CrE
michael@0: 	movq	mm7,mm1			; mm7=CrO
michael@0: 	paddw	mm0,mm0			; mm0=2*CrE
michael@0: 	paddw	mm1,mm1			; mm1=2*CrO
michael@0: 
michael@0: 	pmulhw	mm4,[GOTOFF(eax,PW_MF0228)]	; mm4=(2*CbE * -FIX(0.22800))
michael@0: 	pmulhw	mm5,[GOTOFF(eax,PW_MF0228)]	; mm5=(2*CbO * -FIX(0.22800))
michael@0: 	pmulhw	mm0,[GOTOFF(eax,PW_F0402)]	; mm0=(2*CrE * FIX(0.40200))
michael@0: 	pmulhw	mm1,[GOTOFF(eax,PW_F0402)]	; mm1=(2*CrO * FIX(0.40200))
michael@0: 
michael@0: 	paddw	mm4,[GOTOFF(eax,PW_ONE)]
michael@0: 	paddw	mm5,[GOTOFF(eax,PW_ONE)]
michael@0: 	psraw	mm4,1			; mm4=(CbE * -FIX(0.22800))
michael@0: 	psraw	mm5,1			; mm5=(CbO * -FIX(0.22800))
michael@0: 	paddw	mm0,[GOTOFF(eax,PW_ONE)]
michael@0: 	paddw	mm1,[GOTOFF(eax,PW_ONE)]
michael@0: 	psraw	mm0,1			; mm0=(CrE * FIX(0.40200))
michael@0: 	psraw	mm1,1			; mm1=(CrO * FIX(0.40200))
michael@0: 
michael@0: 	paddw	mm4,mm2
michael@0: 	paddw	mm5,mm3
michael@0: 	paddw	mm4,mm2			; mm4=(CbE * FIX(1.77200))=(B-Y)E
michael@0: 	paddw	mm5,mm3			; mm5=(CbO * FIX(1.77200))=(B-Y)O
michael@0: 	paddw	mm0,mm6			; mm0=(CrE * FIX(1.40200))=(R-Y)E
michael@0: 	paddw	mm1,mm7			; mm1=(CrO * FIX(1.40200))=(R-Y)O
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm4	; wk(0)=(B-Y)E
michael@0: 	movq	MMWORD [wk(1)], mm5	; wk(1)=(B-Y)O
michael@0: 
michael@0: 	movq      mm4,mm2
michael@0: 	movq      mm5,mm3
michael@0: 	punpcklwd mm2,mm6
michael@0: 	punpckhwd mm4,mm6
michael@0: 	pmaddwd   mm2,[GOTOFF(eax,PW_MF0344_F0285)]
michael@0: 	pmaddwd   mm4,[GOTOFF(eax,PW_MF0344_F0285)]
michael@0: 	punpcklwd mm3,mm7
michael@0: 	punpckhwd mm5,mm7
michael@0: 	pmaddwd   mm3,[GOTOFF(eax,PW_MF0344_F0285)]
michael@0: 	pmaddwd   mm5,[GOTOFF(eax,PW_MF0344_F0285)]
michael@0: 
michael@0: 	paddd     mm2,[GOTOFF(eax,PD_ONEHALF)]
michael@0: 	paddd     mm4,[GOTOFF(eax,PD_ONEHALF)]
michael@0: 	psrad     mm2,SCALEBITS
michael@0: 	psrad     mm4,SCALEBITS
michael@0: 	paddd     mm3,[GOTOFF(eax,PD_ONEHALF)]
michael@0: 	paddd     mm5,[GOTOFF(eax,PD_ONEHALF)]
michael@0: 	psrad     mm3,SCALEBITS
michael@0: 	psrad     mm5,SCALEBITS
michael@0: 
michael@0: 	packssdw  mm2,mm4	; mm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
michael@0: 	packssdw  mm3,mm5	; mm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
michael@0: 	psubw     mm2,mm6	; mm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
michael@0: 	psubw     mm3,mm7	; mm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
michael@0: 
michael@0: 	movq      mm5, MMWORD [esi]	; mm5=Y(01234567)
michael@0: 
michael@0: 	pcmpeqw   mm4,mm4
michael@0: 	psrlw     mm4,BYTE_BIT		; mm4={0xFF 0x00 0xFF 0x00 ..}
michael@0: 	pand      mm4,mm5		; mm4=Y(0246)=YE
michael@0: 	psrlw     mm5,BYTE_BIT		; mm5=Y(1357)=YO
michael@0: 
michael@0: 	paddw     mm0,mm4		; mm0=((R-Y)E+YE)=RE=(R0 R2 R4 R6)
michael@0: 	paddw     mm1,mm5		; mm1=((R-Y)O+YO)=RO=(R1 R3 R5 R7)
michael@0: 	packuswb  mm0,mm0		; mm0=(R0 R2 R4 R6 ** ** ** **)
michael@0: 	packuswb  mm1,mm1		; mm1=(R1 R3 R5 R7 ** ** ** **)
michael@0: 
michael@0: 	paddw     mm2,mm4		; mm2=((G-Y)E+YE)=GE=(G0 G2 G4 G6)
michael@0: 	paddw     mm3,mm5		; mm3=((G-Y)O+YO)=GO=(G1 G3 G5 G7)
michael@0: 	packuswb  mm2,mm2		; mm2=(G0 G2 G4 G6 ** ** ** **)
michael@0: 	packuswb  mm3,mm3		; mm3=(G1 G3 G5 G7 ** ** ** **)
michael@0: 
michael@0: 	paddw     mm4, MMWORD [wk(0)]	; mm4=(YE+(B-Y)E)=BE=(B0 B2 B4 B6)
michael@0: 	paddw     mm5, MMWORD [wk(1)]	; mm5=(YO+(B-Y)O)=BO=(B1 B3 B5 B7)
michael@0: 	packuswb  mm4,mm4		; mm4=(B0 B2 B4 B6 ** ** ** **)
michael@0: 	packuswb  mm5,mm5		; mm5=(B1 B3 B5 B7 ** ** ** **)
michael@0: 
michael@0: %if RGB_PIXELSIZE == 3 ; ---------------
michael@0: 
michael@0: 	; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
michael@0: 	; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
michael@0: 	; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
michael@0: 	; mmG=(** ** ** ** ** ** ** **), mmH=(** ** ** ** ** ** ** **)
michael@0: 
michael@0: 	punpcklbw mmA,mmC		; mmA=(00 10 02 12 04 14 06 16)
michael@0: 	punpcklbw mmE,mmB		; mmE=(20 01 22 03 24 05 26 07)
michael@0: 	punpcklbw mmD,mmF		; mmD=(11 21 13 23 15 25 17 27)
michael@0: 
michael@0: 	movq      mmG,mmA
michael@0: 	movq      mmH,mmA
michael@0: 	punpcklwd mmA,mmE		; mmA=(00 10 20 01 02 12 22 03)
michael@0: 	punpckhwd mmG,mmE		; mmG=(04 14 24 05 06 16 26 07)
michael@0: 
michael@0: 	psrlq     mmH,2*BYTE_BIT	; mmH=(02 12 04 14 06 16 -- --)
michael@0: 	psrlq     mmE,2*BYTE_BIT	; mmE=(22 03 24 05 26 07 -- --)
michael@0: 
michael@0: 	movq      mmC,mmD
michael@0: 	movq      mmB,mmD
michael@0: 	punpcklwd mmD,mmH		; mmD=(11 21 02 12 13 23 04 14)
michael@0: 	punpckhwd mmC,mmH		; mmC=(15 25 06 16 17 27 -- --)
michael@0: 
michael@0: 	psrlq     mmB,2*BYTE_BIT	; mmB=(13 23 15 25 17 27 -- --)
michael@0: 
michael@0: 	movq      mmF,mmE
michael@0: 	punpcklwd mmE,mmB		; mmE=(22 03 13 23 24 05 15 25)
michael@0: 	punpckhwd mmF,mmB		; mmF=(26 07 17 27 -- -- -- --)
michael@0: 
michael@0: 	punpckldq mmA,mmD		; mmA=(00 10 20 01 11 21 02 12)
michael@0: 	punpckldq mmE,mmG		; mmE=(22 03 13 23 04 14 24 05)
michael@0: 	punpckldq mmC,mmF		; mmC=(15 25 06 16 26 07 17 27)
michael@0: 
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD
michael@0: 	jb	short .column_st16
michael@0: 
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	MMWORD [edi+1*SIZEOF_MMWORD], mmE
michael@0: 	movq	MMWORD [edi+2*SIZEOF_MMWORD], mmC
michael@0: 
michael@0: 	sub	ecx, byte SIZEOF_MMWORD
michael@0: 	jz	short .nextrow
michael@0: 
michael@0: 	add	esi, byte SIZEOF_MMWORD			; inptr0
michael@0: 	add	ebx, byte SIZEOF_MMWORD			; inptr1
michael@0: 	add	edx, byte SIZEOF_MMWORD			; inptr2
michael@0: 	add	edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD	; outptr
michael@0: 	jmp	near .columnloop
michael@0: 	alignx	16,7
michael@0: 
michael@0: .column_st16:
michael@0: 	lea	ecx, [ecx+ecx*2]	; imul ecx, RGB_PIXELSIZE
michael@0: 	cmp	ecx, byte 2*SIZEOF_MMWORD
michael@0: 	jb	short .column_st8
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	MMWORD [edi+1*SIZEOF_MMWORD], mmE
michael@0: 	movq	mmA,mmC
michael@0: 	sub	ecx, byte 2*SIZEOF_MMWORD
michael@0: 	add	edi, byte 2*SIZEOF_MMWORD
michael@0: 	jmp	short .column_st4
michael@0: .column_st8:
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD
michael@0: 	jb	short .column_st4
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	mmA,mmE
michael@0: 	sub	ecx, byte SIZEOF_MMWORD
michael@0: 	add	edi, byte SIZEOF_MMWORD
michael@0: .column_st4:
michael@0: 	movd	eax,mmA
michael@0: 	cmp	ecx, byte SIZEOF_DWORD
michael@0: 	jb	short .column_st2
michael@0: 	mov	DWORD [edi+0*SIZEOF_DWORD], eax
michael@0: 	psrlq	mmA,DWORD_BIT
michael@0: 	movd	eax,mmA
michael@0: 	sub	ecx, byte SIZEOF_DWORD
michael@0: 	add	edi, byte SIZEOF_DWORD
michael@0: .column_st2:
michael@0: 	cmp	ecx, byte SIZEOF_WORD
michael@0: 	jb	short .column_st1
michael@0: 	mov	WORD [edi+0*SIZEOF_WORD], ax
michael@0: 	shr	eax,WORD_BIT
michael@0: 	sub	ecx, byte SIZEOF_WORD
michael@0: 	add	edi, byte SIZEOF_WORD
michael@0: .column_st1:
michael@0: 	cmp	ecx, byte SIZEOF_BYTE
michael@0: 	jb	short .nextrow
michael@0: 	mov	BYTE [edi+0*SIZEOF_BYTE], al
michael@0: 
michael@0: %else ; RGB_PIXELSIZE == 4 ; -----------
michael@0: 
michael@0: %ifdef RGBX_FILLER_0XFF
michael@0: 	pcmpeqb   mm6,mm6		; mm6=(X0 X2 X4 X6 ** ** ** **)
michael@0: 	pcmpeqb   mm7,mm7		; mm7=(X1 X3 X5 X7 ** ** ** **)
michael@0: %else
michael@0: 	pxor      mm6,mm6		; mm6=(X0 X2 X4 X6 ** ** ** **)
michael@0: 	pxor      mm7,mm7		; mm7=(X1 X3 X5 X7 ** ** ** **)
michael@0: %endif
michael@0: 	; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
michael@0: 	; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
michael@0: 	; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
michael@0: 	; mmG=(30 32 34 36 ** ** ** **), mmH=(31 33 35 37 ** ** ** **)
michael@0: 
michael@0: 	punpcklbw mmA,mmC		; mmA=(00 10 02 12 04 14 06 16)
michael@0: 	punpcklbw mmE,mmG		; mmE=(20 30 22 32 24 34 26 36)
michael@0: 	punpcklbw mmB,mmD		; mmB=(01 11 03 13 05 15 07 17)
michael@0: 	punpcklbw mmF,mmH		; mmF=(21 31 23 33 25 35 27 37)
michael@0: 
michael@0: 	movq      mmC,mmA
michael@0: 	punpcklwd mmA,mmE		; mmA=(00 10 20 30 02 12 22 32)
michael@0: 	punpckhwd mmC,mmE		; mmC=(04 14 24 34 06 16 26 36)
michael@0: 	movq      mmG,mmB
michael@0: 	punpcklwd mmB,mmF		; mmB=(01 11 21 31 03 13 23 33)
michael@0: 	punpckhwd mmG,mmF		; mmG=(05 15 25 35 07 17 27 37)
michael@0: 
michael@0: 	movq      mmD,mmA
michael@0: 	punpckldq mmA,mmB		; mmA=(00 10 20 30 01 11 21 31)
michael@0: 	punpckhdq mmD,mmB		; mmD=(02 12 22 32 03 13 23 33)
michael@0: 	movq      mmH,mmC
michael@0: 	punpckldq mmC,mmG		; mmC=(04 14 24 34 05 15 25 35)
michael@0: 	punpckhdq mmH,mmG		; mmH=(06 16 26 36 07 17 27 37)
michael@0: 
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD
michael@0: 	jb	short .column_st16
michael@0: 
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	MMWORD [edi+1*SIZEOF_MMWORD], mmD
michael@0: 	movq	MMWORD [edi+2*SIZEOF_MMWORD], mmC
michael@0: 	movq	MMWORD [edi+3*SIZEOF_MMWORD], mmH
michael@0: 
michael@0: 	sub	ecx, byte SIZEOF_MMWORD
michael@0: 	jz	short .nextrow
michael@0: 
michael@0: 	add	esi, byte SIZEOF_MMWORD			; inptr0
michael@0: 	add	ebx, byte SIZEOF_MMWORD			; inptr1
michael@0: 	add	edx, byte SIZEOF_MMWORD			; inptr2
michael@0: 	add	edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD	; outptr
michael@0: 	jmp	near .columnloop
michael@0: 	alignx	16,7
michael@0: 
michael@0: .column_st16:
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD/2
michael@0: 	jb	short .column_st8
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	MMWORD [edi+1*SIZEOF_MMWORD], mmD
michael@0: 	movq	mmA,mmC
michael@0: 	movq	mmD,mmH
michael@0: 	sub	ecx, byte SIZEOF_MMWORD/2
michael@0: 	add	edi, byte 2*SIZEOF_MMWORD
michael@0: .column_st8:
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD/4
michael@0: 	jb	short .column_st4
michael@0: 	movq	MMWORD [edi+0*SIZEOF_MMWORD], mmA
michael@0: 	movq	mmA,mmD
michael@0: 	sub	ecx, byte SIZEOF_MMWORD/4
michael@0: 	add	edi, byte 1*SIZEOF_MMWORD
michael@0: .column_st4:
michael@0: 	cmp	ecx, byte SIZEOF_MMWORD/8
michael@0: 	jb	short .nextrow
michael@0: 	movd	DWORD [edi+0*SIZEOF_DWORD], mmA
michael@0: 
michael@0: %endif ; RGB_PIXELSIZE ; ---------------
michael@0: 
michael@0: 	alignx	16,7
michael@0: 
michael@0: .nextrow:
michael@0: 	pop	ecx
michael@0: 	pop	esi
michael@0: 	pop	ebx
michael@0: 	pop	edx
michael@0: 	pop	edi
michael@0: 	pop	eax
michael@0: 
michael@0: 	add	esi, byte SIZEOF_JSAMPROW
michael@0: 	add	ebx, byte SIZEOF_JSAMPROW
michael@0: 	add	edx, byte SIZEOF_JSAMPROW
michael@0: 	add	edi, byte SIZEOF_JSAMPROW	; output_buf
michael@0: 	dec	eax				; num_rows
michael@0: 	jg	near .rowloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: .return:
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16