michael@0: ;
michael@0: ; jfmmxfst.asm - fast integer FDCT (MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains a fast, not so accurate integer implementation of
michael@0: ; the forward DCT (Discrete Cosine Transform). The following code is
michael@0: ; based directly on the IJG's original jfdctfst.c; see the jfdctfst.c
michael@0: ; for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 
michael@0: %define CONST_BITS	8	; 14 is also OK.
michael@0: 
michael@0: %if CONST_BITS == 8
michael@0: F_0_382	equ	 98		; FIX(0.382683433)
michael@0: F_0_541	equ	139		; FIX(0.541196100)
michael@0: F_0_707	equ	181		; FIX(0.707106781)
michael@0: F_1_306	equ	334		; FIX(1.306562965)
michael@0: %else
michael@0: ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0: %define DESCALE(x,n)  (((x)+(1<<((n)-1)))>>(n))
michael@0: F_0_382	equ	DESCALE( 410903207,30-CONST_BITS)	; FIX(0.382683433)
michael@0: F_0_541	equ	DESCALE( 581104887,30-CONST_BITS)	; FIX(0.541196100)
michael@0: F_0_707	equ	DESCALE( 759250124,30-CONST_BITS)	; FIX(0.707106781)
michael@0: F_1_306	equ	DESCALE(1402911301,30-CONST_BITS)	; FIX(1.306562965)
michael@0: %endif
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: ; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
michael@0: ; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
michael@0: 
michael@0: %define PRE_MULTIPLY_SCALE_BITS   2
michael@0: %define CONST_SHIFT     (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_fdct_ifast_mmx)
michael@0: 
michael@0: EXTN(jconst_fdct_ifast_mmx):
michael@0: 
michael@0: PW_F0707	times 4 dw  F_0_707 << CONST_SHIFT
michael@0: PW_F0382	times 4 dw  F_0_382 << CONST_SHIFT
michael@0: PW_F0541	times 4 dw  F_0_541 << CONST_SHIFT
michael@0: PW_F1306	times 4 dw  F_1_306 << CONST_SHIFT
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Perform the forward DCT on one block of samples.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_fdct_ifast_mmx (DCTELEM * data)
michael@0: ;
michael@0: 
michael@0: %define data(b)		(b)+8		; DCTELEM * data
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_fdct_ifast_mmx)
michael@0: 
michael@0: EXTN(jsimd_fdct_ifast_mmx):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [wk(0)]
michael@0: 	pushpic	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: ;	push	esi		; unused
michael@0: ;	push	edi		; unused
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process rows.
michael@0: 
michael@0: 	mov	edx, POINTER [data(eax)]	; (DCTELEM *)
michael@0: 	mov	ecx, DCTSIZE/4
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(2,1,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(3,1,edx,SIZEOF_DCTELEM)]
michael@0: 
michael@0: 	; mm0=(20 21 22 23), mm2=(24 25 26 27)
michael@0: 	; mm1=(30 31 32 33), mm3=(34 35 36 37)
michael@0: 
michael@0: 	movq      mm4,mm0		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm0,mm1		; mm0=(20 30 21 31)
michael@0: 	punpckhwd mm4,mm1		; mm4=(22 32 23 33)
michael@0: 	movq      mm5,mm2		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm2,mm3		; mm2=(24 34 25 35)
michael@0: 	punpckhwd mm5,mm3		; mm5=(26 36 27 37)
michael@0: 
michael@0: 	movq	mm6, MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm7, MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(0,1,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(1,1,edx,SIZEOF_DCTELEM)]
michael@0: 
michael@0: 	; mm6=(00 01 02 03), mm1=(04 05 06 07)
michael@0: 	; mm7=(10 11 12 13), mm3=(14 15 16 17)
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm4	; wk(0)=(22 32 23 33)
michael@0: 	movq	MMWORD [wk(1)], mm2	; wk(1)=(24 34 25 35)
michael@0: 
michael@0: 	movq      mm4,mm6		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm6,mm7		; mm6=(00 10 01 11)
michael@0: 	punpckhwd mm4,mm7		; mm4=(02 12 03 13)
michael@0: 	movq      mm2,mm1		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm1,mm3		; mm1=(04 14 05 15)
michael@0: 	punpckhwd mm2,mm3		; mm2=(06 16 07 17)
michael@0: 
michael@0: 	movq      mm7,mm6		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm6,mm0		; mm6=(00 10 20 30)=data0
michael@0: 	punpckhdq mm7,mm0		; mm7=(01 11 21 31)=data1
michael@0: 	movq      mm3,mm2		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm2,mm5		; mm2=(06 16 26 36)=data6
michael@0: 	punpckhdq mm3,mm5		; mm3=(07 17 27 37)=data7
michael@0: 
michael@0: 	movq	mm0,mm7
michael@0: 	movq	mm5,mm6
michael@0: 	psubw	mm7,mm2			; mm7=data1-data6=tmp6
michael@0: 	psubw	mm6,mm3			; mm6=data0-data7=tmp7
michael@0: 	paddw	mm0,mm2			; mm0=data1+data6=tmp1
michael@0: 	paddw	mm5,mm3			; mm5=data0+data7=tmp0
michael@0: 
michael@0: 	movq	mm2, MMWORD [wk(0)]	; mm2=(22 32 23 33)
michael@0: 	movq	mm3, MMWORD [wk(1)]	; mm3=(24 34 25 35)
michael@0: 	movq	MMWORD [wk(0)], mm7	; wk(0)=tmp6
michael@0: 	movq	MMWORD [wk(1)], mm6	; wk(1)=tmp7
michael@0: 
michael@0: 	movq      mm7,mm4		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm4,mm2		; mm4=(02 12 22 32)=data2
michael@0: 	punpckhdq mm7,mm2		; mm7=(03 13 23 33)=data3
michael@0: 	movq      mm6,mm1		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm1,mm3		; mm1=(04 14 24 34)=data4
michael@0: 	punpckhdq mm6,mm3		; mm6=(05 15 25 35)=data5
michael@0: 
michael@0: 	movq	mm2,mm7
michael@0: 	movq	mm3,mm4
michael@0: 	paddw	mm7,mm1			; mm7=data3+data4=tmp3
michael@0: 	paddw	mm4,mm6			; mm4=data2+data5=tmp2
michael@0: 	psubw	mm2,mm1			; mm2=data3-data4=tmp4
michael@0: 	psubw	mm3,mm6			; mm3=data2-data5=tmp5
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm1,mm5
michael@0: 	movq	mm6,mm0
michael@0: 	psubw	mm5,mm7			; mm5=tmp13
michael@0: 	psubw	mm0,mm4			; mm0=tmp12
michael@0: 	paddw	mm1,mm7			; mm1=tmp10
michael@0: 	paddw	mm6,mm4			; mm6=tmp11
michael@0: 
michael@0: 	paddw	mm0,mm5
michael@0: 	psllw	mm0,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm0,[GOTOFF(ebx,PW_F0707)] ; mm0=z1
michael@0: 
michael@0: 	movq	mm7,mm1
michael@0: 	movq	mm4,mm5
michael@0: 	psubw	mm1,mm6			; mm1=data4
michael@0: 	psubw	mm5,mm0			; mm5=data6
michael@0: 	paddw	mm7,mm6			; mm7=data0
michael@0: 	paddw	mm4,mm0			; mm4=data2
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edx,SIZEOF_DCTELEM)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(2,1,edx,SIZEOF_DCTELEM)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)], mm4
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm6, MMWORD [wk(0)]	; mm6=tmp6
michael@0: 	movq	mm0, MMWORD [wk(1)]	; mm0=tmp7
michael@0: 
michael@0: 	paddw	mm2,mm3			; mm2=tmp10
michael@0: 	paddw	mm3,mm6			; mm3=tmp11
michael@0: 	paddw	mm6,mm0			; mm6=tmp12, mm0=tmp7
michael@0: 
michael@0: 	psllw	mm2,PRE_MULTIPLY_SCALE_BITS
michael@0: 	psllw	mm6,PRE_MULTIPLY_SCALE_BITS
michael@0: 
michael@0: 	psllw	mm3,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm3,[GOTOFF(ebx,PW_F0707)] ; mm3=z3
michael@0: 
michael@0: 	movq	mm1,mm2			; mm1=tmp10
michael@0: 	psubw	mm2,mm6
michael@0: 	pmulhw	mm2,[GOTOFF(ebx,PW_F0382)] ; mm2=z5
michael@0: 	pmulhw	mm1,[GOTOFF(ebx,PW_F0541)] ; mm1=MULTIPLY(tmp10,FIX_0_54119610)
michael@0: 	pmulhw	mm6,[GOTOFF(ebx,PW_F1306)] ; mm6=MULTIPLY(tmp12,FIX_1_30656296)
michael@0: 	paddw	mm1,mm2			; mm1=z2
michael@0: 	paddw	mm6,mm2			; mm6=z4
michael@0: 
michael@0: 	movq	mm5,mm0
michael@0: 	psubw	mm0,mm3			; mm0=z13
michael@0: 	paddw	mm5,mm3			; mm5=z11
michael@0: 
michael@0: 	movq	mm7,mm0
michael@0: 	movq	mm4,mm5
michael@0: 	psubw	mm0,mm1			; mm0=data3
michael@0: 	psubw	mm5,mm6			; mm5=data7
michael@0: 	paddw	mm7,mm1			; mm7=data5
michael@0: 	paddw	mm4,mm6			; mm4=data1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(3,1,edx,SIZEOF_DCTELEM)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edx,SIZEOF_DCTELEM)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)], mm4
michael@0: 
michael@0: 	add	edx, byte 4*DCTSIZE*SIZEOF_DCTELEM
michael@0: 	dec	ecx
michael@0: 	jnz	near .rowloop
michael@0: 
michael@0: 	; ---- Pass 2: process columns.
michael@0: 
michael@0: 	mov	edx, POINTER [data(eax)]	; (DCTELEM *)
michael@0: 	mov	ecx, DCTSIZE/4
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(6,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_DCTELEM)]
michael@0: 
michael@0: 	; mm0=(02 12 22 32), mm2=(42 52 62 72)
michael@0: 	; mm1=(03 13 23 33), mm3=(43 53 63 73)
michael@0: 
michael@0: 	movq      mm4,mm0		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm0,mm1		; mm0=(02 03 12 13)
michael@0: 	punpckhwd mm4,mm1		; mm4=(22 23 32 33)
michael@0: 	movq      mm5,mm2		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm2,mm3		; mm2=(42 43 52 53)
michael@0: 	punpckhwd mm5,mm3		; mm5=(62 63 72 73)
michael@0: 
michael@0: 	movq	mm6, MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm7, MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(4,0,edx,SIZEOF_DCTELEM)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(5,0,edx,SIZEOF_DCTELEM)]
michael@0: 
michael@0: 	; mm6=(00 10 20 30), mm1=(40 50 60 70)
michael@0: 	; mm7=(01 11 21 31), mm3=(41 51 61 71)
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm4	; wk(0)=(22 23 32 33)
michael@0: 	movq	MMWORD [wk(1)], mm2	; wk(1)=(42 43 52 53)
michael@0: 
michael@0: 	movq      mm4,mm6		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm6,mm7		; mm6=(00 01 10 11)
michael@0: 	punpckhwd mm4,mm7		; mm4=(20 21 30 31)
michael@0: 	movq      mm2,mm1		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm1,mm3		; mm1=(40 41 50 51)
michael@0: 	punpckhwd mm2,mm3		; mm2=(60 61 70 71)
michael@0: 
michael@0: 	movq      mm7,mm6		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm6,mm0		; mm6=(00 01 02 03)=data0
michael@0: 	punpckhdq mm7,mm0		; mm7=(10 11 12 13)=data1
michael@0: 	movq      mm3,mm2		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm2,mm5		; mm2=(60 61 62 63)=data6
michael@0: 	punpckhdq mm3,mm5		; mm3=(70 71 72 73)=data7
michael@0: 
michael@0: 	movq	mm0,mm7
michael@0: 	movq	mm5,mm6
michael@0: 	psubw	mm7,mm2			; mm7=data1-data6=tmp6
michael@0: 	psubw	mm6,mm3			; mm6=data0-data7=tmp7
michael@0: 	paddw	mm0,mm2			; mm0=data1+data6=tmp1
michael@0: 	paddw	mm5,mm3			; mm5=data0+data7=tmp0
michael@0: 
michael@0: 	movq	mm2, MMWORD [wk(0)]	; mm2=(22 23 32 33)
michael@0: 	movq	mm3, MMWORD [wk(1)]	; mm3=(42 43 52 53)
michael@0: 	movq	MMWORD [wk(0)], mm7	; wk(0)=tmp6
michael@0: 	movq	MMWORD [wk(1)], mm6	; wk(1)=tmp7
michael@0: 
michael@0: 	movq      mm7,mm4		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm4,mm2		; mm4=(20 21 22 23)=data2
michael@0: 	punpckhdq mm7,mm2		; mm7=(30 31 32 33)=data3
michael@0: 	movq      mm6,mm1		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm1,mm3		; mm1=(40 41 42 43)=data4
michael@0: 	punpckhdq mm6,mm3		; mm6=(50 51 52 53)=data5
michael@0: 
michael@0: 	movq	mm2,mm7
michael@0: 	movq	mm3,mm4
michael@0: 	paddw	mm7,mm1			; mm7=data3+data4=tmp3
michael@0: 	paddw	mm4,mm6			; mm4=data2+data5=tmp2
michael@0: 	psubw	mm2,mm1			; mm2=data3-data4=tmp4
michael@0: 	psubw	mm3,mm6			; mm3=data2-data5=tmp5
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm1,mm5
michael@0: 	movq	mm6,mm0
michael@0: 	psubw	mm5,mm7			; mm5=tmp13
michael@0: 	psubw	mm0,mm4			; mm0=tmp12
michael@0: 	paddw	mm1,mm7			; mm1=tmp10
michael@0: 	paddw	mm6,mm4			; mm6=tmp11
michael@0: 
michael@0: 	paddw	mm0,mm5
michael@0: 	psllw	mm0,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm0,[GOTOFF(ebx,PW_F0707)] ; mm0=z1
michael@0: 
michael@0: 	movq	mm7,mm1
michael@0: 	movq	mm4,mm5
michael@0: 	psubw	mm1,mm6			; mm1=data4
michael@0: 	psubw	mm5,mm0			; mm5=data6
michael@0: 	paddw	mm7,mm6			; mm7=data0
michael@0: 	paddw	mm4,mm0			; mm4=data2
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(4,0,edx,SIZEOF_DCTELEM)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(6,0,edx,SIZEOF_DCTELEM)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)], mm4
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm6, MMWORD [wk(0)]	; mm6=tmp6
michael@0: 	movq	mm0, MMWORD [wk(1)]	; mm0=tmp7
michael@0: 
michael@0: 	paddw	mm2,mm3			; mm2=tmp10
michael@0: 	paddw	mm3,mm6			; mm3=tmp11
michael@0: 	paddw	mm6,mm0			; mm6=tmp12, mm0=tmp7
michael@0: 
michael@0: 	psllw	mm2,PRE_MULTIPLY_SCALE_BITS
michael@0: 	psllw	mm6,PRE_MULTIPLY_SCALE_BITS
michael@0: 
michael@0: 	psllw	mm3,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm3,[GOTOFF(ebx,PW_F0707)] ; mm3=z3
michael@0: 
michael@0: 	movq	mm1,mm2			; mm1=tmp10
michael@0: 	psubw	mm2,mm6
michael@0: 	pmulhw	mm2,[GOTOFF(ebx,PW_F0382)] ; mm2=z5
michael@0: 	pmulhw	mm1,[GOTOFF(ebx,PW_F0541)] ; mm1=MULTIPLY(tmp10,FIX_0_54119610)
michael@0: 	pmulhw	mm6,[GOTOFF(ebx,PW_F1306)] ; mm6=MULTIPLY(tmp12,FIX_1_30656296)
michael@0: 	paddw	mm1,mm2			; mm1=z2
michael@0: 	paddw	mm6,mm2			; mm6=z4
michael@0: 
michael@0: 	movq	mm5,mm0
michael@0: 	psubw	mm0,mm3			; mm0=z13
michael@0: 	paddw	mm5,mm3			; mm5=z11
michael@0: 
michael@0: 	movq	mm7,mm0
michael@0: 	movq	mm4,mm5
michael@0: 	psubw	mm0,mm1			; mm0=data3
michael@0: 	psubw	mm5,mm6			; mm5=data7
michael@0: 	paddw	mm7,mm1			; mm7=data5
michael@0: 	paddw	mm4,mm6			; mm4=data1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(7,0,edx,SIZEOF_DCTELEM)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(5,0,edx,SIZEOF_DCTELEM)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)], mm4
michael@0: 
michael@0: 	add	edx, byte 4*SIZEOF_DCTELEM
michael@0: 	dec	ecx
michael@0: 	jnz	near .columnloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: ;	pop	edi		; unused
michael@0: ;	pop	esi		; unused
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	poppic	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16