1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jfss2fst-64.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,392 @@
1.4 +;
1.5 +; jfss2fst-64.asm - fast integer FDCT (64-bit SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +; Copyright 2009 D. R. Commander
1.9 +;
1.10 +; Based on
1.11 +; x86 SIMD extension for IJG JPEG library
1.12 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.13 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.14 +;
1.15 +; This file should be assembled with NASM (Netwide Assembler),
1.16 +; can *not* be assembled with Microsoft's MASM or any compatible
1.17 +; assembler (including Borland's Turbo Assembler).
1.18 +; NASM is available from http://nasm.sourceforge.net/ or
1.19 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.20 +;
1.21 +; This file contains a fast, not so accurate integer implementation of
1.22 +; the forward DCT (Discrete Cosine Transform). The following code is
1.23 +; based directly on the IJG's original jfdctfst.c; see the jfdctfst.c
1.24 +; for more details.
1.25 +;
1.26 +; [TAB8]
1.27 +
1.28 +%include "jsimdext.inc"
1.29 +%include "jdct.inc"
1.30 +
1.31 +; --------------------------------------------------------------------------
1.32 +
1.33 +%define CONST_BITS 8 ; 14 is also OK.
1.34 +
1.35 +%if CONST_BITS == 8
1.36 +F_0_382 equ 98 ; FIX(0.382683433)
1.37 +F_0_541 equ 139 ; FIX(0.541196100)
1.38 +F_0_707 equ 181 ; FIX(0.707106781)
1.39 +F_1_306 equ 334 ; FIX(1.306562965)
1.40 +%else
1.41 +; NASM cannot do compile-time arithmetic on floating-point constants.
1.42 +%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
1.43 +F_0_382 equ DESCALE( 410903207,30-CONST_BITS) ; FIX(0.382683433)
1.44 +F_0_541 equ DESCALE( 581104887,30-CONST_BITS) ; FIX(0.541196100)
1.45 +F_0_707 equ DESCALE( 759250124,30-CONST_BITS) ; FIX(0.707106781)
1.46 +F_1_306 equ DESCALE(1402911301,30-CONST_BITS) ; FIX(1.306562965)
1.47 +%endif
1.48 +
1.49 +; --------------------------------------------------------------------------
1.50 + SECTION SEG_CONST
1.51 +
1.52 +; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
1.53 +; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
1.54 +
1.55 +%define PRE_MULTIPLY_SCALE_BITS 2
1.56 +%define CONST_SHIFT (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
1.57 +
1.58 + alignz 16
1.59 + global EXTN(jconst_fdct_ifast_sse2)
1.60 +
1.61 +EXTN(jconst_fdct_ifast_sse2):
1.62 +
1.63 +PW_F0707 times 8 dw F_0_707 << CONST_SHIFT
1.64 +PW_F0382 times 8 dw F_0_382 << CONST_SHIFT
1.65 +PW_F0541 times 8 dw F_0_541 << CONST_SHIFT
1.66 +PW_F1306 times 8 dw F_1_306 << CONST_SHIFT
1.67 +
1.68 + alignz 16
1.69 +
1.70 +; --------------------------------------------------------------------------
1.71 + SECTION SEG_TEXT
1.72 + BITS 64
1.73 +;
1.74 +; Perform the forward DCT on one block of samples.
1.75 +;
1.76 +; GLOBAL(void)
1.77 +; jsimd_fdct_ifast_sse2 (DCTELEM * data)
1.78 +;
1.79 +
1.80 +; r10 = DCTELEM * data
1.81 +
1.82 +%define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.83 +%define WK_NUM 2
1.84 +
1.85 + align 16
1.86 + global EXTN(jsimd_fdct_ifast_sse2)
1.87 +
1.88 +EXTN(jsimd_fdct_ifast_sse2):
1.89 + push rbp
1.90 + mov rax,rsp ; rax = original rbp
1.91 + sub rsp, byte 4
1.92 + and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.93 + mov [rsp],rax
1.94 + mov rbp,rsp ; rbp = aligned rbp
1.95 + lea rsp, [wk(0)]
1.96 + collect_args
1.97 +
1.98 + ; ---- Pass 1: process rows.
1.99 +
1.100 + mov rdx, r10 ; (DCTELEM *)
1.101 +
1.102 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)]
1.103 + movdqa xmm1, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)]
1.104 + movdqa xmm2, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)]
1.105 + movdqa xmm3, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)]
1.106 +
1.107 + ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
1.108 + ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
1.109 +
1.110 + movdqa xmm4,xmm0 ; transpose coefficients(phase 1)
1.111 + punpcklwd xmm0,xmm1 ; xmm0=(00 10 01 11 02 12 03 13)
1.112 + punpckhwd xmm4,xmm1 ; xmm4=(04 14 05 15 06 16 07 17)
1.113 + movdqa xmm5,xmm2 ; transpose coefficients(phase 1)
1.114 + punpcklwd xmm2,xmm3 ; xmm2=(20 30 21 31 22 32 23 33)
1.115 + punpckhwd xmm5,xmm3 ; xmm5=(24 34 25 35 26 36 27 37)
1.116 +
1.117 + movdqa xmm6, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)]
1.118 + movdqa xmm7, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)]
1.119 + movdqa xmm1, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)]
1.120 + movdqa xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)]
1.121 +
1.122 + ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
1.123 + ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
1.124 +
1.125 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=(20 30 21 31 22 32 23 33)
1.126 + movdqa XMMWORD [wk(1)], xmm5 ; wk(1)=(24 34 25 35 26 36 27 37)
1.127 +
1.128 + movdqa xmm2,xmm6 ; transpose coefficients(phase 1)
1.129 + punpcklwd xmm6,xmm7 ; xmm6=(40 50 41 51 42 52 43 53)
1.130 + punpckhwd xmm2,xmm7 ; xmm2=(44 54 45 55 46 56 47 57)
1.131 + movdqa xmm5,xmm1 ; transpose coefficients(phase 1)
1.132 + punpcklwd xmm1,xmm3 ; xmm1=(60 70 61 71 62 72 63 73)
1.133 + punpckhwd xmm5,xmm3 ; xmm5=(64 74 65 75 66 76 67 77)
1.134 +
1.135 + movdqa xmm7,xmm6 ; transpose coefficients(phase 2)
1.136 + punpckldq xmm6,xmm1 ; xmm6=(40 50 60 70 41 51 61 71)
1.137 + punpckhdq xmm7,xmm1 ; xmm7=(42 52 62 72 43 53 63 73)
1.138 + movdqa xmm3,xmm2 ; transpose coefficients(phase 2)
1.139 + punpckldq xmm2,xmm5 ; xmm2=(44 54 64 74 45 55 65 75)
1.140 + punpckhdq xmm3,xmm5 ; xmm3=(46 56 66 76 47 57 67 77)
1.141 +
1.142 + movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(20 30 21 31 22 32 23 33)
1.143 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=(24 34 25 35 26 36 27 37)
1.144 + movdqa XMMWORD [wk(0)], xmm7 ; wk(0)=(42 52 62 72 43 53 63 73)
1.145 + movdqa XMMWORD [wk(1)], xmm2 ; wk(1)=(44 54 64 74 45 55 65 75)
1.146 +
1.147 + movdqa xmm7,xmm0 ; transpose coefficients(phase 2)
1.148 + punpckldq xmm0,xmm1 ; xmm0=(00 10 20 30 01 11 21 31)
1.149 + punpckhdq xmm7,xmm1 ; xmm7=(02 12 22 32 03 13 23 33)
1.150 + movdqa xmm2,xmm4 ; transpose coefficients(phase 2)
1.151 + punpckldq xmm4,xmm5 ; xmm4=(04 14 24 34 05 15 25 35)
1.152 + punpckhdq xmm2,xmm5 ; xmm2=(06 16 26 36 07 17 27 37)
1.153 +
1.154 + movdqa xmm1,xmm0 ; transpose coefficients(phase 3)
1.155 + punpcklqdq xmm0,xmm6 ; xmm0=(00 10 20 30 40 50 60 70)=data0
1.156 + punpckhqdq xmm1,xmm6 ; xmm1=(01 11 21 31 41 51 61 71)=data1
1.157 + movdqa xmm5,xmm2 ; transpose coefficients(phase 3)
1.158 + punpcklqdq xmm2,xmm3 ; xmm2=(06 16 26 36 46 56 66 76)=data6
1.159 + punpckhqdq xmm5,xmm3 ; xmm5=(07 17 27 37 47 57 67 77)=data7
1.160 +
1.161 + movdqa xmm6,xmm1
1.162 + movdqa xmm3,xmm0
1.163 + psubw xmm1,xmm2 ; xmm1=data1-data6=tmp6
1.164 + psubw xmm0,xmm5 ; xmm0=data0-data7=tmp7
1.165 + paddw xmm6,xmm2 ; xmm6=data1+data6=tmp1
1.166 + paddw xmm3,xmm5 ; xmm3=data0+data7=tmp0
1.167 +
1.168 + movdqa xmm2, XMMWORD [wk(0)] ; xmm2=(42 52 62 72 43 53 63 73)
1.169 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=(44 54 64 74 45 55 65 75)
1.170 + movdqa XMMWORD [wk(0)], xmm1 ; wk(0)=tmp6
1.171 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=tmp7
1.172 +
1.173 + movdqa xmm1,xmm7 ; transpose coefficients(phase 3)
1.174 + punpcklqdq xmm7,xmm2 ; xmm7=(02 12 22 32 42 52 62 72)=data2
1.175 + punpckhqdq xmm1,xmm2 ; xmm1=(03 13 23 33 43 53 63 73)=data3
1.176 + movdqa xmm0,xmm4 ; transpose coefficients(phase 3)
1.177 + punpcklqdq xmm4,xmm5 ; xmm4=(04 14 24 34 44 54 64 74)=data4
1.178 + punpckhqdq xmm0,xmm5 ; xmm0=(05 15 25 35 45 55 65 75)=data5
1.179 +
1.180 + movdqa xmm2,xmm1
1.181 + movdqa xmm5,xmm7
1.182 + paddw xmm1,xmm4 ; xmm1=data3+data4=tmp3
1.183 + paddw xmm7,xmm0 ; xmm7=data2+data5=tmp2
1.184 + psubw xmm2,xmm4 ; xmm2=data3-data4=tmp4
1.185 + psubw xmm5,xmm0 ; xmm5=data2-data5=tmp5
1.186 +
1.187 + ; -- Even part
1.188 +
1.189 + movdqa xmm4,xmm3
1.190 + movdqa xmm0,xmm6
1.191 + psubw xmm3,xmm1 ; xmm3=tmp13
1.192 + psubw xmm6,xmm7 ; xmm6=tmp12
1.193 + paddw xmm4,xmm1 ; xmm4=tmp10
1.194 + paddw xmm0,xmm7 ; xmm0=tmp11
1.195 +
1.196 + paddw xmm6,xmm3
1.197 + psllw xmm6,PRE_MULTIPLY_SCALE_BITS
1.198 + pmulhw xmm6,[rel PW_F0707] ; xmm6=z1
1.199 +
1.200 + movdqa xmm1,xmm4
1.201 + movdqa xmm7,xmm3
1.202 + psubw xmm4,xmm0 ; xmm4=data4
1.203 + psubw xmm3,xmm6 ; xmm3=data6
1.204 + paddw xmm1,xmm0 ; xmm1=data0
1.205 + paddw xmm7,xmm6 ; xmm7=data2
1.206 +
1.207 + movdqa xmm0, XMMWORD [wk(0)] ; xmm0=tmp6
1.208 + movdqa xmm6, XMMWORD [wk(1)] ; xmm6=tmp7
1.209 + movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=data4
1.210 + movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=data6
1.211 +
1.212 + ; -- Odd part
1.213 +
1.214 + paddw xmm2,xmm5 ; xmm2=tmp10
1.215 + paddw xmm5,xmm0 ; xmm5=tmp11
1.216 + paddw xmm0,xmm6 ; xmm0=tmp12, xmm6=tmp7
1.217 +
1.218 + psllw xmm2,PRE_MULTIPLY_SCALE_BITS
1.219 + psllw xmm0,PRE_MULTIPLY_SCALE_BITS
1.220 +
1.221 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.222 + pmulhw xmm5,[rel PW_F0707] ; xmm5=z3
1.223 +
1.224 + movdqa xmm4,xmm2 ; xmm4=tmp10
1.225 + psubw xmm2,xmm0
1.226 + pmulhw xmm2,[rel PW_F0382] ; xmm2=z5
1.227 + pmulhw xmm4,[rel PW_F0541] ; xmm4=MULTIPLY(tmp10,FIX_0_541196)
1.228 + pmulhw xmm0,[rel PW_F1306] ; xmm0=MULTIPLY(tmp12,FIX_1_306562)
1.229 + paddw xmm4,xmm2 ; xmm4=z2
1.230 + paddw xmm0,xmm2 ; xmm0=z4
1.231 +
1.232 + movdqa xmm3,xmm6
1.233 + psubw xmm6,xmm5 ; xmm6=z13
1.234 + paddw xmm3,xmm5 ; xmm3=z11
1.235 +
1.236 + movdqa xmm2,xmm6
1.237 + movdqa xmm5,xmm3
1.238 + psubw xmm6,xmm4 ; xmm6=data3
1.239 + psubw xmm3,xmm0 ; xmm3=data7
1.240 + paddw xmm2,xmm4 ; xmm2=data5
1.241 + paddw xmm5,xmm0 ; xmm5=data1
1.242 +
1.243 + ; ---- Pass 2: process columns.
1.244 +
1.245 + ; xmm1=(00 10 20 30 40 50 60 70), xmm7=(02 12 22 32 42 52 62 72)
1.246 + ; xmm5=(01 11 21 31 41 51 61 71), xmm6=(03 13 23 33 43 53 63 73)
1.247 +
1.248 + movdqa xmm4,xmm1 ; transpose coefficients(phase 1)
1.249 + punpcklwd xmm1,xmm5 ; xmm1=(00 01 10 11 20 21 30 31)
1.250 + punpckhwd xmm4,xmm5 ; xmm4=(40 41 50 51 60 61 70 71)
1.251 + movdqa xmm0,xmm7 ; transpose coefficients(phase 1)
1.252 + punpcklwd xmm7,xmm6 ; xmm7=(02 03 12 13 22 23 32 33)
1.253 + punpckhwd xmm0,xmm6 ; xmm0=(42 43 52 53 62 63 72 73)
1.254 +
1.255 + movdqa xmm5, XMMWORD [wk(0)] ; xmm5=col4
1.256 + movdqa xmm6, XMMWORD [wk(1)] ; xmm6=col6
1.257 +
1.258 + ; xmm5=(04 14 24 34 44 54 64 74), xmm6=(06 16 26 36 46 56 66 76)
1.259 + ; xmm2=(05 15 25 35 45 55 65 75), xmm3=(07 17 27 37 47 57 67 77)
1.260 +
1.261 + movdqa XMMWORD [wk(0)], xmm7 ; wk(0)=(02 03 12 13 22 23 32 33)
1.262 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=(42 43 52 53 62 63 72 73)
1.263 +
1.264 + movdqa xmm7,xmm5 ; transpose coefficients(phase 1)
1.265 + punpcklwd xmm5,xmm2 ; xmm5=(04 05 14 15 24 25 34 35)
1.266 + punpckhwd xmm7,xmm2 ; xmm7=(44 45 54 55 64 65 74 75)
1.267 + movdqa xmm0,xmm6 ; transpose coefficients(phase 1)
1.268 + punpcklwd xmm6,xmm3 ; xmm6=(06 07 16 17 26 27 36 37)
1.269 + punpckhwd xmm0,xmm3 ; xmm0=(46 47 56 57 66 67 76 77)
1.270 +
1.271 + movdqa xmm2,xmm5 ; transpose coefficients(phase 2)
1.272 + punpckldq xmm5,xmm6 ; xmm5=(04 05 06 07 14 15 16 17)
1.273 + punpckhdq xmm2,xmm6 ; xmm2=(24 25 26 27 34 35 36 37)
1.274 + movdqa xmm3,xmm7 ; transpose coefficients(phase 2)
1.275 + punpckldq xmm7,xmm0 ; xmm7=(44 45 46 47 54 55 56 57)
1.276 + punpckhdq xmm3,xmm0 ; xmm3=(64 65 66 67 74 75 76 77)
1.277 +
1.278 + movdqa xmm6, XMMWORD [wk(0)] ; xmm6=(02 03 12 13 22 23 32 33)
1.279 + movdqa xmm0, XMMWORD [wk(1)] ; xmm0=(42 43 52 53 62 63 72 73)
1.280 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=(24 25 26 27 34 35 36 37)
1.281 + movdqa XMMWORD [wk(1)], xmm7 ; wk(1)=(44 45 46 47 54 55 56 57)
1.282 +
1.283 + movdqa xmm2,xmm1 ; transpose coefficients(phase 2)
1.284 + punpckldq xmm1,xmm6 ; xmm1=(00 01 02 03 10 11 12 13)
1.285 + punpckhdq xmm2,xmm6 ; xmm2=(20 21 22 23 30 31 32 33)
1.286 + movdqa xmm7,xmm4 ; transpose coefficients(phase 2)
1.287 + punpckldq xmm4,xmm0 ; xmm4=(40 41 42 43 50 51 52 53)
1.288 + punpckhdq xmm7,xmm0 ; xmm7=(60 61 62 63 70 71 72 73)
1.289 +
1.290 + movdqa xmm6,xmm1 ; transpose coefficients(phase 3)
1.291 + punpcklqdq xmm1,xmm5 ; xmm1=(00 01 02 03 04 05 06 07)=data0
1.292 + punpckhqdq xmm6,xmm5 ; xmm6=(10 11 12 13 14 15 16 17)=data1
1.293 + movdqa xmm0,xmm7 ; transpose coefficients(phase 3)
1.294 + punpcklqdq xmm7,xmm3 ; xmm7=(60 61 62 63 64 65 66 67)=data6
1.295 + punpckhqdq xmm0,xmm3 ; xmm0=(70 71 72 73 74 75 76 77)=data7
1.296 +
1.297 + movdqa xmm5,xmm6
1.298 + movdqa xmm3,xmm1
1.299 + psubw xmm6,xmm7 ; xmm6=data1-data6=tmp6
1.300 + psubw xmm1,xmm0 ; xmm1=data0-data7=tmp7
1.301 + paddw xmm5,xmm7 ; xmm5=data1+data6=tmp1
1.302 + paddw xmm3,xmm0 ; xmm3=data0+data7=tmp0
1.303 +
1.304 + movdqa xmm7, XMMWORD [wk(0)] ; xmm7=(24 25 26 27 34 35 36 37)
1.305 + movdqa xmm0, XMMWORD [wk(1)] ; xmm0=(44 45 46 47 54 55 56 57)
1.306 + movdqa XMMWORD [wk(0)], xmm6 ; wk(0)=tmp6
1.307 + movdqa XMMWORD [wk(1)], xmm1 ; wk(1)=tmp7
1.308 +
1.309 + movdqa xmm6,xmm2 ; transpose coefficients(phase 3)
1.310 + punpcklqdq xmm2,xmm7 ; xmm2=(20 21 22 23 24 25 26 27)=data2
1.311 + punpckhqdq xmm6,xmm7 ; xmm6=(30 31 32 33 34 35 36 37)=data3
1.312 + movdqa xmm1,xmm4 ; transpose coefficients(phase 3)
1.313 + punpcklqdq xmm4,xmm0 ; xmm4=(40 41 42 43 44 45 46 47)=data4
1.314 + punpckhqdq xmm1,xmm0 ; xmm1=(50 51 52 53 54 55 56 57)=data5
1.315 +
1.316 + movdqa xmm7,xmm6
1.317 + movdqa xmm0,xmm2
1.318 + paddw xmm6,xmm4 ; xmm6=data3+data4=tmp3
1.319 + paddw xmm2,xmm1 ; xmm2=data2+data5=tmp2
1.320 + psubw xmm7,xmm4 ; xmm7=data3-data4=tmp4
1.321 + psubw xmm0,xmm1 ; xmm0=data2-data5=tmp5
1.322 +
1.323 + ; -- Even part
1.324 +
1.325 + movdqa xmm4,xmm3
1.326 + movdqa xmm1,xmm5
1.327 + psubw xmm3,xmm6 ; xmm3=tmp13
1.328 + psubw xmm5,xmm2 ; xmm5=tmp12
1.329 + paddw xmm4,xmm6 ; xmm4=tmp10
1.330 + paddw xmm1,xmm2 ; xmm1=tmp11
1.331 +
1.332 + paddw xmm5,xmm3
1.333 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.334 + pmulhw xmm5,[rel PW_F0707] ; xmm5=z1
1.335 +
1.336 + movdqa xmm6,xmm4
1.337 + movdqa xmm2,xmm3
1.338 + psubw xmm4,xmm1 ; xmm4=data4
1.339 + psubw xmm3,xmm5 ; xmm3=data6
1.340 + paddw xmm6,xmm1 ; xmm6=data0
1.341 + paddw xmm2,xmm5 ; xmm2=data2
1.342 +
1.343 + movdqa XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)], xmm4
1.344 + movdqa XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)], xmm3
1.345 + movdqa XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)], xmm6
1.346 + movdqa XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)], xmm2
1.347 +
1.348 + ; -- Odd part
1.349 +
1.350 + movdqa xmm1, XMMWORD [wk(0)] ; xmm1=tmp6
1.351 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp7
1.352 +
1.353 + paddw xmm7,xmm0 ; xmm7=tmp10
1.354 + paddw xmm0,xmm1 ; xmm0=tmp11
1.355 + paddw xmm1,xmm5 ; xmm1=tmp12, xmm5=tmp7
1.356 +
1.357 + psllw xmm7,PRE_MULTIPLY_SCALE_BITS
1.358 + psllw xmm1,PRE_MULTIPLY_SCALE_BITS
1.359 +
1.360 + psllw xmm0,PRE_MULTIPLY_SCALE_BITS
1.361 + pmulhw xmm0,[rel PW_F0707] ; xmm0=z3
1.362 +
1.363 + movdqa xmm4,xmm7 ; xmm4=tmp10
1.364 + psubw xmm7,xmm1
1.365 + pmulhw xmm7,[rel PW_F0382] ; xmm7=z5
1.366 + pmulhw xmm4,[rel PW_F0541] ; xmm4=MULTIPLY(tmp10,FIX_0_541196)
1.367 + pmulhw xmm1,[rel PW_F1306] ; xmm1=MULTIPLY(tmp12,FIX_1_306562)
1.368 + paddw xmm4,xmm7 ; xmm4=z2
1.369 + paddw xmm1,xmm7 ; xmm1=z4
1.370 +
1.371 + movdqa xmm3,xmm5
1.372 + psubw xmm5,xmm0 ; xmm5=z13
1.373 + paddw xmm3,xmm0 ; xmm3=z11
1.374 +
1.375 + movdqa xmm6,xmm5
1.376 + movdqa xmm2,xmm3
1.377 + psubw xmm5,xmm4 ; xmm5=data3
1.378 + psubw xmm3,xmm1 ; xmm3=data7
1.379 + paddw xmm6,xmm4 ; xmm6=data5
1.380 + paddw xmm2,xmm1 ; xmm2=data1
1.381 +
1.382 + movdqa XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)], xmm5
1.383 + movdqa XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)], xmm3
1.384 + movdqa XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)], xmm6
1.385 + movdqa XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)], xmm2
1.386 +
1.387 + uncollect_args
1.388 + mov rsp,rbp ; rsp <- aligned rbp
1.389 + pop rsp ; rsp <- original rbp
1.390 + pop rbp
1.391 + ret
1.392 +
1.393 +; For some reason, the OS X linker does not honor the request to align the
1.394 +; segment unless we do this.
1.395 + align 16
