• file
• revisions
• annotate
• diff
• comparison
• raw

media/libjpeg/simd/jf3dnflt.asm@6474c204b198 (annotated)

media/libjpeg/simd/jf3dnflt.asm

Wed, 31 Dec 2014 06:09:35 +0100

author

Michael Schloh von Bennewitz <michael@schloh.com>

date

Wed, 31 Dec 2014 06:09:35 +0100

changeset 0

6474c204b198

permissions

-rw-r--r--

Cloned upstream origin tor-browser at tor-browser-31.3.0esr-4.5-1-build1
revision ID fc1c9ff7c1b2defdbc039f12214767608f46423f for hacking purpose.

michael@0	1	;
michael@0	2	; jf3dnflt.asm - floating-point FDCT (3DNow!)
michael@0	3	;
michael@0	4	; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0	5	;
michael@0	6	; Based on
michael@0	7	; x86 SIMD extension for IJG JPEG library
michael@0	8	; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0	9	; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0	10	;
michael@0	11	; This file should be assembled with NASM (Netwide Assembler),
michael@0	12	; can *not* be assembled with Microsoft's MASM or any compatible
michael@0	13	; assembler (including Borland's Turbo Assembler).
michael@0	14	; NASM is available from http://nasm.sourceforge.net/ or
michael@0	15	; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0	16	;
michael@0	17	; This file contains a floating-point implementation of the forward DCT
michael@0	18	; (Discrete Cosine Transform). The following code is based directly on
michael@0	19	; the IJG's original jfdctflt.c; see the jfdctflt.c for more details.
michael@0	20	;
michael@0	21	; [TAB8]
michael@0	22
michael@0	23	%include "jsimdext.inc"
michael@0	24	%include "jdct.inc"
michael@0	25
michael@0	26	; --------------------------------------------------------------------------
michael@0	27	SECTION SEG_CONST
michael@0	28
michael@0	29	alignz 16
michael@0	30	global EXTN(jconst_fdct_float_3dnow)
michael@0	31
michael@0	32	EXTN(jconst_fdct_float_3dnow):
michael@0	33
michael@0	34	PD_0_382 times 2 dd 0.382683432365089771728460
michael@0	35	PD_0_707 times 2 dd 0.707106781186547524400844
michael@0	36	PD_0_541 times 2 dd 0.541196100146196984399723
michael@0	37	PD_1_306 times 2 dd 1.306562964876376527856643
michael@0	38
michael@0	39	alignz 16
michael@0	40
michael@0	41	; --------------------------------------------------------------------------
michael@0	42	SECTION SEG_TEXT
michael@0	43	BITS 32
michael@0	44	;
michael@0	45	; Perform the forward DCT on one block of samples.
michael@0	46	;
michael@0	47	; GLOBAL(void)
michael@0	48	; jsimd_fdct_float_3dnow (FAST_FLOAT * data)
michael@0	49	;
michael@0	50
michael@0	51	%define data(b) (b)+8 ; FAST_FLOAT * data
michael@0	52
michael@0	53	%define original_ebp ebp+0
michael@0	54	%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
michael@0	55	%define WK_NUM 2
michael@0	56
michael@0	57	align 16
michael@0	58	global EXTN(jsimd_fdct_float_3dnow)
michael@0	59
michael@0	60	EXTN(jsimd_fdct_float_3dnow):
michael@0	61	push ebp
michael@0	62	mov eax,esp ; eax = original ebp
michael@0	63	sub esp, byte 4
michael@0	64	and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
michael@0	65	mov [esp],eax
michael@0	66	mov ebp,esp ; ebp = aligned ebp
michael@0	67	lea esp, [wk(0)]
michael@0	68	pushpic ebx
michael@0	69	; push ecx ; need not be preserved
michael@0	70	; push edx ; need not be preserved
michael@0	71	; push esi ; unused
michael@0	72	; push edi ; unused
michael@0	73
michael@0	74	get_GOT ebx ; get GOT address
michael@0	75
michael@0	76	; ---- Pass 1: process rows.
michael@0	77
michael@0	78	mov edx, POINTER [data(eax)] ; (FAST_FLOAT *)
michael@0	79	mov ecx, DCTSIZE/2
michael@0	80	alignx 16,7
michael@0	81	.rowloop:
michael@0	82
michael@0	83	movq mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	84	movq mm1, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	85	movq mm2, MMWORD [MMBLOCK(0,3,edx,SIZEOF_FAST_FLOAT)]
michael@0	86	movq mm3, MMWORD [MMBLOCK(1,3,edx,SIZEOF_FAST_FLOAT)]
michael@0	87
michael@0	88	; mm0=(00 01), mm1=(10 11), mm2=(06 07), mm3=(16 17)
michael@0	89
michael@0	90	movq mm4,mm0 ; transpose coefficients
michael@0	91	punpckldq mm0,mm1 ; mm0=(00 10)=data0
michael@0	92	punpckhdq mm4,mm1 ; mm4=(01 11)=data1
michael@0	93	movq mm5,mm2 ; transpose coefficients
michael@0	94	punpckldq mm2,mm3 ; mm2=(06 16)=data6
michael@0	95	punpckhdq mm5,mm3 ; mm5=(07 17)=data7
michael@0	96
michael@0	97	movq mm6,mm4
michael@0	98	movq mm7,mm0
michael@0	99	pfsub mm4,mm2 ; mm4=data1-data6=tmp6
michael@0	100	pfsub mm0,mm5 ; mm0=data0-data7=tmp7
michael@0	101	pfadd mm6,mm2 ; mm6=data1+data6=tmp1
michael@0	102	pfadd mm7,mm5 ; mm7=data0+data7=tmp0
michael@0	103
michael@0	104	movq mm1, MMWORD [MMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)]
michael@0	105	movq mm3, MMWORD [MMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)]
michael@0	106	movq mm2, MMWORD [MMBLOCK(0,2,edx,SIZEOF_FAST_FLOAT)]
michael@0	107	movq mm5, MMWORD [MMBLOCK(1,2,edx,SIZEOF_FAST_FLOAT)]
michael@0	108
michael@0	109	; mm1=(02 03), mm3=(12 13), mm2=(04 05), mm5=(14 15)
michael@0	110
michael@0	111	movq MMWORD [wk(0)], mm4 ; wk(0)=tmp6
michael@0	112	movq MMWORD [wk(1)], mm0 ; wk(1)=tmp7
michael@0	113
michael@0	114	movq mm4,mm1 ; transpose coefficients
michael@0	115	punpckldq mm1,mm3 ; mm1=(02 12)=data2
michael@0	116	punpckhdq mm4,mm3 ; mm4=(03 13)=data3
michael@0	117	movq mm0,mm2 ; transpose coefficients
michael@0	118	punpckldq mm2,mm5 ; mm2=(04 14)=data4
michael@0	119	punpckhdq mm0,mm5 ; mm0=(05 15)=data5
michael@0	120
michael@0	121	movq mm3,mm4
michael@0	122	movq mm5,mm1
michael@0	123	pfadd mm4,mm2 ; mm4=data3+data4=tmp3
michael@0	124	pfadd mm1,mm0 ; mm1=data2+data5=tmp2
michael@0	125	pfsub mm3,mm2 ; mm3=data3-data4=tmp4
michael@0	126	pfsub mm5,mm0 ; mm5=data2-data5=tmp5
michael@0	127
michael@0	128	; -- Even part
michael@0	129
michael@0	130	movq mm2,mm7
michael@0	131	movq mm0,mm6
michael@0	132	pfsub mm7,mm4 ; mm7=tmp13
michael@0	133	pfsub mm6,mm1 ; mm6=tmp12
michael@0	134	pfadd mm2,mm4 ; mm2=tmp10
michael@0	135	pfadd mm0,mm1 ; mm0=tmp11
michael@0	136
michael@0	137	pfadd mm6,mm7
michael@0	138	pfmul mm6,[GOTOFF(ebx,PD_0_707)] ; mm6=z1
michael@0	139
michael@0	140	movq mm4,mm2
michael@0	141	movq mm1,mm7
michael@0	142	pfsub mm2,mm0 ; mm2=data4
michael@0	143	pfsub mm7,mm6 ; mm7=data6
michael@0	144	pfadd mm4,mm0 ; mm4=data0
michael@0	145	pfadd mm1,mm6 ; mm1=data2
michael@0	146
michael@0	147	movq MMWORD [MMBLOCK(0,2,edx,SIZEOF_FAST_FLOAT)], mm2
michael@0	148	movq MMWORD [MMBLOCK(0,3,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0	149	movq MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0	150	movq MMWORD [MMBLOCK(0,1,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0	151
michael@0	152	; -- Odd part
michael@0	153
michael@0	154	movq mm0, MMWORD [wk(0)] ; mm0=tmp6
michael@0	155	movq mm6, MMWORD [wk(1)] ; mm6=tmp7
michael@0	156
michael@0	157	pfadd mm3,mm5 ; mm3=tmp10
michael@0	158	pfadd mm5,mm0 ; mm5=tmp11
michael@0	159	pfadd mm0,mm6 ; mm0=tmp12, mm6=tmp7
michael@0	160
michael@0	161	pfmul mm5,[GOTOFF(ebx,PD_0_707)] ; mm5=z3
michael@0	162
michael@0	163	movq mm2,mm3 ; mm2=tmp10
michael@0	164	pfsub mm3,mm0
michael@0	165	pfmul mm3,[GOTOFF(ebx,PD_0_382)] ; mm3=z5
michael@0	166	pfmul mm2,[GOTOFF(ebx,PD_0_541)] ; mm2=MULTIPLY(tmp10,FIX_0_54119610)
michael@0	167	pfmul mm0,[GOTOFF(ebx,PD_1_306)] ; mm0=MULTIPLY(tmp12,FIX_1_30656296)
michael@0	168	pfadd mm2,mm3 ; mm2=z2
michael@0	169	pfadd mm0,mm3 ; mm0=z4
michael@0	170
michael@0	171	movq mm7,mm6
michael@0	172	pfsub mm6,mm5 ; mm6=z13
michael@0	173	pfadd mm7,mm5 ; mm7=z11
michael@0	174
michael@0	175	movq mm4,mm6
michael@0	176	movq mm1,mm7
michael@0	177	pfsub mm6,mm2 ; mm6=data3
michael@0	178	pfsub mm7,mm0 ; mm7=data7
michael@0	179	pfadd mm4,mm2 ; mm4=data5
michael@0	180	pfadd mm1,mm0 ; mm1=data1
michael@0	181
michael@0	182	movq MMWORD [MMBLOCK(1,1,edx,SIZEOF_FAST_FLOAT)], mm6
michael@0	183	movq MMWORD [MMBLOCK(1,3,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0	184	movq MMWORD [MMBLOCK(1,2,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0	185	movq MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0	186
michael@0	187	add edx, byte 2*DCTSIZE*SIZEOF_FAST_FLOAT
michael@0	188	dec ecx
michael@0	189	jnz near .rowloop
michael@0	190
michael@0	191	; ---- Pass 2: process columns.
michael@0	192
michael@0	193	mov edx, POINTER [data(eax)] ; (FAST_FLOAT *)
michael@0	194	mov ecx, DCTSIZE/2
michael@0	195	alignx 16,7
michael@0	196	.columnloop:
michael@0	197
michael@0	198	movq mm0, MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	199	movq mm1, MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	200	movq mm2, MMWORD [MMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	201	movq mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	202
michael@0	203	; mm0=(00 10), mm1=(01 11), mm2=(60 70), mm3=(61 71)
michael@0	204
michael@0	205	movq mm4,mm0 ; transpose coefficients
michael@0	206	punpckldq mm0,mm1 ; mm0=(00 01)=data0
michael@0	207	punpckhdq mm4,mm1 ; mm4=(10 11)=data1
michael@0	208	movq mm5,mm2 ; transpose coefficients
michael@0	209	punpckldq mm2,mm3 ; mm2=(60 61)=data6
michael@0	210	punpckhdq mm5,mm3 ; mm5=(70 71)=data7
michael@0	211
michael@0	212	movq mm6,mm4
michael@0	213	movq mm7,mm0
michael@0	214	pfsub mm4,mm2 ; mm4=data1-data6=tmp6
michael@0	215	pfsub mm0,mm5 ; mm0=data0-data7=tmp7
michael@0	216	pfadd mm6,mm2 ; mm6=data1+data6=tmp1
michael@0	217	pfadd mm7,mm5 ; mm7=data0+data7=tmp0
michael@0	218
michael@0	219	movq mm1, MMWORD [MMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	220	movq mm3, MMWORD [MMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	221	movq mm2, MMWORD [MMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	222	movq mm5, MMWORD [MMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)]
michael@0	223
michael@0	224	; mm1=(20 30), mm3=(21 31), mm2=(40 50), mm5=(41 51)
michael@0	225
michael@0	226	movq MMWORD [wk(0)], mm4 ; wk(0)=tmp6
michael@0	227	movq MMWORD [wk(1)], mm0 ; wk(1)=tmp7
michael@0	228
michael@0	229	movq mm4,mm1 ; transpose coefficients
michael@0	230	punpckldq mm1,mm3 ; mm1=(20 21)=data2
michael@0	231	punpckhdq mm4,mm3 ; mm4=(30 31)=data3
michael@0	232	movq mm0,mm2 ; transpose coefficients
michael@0	233	punpckldq mm2,mm5 ; mm2=(40 41)=data4
michael@0	234	punpckhdq mm0,mm5 ; mm0=(50 51)=data5
michael@0	235
michael@0	236	movq mm3,mm4
michael@0	237	movq mm5,mm1
michael@0	238	pfadd mm4,mm2 ; mm4=data3+data4=tmp3
michael@0	239	pfadd mm1,mm0 ; mm1=data2+data5=tmp2
michael@0	240	pfsub mm3,mm2 ; mm3=data3-data4=tmp4
michael@0	241	pfsub mm5,mm0 ; mm5=data2-data5=tmp5
michael@0	242
michael@0	243	; -- Even part
michael@0	244
michael@0	245	movq mm2,mm7
michael@0	246	movq mm0,mm6
michael@0	247	pfsub mm7,mm4 ; mm7=tmp13
michael@0	248	pfsub mm6,mm1 ; mm6=tmp12
michael@0	249	pfadd mm2,mm4 ; mm2=tmp10
michael@0	250	pfadd mm0,mm1 ; mm0=tmp11
michael@0	251
michael@0	252	pfadd mm6,mm7
michael@0	253	pfmul mm6,[GOTOFF(ebx,PD_0_707)] ; mm6=z1
michael@0	254
michael@0	255	movq mm4,mm2
michael@0	256	movq mm1,mm7
michael@0	257	pfsub mm2,mm0 ; mm2=data4
michael@0	258	pfsub mm7,mm6 ; mm7=data6
michael@0	259	pfadd mm4,mm0 ; mm4=data0
michael@0	260	pfadd mm1,mm6 ; mm1=data2
michael@0	261
michael@0	262	movq MMWORD [MMBLOCK(4,0,edx,SIZEOF_FAST_FLOAT)], mm2
michael@0	263	movq MMWORD [MMBLOCK(6,0,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0	264	movq MMWORD [MMBLOCK(0,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0	265	movq MMWORD [MMBLOCK(2,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0	266
michael@0	267	; -- Odd part
michael@0	268
michael@0	269	movq mm0, MMWORD [wk(0)] ; mm0=tmp6
michael@0	270	movq mm6, MMWORD [wk(1)] ; mm6=tmp7
michael@0	271
michael@0	272	pfadd mm3,mm5 ; mm3=tmp10
michael@0	273	pfadd mm5,mm0 ; mm5=tmp11
michael@0	274	pfadd mm0,mm6 ; mm0=tmp12, mm6=tmp7
michael@0	275
michael@0	276	pfmul mm5,[GOTOFF(ebx,PD_0_707)] ; mm5=z3
michael@0	277
michael@0	278	movq mm2,mm3 ; mm2=tmp10
michael@0	279	pfsub mm3,mm0
michael@0	280	pfmul mm3,[GOTOFF(ebx,PD_0_382)] ; mm3=z5
michael@0	281	pfmul mm2,[GOTOFF(ebx,PD_0_541)] ; mm2=MULTIPLY(tmp10,FIX_0_54119610)
michael@0	282	pfmul mm0,[GOTOFF(ebx,PD_1_306)] ; mm0=MULTIPLY(tmp12,FIX_1_30656296)
michael@0	283	pfadd mm2,mm3 ; mm2=z2
michael@0	284	pfadd mm0,mm3 ; mm0=z4
michael@0	285
michael@0	286	movq mm7,mm6
michael@0	287	pfsub mm6,mm5 ; mm6=z13
michael@0	288	pfadd mm7,mm5 ; mm7=z11
michael@0	289
michael@0	290	movq mm4,mm6
michael@0	291	movq mm1,mm7
michael@0	292	pfsub mm6,mm2 ; mm6=data3
michael@0	293	pfsub mm7,mm0 ; mm7=data7
michael@0	294	pfadd mm4,mm2 ; mm4=data5
michael@0	295	pfadd mm1,mm0 ; mm1=data1
michael@0	296
michael@0	297	movq MMWORD [MMBLOCK(3,0,edx,SIZEOF_FAST_FLOAT)], mm6
michael@0	298	movq MMWORD [MMBLOCK(7,0,edx,SIZEOF_FAST_FLOAT)], mm7
michael@0	299	movq MMWORD [MMBLOCK(5,0,edx,SIZEOF_FAST_FLOAT)], mm4
michael@0	300	movq MMWORD [MMBLOCK(1,0,edx,SIZEOF_FAST_FLOAT)], mm1
michael@0	301
michael@0	302	add edx, byte 2*SIZEOF_FAST_FLOAT
michael@0	303	dec ecx
michael@0	304	jnz near .columnloop
michael@0	305
michael@0	306	femms ; empty MMX/3DNow! state
michael@0	307
michael@0	308	; pop edi ; unused
michael@0	309	; pop esi ; unused
michael@0	310	; pop edx ; need not be preserved
michael@0	311	; pop ecx ; need not be preserved
michael@0	312	poppic ebx
michael@0	313	mov esp,ebp ; esp <- aligned ebp
michael@0	314	pop esp ; esp <- original ebp
michael@0	315	pop ebp
michael@0	316	ret
michael@0	317
michael@0	318	; For some reason, the OS X linker does not honor the request to align the
michael@0	319	; segment unless we do this.
michael@0	320	align 16