The Tor Browser / annotate

media/libjpeg/simd/jcqntsse.asm@6474c204b198 (annotated)

media/libjpeg/simd/jcqntsse.asm

Wed, 31 Dec 2014 06:09:35 +0100

author
Michael Schloh von Bennewitz <michael@schloh.com>
date
Wed, 31 Dec 2014 06:09:35 +0100
changeset 0
6474c204b198
permissions
-rw-r--r--

Cloned upstream origin tor-browser at tor-browser-31.3.0esr-4.5-1-build1
revision ID fc1c9ff7c1b2defdbc039f12214767608f46423f for hacking purpose.

michael@0 1 ;
michael@0 2 ; jcqntsse.asm - sample data conversion and quantization (SSE & MMX)
michael@0 3 ;
michael@0 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0 5 ;
michael@0 6 ; Based on
michael@0 7 ; x86 SIMD extension for IJG JPEG library
michael@0 8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0 9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0 10 ;
michael@0 11 ; This file should be assembled with NASM (Netwide Assembler),
michael@0 12 ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0 13 ; assembler (including Borland's Turbo Assembler).
michael@0 14 ; NASM is available from http://nasm.sourceforge.net/ or
michael@0 15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0 16 ;
michael@0 17 ; [TAB8]
michael@0 18
michael@0 19 %include "jsimdext.inc"
michael@0 20 %include "jdct.inc"
michael@0 21
michael@0 22 ; --------------------------------------------------------------------------
michael@0 23 SECTION SEG_TEXT
michael@0 24 BITS 32
michael@0 25 ;
michael@0 26 ; Load data into workspace, applying unsigned->signed conversion
michael@0 27 ;
michael@0 28 ; GLOBAL(void)
michael@0 29 ; jsimd_convsamp_float_sse (JSAMPARRAY sample_data, JDIMENSION start_col,
michael@0 30 ; FAST_FLOAT * workspace);
michael@0 31 ;
michael@0 32
michael@0 33 %define sample_data ebp+8 ; JSAMPARRAY sample_data
michael@0 34 %define start_col ebp+12 ; JDIMENSION start_col
michael@0 35 %define workspace ebp+16 ; FAST_FLOAT * workspace
michael@0 36
michael@0 37 align 16
michael@0 38 global EXTN(jsimd_convsamp_float_sse)
michael@0 39
michael@0 40 EXTN(jsimd_convsamp_float_sse):
michael@0 41 push ebp
michael@0 42 mov ebp,esp
michael@0 43 push ebx
michael@0 44 ; push ecx ; need not be preserved
michael@0 45 ; push edx ; need not be preserved
michael@0 46 push esi
michael@0 47 push edi
michael@0 48
michael@0 49 pcmpeqw mm7,mm7
michael@0 50 psllw mm7,7
michael@0 51 packsswb mm7,mm7 ; mm7 = PB_CENTERJSAMPLE (0x808080..)
michael@0 52
michael@0 53 mov esi, JSAMPARRAY [sample_data] ; (JSAMPROW *)
michael@0 54 mov eax, JDIMENSION [start_col]
michael@0 55 mov edi, POINTER [workspace] ; (DCTELEM *)
michael@0 56 mov ecx, DCTSIZE/2
michael@0 57 alignx 16,7
michael@0 58 .convloop:
michael@0 59 mov ebx, JSAMPROW [esi+0*SIZEOF_JSAMPROW] ; (JSAMPLE *)
michael@0 60 mov edx, JSAMPROW [esi+1*SIZEOF_JSAMPROW] ; (JSAMPLE *)
michael@0 61
michael@0 62 movq mm0, MMWORD [ebx+eax*SIZEOF_JSAMPLE]
michael@0 63 movq mm1, MMWORD [edx+eax*SIZEOF_JSAMPLE]
michael@0 64
michael@0 65 psubb mm0,mm7 ; mm0=(01234567)
michael@0 66 psubb mm1,mm7 ; mm1=(89ABCDEF)
michael@0 67
michael@0 68 punpcklbw mm2,mm0 ; mm2=(*0*1*2*3)
michael@0 69 punpckhbw mm0,mm0 ; mm0=(*4*5*6*7)
michael@0 70 punpcklbw mm3,mm1 ; mm3=(*8*9*A*B)
michael@0 71 punpckhbw mm1,mm1 ; mm1=(*C*D*E*F)
michael@0 72
michael@0 73 punpcklwd mm4,mm2 ; mm4=(***0***1)
michael@0 74 punpckhwd mm2,mm2 ; mm2=(***2***3)
michael@0 75 punpcklwd mm5,mm0 ; mm5=(***4***5)
michael@0 76 punpckhwd mm0,mm0 ; mm0=(***6***7)
michael@0 77
michael@0 78 psrad mm4,(DWORD_BIT-BYTE_BIT) ; mm4=(01)
michael@0 79 psrad mm2,(DWORD_BIT-BYTE_BIT) ; mm2=(23)
michael@0 80 cvtpi2ps xmm0,mm4 ; xmm0=(01**)
michael@0 81 cvtpi2ps xmm1,mm2 ; xmm1=(23**)
michael@0 82 psrad mm5,(DWORD_BIT-BYTE_BIT) ; mm5=(45)
michael@0 83 psrad mm0,(DWORD_BIT-BYTE_BIT) ; mm0=(67)
michael@0 84 cvtpi2ps xmm2,mm5 ; xmm2=(45**)
michael@0 85 cvtpi2ps xmm3,mm0 ; xmm3=(67**)
michael@0 86
michael@0 87 punpcklwd mm6,mm3 ; mm6=(***8***9)
michael@0 88 punpckhwd mm3,mm3 ; mm3=(***A***B)
michael@0 89 punpcklwd mm4,mm1 ; mm4=(***C***D)
michael@0 90 punpckhwd mm1,mm1 ; mm1=(***E***F)
michael@0 91
michael@0 92 psrad mm6,(DWORD_BIT-BYTE_BIT) ; mm6=(89)
michael@0 93 psrad mm3,(DWORD_BIT-BYTE_BIT) ; mm3=(AB)
michael@0 94 cvtpi2ps xmm4,mm6 ; xmm4=(89**)
michael@0 95 cvtpi2ps xmm5,mm3 ; xmm5=(AB**)
michael@0 96 psrad mm4,(DWORD_BIT-BYTE_BIT) ; mm4=(CD)
michael@0 97 psrad mm1,(DWORD_BIT-BYTE_BIT) ; mm1=(EF)
michael@0 98 cvtpi2ps xmm6,mm4 ; xmm6=(CD**)
michael@0 99 cvtpi2ps xmm7,mm1 ; xmm7=(EF**)
michael@0 100
michael@0 101 movlhps xmm0,xmm1 ; xmm0=(0123)
michael@0 102 movlhps xmm2,xmm3 ; xmm2=(4567)
michael@0 103 movlhps xmm4,xmm5 ; xmm4=(89AB)
michael@0 104 movlhps xmm6,xmm7 ; xmm6=(CDEF)
michael@0 105
michael@0 106 movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0 107 movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm2
michael@0 108 movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm4
michael@0 109 movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm6
michael@0 110
michael@0 111 add esi, byte 2*SIZEOF_JSAMPROW
michael@0 112 add edi, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0 113 dec ecx
michael@0 114 jnz near .convloop
michael@0 115
michael@0 116 emms ; empty MMX state
michael@0 117
michael@0 118 pop edi
michael@0 119 pop esi
michael@0 120 ; pop edx ; need not be preserved
michael@0 121 ; pop ecx ; need not be preserved
michael@0 122 pop ebx
michael@0 123 pop ebp
michael@0 124 ret
michael@0 125
michael@0 126
michael@0 127 ; --------------------------------------------------------------------------
michael@0 128 ;
michael@0 129 ; Quantize/descale the coefficients, and store into coef_block
michael@0 130 ;
michael@0 131 ; GLOBAL(void)
michael@0 132 ; jsimd_quantize_float_sse (JCOEFPTR coef_block, FAST_FLOAT * divisors,
michael@0 133 ; FAST_FLOAT * workspace);
michael@0 134 ;
michael@0 135
michael@0 136 %define coef_block ebp+8 ; JCOEFPTR coef_block
michael@0 137 %define divisors ebp+12 ; FAST_FLOAT * divisors
michael@0 138 %define workspace ebp+16 ; FAST_FLOAT * workspace
michael@0 139
michael@0 140 align 16
michael@0 141 global EXTN(jsimd_quantize_float_sse)
michael@0 142
michael@0 143 EXTN(jsimd_quantize_float_sse):
michael@0 144 push ebp
michael@0 145 mov ebp,esp
michael@0 146 ; push ebx ; unused
michael@0 147 ; push ecx ; unused
michael@0 148 ; push edx ; need not be preserved
michael@0 149 push esi
michael@0 150 push edi
michael@0 151
michael@0 152 mov esi, POINTER [workspace]
michael@0 153 mov edx, POINTER [divisors]
michael@0 154 mov edi, JCOEFPTR [coef_block]
michael@0 155 mov eax, DCTSIZE2/16
michael@0 156 alignx 16,7
michael@0 157 .quantloop:
michael@0 158 movaps xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 159 movaps xmm1, XMMWORD [XMMBLOCK(0,1,esi,SIZEOF_FAST_FLOAT)]
michael@0 160 mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0 161 mulps xmm1, XMMWORD [XMMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0 162 movaps xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 163 movaps xmm3, XMMWORD [XMMBLOCK(1,1,esi,SIZEOF_FAST_FLOAT)]
michael@0 164 mulps xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0 165 mulps xmm3, XMMWORD [XMMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0 166
michael@0 167 movhlps xmm4,xmm0
michael@0 168 movhlps xmm5,xmm1
michael@0 169
michael@0 170 cvtps2pi mm0,xmm0
michael@0 171 cvtps2pi mm1,xmm1
michael@0 172 cvtps2pi mm4,xmm4
michael@0 173 cvtps2pi mm5,xmm5
michael@0 174
michael@0 175 movhlps xmm6,xmm2
michael@0 176 movhlps xmm7,xmm3
michael@0 177
michael@0 178 cvtps2pi mm2,xmm2
michael@0 179 cvtps2pi mm3,xmm3
michael@0 180 cvtps2pi mm6,xmm6
michael@0 181 cvtps2pi mm7,xmm7
michael@0 182
michael@0 183 packssdw mm0,mm4
michael@0 184 packssdw mm1,mm5
michael@0 185 packssdw mm2,mm6
michael@0 186 packssdw mm3,mm7
michael@0 187
michael@0 188 movq MMWORD [MMBLOCK(0,0,edi,SIZEOF_JCOEF)], mm0
michael@0 189 movq MMWORD [MMBLOCK(0,1,edi,SIZEOF_JCOEF)], mm1
michael@0 190 movq MMWORD [MMBLOCK(1,0,edi,SIZEOF_JCOEF)], mm2
michael@0 191 movq MMWORD [MMBLOCK(1,1,edi,SIZEOF_JCOEF)], mm3
michael@0 192
michael@0 193 add esi, byte 16*SIZEOF_FAST_FLOAT
michael@0 194 add edx, byte 16*SIZEOF_FAST_FLOAT
michael@0 195 add edi, byte 16*SIZEOF_JCOEF
michael@0 196 dec eax
michael@0 197 jnz short .quantloop
michael@0 198
michael@0 199 emms ; empty MMX state
michael@0 200
michael@0 201 pop edi
michael@0 202 pop esi
michael@0 203 ; pop edx ; need not be preserved
michael@0 204 ; pop ecx ; unused
michael@0 205 ; pop ebx ; unused
michael@0 206 pop ebp
michael@0 207 ret
michael@0 208
michael@0 209 ; For some reason, the OS X linker does not honor the request to align the
michael@0 210 ; segment unless we do this.
michael@0 211 align 16

Mercurial Repository: The Tor Browser

Europalab SCM Repository Server

mercurial