The Tor Browser / annotate

media/libjpeg/simd/jiss2flt.asm@6474c204b198 (annotated)

media/libjpeg/simd/jiss2flt.asm

Wed, 31 Dec 2014 06:09:35 +0100

author
Michael Schloh von Bennewitz <michael@schloh.com>
date
Wed, 31 Dec 2014 06:09:35 +0100
changeset 0
6474c204b198
permissions
-rw-r--r--

Cloned upstream origin tor-browser at tor-browser-31.3.0esr-4.5-1-build1
revision ID fc1c9ff7c1b2defdbc039f12214767608f46423f for hacking purpose.

michael@0 1 ;
michael@0 2 ; jiss2flt.asm - floating-point IDCT (SSE & SSE2)
michael@0 3 ;
michael@0 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0 5 ;
michael@0 6 ; Based on
michael@0 7 ; x86 SIMD extension for IJG JPEG library
michael@0 8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0 9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0 10 ;
michael@0 11 ; This file should be assembled with NASM (Netwide Assembler),
michael@0 12 ; can *not* be assembled with Microsoft's MASM or any compatible
michael@0 13 ; assembler (including Borland's Turbo Assembler).
michael@0 14 ; NASM is available from http://nasm.sourceforge.net/ or
michael@0 15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0 16 ;
michael@0 17 ; This file contains a floating-point implementation of the inverse DCT
michael@0 18 ; (Discrete Cosine Transform). The following code is based directly on
michael@0 19 ; the IJG's original jidctflt.c; see the jidctflt.c for more details.
michael@0 20 ;
michael@0 21 ; [TAB8]
michael@0 22
michael@0 23 %include "jsimdext.inc"
michael@0 24 %include "jdct.inc"
michael@0 25
michael@0 26 ; --------------------------------------------------------------------------
michael@0 27
michael@0 28 %macro unpcklps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(0 1 4 5)
michael@0 29 shufps %1,%2,0x44
michael@0 30 %endmacro
michael@0 31
michael@0 32 %macro unpckhps2 2 ; %1=(0 1 2 3) / %2=(4 5 6 7) => %1=(2 3 6 7)
michael@0 33 shufps %1,%2,0xEE
michael@0 34 %endmacro
michael@0 35
michael@0 36 ; --------------------------------------------------------------------------
michael@0 37 SECTION SEG_CONST
michael@0 38
michael@0 39 alignz 16
michael@0 40 global EXTN(jconst_idct_float_sse2)
michael@0 41
michael@0 42 EXTN(jconst_idct_float_sse2):
michael@0 43
michael@0 44 PD_1_414 times 4 dd 1.414213562373095048801689
michael@0 45 PD_1_847 times 4 dd 1.847759065022573512256366
michael@0 46 PD_1_082 times 4 dd 1.082392200292393968799446
michael@0 47 PD_M2_613 times 4 dd -2.613125929752753055713286
michael@0 48 PD_RNDINT_MAGIC times 4 dd 100663296.0 ; (float)(0x00C00000 << 3)
michael@0 49 PB_CENTERJSAMP times 16 db CENTERJSAMPLE
michael@0 50
michael@0 51 alignz 16
michael@0 52
michael@0 53 ; --------------------------------------------------------------------------
michael@0 54 SECTION SEG_TEXT
michael@0 55 BITS 32
michael@0 56 ;
michael@0 57 ; Perform dequantization and inverse DCT on one block of coefficients.
michael@0 58 ;
michael@0 59 ; GLOBAL(void)
michael@0 60 ; jsimd_idct_float_sse2 (void * dct_table, JCOEFPTR coef_block,
michael@0 61 ; JSAMPARRAY output_buf, JDIMENSION output_col)
michael@0 62 ;
michael@0 63
michael@0 64 %define dct_table(b) (b)+8 ; void * dct_table
michael@0 65 %define coef_block(b) (b)+12 ; JCOEFPTR coef_block
michael@0 66 %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
michael@0 67 %define output_col(b) (b)+20 ; JDIMENSION output_col
michael@0 68
michael@0 69 %define original_ebp ebp+0
michael@0 70 %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
michael@0 71 %define WK_NUM 2
michael@0 72 %define workspace wk(0)-DCTSIZE2*SIZEOF_FAST_FLOAT
michael@0 73 ; FAST_FLOAT workspace[DCTSIZE2]
michael@0 74
michael@0 75 align 16
michael@0 76 global EXTN(jsimd_idct_float_sse2)
michael@0 77
michael@0 78 EXTN(jsimd_idct_float_sse2):
michael@0 79 push ebp
michael@0 80 mov eax,esp ; eax = original ebp
michael@0 81 sub esp, byte 4
michael@0 82 and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
michael@0 83 mov [esp],eax
michael@0 84 mov ebp,esp ; ebp = aligned ebp
michael@0 85 lea esp, [workspace]
michael@0 86 push ebx
michael@0 87 ; push ecx ; need not be preserved
michael@0 88 ; push edx ; need not be preserved
michael@0 89 push esi
michael@0 90 push edi
michael@0 91
michael@0 92 get_GOT ebx ; get GOT address
michael@0 93
michael@0 94 ; ---- Pass 1: process columns from input, store into work array.
michael@0 95
michael@0 96 ; mov eax, [original_ebp]
michael@0 97 mov edx, POINTER [dct_table(eax)] ; quantptr
michael@0 98 mov esi, JCOEFPTR [coef_block(eax)] ; inptr
michael@0 99 lea edi, [workspace] ; FAST_FLOAT * wsptr
michael@0 100 mov ecx, DCTSIZE/4 ; ctr
michael@0 101 alignx 16,7
michael@0 102 .columnloop:
michael@0 103 %ifndef NO_ZERO_COLUMN_TEST_FLOAT_SSE
michael@0 104 mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 105 or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 106 jnz near .columnDCT
michael@0 107
michael@0 108 movq xmm1, XMM_MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 109 movq xmm2, XMM_MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 110 movq xmm3, XMM_MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 111 movq xmm4, XMM_MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0 112 movq xmm5, XMM_MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 113 movq xmm6, XMM_MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0 114 movq xmm7, XMM_MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 115 por xmm1,xmm2
michael@0 116 por xmm3,xmm4
michael@0 117 por xmm5,xmm6
michael@0 118 por xmm1,xmm3
michael@0 119 por xmm5,xmm7
michael@0 120 por xmm1,xmm5
michael@0 121 packsswb xmm1,xmm1
michael@0 122 movd eax,xmm1
michael@0 123 test eax,eax
michael@0 124 jnz short .columnDCT
michael@0 125
michael@0 126 ; -- AC terms all zero
michael@0 127
michael@0 128 movq xmm0, XMM_MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 129
michael@0 130 punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
michael@0 131 psrad xmm0,(DWORD_BIT-WORD_BIT) ; xmm0=in0=(00 01 02 03)
michael@0 132 cvtdq2ps xmm0,xmm0 ; xmm0=in0=(00 01 02 03)
michael@0 133
michael@0 134 mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 135
michael@0 136 movaps xmm1,xmm0
michael@0 137 movaps xmm2,xmm0
michael@0 138 movaps xmm3,xmm0
michael@0 139
michael@0 140 shufps xmm0,xmm0,0x00 ; xmm0=(00 00 00 00)
michael@0 141 shufps xmm1,xmm1,0x55 ; xmm1=(01 01 01 01)
michael@0 142 shufps xmm2,xmm2,0xAA ; xmm2=(02 02 02 02)
michael@0 143 shufps xmm3,xmm3,0xFF ; xmm3=(03 03 03 03)
michael@0 144
michael@0 145 movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0 146 movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0 147 movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm1
michael@0 148 movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm1
michael@0 149 movaps XMMWORD [XMMBLOCK(2,0,edi,SIZEOF_FAST_FLOAT)], xmm2
michael@0 150 movaps XMMWORD [XMMBLOCK(2,1,edi,SIZEOF_FAST_FLOAT)], xmm2
michael@0 151 movaps XMMWORD [XMMBLOCK(3,0,edi,SIZEOF_FAST_FLOAT)], xmm3
michael@0 152 movaps XMMWORD [XMMBLOCK(3,1,edi,SIZEOF_FAST_FLOAT)], xmm3
michael@0 153 jmp near .nextcolumn
michael@0 154 alignx 16,7
michael@0 155 %endif
michael@0 156 .columnDCT:
michael@0 157
michael@0 158 ; -- Even part
michael@0 159
michael@0 160 movq xmm0, XMM_MMWORD [MMBLOCK(0,0,esi,SIZEOF_JCOEF)]
michael@0 161 movq xmm1, XMM_MMWORD [MMBLOCK(2,0,esi,SIZEOF_JCOEF)]
michael@0 162 movq xmm2, XMM_MMWORD [MMBLOCK(4,0,esi,SIZEOF_JCOEF)]
michael@0 163 movq xmm3, XMM_MMWORD [MMBLOCK(6,0,esi,SIZEOF_JCOEF)]
michael@0 164
michael@0 165 punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
michael@0 166 punpcklwd xmm1,xmm1 ; xmm1=(20 20 21 21 22 22 23 23)
michael@0 167 psrad xmm0,(DWORD_BIT-WORD_BIT) ; xmm0=in0=(00 01 02 03)
michael@0 168 psrad xmm1,(DWORD_BIT-WORD_BIT) ; xmm1=in2=(20 21 22 23)
michael@0 169 cvtdq2ps xmm0,xmm0 ; xmm0=in0=(00 01 02 03)
michael@0 170 cvtdq2ps xmm1,xmm1 ; xmm1=in2=(20 21 22 23)
michael@0 171
michael@0 172 punpcklwd xmm2,xmm2 ; xmm2=(40 40 41 41 42 42 43 43)
michael@0 173 punpcklwd xmm3,xmm3 ; xmm3=(60 60 61 61 62 62 63 63)
michael@0 174 psrad xmm2,(DWORD_BIT-WORD_BIT) ; xmm2=in4=(40 41 42 43)
michael@0 175 psrad xmm3,(DWORD_BIT-WORD_BIT) ; xmm3=in6=(60 61 62 63)
michael@0 176 cvtdq2ps xmm2,xmm2 ; xmm2=in4=(40 41 42 43)
michael@0 177 cvtdq2ps xmm3,xmm3 ; xmm3=in6=(60 61 62 63)
michael@0 178
michael@0 179 mulps xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 180 mulps xmm1, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 181 mulps xmm2, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 182 mulps xmm3, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 183
michael@0 184 movaps xmm4,xmm0
michael@0 185 movaps xmm5,xmm1
michael@0 186 subps xmm0,xmm2 ; xmm0=tmp11
michael@0 187 subps xmm1,xmm3
michael@0 188 addps xmm4,xmm2 ; xmm4=tmp10
michael@0 189 addps xmm5,xmm3 ; xmm5=tmp13
michael@0 190
michael@0 191 mulps xmm1,[GOTOFF(ebx,PD_1_414)]
michael@0 192 subps xmm1,xmm5 ; xmm1=tmp12
michael@0 193
michael@0 194 movaps xmm6,xmm4
michael@0 195 movaps xmm7,xmm0
michael@0 196 subps xmm4,xmm5 ; xmm4=tmp3
michael@0 197 subps xmm0,xmm1 ; xmm0=tmp2
michael@0 198 addps xmm6,xmm5 ; xmm6=tmp0
michael@0 199 addps xmm7,xmm1 ; xmm7=tmp1
michael@0 200
michael@0 201 movaps XMMWORD [wk(1)], xmm4 ; tmp3
michael@0 202 movaps XMMWORD [wk(0)], xmm0 ; tmp2
michael@0 203
michael@0 204 ; -- Odd part
michael@0 205
michael@0 206 movq xmm2, XMM_MMWORD [MMBLOCK(1,0,esi,SIZEOF_JCOEF)]
michael@0 207 movq xmm3, XMM_MMWORD [MMBLOCK(3,0,esi,SIZEOF_JCOEF)]
michael@0 208 movq xmm5, XMM_MMWORD [MMBLOCK(5,0,esi,SIZEOF_JCOEF)]
michael@0 209 movq xmm1, XMM_MMWORD [MMBLOCK(7,0,esi,SIZEOF_JCOEF)]
michael@0 210
michael@0 211 punpcklwd xmm2,xmm2 ; xmm2=(10 10 11 11 12 12 13 13)
michael@0 212 punpcklwd xmm3,xmm3 ; xmm3=(30 30 31 31 32 32 33 33)
michael@0 213 psrad xmm2,(DWORD_BIT-WORD_BIT) ; xmm2=in1=(10 11 12 13)
michael@0 214 psrad xmm3,(DWORD_BIT-WORD_BIT) ; xmm3=in3=(30 31 32 33)
michael@0 215 cvtdq2ps xmm2,xmm2 ; xmm2=in1=(10 11 12 13)
michael@0 216 cvtdq2ps xmm3,xmm3 ; xmm3=in3=(30 31 32 33)
michael@0 217
michael@0 218 punpcklwd xmm5,xmm5 ; xmm5=(50 50 51 51 52 52 53 53)
michael@0 219 punpcklwd xmm1,xmm1 ; xmm1=(70 70 71 71 72 72 73 73)
michael@0 220 psrad xmm5,(DWORD_BIT-WORD_BIT) ; xmm5=in5=(50 51 52 53)
michael@0 221 psrad xmm1,(DWORD_BIT-WORD_BIT) ; xmm1=in7=(70 71 72 73)
michael@0 222 cvtdq2ps xmm5,xmm5 ; xmm5=in5=(50 51 52 53)
michael@0 223 cvtdq2ps xmm1,xmm1 ; xmm1=in7=(70 71 72 73)
michael@0 224
michael@0 225 mulps xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 226 mulps xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 227 mulps xmm5, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 228 mulps xmm1, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_FLOAT_MULT_TYPE)]
michael@0 229
michael@0 230 movaps xmm4,xmm2
michael@0 231 movaps xmm0,xmm5
michael@0 232 addps xmm2,xmm1 ; xmm2=z11
michael@0 233 addps xmm5,xmm3 ; xmm5=z13
michael@0 234 subps xmm4,xmm1 ; xmm4=z12
michael@0 235 subps xmm0,xmm3 ; xmm0=z10
michael@0 236
michael@0 237 movaps xmm1,xmm2
michael@0 238 subps xmm2,xmm5
michael@0 239 addps xmm1,xmm5 ; xmm1=tmp7
michael@0 240
michael@0 241 mulps xmm2,[GOTOFF(ebx,PD_1_414)] ; xmm2=tmp11
michael@0 242
michael@0 243 movaps xmm3,xmm0
michael@0 244 addps xmm0,xmm4
michael@0 245 mulps xmm0,[GOTOFF(ebx,PD_1_847)] ; xmm0=z5
michael@0 246 mulps xmm3,[GOTOFF(ebx,PD_M2_613)] ; xmm3=(z10 * -2.613125930)
michael@0 247 mulps xmm4,[GOTOFF(ebx,PD_1_082)] ; xmm4=(z12 * 1.082392200)
michael@0 248 addps xmm3,xmm0 ; xmm3=tmp12
michael@0 249 subps xmm4,xmm0 ; xmm4=tmp10
michael@0 250
michael@0 251 ; -- Final output stage
michael@0 252
michael@0 253 subps xmm3,xmm1 ; xmm3=tmp6
michael@0 254 movaps xmm5,xmm6
michael@0 255 movaps xmm0,xmm7
michael@0 256 addps xmm6,xmm1 ; xmm6=data0=(00 01 02 03)
michael@0 257 addps xmm7,xmm3 ; xmm7=data1=(10 11 12 13)
michael@0 258 subps xmm5,xmm1 ; xmm5=data7=(70 71 72 73)
michael@0 259 subps xmm0,xmm3 ; xmm0=data6=(60 61 62 63)
michael@0 260 subps xmm2,xmm3 ; xmm2=tmp5
michael@0 261
michael@0 262 movaps xmm1,xmm6 ; transpose coefficients(phase 1)
michael@0 263 unpcklps xmm6,xmm7 ; xmm6=(00 10 01 11)
michael@0 264 unpckhps xmm1,xmm7 ; xmm1=(02 12 03 13)
michael@0 265 movaps xmm3,xmm0 ; transpose coefficients(phase 1)
michael@0 266 unpcklps xmm0,xmm5 ; xmm0=(60 70 61 71)
michael@0 267 unpckhps xmm3,xmm5 ; xmm3=(62 72 63 73)
michael@0 268
michael@0 269 movaps xmm7, XMMWORD [wk(0)] ; xmm7=tmp2
michael@0 270 movaps xmm5, XMMWORD [wk(1)] ; xmm5=tmp3
michael@0 271
michael@0 272 movaps XMMWORD [wk(0)], xmm0 ; wk(0)=(60 70 61 71)
michael@0 273 movaps XMMWORD [wk(1)], xmm3 ; wk(1)=(62 72 63 73)
michael@0 274
michael@0 275 addps xmm4,xmm2 ; xmm4=tmp4
michael@0 276 movaps xmm0,xmm7
michael@0 277 movaps xmm3,xmm5
michael@0 278 addps xmm7,xmm2 ; xmm7=data2=(20 21 22 23)
michael@0 279 addps xmm5,xmm4 ; xmm5=data4=(40 41 42 43)
michael@0 280 subps xmm0,xmm2 ; xmm0=data5=(50 51 52 53)
michael@0 281 subps xmm3,xmm4 ; xmm3=data3=(30 31 32 33)
michael@0 282
michael@0 283 movaps xmm2,xmm7 ; transpose coefficients(phase 1)
michael@0 284 unpcklps xmm7,xmm3 ; xmm7=(20 30 21 31)
michael@0 285 unpckhps xmm2,xmm3 ; xmm2=(22 32 23 33)
michael@0 286 movaps xmm4,xmm5 ; transpose coefficients(phase 1)
michael@0 287 unpcklps xmm5,xmm0 ; xmm5=(40 50 41 51)
michael@0 288 unpckhps xmm4,xmm0 ; xmm4=(42 52 43 53)
michael@0 289
michael@0 290 movaps xmm3,xmm6 ; transpose coefficients(phase 2)
michael@0 291 unpcklps2 xmm6,xmm7 ; xmm6=(00 10 20 30)
michael@0 292 unpckhps2 xmm3,xmm7 ; xmm3=(01 11 21 31)
michael@0 293 movaps xmm0,xmm1 ; transpose coefficients(phase 2)
michael@0 294 unpcklps2 xmm1,xmm2 ; xmm1=(02 12 22 32)
michael@0 295 unpckhps2 xmm0,xmm2 ; xmm0=(03 13 23 33)
michael@0 296
michael@0 297 movaps xmm7, XMMWORD [wk(0)] ; xmm7=(60 70 61 71)
michael@0 298 movaps xmm2, XMMWORD [wk(1)] ; xmm2=(62 72 63 73)
michael@0 299
michael@0 300 movaps XMMWORD [XMMBLOCK(0,0,edi,SIZEOF_FAST_FLOAT)], xmm6
michael@0 301 movaps XMMWORD [XMMBLOCK(1,0,edi,SIZEOF_FAST_FLOAT)], xmm3
michael@0 302 movaps XMMWORD [XMMBLOCK(2,0,edi,SIZEOF_FAST_FLOAT)], xmm1
michael@0 303 movaps XMMWORD [XMMBLOCK(3,0,edi,SIZEOF_FAST_FLOAT)], xmm0
michael@0 304
michael@0 305 movaps xmm6,xmm5 ; transpose coefficients(phase 2)
michael@0 306 unpcklps2 xmm5,xmm7 ; xmm5=(40 50 60 70)
michael@0 307 unpckhps2 xmm6,xmm7 ; xmm6=(41 51 61 71)
michael@0 308 movaps xmm3,xmm4 ; transpose coefficients(phase 2)
michael@0 309 unpcklps2 xmm4,xmm2 ; xmm4=(42 52 62 72)
michael@0 310 unpckhps2 xmm3,xmm2 ; xmm3=(43 53 63 73)
michael@0 311
michael@0 312 movaps XMMWORD [XMMBLOCK(0,1,edi,SIZEOF_FAST_FLOAT)], xmm5
michael@0 313 movaps XMMWORD [XMMBLOCK(1,1,edi,SIZEOF_FAST_FLOAT)], xmm6
michael@0 314 movaps XMMWORD [XMMBLOCK(2,1,edi,SIZEOF_FAST_FLOAT)], xmm4
michael@0 315 movaps XMMWORD [XMMBLOCK(3,1,edi,SIZEOF_FAST_FLOAT)], xmm3
michael@0 316
michael@0 317 .nextcolumn:
michael@0 318 add esi, byte 4*SIZEOF_JCOEF ; coef_block
michael@0 319 add edx, byte 4*SIZEOF_FLOAT_MULT_TYPE ; quantptr
michael@0 320 add edi, 4*DCTSIZE*SIZEOF_FAST_FLOAT ; wsptr
michael@0 321 dec ecx ; ctr
michael@0 322 jnz near .columnloop
michael@0 323
michael@0 324 ; -- Prefetch the next coefficient block
michael@0 325
michael@0 326 prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 0*32]
michael@0 327 prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 1*32]
michael@0 328 prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 2*32]
michael@0 329 prefetchnta [esi + (DCTSIZE2-8)*SIZEOF_JCOEF + 3*32]
michael@0 330
michael@0 331 ; ---- Pass 2: process rows from work array, store into output array.
michael@0 332
michael@0 333 mov eax, [original_ebp]
michael@0 334 lea esi, [workspace] ; FAST_FLOAT * wsptr
michael@0 335 mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
michael@0 336 mov eax, JDIMENSION [output_col(eax)]
michael@0 337 mov ecx, DCTSIZE/4 ; ctr
michael@0 338 alignx 16,7
michael@0 339 .rowloop:
michael@0 340
michael@0 341 ; -- Even part
michael@0 342
michael@0 343 movaps xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 344 movaps xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 345 movaps xmm2, XMMWORD [XMMBLOCK(4,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 346 movaps xmm3, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 347
michael@0 348 movaps xmm4,xmm0
michael@0 349 movaps xmm5,xmm1
michael@0 350 subps xmm0,xmm2 ; xmm0=tmp11
michael@0 351 subps xmm1,xmm3
michael@0 352 addps xmm4,xmm2 ; xmm4=tmp10
michael@0 353 addps xmm5,xmm3 ; xmm5=tmp13
michael@0 354
michael@0 355 mulps xmm1,[GOTOFF(ebx,PD_1_414)]
michael@0 356 subps xmm1,xmm5 ; xmm1=tmp12
michael@0 357
michael@0 358 movaps xmm6,xmm4
michael@0 359 movaps xmm7,xmm0
michael@0 360 subps xmm4,xmm5 ; xmm4=tmp3
michael@0 361 subps xmm0,xmm1 ; xmm0=tmp2
michael@0 362 addps xmm6,xmm5 ; xmm6=tmp0
michael@0 363 addps xmm7,xmm1 ; xmm7=tmp1
michael@0 364
michael@0 365 movaps XMMWORD [wk(1)], xmm4 ; tmp3
michael@0 366 movaps XMMWORD [wk(0)], xmm0 ; tmp2
michael@0 367
michael@0 368 ; -- Odd part
michael@0 369
michael@0 370 movaps xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 371 movaps xmm3, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 372 movaps xmm5, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 373 movaps xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_FAST_FLOAT)]
michael@0 374
michael@0 375 movaps xmm4,xmm2
michael@0 376 movaps xmm0,xmm5
michael@0 377 addps xmm2,xmm1 ; xmm2=z11
michael@0 378 addps xmm5,xmm3 ; xmm5=z13
michael@0 379 subps xmm4,xmm1 ; xmm4=z12
michael@0 380 subps xmm0,xmm3 ; xmm0=z10
michael@0 381
michael@0 382 movaps xmm1,xmm2
michael@0 383 subps xmm2,xmm5
michael@0 384 addps xmm1,xmm5 ; xmm1=tmp7
michael@0 385
michael@0 386 mulps xmm2,[GOTOFF(ebx,PD_1_414)] ; xmm2=tmp11
michael@0 387
michael@0 388 movaps xmm3,xmm0
michael@0 389 addps xmm0,xmm4
michael@0 390 mulps xmm0,[GOTOFF(ebx,PD_1_847)] ; xmm0=z5
michael@0 391 mulps xmm3,[GOTOFF(ebx,PD_M2_613)] ; xmm3=(z10 * -2.613125930)
michael@0 392 mulps xmm4,[GOTOFF(ebx,PD_1_082)] ; xmm4=(z12 * 1.082392200)
michael@0 393 addps xmm3,xmm0 ; xmm3=tmp12
michael@0 394 subps xmm4,xmm0 ; xmm4=tmp10
michael@0 395
michael@0 396 ; -- Final output stage
michael@0 397
michael@0 398 subps xmm3,xmm1 ; xmm3=tmp6
michael@0 399 movaps xmm5,xmm6
michael@0 400 movaps xmm0,xmm7
michael@0 401 addps xmm6,xmm1 ; xmm6=data0=(00 10 20 30)
michael@0 402 addps xmm7,xmm3 ; xmm7=data1=(01 11 21 31)
michael@0 403 subps xmm5,xmm1 ; xmm5=data7=(07 17 27 37)
michael@0 404 subps xmm0,xmm3 ; xmm0=data6=(06 16 26 36)
michael@0 405 subps xmm2,xmm3 ; xmm2=tmp5
michael@0 406
michael@0 407 movaps xmm1,[GOTOFF(ebx,PD_RNDINT_MAGIC)] ; xmm1=[PD_RNDINT_MAGIC]
michael@0 408 pcmpeqd xmm3,xmm3
michael@0 409 psrld xmm3,WORD_BIT ; xmm3={0xFFFF 0x0000 0xFFFF 0x0000 ..}
michael@0 410
michael@0 411 addps xmm6,xmm1 ; xmm6=roundint(data0/8)=(00 ** 10 ** 20 ** 30 **)
michael@0 412 addps xmm7,xmm1 ; xmm7=roundint(data1/8)=(01 ** 11 ** 21 ** 31 **)
michael@0 413 addps xmm0,xmm1 ; xmm0=roundint(data6/8)=(06 ** 16 ** 26 ** 36 **)
michael@0 414 addps xmm5,xmm1 ; xmm5=roundint(data7/8)=(07 ** 17 ** 27 ** 37 **)
michael@0 415
michael@0 416 pand xmm6,xmm3 ; xmm6=(00 -- 10 -- 20 -- 30 --)
michael@0 417 pslld xmm7,WORD_BIT ; xmm7=(-- 01 -- 11 -- 21 -- 31)
michael@0 418 pand xmm0,xmm3 ; xmm0=(06 -- 16 -- 26 -- 36 --)
michael@0 419 pslld xmm5,WORD_BIT ; xmm5=(-- 07 -- 17 -- 27 -- 37)
michael@0 420 por xmm6,xmm7 ; xmm6=(00 01 10 11 20 21 30 31)
michael@0 421 por xmm0,xmm5 ; xmm0=(06 07 16 17 26 27 36 37)
michael@0 422
michael@0 423 movaps xmm1, XMMWORD [wk(0)] ; xmm1=tmp2
michael@0 424 movaps xmm3, XMMWORD [wk(1)] ; xmm3=tmp3
michael@0 425
michael@0 426 addps xmm4,xmm2 ; xmm4=tmp4
michael@0 427 movaps xmm7,xmm1
michael@0 428 movaps xmm5,xmm3
michael@0 429 addps xmm1,xmm2 ; xmm1=data2=(02 12 22 32)
michael@0 430 addps xmm3,xmm4 ; xmm3=data4=(04 14 24 34)
michael@0 431 subps xmm7,xmm2 ; xmm7=data5=(05 15 25 35)
michael@0 432 subps xmm5,xmm4 ; xmm5=data3=(03 13 23 33)
michael@0 433
michael@0 434 movaps xmm2,[GOTOFF(ebx,PD_RNDINT_MAGIC)] ; xmm2=[PD_RNDINT_MAGIC]
michael@0 435 pcmpeqd xmm4,xmm4
michael@0 436 psrld xmm4,WORD_BIT ; xmm4={0xFFFF 0x0000 0xFFFF 0x0000 ..}
michael@0 437
michael@0 438 addps xmm3,xmm2 ; xmm3=roundint(data4/8)=(04 ** 14 ** 24 ** 34 **)
michael@0 439 addps xmm7,xmm2 ; xmm7=roundint(data5/8)=(05 ** 15 ** 25 ** 35 **)
michael@0 440 addps xmm1,xmm2 ; xmm1=roundint(data2/8)=(02 ** 12 ** 22 ** 32 **)
michael@0 441 addps xmm5,xmm2 ; xmm5=roundint(data3/8)=(03 ** 13 ** 23 ** 33 **)
michael@0 442
michael@0 443 pand xmm3,xmm4 ; xmm3=(04 -- 14 -- 24 -- 34 --)
michael@0 444 pslld xmm7,WORD_BIT ; xmm7=(-- 05 -- 15 -- 25 -- 35)
michael@0 445 pand xmm1,xmm4 ; xmm1=(02 -- 12 -- 22 -- 32 --)
michael@0 446 pslld xmm5,WORD_BIT ; xmm5=(-- 03 -- 13 -- 23 -- 33)
michael@0 447 por xmm3,xmm7 ; xmm3=(04 05 14 15 24 25 34 35)
michael@0 448 por xmm1,xmm5 ; xmm1=(02 03 12 13 22 23 32 33)
michael@0 449
michael@0 450 movdqa xmm2,[GOTOFF(ebx,PB_CENTERJSAMP)] ; xmm2=[PB_CENTERJSAMP]
michael@0 451
michael@0 452 packsswb xmm6,xmm3 ; xmm6=(00 01 10 11 20 21 30 31 04 05 14 15 24 25 34 35)
michael@0 453 packsswb xmm1,xmm0 ; xmm1=(02 03 12 13 22 23 32 33 06 07 16 17 26 27 36 37)
michael@0 454 paddb xmm6,xmm2
michael@0 455 paddb xmm1,xmm2
michael@0 456
michael@0 457 movdqa xmm4,xmm6 ; transpose coefficients(phase 2)
michael@0 458 punpcklwd xmm6,xmm1 ; xmm6=(00 01 02 03 10 11 12 13 20 21 22 23 30 31 32 33)
michael@0 459 punpckhwd xmm4,xmm1 ; xmm4=(04 05 06 07 14 15 16 17 24 25 26 27 34 35 36 37)
michael@0 460
michael@0 461 movdqa xmm7,xmm6 ; transpose coefficients(phase 3)
michael@0 462 punpckldq xmm6,xmm4 ; xmm6=(00 01 02 03 04 05 06 07 10 11 12 13 14 15 16 17)
michael@0 463 punpckhdq xmm7,xmm4 ; xmm7=(20 21 22 23 24 25 26 27 30 31 32 33 34 35 36 37)
michael@0 464
michael@0 465 pshufd xmm5,xmm6,0x4E ; xmm5=(10 11 12 13 14 15 16 17 00 01 02 03 04 05 06 07)
michael@0 466 pshufd xmm3,xmm7,0x4E ; xmm3=(30 31 32 33 34 35 36 37 20 21 22 23 24 25 26 27)
michael@0 467
michael@0 468 pushpic ebx ; save GOT address
michael@0 469
michael@0 470 mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
michael@0 471 mov ebx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
michael@0 472 movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm6
michael@0 473 movq XMM_MMWORD [ebx+eax*SIZEOF_JSAMPLE], xmm7
michael@0 474 mov edx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
michael@0 475 mov ebx, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
michael@0 476 movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm5
michael@0 477 movq XMM_MMWORD [ebx+eax*SIZEOF_JSAMPLE], xmm3
michael@0 478
michael@0 479 poppic ebx ; restore GOT address
michael@0 480
michael@0 481 add esi, byte 4*SIZEOF_FAST_FLOAT ; wsptr
michael@0 482 add edi, byte 4*SIZEOF_JSAMPROW
michael@0 483 dec ecx ; ctr
michael@0 484 jnz near .rowloop
michael@0 485
michael@0 486 pop edi
michael@0 487 pop esi
michael@0 488 ; pop edx ; need not be preserved
michael@0 489 ; pop ecx ; need not be preserved
michael@0 490 pop ebx
michael@0 491 mov esp,ebp ; esp <- aligned ebp
michael@0 492 pop esp ; esp <- original ebp
michael@0 493 pop ebp
michael@0 494 ret
michael@0 495
michael@0 496 ; For some reason, the OS X linker does not honor the request to align the
michael@0 497 ; segment unless we do this.
michael@0 498 align 16

Mercurial Repository: The Tor Browser

Europalab SCM Repository Server

mercurial