michael@0: ;
michael@0: ; ji3dnflt.asm - floating-point IDCT (3DNow! & MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains a floating-point implementation of the inverse DCT
michael@0: ; (Discrete Cosine Transform). The following code is based directly on
michael@0: ; the IJG's original jidctflt.c; see the jidctflt.c for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_idct_float_3dnow)
michael@0: 
michael@0: EXTN(jconst_idct_float_3dnow):
michael@0: 
michael@0: PD_1_414	times 2 dd  1.414213562373095048801689
michael@0: PD_1_847	times 2 dd  1.847759065022573512256366
michael@0: PD_1_082	times 2 dd  1.082392200292393968799446
michael@0: PD_2_613	times 2 dd  2.613125929752753055713286
michael@0: PD_RNDINT_MAGIC	times 2 dd  100663296.0	; (float)(0x00C00000 << 3)
michael@0: PB_CENTERJSAMP	times 8 db  CENTERJSAMPLE
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_float_3dnow (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                         JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: %define dct_table(b)	(b)+8			; void * dct_table
michael@0: %define coef_block(b)	(b)+12		; JCOEFPTR coef_block
michael@0: %define output_buf(b)	(b)+16		; JSAMPARRAY output_buf
michael@0: %define output_col(b)	(b)+20		; JDIMENSION output_col
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: %define workspace	wk(0)-DCTSIZE2*SIZEOF_FAST_FLOAT
michael@0: 					; FAST_FLOAT workspace[DCTSIZE2]
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_float_3dnow)
michael@0: 
michael@0: EXTN(jsimd_idct_float_3dnow):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [workspace]
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input, store into work array.
michael@0: 
michael@0: ;	mov	eax, [original_ebp]
michael@0: 	mov	edx, POINTER [dct_table(eax)]	; quantptr
michael@0: 	mov	esi, JCOEFPTR [coef_block(eax)]		; inptr
michael@0: 	lea	edi, [workspace]			; FAST_FLOAT * wsptr
michael@0: 	mov	ecx, DCTSIZE/2				; ctr
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: %ifndef NO_ZERO_COLUMN_TEST_FLOAT_3DNOW
michael@0: 	mov	eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	pushpic	ebx		; save GOT address
michael@0: 	mov	ebx, DWORD [DWBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	mov	eax, DWORD [DWBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	ebx, DWORD [DWBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	eax, DWORD [DWBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	ebx, DWORD [DWBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	eax,ebx
michael@0: 	poppic	ebx		; restore GOT address
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	; -- AC terms all zero
michael@0: 
michael@0: 	movd      mm0, DWORD [DWBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	punpcklwd mm0,mm0
michael@0: 	psrad     mm0,(DWORD_BIT-WORD_BIT)
michael@0: 	pi2fd     mm0,mm0
michael@0: 
michael@0: 	pfmul     mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 
michael@0: 	movq      mm1,mm0
michael@0: 	punpckldq mm0,mm0
michael@0: 	punpckhdq mm1,mm1
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,2,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,3,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,2,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,3,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 	jmp	near .nextcolumn
michael@0: 	alignx	16,7
michael@0: %endif
michael@0: .columnDCT:
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movd      mm0, DWORD [DWBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm1, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm2, DWORD [DWBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm3, DWORD [DWBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	punpcklwd mm0,mm0
michael@0: 	punpcklwd mm1,mm1
michael@0: 	psrad     mm0,(DWORD_BIT-WORD_BIT)
michael@0: 	psrad     mm1,(DWORD_BIT-WORD_BIT)
michael@0: 	pi2fd     mm0,mm0
michael@0: 	pi2fd     mm1,mm1
michael@0: 
michael@0: 	pfmul     mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 	pfmul     mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 
michael@0: 	punpcklwd mm2,mm2
michael@0: 	punpcklwd mm3,mm3
michael@0: 	psrad     mm2,(DWORD_BIT-WORD_BIT)
michael@0: 	psrad     mm3,(DWORD_BIT-WORD_BIT)
michael@0: 	pi2fd     mm2,mm2
michael@0: 	pi2fd     mm3,mm3
michael@0: 
michael@0: 	pfmul     mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 	pfmul     mm3, MMWORD [MMBLOCK(6,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 
michael@0: 	movq	mm4,mm0
michael@0: 	movq	mm5,mm1
michael@0: 	pfsub	mm0,mm2			; mm0=tmp11
michael@0: 	pfsub	mm1,mm3
michael@0: 	pfadd	mm4,mm2			; mm4=tmp10
michael@0: 	pfadd	mm5,mm3			; mm5=tmp13
michael@0: 
michael@0: 	pfmul	mm1,[GOTOFF(ebx,PD_1_414)]
michael@0: 	pfsub	mm1,mm5			; mm1=tmp12
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	pfsub	mm4,mm5			; mm4=tmp3
michael@0: 	pfsub	mm0,mm1			; mm0=tmp2
michael@0: 	pfadd	mm6,mm5			; mm6=tmp0
michael@0: 	pfadd	mm7,mm1			; mm7=tmp1
michael@0: 
michael@0: 	movq	MMWORD [wk(1)], mm4	; tmp3
michael@0: 	movq	MMWORD [wk(0)], mm0	; tmp2
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movd      mm2, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm3, DWORD [DWBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm5, DWORD [DWBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movd      mm1, DWORD [DWBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	punpcklwd mm2,mm2
michael@0: 	punpcklwd mm3,mm3
michael@0: 	psrad     mm2,(DWORD_BIT-WORD_BIT)
michael@0: 	psrad     mm3,(DWORD_BIT-WORD_BIT)
michael@0: 	pi2fd     mm2,mm2
michael@0: 	pi2fd     mm3,mm3
michael@0: 
michael@0: 	pfmul     mm2, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 	pfmul     mm3, MMWORD [MMBLOCK(3,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 
michael@0: 	punpcklwd mm5,mm5
michael@0: 	punpcklwd mm1,mm1
michael@0: 	psrad     mm5,(DWORD_BIT-WORD_BIT)
michael@0: 	psrad     mm1,(DWORD_BIT-WORD_BIT)
michael@0: 	pi2fd     mm5,mm5
michael@0: 	pi2fd     mm1,mm1
michael@0: 
michael@0: 	pfmul     mm5, MMWORD [MMBLOCK(5,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 	pfmul     mm1, MMWORD [MMBLOCK(7,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm0,mm5
michael@0: 	pfadd	mm2,mm1			; mm2=z11
michael@0: 	pfadd	mm5,mm3			; mm5=z13
michael@0: 	pfsub	mm4,mm1			; mm4=z12
michael@0: 	pfsub	mm0,mm3			; mm0=z10
michael@0: 
michael@0: 	movq	mm1,mm2
michael@0: 	pfsub	mm2,mm5
michael@0: 	pfadd	mm1,mm5			; mm1=tmp7
michael@0: 
michael@0: 	pfmul	mm2,[GOTOFF(ebx,PD_1_414)]	; mm2=tmp11
michael@0: 
michael@0: 	movq	mm3,mm0
michael@0: 	pfadd	mm0,mm4
michael@0: 	pfmul	mm0,[GOTOFF(ebx,PD_1_847)]	; mm0=z5
michael@0: 	pfmul	mm3,[GOTOFF(ebx,PD_2_613)]	; mm3=(z10 * 2.613125930)
michael@0: 	pfmul	mm4,[GOTOFF(ebx,PD_1_082)]	; mm4=(z12 * 1.082392200)
michael@0: 	pfsubr	mm3,mm0			; mm3=tmp12
michael@0: 	pfsub	mm4,mm0			; mm4=tmp10
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	pfsub	mm3,mm1			; mm3=tmp6
michael@0: 	movq	mm5,mm6
michael@0: 	movq	mm0,mm7
michael@0: 	pfadd	mm6,mm1			; mm6=data0=(00 01)
michael@0: 	pfadd	mm7,mm3			; mm7=data1=(10 11)
michael@0: 	pfsub	mm5,mm1			; mm5=data7=(70 71)
michael@0: 	pfsub	mm0,mm3			; mm0=data6=(60 61)
michael@0: 	pfsub	mm2,mm3			; mm2=tmp5
michael@0: 
michael@0: 	movq      mm1,mm6		; transpose coefficients
michael@0: 	punpckldq mm6,mm7		; mm6=(00 10)
michael@0: 	punpckhdq mm1,mm7		; mm1=(01 11)
michael@0: 	movq      mm3,mm0		; transpose coefficients
michael@0: 	punpckldq mm0,mm5		; mm0=(60 70)
michael@0: 	punpckhdq mm3,mm5		; mm3=(61 71)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(0,3,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(1,3,edi,SIZEOF_FAST_FLOAT)], mm3
michael@0: 
michael@0: 	movq	mm7, MMWORD [wk(0)]	; mm7=tmp2
michael@0: 	movq	mm5, MMWORD [wk(1)]	; mm5=tmp3
michael@0: 
michael@0: 	pfadd	mm4,mm2			; mm4=tmp4
michael@0: 	movq	mm6,mm7
michael@0: 	movq	mm1,mm5
michael@0: 	pfadd	mm7,mm2			; mm7=data2=(20 21)
michael@0: 	pfadd	mm5,mm4			; mm5=data4=(40 41)
michael@0: 	pfsub	mm6,mm2			; mm6=data5=(50 51)
michael@0: 	pfsub	mm1,mm4			; mm1=data3=(30 31)
michael@0: 
michael@0: 	movq      mm0,mm7		; transpose coefficients
michael@0: 	punpckldq mm7,mm1		; mm7=(20 30)
michael@0: 	punpckhdq mm0,mm1		; mm0=(21 31)
michael@0: 	movq      mm3,mm5		; transpose coefficients
michael@0: 	punpckldq mm5,mm6		; mm5=(40 50)
michael@0: 	punpckhdq mm3,mm6		; mm3=(41 51)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], mm7
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,2,edi,SIZEOF_FAST_FLOAT)], mm5
michael@0: 	movq	MMWORD [MMBLOCK(1,2,edi,SIZEOF_FAST_FLOAT)], mm3
michael@0: 
michael@0: .nextcolumn:
michael@0: 	add	esi, byte 2*SIZEOF_JCOEF		; coef_block
michael@0: 	add	edx, byte 2*SIZEOF_FLOAT_MULT_TYPE	; quantptr
michael@0: 	add	edi, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT	; wsptr
michael@0: 	dec	ecx					; ctr
michael@0: 	jnz	near .columnloop
michael@0: 
michael@0: 	; -- Prefetch the next coefficient block
michael@0: 
michael@0: 	prefetch [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 0*32]
michael@0: 	prefetch [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 1*32]
michael@0: 	prefetch [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 2*32]
michael@0: 	prefetch [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 3*32]
michael@0: 
michael@0: 	; ---- Pass 2: process rows from work array, store into output array.
michael@0: 
michael@0: 	mov	eax, [original_ebp]
michael@0: 	lea	esi, [workspace]			; FAST_FLOAT * wsptr
michael@0: 	mov	edi, JSAMPARRAY [output_buf(eax)]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [output_col(eax)]
michael@0: 	mov	ecx, DCTSIZE/2				; ctr
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	movq	mm4,mm0
michael@0: 	movq	mm5,mm1
michael@0: 	pfsub	mm0,mm2			; mm0=tmp11
michael@0: 	pfsub	mm1,mm3
michael@0: 	pfadd	mm4,mm2			; mm4=tmp10
michael@0: 	pfadd	mm5,mm3			; mm5=tmp13
michael@0: 
michael@0: 	pfmul	mm1,[GOTOFF(ebx,PD_1_414)]
michael@0: 	pfsub	mm1,mm5			; mm1=tmp12
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	pfsub	mm4,mm5			; mm4=tmp3
michael@0: 	pfsub	mm0,mm1			; mm0=tmp2
michael@0: 	pfadd	mm6,mm5			; mm6=tmp0
michael@0: 	pfadd	mm7,mm1			; mm7=tmp1
michael@0: 
michael@0: 	movq	MMWORD [wk(1)], mm4	; tmp3
michael@0: 	movq	MMWORD [wk(0)], mm0	; tmp2
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm2, MMWORD [MMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(3,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_FAST_FLOAT)]
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm0,mm5
michael@0: 	pfadd	mm2,mm1			; mm2=z11
michael@0: 	pfadd	mm5,mm3			; mm5=z13
michael@0: 	pfsub	mm4,mm1			; mm4=z12
michael@0: 	pfsub	mm0,mm3			; mm0=z10
michael@0: 
michael@0: 	movq	mm1,mm2
michael@0: 	pfsub	mm2,mm5
michael@0: 	pfadd	mm1,mm5			; mm1=tmp7
michael@0: 
michael@0: 	pfmul	mm2,[GOTOFF(ebx,PD_1_414)]	; mm2=tmp11
michael@0: 
michael@0: 	movq	mm3,mm0
michael@0: 	pfadd	mm0,mm4
michael@0: 	pfmul	mm0,[GOTOFF(ebx,PD_1_847)]	; mm0=z5
michael@0: 	pfmul	mm3,[GOTOFF(ebx,PD_2_613)]	; mm3=(z10 * 2.613125930)
michael@0: 	pfmul	mm4,[GOTOFF(ebx,PD_1_082)]	; mm4=(z12 * 1.082392200)
michael@0: 	pfsubr	mm3,mm0			; mm3=tmp12
michael@0: 	pfsub	mm4,mm0			; mm4=tmp10
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	pfsub	mm3,mm1			; mm3=tmp6
michael@0: 	movq	mm5,mm6
michael@0: 	movq	mm0,mm7
michael@0: 	pfadd	mm6,mm1			; mm6=data0=(00 10)
michael@0: 	pfadd	mm7,mm3			; mm7=data1=(01 11)
michael@0: 	pfsub	mm5,mm1			; mm5=data7=(07 17)
michael@0: 	pfsub	mm0,mm3			; mm0=data6=(06 16)
michael@0: 	pfsub	mm2,mm3			; mm2=tmp5
michael@0: 
michael@0: 	movq	mm1,[GOTOFF(ebx,PD_RNDINT_MAGIC)]	; mm1=[PD_RNDINT_MAGIC]
michael@0: 	pcmpeqd	mm3,mm3
michael@0: 	psrld	mm3,WORD_BIT		; mm3={0xFFFF 0x0000 0xFFFF 0x0000}
michael@0: 
michael@0: 	pfadd	mm6,mm1			; mm6=roundint(data0/8)=(00 ** 10 **)
michael@0: 	pfadd	mm7,mm1			; mm7=roundint(data1/8)=(01 ** 11 **)
michael@0: 	pfadd	mm0,mm1			; mm0=roundint(data6/8)=(06 ** 16 **)
michael@0: 	pfadd	mm5,mm1			; mm5=roundint(data7/8)=(07 ** 17 **)
michael@0: 
michael@0: 	pand	mm6,mm3			; mm6=(00 -- 10 --)
michael@0: 	pslld	mm7,WORD_BIT		; mm7=(-- 01 -- 11)
michael@0: 	pand	mm0,mm3			; mm0=(06 -- 16 --)
michael@0: 	pslld	mm5,WORD_BIT		; mm5=(-- 07 -- 17)
michael@0: 	por	mm6,mm7			; mm6=(00 01 10 11)
michael@0: 	por	mm0,mm5			; mm0=(06 07 16 17)
michael@0: 
michael@0: 	movq	mm1, MMWORD [wk(0)]	; mm1=tmp2
michael@0: 	movq	mm3, MMWORD [wk(1)]	; mm3=tmp3
michael@0: 
michael@0: 	pfadd	mm4,mm2			; mm4=tmp4
michael@0: 	movq	mm7,mm1
michael@0: 	movq	mm5,mm3
michael@0: 	pfadd	mm1,mm2			; mm1=data2=(02 12)
michael@0: 	pfadd	mm3,mm4			; mm3=data4=(04 14)
michael@0: 	pfsub	mm7,mm2			; mm7=data5=(05 15)
michael@0: 	pfsub	mm5,mm4			; mm5=data3=(03 13)
michael@0: 
michael@0: 	movq	mm2,[GOTOFF(ebx,PD_RNDINT_MAGIC)]	; mm2=[PD_RNDINT_MAGIC]
michael@0: 	pcmpeqd	mm4,mm4
michael@0: 	psrld	mm4,WORD_BIT		; mm4={0xFFFF 0x0000 0xFFFF 0x0000}
michael@0: 
michael@0: 	pfadd	mm3,mm2			; mm3=roundint(data4/8)=(04 ** 14 **)
michael@0: 	pfadd	mm7,mm2			; mm7=roundint(data5/8)=(05 ** 15 **)
michael@0: 	pfadd	mm1,mm2			; mm1=roundint(data2/8)=(02 ** 12 **)
michael@0: 	pfadd	mm5,mm2			; mm5=roundint(data3/8)=(03 ** 13 **)
michael@0: 
michael@0: 	pand	mm3,mm4			; mm3=(04 -- 14 --)
michael@0: 	pslld	mm7,WORD_BIT		; mm7=(-- 05 -- 15)
michael@0: 	pand	mm1,mm4			; mm1=(02 -- 12 --)
michael@0: 	pslld	mm5,WORD_BIT		; mm5=(-- 03 -- 13)
michael@0: 	por	mm3,mm7			; mm3=(04 05 14 15)
michael@0: 	por	mm1,mm5			; mm1=(02 03 12 13)
michael@0: 
michael@0: 	movq      mm2,[GOTOFF(ebx,PB_CENTERJSAMP)]	; mm2=[PB_CENTERJSAMP]
michael@0: 
michael@0: 	packsswb  mm6,mm3		; mm6=(00 01 10 11 04 05 14 15)
michael@0: 	packsswb  mm1,mm0		; mm1=(02 03 12 13 06 07 16 17)
michael@0: 	paddb     mm6,mm2
michael@0: 	paddb     mm1,mm2
michael@0: 
michael@0: 	movq      mm4,mm6		; transpose coefficients(phase 2)
michael@0: 	punpcklwd mm6,mm1		; mm6=(00 01 02 03 10 11 12 13)
michael@0: 	punpckhwd mm4,mm1		; mm4=(04 05 06 07 14 15 16 17)
michael@0: 
michael@0: 	movq      mm7,mm6		; transpose coefficients(phase 3)
michael@0: 	punpckldq mm6,mm4		; mm6=(00 01 02 03 04 05 06 07)
michael@0: 	punpckhdq mm7,mm4		; mm7=(10 11 12 13 14 15 16 17)
michael@0: 
michael@0: 	pushpic	ebx			; save GOT address
michael@0: 
michael@0: 	mov	edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	ebx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0: 	movq	MMWORD [edx+eax*SIZEOF_JSAMPLE], mm6
michael@0: 	movq	MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm7
michael@0: 
michael@0: 	poppic	ebx			; restore GOT address
michael@0: 
michael@0: 	add	esi, byte 2*SIZEOF_FAST_FLOAT	; wsptr
michael@0: 	add	edi, byte 2*SIZEOF_JSAMPROW
michael@0: 	dec	ecx				; ctr
michael@0: 	jnz	near .rowloop
michael@0: 
michael@0: 	femms		; empty MMX/3DNow! state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16