michael@0: ;
michael@0: ; jimmxfst.asm - fast integer IDCT (MMX)
michael@0: ;
michael@0: ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0: ;
michael@0: ; Based on
michael@0: ; x86 SIMD extension for IJG JPEG library
michael@0: ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0: ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0: ;
michael@0: ; This file should be assembled with NASM (Netwide Assembler),
michael@0: ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0: ; assembler (including Borland's Turbo Assembler).
michael@0: ; NASM is available from http://nasm.sourceforge.net/ or
michael@0: ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0: ;
michael@0: ; This file contains a fast, not so accurate integer implementation of
michael@0: ; the inverse DCT (Discrete Cosine Transform). The following code is
michael@0: ; based directly on the IJG's original jidctfst.c; see the jidctfst.c
michael@0: ; for more details.
michael@0: ;
michael@0: ; [TAB8]
michael@0: 
michael@0: %include "jsimdext.inc"
michael@0: %include "jdct.inc"
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 
michael@0: %define CONST_BITS	8	; 14 is also OK.
michael@0: %define PASS1_BITS	2
michael@0: 
michael@0: %if IFAST_SCALE_BITS != PASS1_BITS
michael@0: %error "'IFAST_SCALE_BITS' must be equal to 'PASS1_BITS'."
michael@0: %endif
michael@0: 
michael@0: %if CONST_BITS == 8
michael@0: F_1_082	equ	277		; FIX(1.082392200)
michael@0: F_1_414	equ	362		; FIX(1.414213562)
michael@0: F_1_847	equ	473		; FIX(1.847759065)
michael@0: F_2_613	equ	669		; FIX(2.613125930)
michael@0: F_1_613	equ	(F_2_613 - 256)	; FIX(2.613125930) - FIX(1)
michael@0: %else
michael@0: ; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0: %define	DESCALE(x,n)  (((x)+(1<<((n)-1)))>>(n))
michael@0: F_1_082	equ	DESCALE(1162209775,30-CONST_BITS)	; FIX(1.082392200)
michael@0: F_1_414	equ	DESCALE(1518500249,30-CONST_BITS)	; FIX(1.414213562)
michael@0: F_1_847	equ	DESCALE(1984016188,30-CONST_BITS)	; FIX(1.847759065)
michael@0: F_2_613	equ	DESCALE(2805822602,30-CONST_BITS)	; FIX(2.613125930)
michael@0: F_1_613	equ	(F_2_613 - (1 << CONST_BITS))	; FIX(2.613125930) - FIX(1)
michael@0: %endif
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_CONST
michael@0: 
michael@0: ; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
michael@0: ; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
michael@0: 
michael@0: %define PRE_MULTIPLY_SCALE_BITS   2
michael@0: %define CONST_SHIFT     (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
michael@0: 
michael@0: 	alignz	16
michael@0: 	global	EXTN(jconst_idct_ifast_mmx)
michael@0: 
michael@0: EXTN(jconst_idct_ifast_mmx):
michael@0: 
michael@0: PW_F1414	times 4 dw  F_1_414 << CONST_SHIFT
michael@0: PW_F1847	times 4 dw  F_1_847 << CONST_SHIFT
michael@0: PW_MF1613	times 4 dw -F_1_613 << CONST_SHIFT
michael@0: PW_F1082	times 4 dw  F_1_082 << CONST_SHIFT
michael@0: PB_CENTERJSAMP	times 8 db  CENTERJSAMPLE
michael@0: 
michael@0: 	alignz	16
michael@0: 
michael@0: ; --------------------------------------------------------------------------
michael@0: 	SECTION	SEG_TEXT
michael@0: 	BITS	32
michael@0: ;
michael@0: ; Perform dequantization and inverse DCT on one block of coefficients.
michael@0: ;
michael@0: ; GLOBAL(void)
michael@0: ; jsimd_idct_ifast_mmx (void * dct_table, JCOEFPTR coef_block,
michael@0: ;                       JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0: ;
michael@0: 
michael@0: %define dct_table(b)	(b)+8			; jpeg_component_info * compptr
michael@0: %define coef_block(b)	(b)+12		; JCOEFPTR coef_block
michael@0: %define output_buf(b)	(b)+16		; JSAMPARRAY output_buf
michael@0: %define output_col(b)	(b)+20		; JDIMENSION output_col
michael@0: 
michael@0: %define original_ebp	ebp+0
michael@0: %define wk(i)		ebp-(WK_NUM-(i))*SIZEOF_MMWORD	; mmword wk[WK_NUM]
michael@0: %define WK_NUM		2
michael@0: %define workspace	wk(0)-DCTSIZE2*SIZEOF_JCOEF
michael@0: 					; JCOEF workspace[DCTSIZE2]
michael@0: 
michael@0: 	align	16
michael@0: 	global	EXTN(jsimd_idct_ifast_mmx)
michael@0: 
michael@0: EXTN(jsimd_idct_ifast_mmx):
michael@0: 	push	ebp
michael@0: 	mov	eax,esp				; eax = original ebp
michael@0: 	sub	esp, byte 4
michael@0: 	and	esp, byte (-SIZEOF_MMWORD)	; align to 64 bits
michael@0: 	mov	[esp],eax
michael@0: 	mov	ebp,esp				; ebp = aligned ebp
michael@0: 	lea	esp, [workspace]
michael@0: 	push	ebx
michael@0: ;	push	ecx		; need not be preserved
michael@0: ;	push	edx		; need not be preserved
michael@0: 	push	esi
michael@0: 	push	edi
michael@0: 
michael@0: 	get_GOT	ebx		; get GOT address
michael@0: 
michael@0: 	; ---- Pass 1: process columns from input, store into work array.
michael@0: 
michael@0: ;	mov	eax, [original_ebp]
michael@0: 	mov	edx, POINTER [dct_table(eax)]	; quantptr
michael@0: 	mov	esi, JCOEFPTR [coef_block(eax)]		; inptr
michael@0: 	lea	edi, [workspace]			; JCOEF * wsptr
michael@0: 	mov	ecx, DCTSIZE/4				; ctr
michael@0: 	alignx	16,7
michael@0: .columnloop:
michael@0: %ifndef NO_ZERO_COLUMN_TEST_IFAST_MMX
michael@0: 	mov	eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	or	eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm1, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm1, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm0, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	por	mm1,mm0
michael@0: 	packsswb mm1,mm1
michael@0: 	movd	eax,mm1
michael@0: 	test	eax,eax
michael@0: 	jnz	short .columnDCT
michael@0: 
michael@0: 	; -- AC terms all zero
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 
michael@0: 	movq      mm2,mm0		; mm0=in0=(00 01 02 03)
michael@0: 	punpcklwd mm0,mm0		; mm0=(00 00 01 01)
michael@0: 	punpckhwd mm2,mm2		; mm2=(02 02 03 03)
michael@0: 
michael@0: 	movq      mm1,mm0
michael@0: 	punpckldq mm0,mm0		; mm0=(00 00 00 00)
michael@0: 	punpckhdq mm1,mm1		; mm1=(01 01 01 01)
michael@0: 	movq      mm3,mm2
michael@0: 	punpckldq mm2,mm2		; mm2=(02 02 02 02)
michael@0: 	punpckhdq mm3,mm3		; mm3=(03 03 03 03)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm3
michael@0: 	movq	MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm3
michael@0: 	jmp	near .nextcolumn
michael@0: 	alignx	16,7
michael@0: %endif
michael@0: .columnDCT:
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	pmullw	mm3, MMWORD [MMBLOCK(6,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 
michael@0: 	movq	mm4,mm0
michael@0: 	movq	mm5,mm1
michael@0: 	psubw	mm0,mm2			; mm0=tmp11
michael@0: 	psubw	mm1,mm3
michael@0: 	paddw	mm4,mm2			; mm4=tmp10
michael@0: 	paddw	mm5,mm3			; mm5=tmp13
michael@0: 
michael@0: 	psllw	mm1,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm1,[GOTOFF(ebx,PW_F1414)]
michael@0: 	psubw	mm1,mm5			; mm1=tmp12
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	psubw	mm4,mm5			; mm4=tmp3
michael@0: 	psubw	mm0,mm1			; mm0=tmp2
michael@0: 	paddw	mm6,mm5			; mm6=tmp0
michael@0: 	paddw	mm7,mm1			; mm7=tmp1
michael@0: 
michael@0: 	movq	MMWORD [wk(1)], mm4	; wk(1)=tmp3
michael@0: 	movq	MMWORD [wk(0)], mm0	; wk(0)=tmp2
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm2, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm2, MMWORD [MMBLOCK(1,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	pmullw	mm3, MMWORD [MMBLOCK(3,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 	pmullw	mm5, MMWORD [MMBLOCK(5,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 	pmullw	mm1, MMWORD [MMBLOCK(7,0,edx,SIZEOF_IFAST_MULT_TYPE)]
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm0,mm5
michael@0: 	psubw	mm2,mm1			; mm2=z12
michael@0: 	psubw	mm5,mm3			; mm5=z10
michael@0: 	paddw	mm4,mm1			; mm4=z11
michael@0: 	paddw	mm0,mm3			; mm0=z13
michael@0: 
michael@0: 	movq	mm1,mm5			; mm1=z10(unscaled)
michael@0: 	psllw	mm2,PRE_MULTIPLY_SCALE_BITS
michael@0: 	psllw	mm5,PRE_MULTIPLY_SCALE_BITS
michael@0: 
michael@0: 	movq	mm3,mm4
michael@0: 	psubw	mm4,mm0
michael@0: 	paddw	mm3,mm0			; mm3=tmp7
michael@0: 
michael@0: 	psllw	mm4,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm4,[GOTOFF(ebx,PW_F1414)]	; mm4=tmp11
michael@0: 
michael@0: 	; To avoid overflow...
michael@0: 	;
michael@0: 	; (Original)
michael@0: 	; tmp12 = -2.613125930 * z10 + z5;
michael@0: 	;
michael@0: 	; (This implementation)
michael@0: 	; tmp12 = (-1.613125930 - 1) * z10 + z5;
michael@0: 	;       = -1.613125930 * z10 - z10 + z5;
michael@0: 
michael@0: 	movq	mm0,mm5
michael@0: 	paddw	mm5,mm2
michael@0: 	pmulhw	mm5,[GOTOFF(ebx,PW_F1847)]	; mm5=z5
michael@0: 	pmulhw	mm0,[GOTOFF(ebx,PW_MF1613)]
michael@0: 	pmulhw	mm2,[GOTOFF(ebx,PW_F1082)]
michael@0: 	psubw	mm0,mm1
michael@0: 	psubw	mm2,mm5			; mm2=tmp10
michael@0: 	paddw	mm0,mm5			; mm0=tmp12
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	psubw	mm0,mm3			; mm0=tmp6
michael@0: 	movq	mm1,mm6
michael@0: 	movq	mm5,mm7
michael@0: 	paddw	mm6,mm3			; mm6=data0=(00 01 02 03)
michael@0: 	paddw	mm7,mm0			; mm7=data1=(10 11 12 13)
michael@0: 	psubw	mm1,mm3			; mm1=data7=(70 71 72 73)
michael@0: 	psubw	mm5,mm0			; mm5=data6=(60 61 62 63)
michael@0: 	psubw	mm4,mm0			; mm4=tmp5
michael@0: 
michael@0: 	movq      mm3,mm6		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm6,mm7		; mm6=(00 10 01 11)
michael@0: 	punpckhwd mm3,mm7		; mm3=(02 12 03 13)
michael@0: 	movq      mm0,mm5		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm5,mm1		; mm5=(60 70 61 71)
michael@0: 	punpckhwd mm0,mm1		; mm0=(62 72 63 73)
michael@0: 
michael@0: 	movq	mm7, MMWORD [wk(0)]	; mm7=tmp2
michael@0: 	movq	mm1, MMWORD [wk(1)]	; mm1=tmp3
michael@0: 
michael@0: 	movq	MMWORD [wk(0)], mm5	; wk(0)=(60 70 61 71)
michael@0: 	movq	MMWORD [wk(1)], mm0	; wk(1)=(62 72 63 73)
michael@0: 
michael@0: 	paddw	mm2,mm4			; mm2=tmp4
michael@0: 	movq	mm5,mm7
michael@0: 	movq	mm0,mm1
michael@0: 	paddw	mm7,mm4			; mm7=data2=(20 21 22 23)
michael@0: 	paddw	mm1,mm2			; mm1=data4=(40 41 42 43)
michael@0: 	psubw	mm5,mm4			; mm5=data5=(50 51 52 53)
michael@0: 	psubw	mm0,mm2			; mm0=data3=(30 31 32 33)
michael@0: 
michael@0: 	movq      mm4,mm7		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm7,mm0		; mm7=(20 30 21 31)
michael@0: 	punpckhwd mm4,mm0		; mm4=(22 32 23 33)
michael@0: 	movq      mm2,mm1		; transpose coefficients(phase 1)
michael@0: 	punpcklwd mm1,mm5		; mm1=(40 50 41 51)
michael@0: 	punpckhwd mm2,mm5		; mm2=(42 52 43 53)
michael@0: 
michael@0: 	movq      mm0,mm6		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm6,mm7		; mm6=(00 10 20 30)
michael@0: 	punpckhdq mm0,mm7		; mm0=(01 11 21 31)
michael@0: 	movq      mm5,mm3		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm3,mm4		; mm3=(02 12 22 32)
michael@0: 	punpckhdq mm5,mm4		; mm5=(03 13 23 33)
michael@0: 
michael@0: 	movq	mm7, MMWORD [wk(0)]	; mm7=(60 70 61 71)
michael@0: 	movq	mm4, MMWORD [wk(1)]	; mm4=(62 72 63 73)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm0
michael@0: 	movq	MMWORD [MMBLOCK(2,0,edi,SIZEOF_JCOEF)], mm3
michael@0: 	movq	MMWORD [MMBLOCK(3,0,edi,SIZEOF_JCOEF)], mm5
michael@0: 
michael@0: 	movq      mm6,mm1		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm1,mm7		; mm1=(40 50 60 70)
michael@0: 	punpckhdq mm6,mm7		; mm6=(41 51 61 71)
michael@0: 	movq      mm0,mm2		; transpose coefficients(phase 2)
michael@0: 	punpckldq mm2,mm4		; mm2=(42 52 62 72)
michael@0: 	punpckhdq mm0,mm4		; mm0=(43 53 63 73)
michael@0: 
michael@0: 	movq	MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm1
michael@0: 	movq	MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm6
michael@0: 	movq	MMWORD [MMBLOCK(2,1,edi,SIZEOF_JCOEF)], mm2
michael@0: 	movq	MMWORD [MMBLOCK(3,1,edi,SIZEOF_JCOEF)], mm0
michael@0: 
michael@0: .nextcolumn:
michael@0: 	add	esi, byte 4*SIZEOF_JCOEF		; coef_block
michael@0: 	add	edx, byte 4*SIZEOF_IFAST_MULT_TYPE	; quantptr
michael@0: 	add	edi, byte 4*DCTSIZE*SIZEOF_JCOEF	; wsptr
michael@0: 	dec	ecx					; ctr
michael@0: 	jnz	near .columnloop
michael@0: 
michael@0: 	; ---- Pass 2: process rows from work array, store into output array.
michael@0: 
michael@0: 	mov	eax, [original_ebp]
michael@0: 	lea	esi, [workspace]			; JCOEF * wsptr
michael@0: 	mov	edi, JSAMPARRAY [output_buf(eax)]	; (JSAMPROW *)
michael@0: 	mov	eax, JDIMENSION [output_col(eax)]
michael@0: 	mov	ecx, DCTSIZE/4				; ctr
michael@0: 	alignx	16,7
michael@0: .rowloop:
michael@0: 
michael@0: 	; -- Even part
michael@0: 
michael@0: 	movq	mm0, MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm2, MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	movq	mm4,mm0
michael@0: 	movq	mm5,mm1
michael@0: 	psubw	mm0,mm2			; mm0=tmp11
michael@0: 	psubw	mm1,mm3
michael@0: 	paddw	mm4,mm2			; mm4=tmp10
michael@0: 	paddw	mm5,mm3			; mm5=tmp13
michael@0: 
michael@0: 	psllw	mm1,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm1,[GOTOFF(ebx,PW_F1414)]
michael@0: 	psubw	mm1,mm5			; mm1=tmp12
michael@0: 
michael@0: 	movq	mm6,mm4
michael@0: 	movq	mm7,mm0
michael@0: 	psubw	mm4,mm5			; mm4=tmp3
michael@0: 	psubw	mm0,mm1			; mm0=tmp2
michael@0: 	paddw	mm6,mm5			; mm6=tmp0
michael@0: 	paddw	mm7,mm1			; mm7=tmp1
michael@0: 
michael@0: 	movq	MMWORD [wk(1)], mm4	; wk(1)=tmp3
michael@0: 	movq	MMWORD [wk(0)], mm0	; wk(0)=tmp2
michael@0: 
michael@0: 	; -- Odd part
michael@0: 
michael@0: 	movq	mm2, MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm3, MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm5, MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0: 	movq	mm1, MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0: 
michael@0: 	movq	mm4,mm2
michael@0: 	movq	mm0,mm5
michael@0: 	psubw	mm2,mm1			; mm2=z12
michael@0: 	psubw	mm5,mm3			; mm5=z10
michael@0: 	paddw	mm4,mm1			; mm4=z11
michael@0: 	paddw	mm0,mm3			; mm0=z13
michael@0: 
michael@0: 	movq	mm1,mm5			; mm1=z10(unscaled)
michael@0: 	psllw	mm2,PRE_MULTIPLY_SCALE_BITS
michael@0: 	psllw	mm5,PRE_MULTIPLY_SCALE_BITS
michael@0: 
michael@0: 	movq	mm3,mm4
michael@0: 	psubw	mm4,mm0
michael@0: 	paddw	mm3,mm0			; mm3=tmp7
michael@0: 
michael@0: 	psllw	mm4,PRE_MULTIPLY_SCALE_BITS
michael@0: 	pmulhw	mm4,[GOTOFF(ebx,PW_F1414)]	; mm4=tmp11
michael@0: 
michael@0: 	; To avoid overflow...
michael@0: 	;
michael@0: 	; (Original)
michael@0: 	; tmp12 = -2.613125930 * z10 + z5;
michael@0: 	;
michael@0: 	; (This implementation)
michael@0: 	; tmp12 = (-1.613125930 - 1) * z10 + z5;
michael@0: 	;       = -1.613125930 * z10 - z10 + z5;
michael@0: 
michael@0: 	movq	mm0,mm5
michael@0: 	paddw	mm5,mm2
michael@0: 	pmulhw	mm5,[GOTOFF(ebx,PW_F1847)]	; mm5=z5
michael@0: 	pmulhw	mm0,[GOTOFF(ebx,PW_MF1613)]
michael@0: 	pmulhw	mm2,[GOTOFF(ebx,PW_F1082)]
michael@0: 	psubw	mm0,mm1
michael@0: 	psubw	mm2,mm5			; mm2=tmp10
michael@0: 	paddw	mm0,mm5			; mm0=tmp12
michael@0: 
michael@0: 	; -- Final output stage
michael@0: 
michael@0: 	psubw	mm0,mm3			; mm0=tmp6
michael@0: 	movq	mm1,mm6
michael@0: 	movq	mm5,mm7
michael@0: 	paddw	mm6,mm3			; mm6=data0=(00 10 20 30)
michael@0: 	paddw	mm7,mm0			; mm7=data1=(01 11 21 31)
michael@0: 	psraw	mm6,(PASS1_BITS+3)	; descale
michael@0: 	psraw	mm7,(PASS1_BITS+3)	; descale
michael@0: 	psubw	mm1,mm3			; mm1=data7=(07 17 27 37)
michael@0: 	psubw	mm5,mm0			; mm5=data6=(06 16 26 36)
michael@0: 	psraw	mm1,(PASS1_BITS+3)	; descale
michael@0: 	psraw	mm5,(PASS1_BITS+3)	; descale
michael@0: 	psubw	mm4,mm0			; mm4=tmp5
michael@0: 
michael@0: 	packsswb  mm6,mm5		; mm6=(00 10 20 30 06 16 26 36)
michael@0: 	packsswb  mm7,mm1		; mm7=(01 11 21 31 07 17 27 37)
michael@0: 
michael@0: 	movq	mm3, MMWORD [wk(0)]	; mm3=tmp2
michael@0: 	movq	mm0, MMWORD [wk(1)]	; mm0=tmp3
michael@0: 
michael@0: 	paddw	mm2,mm4			; mm2=tmp4
michael@0: 	movq	mm5,mm3
michael@0: 	movq	mm1,mm0
michael@0: 	paddw	mm3,mm4			; mm3=data2=(02 12 22 32)
michael@0: 	paddw	mm0,mm2			; mm0=data4=(04 14 24 34)
michael@0: 	psraw	mm3,(PASS1_BITS+3)	; descale
michael@0: 	psraw	mm0,(PASS1_BITS+3)	; descale
michael@0: 	psubw	mm5,mm4			; mm5=data5=(05 15 25 35)
michael@0: 	psubw	mm1,mm2			; mm1=data3=(03 13 23 33)
michael@0: 	psraw	mm5,(PASS1_BITS+3)	; descale
michael@0: 	psraw	mm1,(PASS1_BITS+3)	; descale
michael@0: 
michael@0: 	movq      mm4,[GOTOFF(ebx,PB_CENTERJSAMP)]	; mm4=[PB_CENTERJSAMP]
michael@0: 
michael@0: 	packsswb  mm3,mm0		; mm3=(02 12 22 32 04 14 24 34)
michael@0: 	packsswb  mm1,mm5		; mm1=(03 13 23 33 05 15 25 35)
michael@0: 
michael@0: 	paddb     mm6,mm4
michael@0: 	paddb     mm7,mm4
michael@0: 	paddb     mm3,mm4
michael@0: 	paddb     mm1,mm4
michael@0: 
michael@0: 	movq      mm2,mm6		; transpose coefficients(phase 1)
michael@0: 	punpcklbw mm6,mm7		; mm6=(00 01 10 11 20 21 30 31)
michael@0: 	punpckhbw mm2,mm7		; mm2=(06 07 16 17 26 27 36 37)
michael@0: 	movq      mm0,mm3		; transpose coefficients(phase 1)
michael@0: 	punpcklbw mm3,mm1		; mm3=(02 03 12 13 22 23 32 33)
michael@0: 	punpckhbw mm0,mm1		; mm0=(04 05 14 15 24 25 34 35)
michael@0: 
michael@0: 	movq      mm5,mm6		; transpose coefficients(phase 2)
michael@0: 	punpcklwd mm6,mm3		; mm6=(00 01 02 03 10 11 12 13)
michael@0: 	punpckhwd mm5,mm3		; mm5=(20 21 22 23 30 31 32 33)
michael@0: 	movq      mm4,mm0		; transpose coefficients(phase 2)
michael@0: 	punpcklwd mm0,mm2		; mm0=(04 05 06 07 14 15 16 17)
michael@0: 	punpckhwd mm4,mm2		; mm4=(24 25 26 27 34 35 36 37)
michael@0: 
michael@0: 	movq      mm7,mm6		; transpose coefficients(phase 3)
michael@0: 	punpckldq mm6,mm0		; mm6=(00 01 02 03 04 05 06 07)
michael@0: 	punpckhdq mm7,mm0		; mm7=(10 11 12 13 14 15 16 17)
michael@0: 	movq      mm1,mm5		; transpose coefficients(phase 3)
michael@0: 	punpckldq mm5,mm4		; mm5=(20 21 22 23 24 25 26 27)
michael@0: 	punpckhdq mm1,mm4		; mm1=(30 31 32 33 34 35 36 37)
michael@0: 
michael@0: 	pushpic	ebx			; save GOT address
michael@0: 
michael@0: 	mov	edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0: 	mov	ebx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0: 	movq	MMWORD [edx+eax*SIZEOF_JSAMPLE], mm6
michael@0: 	movq	MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm7
michael@0: 	mov	edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
michael@0: 	mov	ebx, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
michael@0: 	movq	MMWORD [edx+eax*SIZEOF_JSAMPLE], mm5
michael@0: 	movq	MMWORD [ebx+eax*SIZEOF_JSAMPLE], mm1
michael@0: 
michael@0: 	poppic	ebx			; restore GOT address
michael@0: 
michael@0: 	add	esi, byte 4*SIZEOF_JCOEF	; wsptr
michael@0: 	add	edi, byte 4*SIZEOF_JSAMPROW
michael@0: 	dec	ecx				; ctr
michael@0: 	jnz	near .rowloop
michael@0: 
michael@0: 	emms		; empty MMX state
michael@0: 
michael@0: 	pop	edi
michael@0: 	pop	esi
michael@0: ;	pop	edx		; need not be preserved
michael@0: ;	pop	ecx		; need not be preserved
michael@0: 	pop	ebx
michael@0: 	mov	esp,ebp		; esp <- aligned ebp
michael@0: 	pop	esp		; esp <- original ebp
michael@0: 	pop	ebp
michael@0: 	ret
michael@0: 
michael@0: ; For some reason, the OS X linker does not honor the request to align the
michael@0: ; segment unless we do this.
michael@0: 	align	16