michael@0: ;
michael@0: ; jcqntsse.asm - sample data conversion and quantization (SSE & MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Load data into workspace, applying unsigned->signed conversion
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_convsamp_float_sse (JSAMPARRAY sample_data, JDIMENSION start_col,
michael@0: ;                           FAST_FLOAT * workspace);
michael@0: ;
michael@0: 
michael@0: %define sample_data	ebp+8		; JSAMPARRAY sample_data
michael@0: %define start_col	ebp+12		; JDIMENSION start_col
michael@0: %define workspace	ebp+16		; FAST_FLOAT * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_convsamp_float_sse)
michael@0: 
michael@0: EXTN(jsimd_convsamp_float_sse):
michael@0: 	push	ebp
michael@0: 	mov	ebp,esp
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	pcmpeqw  mm7,mm7
michael@0: 	psllw    mm7,7
michael@0: 	packsswb mm7,mm7		; mm7 = PB_CENTERJSAMPLE (0x808080..)
michael@0: 
michael@0: 	mov	esi, JSAMPARRAY [sample_data]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [start_col]
michael@0: 	mov	edi, POINTER [workspace]	; (DCTELEM *)
michael@0: 	mov	ecx, DCTSIZE/2
michael@0: 	alignx	16,7
michael@0: .convloop:
michael@0: 	mov	ebx, JSAMPROW [esi+0*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 	mov	edx, JSAMPROW [esi+1*SIZEOF_JSAMPROW]	; (JSAMPLE *)
michael@0: 
michael@0: 	movq	mm0, MMWORD [ebx+eax*SIZEOF_JSAMPLE]
michael@0: 	movq	mm1, MMWORD [edx+eax*SIZEOF_JSAMPLE]
michael@0: 
michael@0: 	psubb	mm0,mm7				; mm0=(01234567)
michael@0: 	psubb	mm1,mm7				; mm1=(89ABCDEF)
michael@0: 
michael@0: 	punpcklbw mm2,mm0			; mm2=(*0*1*2*3)
michael@0: 	punpckhbw mm0,mm0			; mm0=(*4*5*6*7)
michael@0: 	punpcklbw mm3,mm1			; mm3=(*8*9*A*B)
michael@0: 	punpckhbw mm1,mm1			; mm1=(*C*D*E*F)
michael@0: 
michael@0: 	punpcklwd mm4,mm2			; mm4=(***0***1)
michael@0: 	punpckhwd mm2,mm2			; mm2=(***2***3)
michael@0: 	punpcklwd mm5,mm0			; mm5=(***4***5)
michael@0: 	punpckhwd mm0,mm0			; mm0=(***6***7)
michael@0: 
michael@0: 	psrad     mm4,(DWORD_BIT-BYTE_BIT)	; mm4=(01)
michael@0: 	psrad     mm2,(DWORD_BIT-BYTE_BIT)	; mm2=(23)
michael@0: 	cvtpi2ps  xmm0,mm4			; xmm0=(01**)
michael@0: 	cvtpi2ps  xmm1,mm2			; xmm1=(23**)
michael@0: 	psrad     mm5,(DWORD_BIT-BYTE_BIT)	; mm5=(45)
michael@0: 	psrad     mm0,(DWORD_BIT-BYTE_BIT)	; mm0=(67)
michael@0: 	cvtpi2ps  xmm2,mm5			; xmm2=(45**)
michael@0: 	cvtpi2ps  xmm3,mm0			; xmm3=(67**)
michael@0: 
michael@0: 	punpcklwd mm6,mm3			; mm6=(***8***9)
michael@0: 	punpckhwd mm3,mm3			; mm3=(***A***B)
michael@0: 	punpcklwd mm4,mm1			; mm4=(***C***D)
michael@0: 	punpckhwd mm1,mm1			; mm1=(***E***F)
michael@0: 
michael@0: 	psrad     mm6,(DWORD_BIT-BYTE_BIT)	; mm6=(89)
michael@0: 	psrad     mm3,(DWORD_BIT-BYTE_BIT)	; mm3=(AB)
michael@0: 	cvtpi2ps  xmm4,mm6			; xmm4=(89**)
michael@0: 	cvtpi2ps  xmm5,mm3			; xmm5=(AB**)
michael@0: 	psrad     mm4,(DWORD_BIT-BYTE_BIT)	; mm4=(CD)
michael@0: 	psrad     mm1,(DWORD_BIT-BYTE_BIT)	; mm1=(EF)
michael@0: 	cvtpi2ps  xmm6,mm4			; xmm6=(CD**)
michael@0: 	cvtpi2ps  xmm7,mm1			; xmm7=(EF**)
michael@0: 
michael@0: 	movlhps   xmm0,xmm1			; xmm0=(0123)
michael@0: 	movlhps   xmm2,xmm3			; xmm2=(4567)
michael@0: 	movlhps   xmm4,xmm5			; xmm4=(89AB)
michael@0: 	movlhps   xmm6,xmm7			; xmm6=(CDEF)
michael@0: 
michael@0: 	movaps	XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0: 	movaps	XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm2
michael@0: 	movaps	XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm4
michael@0: 	movaps	XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm6
michael@0: 
michael@0: 	add	esi, byte 2*SIZEOF_JSAMPROW
michael@0: 	add	edi, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0: 	dec	ecx
michael@0: 	jnz	near .convloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: ;
michael@0: ; Quantize/descale the coefficients, and store into coef_block
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_quantize_float_sse (JCOEFPTR coef_block, FAST_FLOAT * divisors,
michael@0: ;                           FAST_FLOAT * workspace);
michael@0: ;
michael@0: 
michael@0: %define coef_block	ebp+8		; JCOEFPTR coef_block
michael@0: %define divisors	ebp+12		; FAST_FLOAT * divisors
michael@0: %define workspace	ebp+16		; FAST_FLOAT * workspace
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_quantize_float_sse)
michael@0: 
michael@0: EXTN(jsimd_quantize_float_sse):
michael@0: 	push	ebp
michael@0: 	mov	ebp,esp
michael@0: ;	push	ebx		; unused
michael@0: ;	push	ecx		; unused
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	mov	esi, POINTER [workspace]
michael@0: 	mov	edx, POINTER [divisors]
michael@0: 	mov	edi, JCOEFPTR [coef_block]
michael@0: 	mov	eax, DCTSIZE2/16
michael@0: 	alignx	16,7
michael@0: .quantloop:
michael@0: 	movaps	xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movaps	xmm1, XMMWORD [XMMBLOCK(0,1,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	mulps	xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	mulps	xmm1, XMMWORD [XMMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movaps	xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movaps	xmm3, XMMWORD [XMMBLOCK(1,1,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	mulps	xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	mulps	xmm3, XMMWORD [XMMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	movhlps  xmm4,xmm0
michael@0: 	movhlps  xmm5,xmm1
michael@0: 
michael@0: 	cvtps2pi mm0,xmm0
michael@0: 	cvtps2pi mm1,xmm1
michael@0: 	cvtps2pi mm4,xmm4
michael@0: 	cvtps2pi mm5,xmm5
michael@0: 
michael@0: 	movhlps  xmm6,xmm2
michael@0: 	movhlps  xmm7,xmm3
michael@0: 
michael@0: 	cvtps2pi mm2,xmm2
michael@0: 	cvtps2pi mm3,xmm3
michael@0: 	cvtps2pi mm6,xmm6
michael@0: 	cvtps2pi mm7,xmm7
michael@0: 
michael@0: 	packssdw mm0,mm4
michael@0: 	packssdw mm1,mm5
michael@0: 	packssdw mm2,mm6
michael@0: 	packssdw mm3,mm7
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm3
michael@0: 
michael@0: 	add	esi, byte 16*SIZEOF_FAST_FLOAT
michael@0: 	add	edx, byte 16*SIZEOF_FAST_FLOAT
michael@0: 	add	edi, byte 16*SIZEOF_JCOEF
michael@0: 	dec	eax
michael@0: 	jnz	short .quantloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; unused
michael@0: ;	pop	ebx		; unused
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16