diff -r 000000000000 -r 6474c204b198 dom/network/src/PTCPSocket.ipdl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/dom/network/src/PTCPSocket.ipdl	Wed Dec 31 06:09:35 2014 +0100
@@ -0,0 +1,76 @@
+/* -*- Mode: C++; tab-width: 8; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
+/* vim: set sw=2 ts=8 et tw=80 ft=cpp : */
+
+/* This Source Code Form is subject to the terms of the Mozilla Public
+ * License, v. 2.0. If a copy of the MPL was not distributed with this
+ * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
+
+include protocol PNecko;
+
+include "mozilla/net/NeckoMessageUtils.h";
+
+using struct mozilla::void_t from "ipc/IPCMessageUtils.h";
+
+struct TCPError {
+  nsString name;
+};
+
+union SendableData {
+  uint8_t[];
+  nsString;
+};
+
+union CallbackData {
+  void_t;
+  SendableData;
+  TCPError;
+};
+
+namespace mozilla {
+namespace net {
+
+//-------------------------------------------------------------------
+protocol PTCPSocket
+{
+  manager PNecko;
+
+parent:
+  // Forward calling to child's open() method to parent, expect TCPOptions
+  // is expanded to |useSSL| (from TCPOptions.useSecureTransport) and
+  // |binaryType| (from TCPOption.binaryType).
+  Open(nsString host, uint16_t port, bool useSSL, nsString binaryType);
+
+  // When child's send() is called, this message requrests parent to send
+  // data and update it's trackingNumber.
+  Data(SendableData data, uint32_t trackingNumber);
+
+  // Forward calling to child's upgradeToSecure() method to parent.
+  StartTLS();
+
+  // Forward calling to child's send() method to parent.
+  Suspend();
+
+  // Forward calling to child's resume() method to parent.
+  Resume();
+
+  // Forward calling to child's close() method to parent.
+  Close();
+
+child:
+  // Forward events that are dispatched by parent.
+  Callback(nsString type, CallbackData data, nsString readyState);
+
+  // Update child's bufferedAmount when parent's bufferedAmount is updated.
+  // trackingNumber is also passed back to child to ensure the bufferedAmount
+  // is corresponding the last call to send().
+  UpdateBufferedAmount(uint32_t bufferedAmount, uint32_t trackingNumber);
+
+both:
+  RequestDelete();
+  __delete__();
+};
+
+
+} // namespace net
+} // namespace mozilla
+