michael@0: ;
michael@0: ; jiss2red-64.asm - reduced-size IDCT (64-bit SSE2)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ; Copyright 2009 D. R. Commander
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains inverse-DCT routines that produce reduced-size
michael@0: ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.
michael@0: ; The following code is based directly on the IJG's original jidctred.c;
michael@0: ; see the jidctred.c for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 
michael@0: %define CONST_BITS	13
michael@0: %define PASS1_BITS	2
michael@0: 
michael@0: %define DESCALE_P1_4	(CONST_BITS-PASS1_BITS+1)
michael@0: %define DESCALE_P2_4	(CONST_BITS+PASS1_BITS+3+1)
michael@0: %define DESCALE_P1_2	(CONST_BITS-PASS1_BITS+2)
michael@0: %define DESCALE_P2_2	(CONST_BITS+PASS1_BITS+3+2)
michael@0: 
michael@0: %if CONST_BITS == 13
michael@0: F_0_211	equ	 1730		; FIX(0.211164243)
michael@0: F_0_509	equ	 4176		; FIX(0.509795579)
michael@0: F_0_601	equ	 4926		; FIX(0.601344887)
michael@0: F_0_720	equ	 5906		; FIX(0.720959822)
michael@0: F_0_765	equ	 6270		; FIX(0.765366865)
michael@0: F_0_850	equ	 6967		; FIX(0.850430095)
michael@0: F_0_899	equ	 7373		; FIX(0.899976223)
michael@0: F_1_061	equ	 8697		; FIX(1.061594337)
michael@0: F_1_272	equ	10426		; FIX(1.272758580)
michael@0: F_1_451	equ	11893		; FIX(1.451774981)
michael@0: F_1_847	equ	15137		; FIX(1.847759065)
michael@0: F_2_172	equ	17799		; FIX(2.172734803)
michael@0: F_2_562	equ	20995		; FIX(2.562915447)
michael@0: F_3_624	equ	29692		; FIX(3.624509785)
michael@0: %else
michael@0: ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0: %define DESCALE(x,n)  (((x)+(1<<((n)-1)))>>(n))
michael@0: F_0_211	equ	DESCALE( 226735879,30-CONST_BITS)	; FIX(0.211164243)
michael@0: F_0_509	equ	DESCALE( 547388834,30-CONST_BITS)	; FIX(0.509795579)
michael@0: F_0_601	equ	DESCALE( 645689155,30-CONST_BITS)	; FIX(0.601344887)
michael@0: F_0_720	equ	DESCALE( 774124714,30-CONST_BITS)	; FIX(0.720959822)
michael@0: F_0_765	equ	DESCALE( 821806413,30-CONST_BITS)	; FIX(0.765366865)
michael@0: F_0_850	equ	DESCALE( 913142361,30-CONST_BITS)	; FIX(0.850430095)
michael@0: F_0_899	equ	DESCALE( 966342111,30-CONST_BITS)	; FIX(0.899976223)
michael@0: F_1_061	equ	DESCALE(1139878239,30-CONST_BITS)	; FIX(1.061594337)
michael@0: F_1_272	equ	DESCALE(1366614119,30-CONST_BITS)	; FIX(1.272758580)
michael@0: F_1_451	equ	DESCALE(1558831516,30-CONST_BITS)	; FIX(1.451774981)
michael@0: F_1_847	equ	DESCALE(1984016188,30-CONST_BITS)	; FIX(1.847759065)
michael@0: F_2_172	equ	DESCALE(2332956230,30-CONST_BITS)	; FIX(2.172734803)
michael@0: F_2_562	equ	DESCALE(2751909506,30-CONST_BITS)	; FIX(2.562915447)
michael@0: F_3_624	equ	DESCALE(3891787747,30-CONST_BITS)	; FIX(3.624509785)
michael@0: %endif
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_idct_red_sse2)
michael@0: 
michael@0: EXTN(jconst_idct_red_sse2):
michael@0: 
michael@0: PW_F184_MF076	times 4 dw  F_1_847,-F_0_765
michael@0: PW_F256_F089	times 4 dw  F_2_562, F_0_899
michael@0: PW_F106_MF217	times 4 dw  F_1_061,-F_2_172
michael@0: PW_MF060_MF050	times 4 dw -F_0_601,-F_0_509
michael@0: PW_F145_MF021	times 4 dw  F_1_451,-F_0_211
michael@0: PW_F362_MF127	times 4 dw  F_3_624,-F_1_272
michael@0: PW_F085_MF072	times 4 dw  F_0_850,-F_0_720
michael@0: PD_DESCALE_P1_4	times 4 dd  1 << (DESCALE_P1_4-1)
michael@0: PD_DESCALE_P2_4	times 4 dd  1 << (DESCALE_P2_4-1)
michael@0: PD_DESCALE_P1_2	times 4 dd  1 << (DESCALE_P1_2-1)
michael@0: PD_DESCALE_P2_2	times 4 dd  1 << (DESCALE_P2_2-1)
michael@0: PB_CENTERJSAMP	times 16 db CENTERJSAMPLE
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	64
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0: ; producing a reduced-size 4x4 output block.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_4x4_sse2 (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                      JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: ; r10 = void * dct_table
michael@0: ; r11 = JCOEFPTR coef_block
michael@0: ; r12 = JSAMPARRAY output_buf
michael@0: ; r13 = JDIMENSION output_col
michael@0: 
michael@0: %define original_rbp	rbp+0
michael@0: %define wk(i)		rbp-(WK_NUM-(i))*SIZEOF_XMMWORD	; xmmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_4x4_sse2)
michael@0: 
michael@0: EXTN(jsimd_idct_4x4_sse2):
michael@0: 	push	rbp
michael@0: 	mov	rax,rsp				; rax = original rbp
michael@0: 	sub	rsp, byte 4
michael@0: 	and	rsp, byte (-SIZEOF_XMMWORD)	; align to 128 bits
michael@0: 	mov	[rsp],rax
michael@0: 	mov	rbp,rsp				; rbp = aligned rbp
michael@0: 	lea	rsp, [wk(0)]
michael@0: 	collect_args
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input.
michael@0: 
michael@0: 	mov	rdx, r10	; quantptr
michael@0: 	mov	rsi, r11		; inptr
michael@0: 
michael@0: %ifndef NO_ZERO_COLUMN_TEST_4X4_SSE2
michael@0: 	mov	eax, DWORD [DWBLOCK(1,0,rsi,SIZEOF_JCOEF)]
michael@0: 	or	eax, DWORD [DWBLOCK(2,0,rsi,SIZEOF_JCOEF)]
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	movdqa	xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm1, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
michael@0: 	por	xmm0, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
michael@0: 	por	xmm1, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
michael@0: 	por	xmm0, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
michael@0: 	por	xmm1, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
michael@0: 	por	xmm0,xmm1
michael@0: 	packsswb xmm0,xmm0
michael@0: 	packsswb xmm0,xmm0
michael@0: 	movd	eax,xmm0
michael@0: 	test	rax,rax
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	; -- AC terms all zero
michael@0: 
michael@0: 	movdqa	xmm0, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	psllw	xmm0,PASS1_BITS
michael@0: 
michael@0: 	movdqa    xmm3,xmm0	; xmm0=in0=(00 01 02 03 04 05 06 07)
michael@0: 	punpcklwd xmm0,xmm0	; xmm0=(00 00 01 01 02 02 03 03)
michael@0: 	punpckhwd xmm3,xmm3	; xmm3=(04 04 05 05 06 06 07 07)
michael@0: 
michael@0: 	pshufd	xmm1,xmm0,0x50	; xmm1=[col0 col1]=(00 00 00 00 01 01 01 01)
michael@0: 	pshufd	xmm0,xmm0,0xFA	; xmm0=[col2 col3]=(02 02 02 02 03 03 03 03)
michael@0: 	pshufd	xmm6,xmm3,0x50	; xmm6=[col4 col5]=(04 04 04 04 05 05 05 05)
michael@0: 	pshufd	xmm3,xmm3,0xFA	; xmm3=[col6 col7]=(06 06 06 06 07 07 07 07)
michael@0: 
michael@0: 	jmp	near .column_end
michael@0: %endif
michael@0: .columnDCT:
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movdqa	xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm1, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm0, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	movdqa	xmm2, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm3, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm2, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	movdqa    xmm4,xmm0
michael@0: 	movdqa    xmm5,xmm0
michael@0: 	punpcklwd xmm4,xmm1
michael@0: 	punpckhwd xmm5,xmm1
michael@0: 	movdqa    xmm0,xmm4
michael@0: 	movdqa    xmm1,xmm5
michael@0: 	pmaddwd   xmm4,[rel PW_F256_F089]	; xmm4=(tmp2L)
michael@0: 	pmaddwd   xmm5,[rel PW_F256_F089]	; xmm5=(tmp2H)
michael@0: 	pmaddwd   xmm0,[rel PW_F106_MF217]	; xmm0=(tmp0L)
michael@0: 	pmaddwd   xmm1,[rel PW_F106_MF217]	; xmm1=(tmp0H)
michael@0: 
michael@0: 	movdqa    xmm6,xmm2
michael@0: 	movdqa    xmm7,xmm2
michael@0: 	punpcklwd xmm6,xmm3
michael@0: 	punpckhwd xmm7,xmm3
michael@0: 	movdqa    xmm2,xmm6
michael@0: 	movdqa    xmm3,xmm7
michael@0: 	pmaddwd   xmm6,[rel PW_MF060_MF050]	; xmm6=(tmp2L)
michael@0: 	pmaddwd   xmm7,[rel PW_MF060_MF050]	; xmm7=(tmp2H)
michael@0: 	pmaddwd   xmm2,[rel PW_F145_MF021]	; xmm2=(tmp0L)
michael@0: 	pmaddwd   xmm3,[rel PW_F145_MF021]	; xmm3=(tmp0H)
michael@0: 
michael@0: 	paddd	xmm6,xmm4		; xmm6=tmp2L
michael@0: 	paddd	xmm7,xmm5		; xmm7=tmp2H
michael@0: 	paddd	xmm2,xmm0		; xmm2=tmp0L
michael@0: 	paddd	xmm3,xmm1		; xmm3=tmp0H
michael@0: 
michael@0: 	movdqa	XMMWORD [wk(0)], xmm2	; wk(0)=tmp0L
michael@0: 	movdqa	XMMWORD [wk(1)], xmm3	; wk(1)=tmp0H
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movdqa	xmm4, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm5, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm0, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm4, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm5, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm0, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	pxor      xmm1,xmm1
michael@0: 	pxor      xmm2,xmm2
michael@0: 	punpcklwd xmm1,xmm4		; xmm1=tmp0L
michael@0: 	punpckhwd xmm2,xmm4		; xmm2=tmp0H
michael@0: 	psrad     xmm1,(16-CONST_BITS-1) ; psrad xmm1,16 & pslld xmm1,CONST_BITS+1
michael@0: 	psrad     xmm2,(16-CONST_BITS-1) ; psrad xmm2,16 & pslld xmm2,CONST_BITS+1
michael@0: 
michael@0: 	movdqa    xmm3,xmm5		; xmm5=in2=z2
michael@0: 	punpcklwd xmm5,xmm0		; xmm0=in6=z3
michael@0: 	punpckhwd xmm3,xmm0
michael@0: 	pmaddwd   xmm5,[rel PW_F184_MF076]	; xmm5=tmp2L
michael@0: 	pmaddwd   xmm3,[rel PW_F184_MF076]	; xmm3=tmp2H
michael@0: 
michael@0: 	movdqa	xmm4,xmm1
michael@0: 	movdqa	xmm0,xmm2
michael@0: 	paddd	xmm1,xmm5		; xmm1=tmp10L
michael@0: 	paddd	xmm2,xmm3		; xmm2=tmp10H
michael@0: 	psubd	xmm4,xmm5		; xmm4=tmp12L
michael@0: 	psubd	xmm0,xmm3		; xmm0=tmp12H
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movdqa	xmm5,xmm1
michael@0: 	movdqa	xmm3,xmm2
michael@0: 	paddd	xmm1,xmm6		; xmm1=data0L
michael@0: 	paddd	xmm2,xmm7		; xmm2=data0H
michael@0: 	psubd	xmm5,xmm6		; xmm5=data3L
michael@0: 	psubd	xmm3,xmm7		; xmm3=data3H
michael@0: 
michael@0: 	movdqa	xmm6,[rel PD_DESCALE_P1_4]	; xmm6=[rel PD_DESCALE_P1_4]
michael@0: 
michael@0: 	paddd	xmm1,xmm6
michael@0: 	paddd	xmm2,xmm6
michael@0: 	psrad	xmm1,DESCALE_P1_4
michael@0: 	psrad	xmm2,DESCALE_P1_4
michael@0: 	paddd	xmm5,xmm6
michael@0: 	paddd	xmm3,xmm6
michael@0: 	psrad	xmm5,DESCALE_P1_4
michael@0: 	psrad	xmm3,DESCALE_P1_4
michael@0: 
michael@0: 	packssdw  xmm1,xmm2		; xmm1=data0=(00 01 02 03 04 05 06 07)
michael@0: 	packssdw  xmm5,xmm3		; xmm5=data3=(30 31 32 33 34 35 36 37)
michael@0: 
michael@0: 	movdqa	xmm7, XMMWORD [wk(0)]	; xmm7=tmp0L
michael@0: 	movdqa	xmm6, XMMWORD [wk(1)]	; xmm6=tmp0H
michael@0: 
michael@0: 	movdqa	xmm2,xmm4
michael@0: 	movdqa	xmm3,xmm0
michael@0: 	paddd	xmm4,xmm7		; xmm4=data1L
michael@0: 	paddd	xmm0,xmm6		; xmm0=data1H
michael@0: 	psubd	xmm2,xmm7		; xmm2=data2L
michael@0: 	psubd	xmm3,xmm6		; xmm3=data2H
michael@0: 
michael@0: 	movdqa	xmm7,[rel PD_DESCALE_P1_4]	; xmm7=[rel PD_DESCALE_P1_4]
michael@0: 
michael@0: 	paddd	xmm4,xmm7
michael@0: 	paddd	xmm0,xmm7
michael@0: 	psrad	xmm4,DESCALE_P1_4
michael@0: 	psrad	xmm0,DESCALE_P1_4
michael@0: 	paddd	xmm2,xmm7
michael@0: 	paddd	xmm3,xmm7
michael@0: 	psrad	xmm2,DESCALE_P1_4
michael@0: 	psrad	xmm3,DESCALE_P1_4
michael@0: 
michael@0: 	packssdw  xmm4,xmm0		; xmm4=data1=(10 11 12 13 14 15 16 17)
michael@0: 	packssdw  xmm2,xmm3		; xmm2=data2=(20 21 22 23 24 25 26 27)
michael@0: 
michael@0: 	movdqa    xmm6,xmm1	; transpose coefficients(phase 1)
michael@0: 	punpcklwd xmm1,xmm4	; xmm1=(00 10 01 11 02 12 03 13)
michael@0: 	punpckhwd xmm6,xmm4	; xmm6=(04 14 05 15 06 16 07 17)
michael@0: 	movdqa    xmm7,xmm2	; transpose coefficients(phase 1)
michael@0: 	punpcklwd xmm2,xmm5	; xmm2=(20 30 21 31 22 32 23 33)
michael@0: 	punpckhwd xmm7,xmm5	; xmm7=(24 34 25 35 26 36 27 37)
michael@0: 
michael@0: 	movdqa    xmm0,xmm1	; transpose coefficients(phase 2)
michael@0: 	punpckldq xmm1,xmm2	; xmm1=[col0 col1]=(00 10 20 30 01 11 21 31)
michael@0: 	punpckhdq xmm0,xmm2	; xmm0=[col2 col3]=(02 12 22 32 03 13 23 33)
michael@0: 	movdqa    xmm3,xmm6	; transpose coefficients(phase 2)
michael@0: 	punpckldq xmm6,xmm7	; xmm6=[col4 col5]=(04 14 24 34 05 15 25 35)
michael@0: 	punpckhdq xmm3,xmm7	; xmm3=[col6 col7]=(06 16 26 36 07 17 27 37)
michael@0: .column_end:
michael@0: 
michael@0: 	; -- Prefetch the next coefficient block
michael@0: 
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
michael@0: 
michael@0: 	; ---- Pass 2: process rows, store into output array.
michael@0: 
michael@0: 	mov	rax, [original_rbp]
michael@0: 	mov	rdi, r12	; (JSAMPROW *)
michael@0: 	mov	rax, r13
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	pxor      xmm4,xmm4
michael@0: 	punpcklwd xmm4,xmm1		; xmm4=tmp0
michael@0: 	psrad     xmm4,(16-CONST_BITS-1) ; psrad xmm4,16 & pslld xmm4,CONST_BITS+1
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	punpckhwd xmm1,xmm0
michael@0: 	punpckhwd xmm6,xmm3
michael@0: 	movdqa    xmm5,xmm1
michael@0: 	movdqa    xmm2,xmm6
michael@0: 	pmaddwd   xmm1,[rel PW_F256_F089]	; xmm1=(tmp2)
michael@0: 	pmaddwd   xmm6,[rel PW_MF060_MF050]	; xmm6=(tmp2)
michael@0: 	pmaddwd   xmm5,[rel PW_F106_MF217]	; xmm5=(tmp0)
michael@0: 	pmaddwd   xmm2,[rel PW_F145_MF021]	; xmm2=(tmp0)
michael@0: 
michael@0: 	paddd     xmm6,xmm1		; xmm6=tmp2
michael@0: 	paddd     xmm2,xmm5		; xmm2=tmp0
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	punpcklwd xmm0,xmm3
michael@0: 	pmaddwd   xmm0,[rel PW_F184_MF076]	; xmm0=tmp2
michael@0: 
michael@0: 	movdqa    xmm7,xmm4
michael@0: 	paddd     xmm4,xmm0		; xmm4=tmp10
michael@0: 	psubd     xmm7,xmm0		; xmm7=tmp12
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movdqa	xmm1,[rel PD_DESCALE_P2_4]	; xmm1=[rel PD_DESCALE_P2_4]
michael@0: 
michael@0: 	movdqa	xmm5,xmm4
michael@0: 	movdqa	xmm3,xmm7
michael@0: 	paddd	xmm4,xmm6		; xmm4=data0=(00 10 20 30)
michael@0: 	paddd	xmm7,xmm2		; xmm7=data1=(01 11 21 31)
michael@0: 	psubd	xmm5,xmm6		; xmm5=data3=(03 13 23 33)
michael@0: 	psubd	xmm3,xmm2		; xmm3=data2=(02 12 22 32)
michael@0: 
michael@0: 	paddd	xmm4,xmm1
michael@0: 	paddd	xmm7,xmm1
michael@0: 	psrad	xmm4,DESCALE_P2_4
michael@0: 	psrad	xmm7,DESCALE_P2_4
michael@0: 	paddd	xmm5,xmm1
michael@0: 	paddd	xmm3,xmm1
michael@0: 	psrad	xmm5,DESCALE_P2_4
michael@0: 	psrad	xmm3,DESCALE_P2_4
michael@0: 
michael@0: 	packssdw  xmm4,xmm3		; xmm4=(00 10 20 30 02 12 22 32)
michael@0: 	packssdw  xmm7,xmm5		; xmm7=(01 11 21 31 03 13 23 33)
michael@0: 
michael@0: 	movdqa    xmm0,xmm4		; transpose coefficients(phase 1)
michael@0: 	punpcklwd xmm4,xmm7		; xmm4=(00 01 10 11 20 21 30 31)
michael@0: 	punpckhwd xmm0,xmm7		; xmm0=(02 03 12 13 22 23 32 33)
michael@0: 
michael@0: 	movdqa    xmm6,xmm4		; transpose coefficients(phase 2)
michael@0: 	punpckldq xmm4,xmm0		; xmm4=(00 01 02 03 10 11 12 13)
michael@0: 	punpckhdq xmm6,xmm0		; xmm6=(20 21 22 23 30 31 32 33)
michael@0: 
michael@0: 	packsswb  xmm4,xmm6		; xmm4=(00 01 02 03 10 11 12 13 20 ..)
michael@0: 	paddb     xmm4,[rel PB_CENTERJSAMP]
michael@0: 
michael@0: 	pshufd    xmm2,xmm4,0x39	; xmm2=(10 11 12 13 20 21 22 23 30 ..)
michael@0: 	pshufd    xmm1,xmm4,0x4E	; xmm1=(20 21 22 23 30 31 32 33 00 ..)
michael@0: 	pshufd    xmm3,xmm4,0x93	; xmm3=(30 31 32 33 00 01 02 03 10 ..)
michael@0: 
michael@0: 	mov	rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	rsi, JSAMPROW [rdi+1*SIZEOF_JSAMPROW]
michael@0: 	movd	XMM_DWORD [rdx+rax*SIZEOF_JSAMPLE], xmm4
michael@0: 	movd	XMM_DWORD [rsi+rax*SIZEOF_JSAMPLE], xmm2
michael@0: 	mov	rdx, JSAMPROW [rdi+2*SIZEOF_JSAMPROW]
michael@0: 	mov	rsi, JSAMPROW [rdi+3*SIZEOF_JSAMPROW]
michael@0: 	movd	XMM_DWORD [rdx+rax*SIZEOF_JSAMPLE], xmm1
michael@0: 	movd	XMM_DWORD [rsi+rax*SIZEOF_JSAMPLE], xmm3
michael@0: 
michael@0: 	uncollect_args
michael@0: 	mov	rsp,rbp		; rsp <- aligned rbp
michael@0: 	pop	rsp		; rsp <- original rbp
michael@0: 	pop	rbp
michael@0: 	ret
michael@0: 
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients,
michael@0: ; producing a reduced-size 2x2 output block.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_2x2_sse2 (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                      JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: ; r10 = void * dct_table
michael@0: ; r11 = JCOEFPTR coef_block
michael@0: ; r12 = JSAMPARRAY output_buf
michael@0: ; r13 = JDIMENSION output_col
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_2x2_sse2)
michael@0: 
michael@0: EXTN(jsimd_idct_2x2_sse2):
michael@0: 	push	rbp
michael@0: 	mov	rax,rsp
michael@0: 	mov	rbp,rsp
michael@0: 	collect_args
michael@0: 	push	rbx
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input.
michael@0: 
michael@0: 	mov	rdx, r10	; quantptr
michael@0: 	mov	rsi, r11		; inptr
michael@0: 
michael@0: 	; | input:                  | result:        |
michael@0: 	; | 00 01 ** 03 ** 05 ** 07 |                |
michael@0: 	; | 10 11 ** 13 ** 15 ** 17 |                |
michael@0: 	; | ** ** ** ** ** ** ** ** |                |
michael@0: 	; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 |
michael@0: 	; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 |
michael@0: 	; | 50 51 ** 53 ** 55 ** 57 |                |
michael@0: 	; | ** ** ** ** ** ** ** ** |                |
michael@0: 	; | 70 71 ** 73 ** 75 ** 77 |                |
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movdqa	xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm1, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm0, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	movdqa	xmm2, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)]
michael@0: 	movdqa	xmm3, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm2, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 	pmullw	xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	; xmm0=(10 11 ** 13 ** 15 ** 17), xmm1=(30 31 ** 33 ** 35 ** 37)
michael@0: 	; xmm2=(50 51 ** 53 ** 55 ** 57), xmm3=(70 71 ** 73 ** 75 ** 77)
michael@0: 
michael@0: 	pcmpeqd   xmm7,xmm7
michael@0: 	pslld     xmm7,WORD_BIT		; xmm7={0x0000 0xFFFF 0x0000 0xFFFF ..}
michael@0: 
michael@0: 	movdqa    xmm4,xmm0		; xmm4=(10 11 ** 13 ** 15 ** 17)
michael@0: 	movdqa    xmm5,xmm2		; xmm5=(50 51 ** 53 ** 55 ** 57)
michael@0: 	punpcklwd xmm4,xmm1		; xmm4=(10 30 11 31 ** ** 13 33)
michael@0: 	punpcklwd xmm5,xmm3		; xmm5=(50 70 51 71 ** ** 53 73)
michael@0: 	pmaddwd   xmm4,[rel PW_F362_MF127]
michael@0: 	pmaddwd   xmm5,[rel PW_F085_MF072]
michael@0: 
michael@0: 	psrld	xmm0,WORD_BIT		; xmm0=(11 -- 13 -- 15 -- 17 --)
michael@0: 	pand	xmm1,xmm7		; xmm1=(-- 31 -- 33 -- 35 -- 37)
michael@0: 	psrld	xmm2,WORD_BIT		; xmm2=(51 -- 53 -- 55 -- 57 --)
michael@0: 	pand	xmm3,xmm7		; xmm3=(-- 71 -- 73 -- 75 -- 77)
michael@0: 	por	xmm0,xmm1		; xmm0=(11 31 13 33 15 35 17 37)
michael@0: 	por	xmm2,xmm3		; xmm2=(51 71 53 73 55 75 57 77)
michael@0: 	pmaddwd	xmm0,[rel PW_F362_MF127]
michael@0: 	pmaddwd	xmm2,[rel PW_F085_MF072]
michael@0: 
michael@0: 	paddd	xmm4,xmm5		; xmm4=tmp0[col0 col1 **** col3]
michael@0: 	paddd	xmm0,xmm2		; xmm0=tmp0[col1 col3 col5 col7]
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movdqa	xmm6, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)]
michael@0: 	pmullw	xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)]
michael@0: 
michael@0: 	; xmm6=(00 01 ** 03 ** 05 ** 07)
michael@0: 
michael@0: 	movdqa	xmm1,xmm6		; xmm1=(00 01 ** 03 ** 05 ** 07)
michael@0: 	pslld	xmm6,WORD_BIT		; xmm6=(-- 00 -- ** -- ** -- **)
michael@0: 	pand	xmm1,xmm7		; xmm1=(-- 01 -- 03 -- 05 -- 07)
michael@0: 	psrad	xmm6,(WORD_BIT-CONST_BITS-2) ; xmm6=tmp10[col0 **** **** ****]
michael@0: 	psrad	xmm1,(WORD_BIT-CONST_BITS-2) ; xmm1=tmp10[col1 col3 col5 col7]
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movdqa	xmm3,xmm6
michael@0: 	movdqa	xmm5,xmm1
michael@0: 	paddd	xmm6,xmm4	; xmm6=data0[col0 **** **** ****]=(A0 ** ** **)
michael@0: 	paddd	xmm1,xmm0	; xmm1=data0[col1 col3 col5 col7]=(A1 A3 A5 A7)
michael@0: 	psubd	xmm3,xmm4	; xmm3=data1[col0 **** **** ****]=(B0 ** ** **)
michael@0: 	psubd	xmm5,xmm0	; xmm5=data1[col1 col3 col5 col7]=(B1 B3 B5 B7)
michael@0: 
michael@0: 	movdqa	xmm2,[rel PD_DESCALE_P1_2]	; xmm2=[rel PD_DESCALE_P1_2]
michael@0: 
michael@0: 	punpckldq  xmm6,xmm3		; xmm6=(A0 B0 ** **)
michael@0: 
michael@0: 	movdqa     xmm7,xmm1
michael@0: 	punpcklqdq xmm1,xmm5		; xmm1=(A1 A3 B1 B3)
michael@0: 	punpckhqdq xmm7,xmm5		; xmm7=(A5 A7 B5 B7)
michael@0: 
michael@0: 	paddd	xmm6,xmm2
michael@0: 	psrad	xmm6,DESCALE_P1_2
michael@0: 
michael@0: 	paddd	xmm1,xmm2
michael@0: 	paddd	xmm7,xmm2
michael@0: 	psrad	xmm1,DESCALE_P1_2
michael@0: 	psrad	xmm7,DESCALE_P1_2
michael@0: 
michael@0: 	; -- Prefetch the next coefficient block
michael@0: 
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
michael@0: 	prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
michael@0: 
michael@0: 	; ---- Pass 2: process rows, store into output array.
michael@0: 
michael@0: 	mov	rdi, r12	; (JSAMPROW *)
michael@0: 	mov	rax, r13
michael@0: 
michael@0: 	; | input:| result:|
michael@0: 	; | A0 B0 |        |
michael@0: 	; | A1 B1 | C0 C1  |
michael@0: 	; | A3 B3 | D0 D1  |
michael@0: 	; | A5 B5 |        |
michael@0: 	; | A7 B7 |        |
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	packssdw  xmm1,xmm1		; xmm1=(A1 A3 B1 B3 A1 A3 B1 B3)
michael@0: 	packssdw  xmm7,xmm7		; xmm7=(A5 A7 B5 B7 A5 A7 B5 B7)
michael@0: 	pmaddwd   xmm1,[rel PW_F362_MF127]
michael@0: 	pmaddwd   xmm7,[rel PW_F085_MF072]
michael@0: 
michael@0: 	paddd     xmm1,xmm7		; xmm1=tmp0[row0 row1 row0 row1]
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	pslld     xmm6,(CONST_BITS+2)	; xmm6=tmp10[row0 row1 **** ****]
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	movdqa    xmm4,xmm6
michael@0: 	paddd     xmm6,xmm1	; xmm6=data0[row0 row1 **** ****]=(C0 C1 ** **)
michael@0: 	psubd     xmm4,xmm1	; xmm4=data1[row0 row1 **** ****]=(D0 D1 ** **)
michael@0: 
michael@0: 	punpckldq xmm6,xmm4	; xmm6=(C0 D0 C1 D1)
michael@0: 
michael@0: 	paddd     xmm6,[rel PD_DESCALE_P2_2]
michael@0: 	psrad     xmm6,DESCALE_P2_2
michael@0: 
michael@0: 	packssdw  xmm6,xmm6		; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1)
michael@0: 	packsswb  xmm6,xmm6		; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1 ..)
michael@0: 	paddb     xmm6,[rel PB_CENTERJSAMP]
michael@0: 
michael@0: 	pextrw	ebx,xmm6,0x00		; ebx=(C0 D0 -- --)
michael@0: 	pextrw	ecx,xmm6,0x01		; ecx=(C1 D1 -- --)
michael@0: 
michael@0: 	mov	rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	rsi, JSAMPROW [rdi+1*SIZEOF_JSAMPROW]
michael@0: 	mov	WORD [rdx+rax*SIZEOF_JSAMPLE], bx
michael@0: 	mov	WORD [rsi+rax*SIZEOF_JSAMPLE], cx
michael@0: 
michael@0: 	pop	rbx
michael@0: 	uncollect_args
michael@0: 	pop	rbp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16