michael@0: ;
michael@0: ; jf3dnflt.asm - floating-point FDCT (3DNow!)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains a floating-point implementation of the forward DCT
michael@0: ; (Discrete Cosine Transform). The following code is based directly on
michael@0: ; the IJG's original jfdctflt.c; see the jfdctflt.c for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_fdct_float_3dnow)
michael@0: 
michael@0: EXTN(jconst_fdct_float_3dnow):
michael@0: 
michael@0: PD_0_382	times 2 dd  0.382683432365089771728460
michael@0: PD_0_707	times 2 dd  0.707106781186547524400844
michael@0: PD_0_541	times 2 dd  0.541196100146196984399723
michael@0: PD_1_306	times 2 dd  1.306562964876376527856643
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Perform the forward DCT on one block of samples.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_fdct_float_3dnow (FAST_FLOAT * data)
michael@0: ;
michael@0: 
michael@0: %define data(b)		(b)+8		; FAST_FLOAT * data
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_fdct_float_3dnow)
michael@0: 
michael@0: EXTN(jsimd_fdct_float_3dnow):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [wk(0)]
michael@0: 	pushpic	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: ;	push	esi		; unused
michael@0: ;	push	edi		; unused
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process rows.
michael@0: 
michael@0: 	mov	edx, POINTER [data(eax)]	; (FAST_FLOAT *)
michael@0: 	mov	ecx, DCTSIZE/2
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(0,3,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(1,3,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	; mm0=(00 01), mm1=(10 11), mm2=(06 07), mm3=(16 17)
michael@0: 
michael@0: 	movq      mm4,mm0		; transpose coefficients
michael@0: 	punpckldq mm0,mm1		; mm0=(00 10)=data0
michael@0: 	punpckhdq mm4,mm1		; mm4=(01 11)=data1
michael@0: 	movq      mm5,mm2		; transpose coefficients
michael@0: 	punpckldq mm2,mm3		; mm2=(06 16)=data6
michael@0: 	punpckhdq mm5,mm3		; mm5=(07 17)=data7
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	pfsub	mm4,mm2			; mm4=data1-data6=tmp6
michael@0: 	pfsub	mm0,mm5			; mm0=data0-data7=tmp7
michael@0: 	pfadd	mm6,mm2			; mm6=data1+data6=tmp1
michael@0: 	pfadd	mm7,mm5			; mm7=data0+data7=tmp0
michael@0: 
michael@0: 	movq	mm1, MMWORD [MMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(0,2,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(1,2,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	; mm1=(02 03), mm3=(12 13), mm2=(04 05), mm5=(14 15)
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm4	; wk(0)=tmp6
michael@0: 	movq	MMWORD [wk(1)], mm0	; wk(1)=tmp7
michael@0: 
michael@0: 	movq      mm4,mm1		; transpose coefficients
michael@0: 	punpckldq mm1,mm3		; mm1=(02 12)=data2
michael@0: 	punpckhdq mm4,mm3		; mm4=(03 13)=data3
michael@0: 	movq      mm0,mm2		; transpose coefficients
michael@0: 	punpckldq mm2,mm5		; mm2=(04 14)=data4
michael@0: 	punpckhdq mm0,mm5		; mm0=(05 15)=data5
michael@0: 
michael@0: 	movq	mm3,mm4
michael@0: 	movq	mm5,mm1
michael@0: 	pfadd	mm4,mm2			; mm4=data3+data4=tmp3
michael@0: 	pfadd	mm1,mm0			; mm1=data2+data5=tmp2
michael@0: 	pfsub	mm3,mm2			; mm3=data3-data4=tmp4
michael@0: 	pfsub	mm5,mm0			; mm5=data2-data5=tmp5
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm2,mm7
michael@0: 	movq	mm0,mm6
michael@0: 	pfsub	mm7,mm4			; mm7=tmp13
michael@0: 	pfsub	mm6,mm1			; mm6=tmp12
michael@0: 	pfadd	mm2,mm4			; mm2=tmp10
michael@0: 	pfadd	mm0,mm1			; mm0=tmp11
michael@0: 
michael@0: 	pfadd	mm6,mm7
michael@0: 	pfmul	mm6,[GOTOFF(ebx,PD_0_707)] ; mm6=z1
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm1,mm7
michael@0: 	pfsub	mm2,mm0			; mm2=data4
michael@0: 	pfsub	mm7,mm6			; mm7=data6
michael@0: 	pfadd	mm4,mm0			; mm4=data0
michael@0: 	pfadd	mm1,mm6			; mm1=data2
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,2,edx,SIZEOF_FAST_FLOAT)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(0,3,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm0, MMWORD [wk(0)]	; mm0=tmp6
michael@0: 	movq	mm6, MMWORD [wk(1)]	; mm6=tmp7
michael@0: 
michael@0: 	pfadd	mm3,mm5			; mm3=tmp10
michael@0: 	pfadd	mm5,mm0			; mm5=tmp11
michael@0: 	pfadd	mm0,mm6			; mm0=tmp12, mm6=tmp7
michael@0: 
michael@0: 	pfmul	mm5,[GOTOFF(ebx,PD_0_707)] ; mm5=z3
michael@0: 
michael@0: 	movq	mm2,mm3			; mm2=tmp10
michael@0: 	pfsub	mm3,mm0
michael@0: 	pfmul	mm3,[GOTOFF(ebx,PD_0_382)] ; mm3=z5
michael@0: 	pfmul	mm2,[GOTOFF(ebx,PD_0_541)] ; mm2=MULTIPLY(tmp10,FIX_0_54119610)
michael@0: 	pfmul	mm0,[GOTOFF(ebx,PD_1_306)] ; mm0=MULTIPLY(tmp12,FIX_1_30656296)
michael@0: 	pfadd	mm2,mm3			; mm2=z2
michael@0: 	pfadd	mm0,mm3			; mm0=z4
michael@0: 
michael@0: 	movq	mm7,mm6
michael@0: 	pfsub	mm6,mm5			; mm6=z13
michael@0: 	pfadd	mm7,mm5			; mm7=z11
michael@0: 
michael@0: 	movq	mm4,mm6
michael@0: 	movq	mm1,mm7
michael@0: 	pfsub	mm6,mm2			; mm6=data3
michael@0: 	pfsub	mm7,mm0			; mm7=data7
michael@0: 	pfadd	mm4,mm2			; mm4=data5
michael@0: 	pfadd	mm1,mm0			; mm1=data1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(1,3,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(1,2,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0: 
michael@0: 	add	edx, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0: 	dec	ecx
michael@0: 	jnz	near .rowloop
michael@0: 
michael@0: 	; ---- Pass 2: process columns.
michael@0: 
michael@0: 	mov	edx, POINTER [data(eax)]	; (FAST_FLOAT *)
michael@0: 	mov	ecx, DCTSIZE/2
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	; mm0=(00 10), mm1=(01 11), mm2=(60 70), mm3=(61 71)
michael@0: 
michael@0: 	movq      mm4,mm0		; transpose coefficients
michael@0: 	punpckldq mm0,mm1		; mm0=(00 01)=data0
michael@0: 	punpckhdq mm4,mm1		; mm4=(10 11)=data1
michael@0: 	movq      mm5,mm2		; transpose coefficients
michael@0: 	punpckldq mm2,mm3		; mm2=(60 61)=data6
michael@0: 	punpckhdq mm5,mm3		; mm5=(70 71)=data7
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	pfsub	mm4,mm2			; mm4=data1-data6=tmp6
michael@0: 	pfsub	mm0,mm5			; mm0=data0-data7=tmp7
michael@0: 	pfadd	mm6,mm2			; mm6=data1+data6=tmp1
michael@0: 	pfadd	mm7,mm5			; mm7=data0+data7=tmp0
michael@0: 
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	; mm1=(20 30), mm3=(21 31), mm2=(40 50), mm5=(41 51)
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm4	; wk(0)=tmp6
michael@0: 	movq	MMWORD [wk(1)], mm0	; wk(1)=tmp7
michael@0: 
michael@0: 	movq      mm4,mm1		; transpose coefficients
michael@0: 	punpckldq mm1,mm3		; mm1=(20 21)=data2
michael@0: 	punpckhdq mm4,mm3		; mm4=(30 31)=data3
michael@0: 	movq      mm0,mm2		; transpose coefficients
michael@0: 	punpckldq mm2,mm5		; mm2=(40 41)=data4
michael@0: 	punpckhdq mm0,mm5		; mm0=(50 51)=data5
michael@0: 
michael@0: 	movq	mm3,mm4
michael@0: 	movq	mm5,mm1
michael@0: 	pfadd	mm4,mm2			; mm4=data3+data4=tmp3
michael@0: 	pfadd	mm1,mm0			; mm1=data2+data5=tmp2
michael@0: 	pfsub	mm3,mm2			; mm3=data3-data4=tmp4
michael@0: 	pfsub	mm5,mm0			; mm5=data2-data5=tmp5
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm2,mm7
michael@0: 	movq	mm0,mm6
michael@0: 	pfsub	mm7,mm4			; mm7=tmp13
michael@0: 	pfsub	mm6,mm1			; mm6=tmp12
michael@0: 	pfadd	mm2,mm4			; mm2=tmp10
michael@0: 	pfadd	mm0,mm1			; mm0=tmp11
michael@0: 
michael@0: 	pfadd	mm6,mm7
michael@0: 	pfmul	mm6,[GOTOFF(ebx,PD_0_707)] ; mm6=z1
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm1,mm7
michael@0: 	pfsub	mm2,mm0			; mm2=data4
michael@0: 	pfsub	mm7,mm6			; mm7=data6
michael@0: 	pfadd	mm4,mm0			; mm4=data0
michael@0: 	pfadd	mm1,mm6			; mm1=data2
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm0, MMWORD [wk(0)]	; mm0=tmp6
michael@0: 	movq	mm6, MMWORD [wk(1)]	; mm6=tmp7
michael@0: 
michael@0: 	pfadd	mm3,mm5			; mm3=tmp10
michael@0: 	pfadd	mm5,mm0			; mm5=tmp11
michael@0: 	pfadd	mm0,mm6			; mm0=tmp12, mm6=tmp7
michael@0: 
michael@0: 	pfmul	mm5,[GOTOFF(ebx,PD_0_707)] ; mm5=z3
michael@0: 
michael@0: 	movq	mm2,mm3			; mm2=tmp10
michael@0: 	pfsub	mm3,mm0
michael@0: 	pfmul	mm3,[GOTOFF(ebx,PD_0_382)] ; mm3=z5
michael@0: 	pfmul	mm2,[GOTOFF(ebx,PD_0_541)] ; mm2=MULTIPLY(tmp10,FIX_0_54119610)
michael@0: 	pfmul	mm0,[GOTOFF(ebx,PD_1_306)] ; mm0=MULTIPLY(tmp12,FIX_1_30656296)
michael@0: 	pfadd	mm2,mm3			; mm2=z2
michael@0: 	pfadd	mm0,mm3			; mm0=z4
michael@0: 
michael@0: 	movq	mm7,mm6
michael@0: 	pfsub	mm6,mm5			; mm6=z13
michael@0: 	pfadd	mm7,mm5			; mm7=z11
michael@0: 
michael@0: 	movq	mm4,mm6
michael@0: 	movq	mm1,mm7
michael@0: 	pfsub	mm6,mm2			; mm6=data3
michael@0: 	pfsub	mm7,mm0			; mm7=data7
michael@0: 	pfadd	mm4,mm2			; mm4=data5
michael@0: 	pfadd	mm1,mm0			; mm1=data1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0: 
michael@0: 	add	edx, byte 2*SIZEOF_FAST_FLOAT
michael@0: 	dec	ecx
michael@0: 	jnz	near .columnloop
michael@0: 
michael@0: 	femms		; empty MMX/3DNow! state
michael@0: 
michael@0: ;	pop	edi		; unused
michael@0: ;	pop	esi		; unused
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	poppic	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16