michael@0: ;
michael@0: ; jimmxred.asm - reduced-size IDCT (MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains inverse-DCT routines that produce reduced-size
michael@0: ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.
michael@0: ; The following code is based directly on the IJG's original jidctred.c;
michael@0: ; see the jidctred.c for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 
michael@0: %define CONST_BITS	13
michael@0: %define PASS1_BITS	2
michael@0: 
michael@0: %define DESCALE_P1_4	(CONST_BITS-PASS1_BITS+1)
michael@0: %define DESCALE_P2_4	(CONST_BITS+PASS1_BITS+3+1)
michael@0: %define DESCALE_P1_2	(CONST_BITS-PASS1_BITS+2)
michael@0: %define DESCALE_P2_2	(CONST_BITS+PASS1_BITS+3+2)
michael@0: 
michael@0: %if CONST_BITS == 13
michael@0: F_0_211	equ	 1730		; FIX(0.211164243)
michael@0: F_0_509	equ	 4176		; FIX(0.509795579)
michael@0: F_0_601	equ	 4926		; FIX(0.601344887)
michael@0: F_0_720	equ	 5906		; FIX(0.720959822)
michael@0: F_0_765	equ	 6270		; FIX(0.765366865)
michael@0: F_0_850	equ	 6967		; FIX(0.850430095)
michael@0: F_0_899	equ	 7373		; FIX(0.899976223)
michael@0: F_1_061	equ	 8697		; FIX(1.061594337)
michael@0: F_1_272	equ	10426		; FIX(1.272758580)
michael@0: F_1_451	equ	11893		; FIX(1.451774981)
michael@0: F_1_847	equ	15137		; FIX(1.847759065)
michael@0: F_2_172	equ	17799		; FIX(2.172734803)
michael@0: F_2_562	equ	20995		; FIX(2.562915447)
michael@0: F_3_624	equ	29692		; FIX(3.624509785)
michael@0: %else
michael@0: ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0: %define DESCALE(x,n)  (((x)+(1<<((n)-1)))>>(n))
michael@0: F_0_211	equ	DESCALE( 226735879,30-CONST_BITS)	; FIX(0.211164243)
michael@0: F_0_509	equ	DESCALE( 547388834,30-CONST_BITS)	; FIX(0.509795579)
michael@0: F_0_601	equ	DESCALE( 645689155,30-CONST_BITS)	; FIX(0.601344887)
michael@0: F_0_720	equ	DESCALE( 774124714,30-CONST_BITS)	; FIX(0.720959822)
michael@0: F_0_765	equ	DESCALE( 821806413,30-CONST_BITS)	; FIX(0.765366865)
michael@0: F_0_850	equ	DESCALE( 913142361,30-CONST_BITS)	; FIX(0.850430095)
michael@0: F_0_899	equ	DESCALE( 966342111,30-CONST_BITS)	; FIX(0.899976223)
michael@0: F_1_061	equ	DESCALE(1139878239,30-CONST_BITS)	; FIX(1.061594337)
michael@0: F_1_272	equ	DESCALE(1366614119,30-CONST_BITS)	; FIX(1.272758580)
michael@0: F_1_451	equ	DESCALE(1558831516,30-CONST_BITS)	; FIX(1.451774981)
michael@0: F_1_847	equ	DESCALE(1984016188,30-CONST_BITS)	; FIX(1.847759065)
michael@0: F_2_172	equ	DESCALE(2332956230,30-CONST_BITS)	; FIX(2.172734803)
michael@0: F_2_562	equ	DESCALE(2751909506,30-CONST_BITS)	; FIX(2.562915447)
michael@0: F_3_624	equ	DESCALE(3891787747,30-CONST_BITS)	; FIX(3.624509785)
michael@0: %endif
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_idct_red_mmx)
michael@0: 
michael@0: EXTN(jconst_idct_red_mmx):
michael@0: 
michael@0: PW_F184_MF076	times 2 dw  F_1_847,-F_0_765
michael@0: PW_F256_F089	times 2 dw  F_2_562, F_0_899
michael@0: PW_F106_MF217	times 2 dw  F_1_061,-F_2_172
michael@0: PW_MF060_MF050	times 2 dw -F_0_601,-F_0_509
michael@0: PW_F145_MF021	times 2 dw  F_1_451,-F_0_211
michael@0: PW_F362_MF127	times 2 dw  F_3_624,-F_1_272
michael@0: PW_F085_MF072	times 2 dw  F_0_850,-F_0_720
michael@0: PD_DESCALE_P1_4	times 2 dd  1 << (DESCALE_P1_4-1)
michael@0: PD_DESCALE_P2_4	times 2 dd  1 << (DESCALE_P2_4-1)
michael@0: PD_DESCALE_P1_2	times 2 dd  1 << (DESCALE_P1_2-1)
michael@0: PD_DESCALE_P2_2	times 2 dd  1 << (DESCALE_P2_2-1)
michael@0: PB_CENTERJSAMP	times 8 db  CENTERJSAMPLE
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0: ; producing a reduced-size 4x4 output block.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_4x4_mmx (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                     JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: %define dct_table(b)	(b)+8			; void * dct_table
michael@0: %define coef_block(b)	(b)+12		; JCOEFPTR coef_block
michael@0: %define output_buf(b)	(b)+16		; JSAMPARRAY output_buf
michael@0: %define output_col(b)	(b)+20		; JDIMENSION output_col
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: %define workspace	wk(0)-DCTSIZE2*SIZEOF_JCOEF
michael@0: 					; JCOEF workspace[DCTSIZE2]
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_4x4_mmx)
michael@0: 
michael@0: EXTN(jsimd_idct_4x4_mmx):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [workspace]
michael@0: 	pushpic	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input, store into work array.
michael@0: 
michael@0: ;	mov	eax, [original_ebp]
michael@0: 	mov	edx, POINTER [dct_table(eax)]	; quantptr
michael@0: 	mov	esi, JCOEFPTR [coef_block(eax)]		; inptr
michael@0: 	lea	edi, [workspace]			; JCOEF * wsptr
michael@0: 	mov	ecx, DCTSIZE/4				; ctr
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: %ifndef NO_ZERO_COLUMN_TEST_4X4_MMX
michael@0: 	mov	eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm1, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0,mm1
michael@0: 	packsswb mm0,mm0
michael@0: 	movd	eax,mm0
michael@0: 	test	eax,eax
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	; -- AC terms all zero
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	psllw	mm0,PASS1_BITS
michael@0: 
michael@0: 	movq      mm2,mm0		; mm0=in0=(00 01 02 03)
michael@0: 	punpcklwd mm0,mm0		; mm0=(00 00 01 01)
michael@0: 	punpckhwd mm2,mm2		; mm2=(02 02 03 03)
michael@0: 
michael@0: 	movq      mm1,mm0
michael@0: 	punpckldq mm0,mm0		; mm0=(00 00 00 00)
michael@0: 	punpckhdq mm1,mm1		; mm1=(01 01 01 01)
michael@0: 	movq      mm3,mm2
michael@0: 	punpckldq mm2,mm2		; mm2=(02 02 02 02)
michael@0: 	punpckhdq mm3,mm3		; mm3=(03 03 03 03)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
michael@0: 	jmp	near .nextcolumn
michael@0: 	alignx	16,7
michael@0: %endif
michael@0: .columnDCT:
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm2, MMWORD [MMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	movq      mm4,mm0
michael@0: 	movq      mm5,mm0
michael@0: 	punpcklwd mm4,mm1
michael@0: 	punpckhwd mm5,mm1
michael@0: 	movq      mm0,mm4
michael@0: 	movq      mm1,mm5
michael@0: 	pmaddwd   mm4,[GOTOFF(ebx,PW_F256_F089)]	; mm4=(tmp2L)
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F256_F089)]	; mm5=(tmp2H)
michael@0: 	pmaddwd   mm0,[GOTOFF(ebx,PW_F106_MF217)]	; mm0=(tmp0L)
michael@0: 	pmaddwd   mm1,[GOTOFF(ebx,PW_F106_MF217)]	; mm1=(tmp0H)
michael@0: 
michael@0: 	movq      mm6,mm2
michael@0: 	movq      mm7,mm2
michael@0: 	punpcklwd mm6,mm3
michael@0: 	punpckhwd mm7,mm3
michael@0: 	movq      mm2,mm6
michael@0: 	movq      mm3,mm7
michael@0: 	pmaddwd   mm6,[GOTOFF(ebx,PW_MF060_MF050)]	; mm6=(tmp2L)
michael@0: 	pmaddwd   mm7,[GOTOFF(ebx,PW_MF060_MF050)]	; mm7=(tmp2H)
michael@0: 	pmaddwd   mm2,[GOTOFF(ebx,PW_F145_MF021)]	; mm2=(tmp0L)
michael@0: 	pmaddwd   mm3,[GOTOFF(ebx,PW_F145_MF021)]	; mm3=(tmp0H)
michael@0: 
michael@0: 	paddd	mm6,mm4			; mm6=tmp2L
michael@0: 	paddd	mm7,mm5			; mm7=tmp2H
michael@0: 	paddd	mm2,mm0			; mm2=tmp0L
michael@0: 	paddd	mm3,mm1			; mm3=tmp0H
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm2	; wk(0)=tmp0L
michael@0: 	movq	MMWORD [wk(1)], mm3	; wk(1)=tmp0H
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm4, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm4, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm5, MMWORD [MMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	pxor      mm1,mm1
michael@0: 	pxor      mm2,mm2
michael@0: 	punpcklwd mm1,mm4		; mm1=tmp0L
michael@0: 	punpckhwd mm2,mm4		; mm2=tmp0H
michael@0: 	psrad     mm1,(16-CONST_BITS-1)	; psrad mm1,16 & pslld mm1,CONST_BITS+1
michael@0: 	psrad     mm2,(16-CONST_BITS-1)	; psrad mm2,16 & pslld mm2,CONST_BITS+1
michael@0: 
michael@0: 	movq      mm3,mm5		; mm5=in2=z2
michael@0: 	punpcklwd mm5,mm0		; mm0=in6=z3
michael@0: 	punpckhwd mm3,mm0
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F184_MF076)]	; mm5=tmp2L
michael@0: 	pmaddwd   mm3,[GOTOFF(ebx,PW_F184_MF076)]	; mm3=tmp2H
michael@0: 
michael@0: 	movq	mm4,mm1
michael@0: 	movq	mm0,mm2
michael@0: 	paddd	mm1,mm5			; mm1=tmp10L
michael@0: 	paddd	mm2,mm3			; mm2=tmp10H
michael@0: 	psubd	mm4,mm5			; mm4=tmp12L
michael@0: 	psubd	mm0,mm3			; mm0=tmp12H
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movq	mm5,mm1
michael@0: 	movq	mm3,mm2
michael@0: 	paddd	mm1,mm6			; mm1=data0L
michael@0: 	paddd	mm2,mm7			; mm2=data0H
michael@0: 	psubd	mm5,mm6			; mm5=data3L
michael@0: 	psubd	mm3,mm7			; mm3=data3H
michael@0: 
michael@0: 	movq	mm6,[GOTOFF(ebx,PD_DESCALE_P1_4)]	; mm6=[PD_DESCALE_P1_4]
michael@0: 
michael@0: 	paddd	mm1,mm6
michael@0: 	paddd	mm2,mm6
michael@0: 	psrad	mm1,DESCALE_P1_4
michael@0: 	psrad	mm2,DESCALE_P1_4
michael@0: 	paddd	mm5,mm6
michael@0: 	paddd	mm3,mm6
michael@0: 	psrad	mm5,DESCALE_P1_4
michael@0: 	psrad	mm3,DESCALE_P1_4
michael@0: 
michael@0: 	packssdw  mm1,mm2		; mm1=data0=(00 01 02 03)
michael@0: 	packssdw  mm5,mm3		; mm5=data3=(30 31 32 33)
michael@0: 
michael@0: 	movq	mm7, MMWORD [wk(0)]	; mm7=tmp0L
michael@0: 	movq	mm6, MMWORD [wk(1)]	; mm6=tmp0H
michael@0: 
michael@0: 	movq	mm2,mm4
michael@0: 	movq	mm3,mm0
michael@0: 	paddd	mm4,mm7			; mm4=data1L
michael@0: 	paddd	mm0,mm6			; mm0=data1H
michael@0: 	psubd	mm2,mm7			; mm2=data2L
michael@0: 	psubd	mm3,mm6			; mm3=data2H
michael@0: 
michael@0: 	movq	mm7,[GOTOFF(ebx,PD_DESCALE_P1_4)]	; mm7=[PD_DESCALE_P1_4]
michael@0: 
michael@0: 	paddd	mm4,mm7
michael@0: 	paddd	mm0,mm7
michael@0: 	psrad	mm4,DESCALE_P1_4
michael@0: 	psrad	mm0,DESCALE_P1_4
michael@0: 	paddd	mm2,mm7
michael@0: 	paddd	mm3,mm7
michael@0: 	psrad	mm2,DESCALE_P1_4
michael@0: 	psrad	mm3,DESCALE_P1_4
michael@0: 
michael@0: 	packssdw  mm4,mm0		; mm4=data1=(10 11 12 13)
michael@0: 	packssdw  mm2,mm3		; mm2=data2=(20 21 22 23)
michael@0: 
michael@0: 	movq      mm6,mm1		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm1,mm4		; mm1=(00 10 01 11)
michael@0: 	punpckhwd mm6,mm4		; mm6=(02 12 03 13)
michael@0: 	movq      mm7,mm2		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm2,mm5		; mm2=(20 30 21 31)
michael@0: 	punpckhwd mm7,mm5		; mm7=(22 32 23 33)
michael@0: 
michael@0: 	movq      mm0,mm1		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm1,mm2		; mm1=(00 10 20 30)
michael@0: 	punpckhdq mm0,mm2		; mm0=(01 11 21 31)
michael@0: 	movq      mm3,mm6		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm6,mm7		; mm6=(02 12 22 32)
michael@0: 	punpckhdq mm3,mm7		; mm3=(03 13 23 33)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
michael@0: 
michael@0: .nextcolumn:
michael@0: 	add	esi, byte 4*SIZEOF_JCOEF		; coef_block
michael@0: 	add	edx, byte 4*SIZEOF_ISLOW_MULT_TYPE	; quantptr
michael@0: 	add	edi, byte 4*DCTSIZE*SIZEOF_JCOEF	; wsptr
michael@0: 	dec	ecx					; ctr
michael@0: 	jnz	near .columnloop
michael@0: 
michael@0: 	; ---- Pass 2: process rows from work array, store into output array.
michael@0: 
michael@0: 	mov	eax, [original_ebp]
michael@0: 	lea	esi, [workspace]			; JCOEF * wsptr
michael@0: 	mov	edi, JSAMPARRAY [output_buf(eax)]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [output_col(eax)]
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	movq      mm4,mm0
michael@0: 	movq      mm5,mm0
michael@0: 	punpcklwd mm4,mm1
michael@0: 	punpckhwd mm5,mm1
michael@0: 	movq      mm0,mm4
michael@0: 	movq      mm1,mm5
michael@0: 	pmaddwd   mm4,[GOTOFF(ebx,PW_F256_F089)]	; mm4=(tmp2L)
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F256_F089)]	; mm5=(tmp2H)
michael@0: 	pmaddwd   mm0,[GOTOFF(ebx,PW_F106_MF217)]	; mm0=(tmp0L)
michael@0: 	pmaddwd   mm1,[GOTOFF(ebx,PW_F106_MF217)]	; mm1=(tmp0H)
michael@0: 
michael@0: 	movq      mm6,mm2
michael@0: 	movq      mm7,mm2
michael@0: 	punpcklwd mm6,mm3
michael@0: 	punpckhwd mm7,mm3
michael@0: 	movq      mm2,mm6
michael@0: 	movq      mm3,mm7
michael@0: 	pmaddwd   mm6,[GOTOFF(ebx,PW_MF060_MF050)]	; mm6=(tmp2L)
michael@0: 	pmaddwd   mm7,[GOTOFF(ebx,PW_MF060_MF050)]	; mm7=(tmp2H)
michael@0: 	pmaddwd   mm2,[GOTOFF(ebx,PW_F145_MF021)]	; mm2=(tmp0L)
michael@0: 	pmaddwd   mm3,[GOTOFF(ebx,PW_F145_MF021)]	; mm3=(tmp0H)
michael@0: 
michael@0: 	paddd	mm6,mm4			; mm6=tmp2L
michael@0: 	paddd	mm7,mm5			; mm7=tmp2H
michael@0: 	paddd	mm2,mm0			; mm2=tmp0L
michael@0: 	paddd	mm3,mm1			; mm3=tmp0H
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm2	; wk(0)=tmp0L
michael@0: 	movq	MMWORD [wk(1)], mm3	; wk(1)=tmp0H
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm4, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm0, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	pxor      mm1,mm1
michael@0: 	pxor      mm2,mm2
michael@0: 	punpcklwd mm1,mm4		; mm1=tmp0L
michael@0: 	punpckhwd mm2,mm4		; mm2=tmp0H
michael@0: 	psrad     mm1,(16-CONST_BITS-1)	; psrad mm1,16 & pslld mm1,CONST_BITS+1
michael@0: 	psrad     mm2,(16-CONST_BITS-1)	; psrad mm2,16 & pslld mm2,CONST_BITS+1
michael@0: 
michael@0: 	movq      mm3,mm5		; mm5=in2=z2
michael@0: 	punpcklwd mm5,mm0		; mm0=in6=z3
michael@0: 	punpckhwd mm3,mm0
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F184_MF076)]	; mm5=tmp2L
michael@0: 	pmaddwd   mm3,[GOTOFF(ebx,PW_F184_MF076)]	; mm3=tmp2H
michael@0: 
michael@0: 	movq	mm4,mm1
michael@0: 	movq	mm0,mm2
michael@0: 	paddd	mm1,mm5			; mm1=tmp10L
michael@0: 	paddd	mm2,mm3			; mm2=tmp10H
michael@0: 	psubd	mm4,mm5			; mm4=tmp12L
michael@0: 	psubd	mm0,mm3			; mm0=tmp12H
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movq	mm5,mm1
michael@0: 	movq	mm3,mm2
michael@0: 	paddd	mm1,mm6			; mm1=data0L
michael@0: 	paddd	mm2,mm7			; mm2=data0H
michael@0: 	psubd	mm5,mm6			; mm5=data3L
michael@0: 	psubd	mm3,mm7			; mm3=data3H
michael@0: 
michael@0: 	movq	mm6,[GOTOFF(ebx,PD_DESCALE_P2_4)]	; mm6=[PD_DESCALE_P2_4]
michael@0: 
michael@0: 	paddd	mm1,mm6
michael@0: 	paddd	mm2,mm6
michael@0: 	psrad	mm1,DESCALE_P2_4
michael@0: 	psrad	mm2,DESCALE_P2_4
michael@0: 	paddd	mm5,mm6
michael@0: 	paddd	mm3,mm6
michael@0: 	psrad	mm5,DESCALE_P2_4
michael@0: 	psrad	mm3,DESCALE_P2_4
michael@0: 
michael@0: 	packssdw  mm1,mm2		; mm1=data0=(00 10 20 30)
michael@0: 	packssdw  mm5,mm3		; mm5=data3=(03 13 23 33)
michael@0: 
michael@0: 	movq	mm7, MMWORD [wk(0)]	; mm7=tmp0L
michael@0: 	movq	mm6, MMWORD [wk(1)]	; mm6=tmp0H
michael@0: 
michael@0: 	movq	mm2,mm4
michael@0: 	movq	mm3,mm0
michael@0: 	paddd	mm4,mm7			; mm4=data1L
michael@0: 	paddd	mm0,mm6			; mm0=data1H
michael@0: 	psubd	mm2,mm7			; mm2=data2L
michael@0: 	psubd	mm3,mm6			; mm3=data2H
michael@0: 
michael@0: 	movq	mm7,[GOTOFF(ebx,PD_DESCALE_P2_4)]	; mm7=[PD_DESCALE_P2_4]
michael@0: 
michael@0: 	paddd	mm4,mm7
michael@0: 	paddd	mm0,mm7
michael@0: 	psrad	mm4,DESCALE_P2_4
michael@0: 	psrad	mm0,DESCALE_P2_4
michael@0: 	paddd	mm2,mm7
michael@0: 	paddd	mm3,mm7
michael@0: 	psrad	mm2,DESCALE_P2_4
michael@0: 	psrad	mm3,DESCALE_P2_4
michael@0: 
michael@0: 	packssdw  mm4,mm0		; mm4=data1=(01 11 21 31)
michael@0: 	packssdw  mm2,mm3		; mm2=data2=(02 12 22 32)
michael@0: 
michael@0: 	movq      mm6,[GOTOFF(ebx,PB_CENTERJSAMP)]	; mm6=[PB_CENTERJSAMP]
michael@0: 
michael@0: 	packsswb  mm1,mm2		; mm1=(00 10 20 30 02 12 22 32)
michael@0: 	packsswb  mm4,mm5		; mm4=(01 11 21 31 03 13 23 33)
michael@0: 	paddb     mm1,mm6
michael@0: 	paddb     mm4,mm6
michael@0: 
michael@0: 	movq      mm7,mm1		; transpose coefficients(phase 1)
michael@0: 	punpcklbw mm1,mm4		; mm1=(00 01 10 11 20 21 30 31)
michael@0: 	punpckhbw mm7,mm4		; mm7=(02 03 12 13 22 23 32 33)
michael@0: 
michael@0: 	movq      mm0,mm1		; transpose coefficients(phase 2)
michael@0: 	punpcklwd mm1,mm7		; mm1=(00 01 02 03 10 11 12 13)
michael@0: 	punpckhwd mm0,mm7		; mm0=(20 21 22 23 30 31 32 33)
michael@0: 
michael@0: 	mov	edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	esi, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
michael@0: 	movd	DWORD [edx+eax*SIZEOF_JSAMPLE], mm1
michael@0: 	movd	DWORD [esi+eax*SIZEOF_JSAMPLE], mm0
michael@0: 
michael@0: 	psrlq	mm1,4*BYTE_BIT
michael@0: 	psrlq	mm0,4*BYTE_BIT
michael@0: 
michael@0: 	mov	edx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0: 	mov	esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
michael@0: 	movd	DWORD [edx+eax*SIZEOF_JSAMPLE], mm1
michael@0: 	movd	DWORD [esi+eax*SIZEOF_JSAMPLE], mm0
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	poppic	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0: ; producing a reduced-size 2x2 output block.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_2x2_mmx (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                     JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: %define dct_table(b)	(b)+8			; void * dct_table
michael@0: %define coef_block(b)	(b)+12		; JCOEFPTR coef_block
michael@0: %define output_buf(b)	(b)+16		; JSAMPARRAY output_buf
michael@0: %define output_col(b)	(b)+20		; JDIMENSION output_col
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_2x2_mmx)
michael@0: 
michael@0: EXTN(jsimd_idct_2x2_mmx):
michael@0: 	push	ebp
michael@0: 	mov	ebp,esp
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input.
michael@0: 
michael@0: 	mov	edx, POINTER [dct_table(ebp)]	; quantptr
michael@0: 	mov	esi, JCOEFPTR [coef_block(ebp)]		; inptr
michael@0: 
michael@0: 	; | input:                  | result:        |
michael@0: 	; | 00 01 ** 03 ** 05 ** 07 |                |
michael@0: 	; | 10 11 ** 13 ** 15 ** 17 |                |
michael@0: 	; | ** ** ** ** ** ** ** ** |                |
michael@0: 	; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 |
michael@0: 	; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 |
michael@0: 	; | 50 51 ** 53 ** 55 ** 57 |                |
michael@0: 	; | ** ** ** ** ** ** ** ** |                |
michael@0: 	; | 70 71 ** 73 ** 75 ** 77 |                |
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm2, MMWORD [MMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	; mm0=(10 11 ** 13), mm1=(30 31 ** 33)
michael@0: 	; mm2=(50 51 ** 53), mm3=(70 71 ** 73)
michael@0: 
michael@0: 	pcmpeqd   mm7,mm7
michael@0: 	pslld     mm7,WORD_BIT		; mm7={0x0000 0xFFFF 0x0000 0xFFFF}
michael@0: 
michael@0: 	movq      mm4,mm0		; mm4=(10 11 ** 13)
michael@0: 	movq      mm5,mm2		; mm5=(50 51 ** 53)
michael@0: 	punpcklwd mm4,mm1		; mm4=(10 30 11 31)
michael@0: 	punpcklwd mm5,mm3		; mm5=(50 70 51 71)
michael@0: 	pmaddwd   mm4,[GOTOFF(ebx,PW_F362_MF127)]
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F085_MF072)]
michael@0: 
michael@0: 	psrld	mm0,WORD_BIT		; mm0=(11 -- 13 --)
michael@0: 	pand	mm1,mm7			; mm1=(-- 31 -- 33)
michael@0: 	psrld	mm2,WORD_BIT		; mm2=(51 -- 53 --)
michael@0: 	pand	mm3,mm7			; mm3=(-- 71 -- 73)
michael@0: 	por	mm0,mm1			; mm0=(11 31 13 33)
michael@0: 	por	mm2,mm3			; mm2=(51 71 53 73)
michael@0: 	pmaddwd	mm0,[GOTOFF(ebx,PW_F362_MF127)]
michael@0: 	pmaddwd	mm2,[GOTOFF(ebx,PW_F085_MF072)]
michael@0: 
michael@0: 	paddd	mm4,mm5			; mm4=tmp0[col0 col1]
michael@0: 
michael@0: 	movq	mm6, MMWORD [MMBLOCK(1,1,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(3,1,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm6, MMWORD [MMBLOCK(1,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(3,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(5,1,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(7,1,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm3, MMWORD [MMBLOCK(5,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm5, MMWORD [MMBLOCK(7,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	; mm6=(** 15 ** 17), mm1=(** 35 ** 37)
michael@0: 	; mm3=(** 55 ** 57), mm5=(** 75 ** 77)
michael@0: 
michael@0: 	psrld	mm6,WORD_BIT		; mm6=(15 -- 17 --)
michael@0: 	pand	mm1,mm7			; mm1=(-- 35 -- 37)
michael@0: 	psrld	mm3,WORD_BIT		; mm3=(55 -- 57 --)
michael@0: 	pand	mm5,mm7			; mm5=(-- 75 -- 77)
michael@0: 	por	mm6,mm1			; mm6=(15 35 17 37)
michael@0: 	por	mm3,mm5			; mm3=(55 75 57 77)
michael@0: 	pmaddwd	mm6,[GOTOFF(ebx,PW_F362_MF127)]
michael@0: 	pmaddwd	mm3,[GOTOFF(ebx,PW_F085_MF072)]
michael@0: 
michael@0: 	paddd	mm0,mm2			; mm0=tmp0[col1 col3]
michael@0: 	paddd	mm6,mm3			; mm6=tmp0[col5 col7]
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm1, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(0,1,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	mm5, MMWORD [MMBLOCK(0,1,edx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	; mm1=(00 01 ** 03), mm5=(** 05 ** 07)
michael@0: 
michael@0: 	movq	mm2,mm1				; mm2=(00 01 ** 03)
michael@0: 	pslld	mm1,WORD_BIT			; mm1=(-- 00 -- **)
michael@0: 	psrad	mm1,(WORD_BIT-CONST_BITS-2)	; mm1=tmp10[col0 ****]
michael@0: 
michael@0: 	pand	mm2,mm7				; mm2=(-- 01 -- 03)
michael@0: 	pand	mm5,mm7				; mm5=(-- 05 -- 07)
michael@0: 	psrad	mm2,(WORD_BIT-CONST_BITS-2)	; mm2=tmp10[col1 col3]
michael@0: 	psrad	mm5,(WORD_BIT-CONST_BITS-2)	; mm5=tmp10[col5 col7]
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movq      mm3,mm1
michael@0: 	paddd     mm1,mm4		; mm1=data0[col0 ****]=(A0 **)
michael@0: 	psubd     mm3,mm4		; mm3=data1[col0 ****]=(B0 **)
michael@0: 	punpckldq mm1,mm3		; mm1=(A0 B0)
michael@0: 
michael@0: 	movq	mm7,[GOTOFF(ebx,PD_DESCALE_P1_2)]	; mm7=[PD_DESCALE_P1_2]
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm3,mm5
michael@0: 	paddd	mm2,mm0			; mm2=data0[col1 col3]=(A1 A3)
michael@0: 	paddd	mm5,mm6			; mm5=data0[col5 col7]=(A5 A7)
michael@0: 	psubd	mm4,mm0			; mm4=data1[col1 col3]=(B1 B3)
michael@0: 	psubd	mm3,mm6			; mm3=data1[col5 col7]=(B5 B7)
michael@0: 
michael@0: 	paddd	mm1,mm7
michael@0: 	psrad	mm1,DESCALE_P1_2
michael@0: 
michael@0: 	paddd	mm2,mm7
michael@0: 	paddd	mm5,mm7
michael@0: 	psrad	mm2,DESCALE_P1_2
michael@0: 	psrad	mm5,DESCALE_P1_2
michael@0: 	paddd	mm4,mm7
michael@0: 	paddd	mm3,mm7
michael@0: 	psrad	mm4,DESCALE_P1_2
michael@0: 	psrad	mm3,DESCALE_P1_2
michael@0: 
michael@0: 	; ---- Pass 2: process rows, store into output array.
michael@0: 
michael@0: 	mov	edi, JSAMPARRAY [output_buf(ebp)]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [output_col(ebp)]
michael@0: 
michael@0: 	; | input:| result:|
michael@0: 	; | A0 B0 |        |
michael@0: 	; | A1 B1 | C0 C1  |
michael@0: 	; | A3 B3 | D0 D1  |
michael@0: 	; | A5 B5 |        |
michael@0: 	; | A7 B7 |        |
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	packssdw  mm2,mm4		; mm2=(A1 A3 B1 B3)
michael@0: 	packssdw  mm5,mm3		; mm5=(A5 A7 B5 B7)
michael@0: 	pmaddwd   mm2,[GOTOFF(ebx,PW_F362_MF127)]
michael@0: 	pmaddwd   mm5,[GOTOFF(ebx,PW_F085_MF072)]
michael@0: 
michael@0: 	paddd     mm2,mm5		; mm2=tmp0[row0 row1]
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	pslld     mm1,(CONST_BITS+2)	; mm1=tmp10[row0 row1]
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movq      mm0,[GOTOFF(ebx,PD_DESCALE_P2_2)]	; mm0=[PD_DESCALE_P2_2]
michael@0: 
michael@0: 	movq      mm6,mm1
michael@0: 	paddd     mm1,mm2		; mm1=data0[row0 row1]=(C0 C1)
michael@0: 	psubd     mm6,mm2		; mm6=data1[row0 row1]=(D0 D1)
michael@0: 
michael@0: 	paddd     mm1,mm0
michael@0: 	paddd     mm6,mm0
michael@0: 	psrad     mm1,DESCALE_P2_2
michael@0: 	psrad     mm6,DESCALE_P2_2
michael@0: 
michael@0: 	movq      mm7,mm1		; transpose coefficients
michael@0: 	punpckldq mm1,mm6		; mm1=(C0 D0)
michael@0: 	punpckhdq mm7,mm6		; mm7=(C1 D1)
michael@0: 
michael@0: 	packssdw  mm1,mm7		; mm1=(C0 D0 C1 D1)
michael@0: 	packsswb  mm1,mm1		; mm1=(C0 D0 C1 D1 C0 D0 C1 D1)
michael@0: 	paddb     mm1,[GOTOFF(ebx,PB_CENTERJSAMP)]
michael@0: 
michael@0: 	movd	ecx,mm1
michael@0: 	movd	ebx,mm1			; ebx=(C0 D0 C1 D1)
michael@0: 	shr	ecx,2*BYTE_BIT		; ecx=(C1 D1 -- --)
michael@0: 
michael@0: 	mov	edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0: 	mov	WORD [edx+eax*SIZEOF_JSAMPLE], bx
michael@0: 	mov	WORD [esi+eax*SIZEOF_JSAMPLE], cx
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16