1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/media/libjpeg/simd/jiss2fst.asm Wed Dec 31 06:09:35 2014 +0100
1.3 @@ -0,0 +1,502 @@
1.4 +;
1.5 +; jiss2fst.asm - fast integer IDCT (SSE2)
1.6 +;
1.7 +; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
1.8 +;
1.9 +; Based on
1.10 +; x86 SIMD extension for IJG JPEG library
1.11 +; Copyright (C) 1999-2006, MIYASAKA Masaru.
1.12 +; For conditions of distribution and use, see copyright notice in jsimdext.inc
1.13 +;
1.14 +; This file should be assembled with NASM (Netwide Assembler),
1.15 +; can *not* be assembled with Microsoft's MASM or any compatible
1.16 +; assembler (including Borland's Turbo Assembler).
1.17 +; NASM is available from http://nasm.sourceforge.net/ or
1.18 +; http://sourceforge.net/project/showfiles.php?group_id=6208
1.19 +;
1.20 +; This file contains a fast, not so accurate integer implementation of
1.21 +; the inverse DCT (Discrete Cosine Transform). The following code is
1.22 +; based directly on the IJG's original jidctfst.c; see the jidctfst.c
1.23 +; for more details.
1.24 +;
1.25 +; [TAB8]
1.26 +
1.27 +%include "jsimdext.inc"
1.28 +%include "jdct.inc"
1.29 +
1.30 +; --------------------------------------------------------------------------
1.31 +
1.32 +%define CONST_BITS 8 ; 14 is also OK.
1.33 +%define PASS1_BITS 2
1.34 +
1.35 +%if IFAST_SCALE_BITS != PASS1_BITS
1.36 +%error "'IFAST_SCALE_BITS' must be equal to 'PASS1_BITS'."
1.37 +%endif
1.38 +
1.39 +%if CONST_BITS == 8
1.40 +F_1_082 equ 277 ; FIX(1.082392200)
1.41 +F_1_414 equ 362 ; FIX(1.414213562)
1.42 +F_1_847 equ 473 ; FIX(1.847759065)
1.43 +F_2_613 equ 669 ; FIX(2.613125930)
1.44 +F_1_613 equ (F_2_613 - 256) ; FIX(2.613125930) - FIX(1)
1.45 +%else
1.46 +; NASM cannot do compile-time arithmetic on floating-point constants.
1.47 +%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
1.48 +F_1_082 equ DESCALE(1162209775,30-CONST_BITS) ; FIX(1.082392200)
1.49 +F_1_414 equ DESCALE(1518500249,30-CONST_BITS) ; FIX(1.414213562)
1.50 +F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)
1.51 +F_2_613 equ DESCALE(2805822602,30-CONST_BITS) ; FIX(2.613125930)
1.52 +F_1_613 equ (F_2_613 - (1 << CONST_BITS)) ; FIX(2.613125930) - FIX(1)
1.53 +%endif
1.54 +
1.55 +; --------------------------------------------------------------------------
1.56 + SECTION SEG_CONST
1.57 +
1.58 +; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
1.59 +; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
1.60 +
1.61 +%define PRE_MULTIPLY_SCALE_BITS 2
1.62 +%define CONST_SHIFT (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
1.63 +
1.64 + alignz 16
1.65 + global EXTN(jconst_idct_ifast_sse2)
1.66 +
1.67 +EXTN(jconst_idct_ifast_sse2):
1.68 +
1.69 +PW_F1414 times 8 dw F_1_414 << CONST_SHIFT
1.70 +PW_F1847 times 8 dw F_1_847 << CONST_SHIFT
1.71 +PW_MF1613 times 8 dw -F_1_613 << CONST_SHIFT
1.72 +PW_F1082 times 8 dw F_1_082 << CONST_SHIFT
1.73 +PB_CENTERJSAMP times 16 db CENTERJSAMPLE
1.74 +
1.75 + alignz 16
1.76 +
1.77 +; --------------------------------------------------------------------------
1.78 + SECTION SEG_TEXT
1.79 + BITS 32
1.80 +;
1.81 +; Perform dequantization and inverse DCT on one block of coefficients.
1.82 +;
1.83 +; GLOBAL(void)
1.84 +; jsimd_idct_ifast_sse2 (void * dct_table, JCOEFPTR coef_block,
1.85 +; JSAMPARRAY output_buf, JDIMENSION output_col)
1.86 +;
1.87 +
1.88 +%define dct_table(b) (b)+8 ; jpeg_component_info * compptr
1.89 +%define coef_block(b) (b)+12 ; JCOEFPTR coef_block
1.90 +%define output_buf(b) (b)+16 ; JSAMPARRAY output_buf
1.91 +%define output_col(b) (b)+20 ; JDIMENSION output_col
1.92 +
1.93 +%define original_ebp ebp+0
1.94 +%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
1.95 +%define WK_NUM 2
1.96 +
1.97 + align 16
1.98 + global EXTN(jsimd_idct_ifast_sse2)
1.99 +
1.100 +EXTN(jsimd_idct_ifast_sse2):
1.101 + push ebp
1.102 + mov eax,esp ; eax = original ebp
1.103 + sub esp, byte 4
1.104 + and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits
1.105 + mov [esp],eax
1.106 + mov ebp,esp ; ebp = aligned ebp
1.107 + lea esp, [wk(0)]
1.108 + pushpic ebx
1.109 +; push ecx ; unused
1.110 +; push edx ; need not be preserved
1.111 + push esi
1.112 + push edi
1.113 +
1.114 + get_GOT ebx ; get GOT address
1.115 +
1.116 + ; ---- Pass 1: process columns from input.
1.117 +
1.118 +; mov eax, [original_ebp]
1.119 + mov edx, POINTER [dct_table(eax)] ; quantptr
1.120 + mov esi, JCOEFPTR [coef_block(eax)] ; inptr
1.121 +
1.122 +%ifndef NO_ZERO_COLUMN_TEST_IFAST_SSE2
1.123 + mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.124 + or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.125 + jnz near .columnDCT
1.126 +
1.127 + movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.128 + movdqa xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.129 + por xmm0, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.130 + por xmm1, XMMWORD [XMMBLOCK(4,0,esi,SIZEOF_JCOEF)]
1.131 + por xmm0, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.132 + por xmm1, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.133 + por xmm0, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.134 + por xmm1,xmm0
1.135 + packsswb xmm1,xmm1
1.136 + packsswb xmm1,xmm1
1.137 + movd eax,xmm1
1.138 + test eax,eax
1.139 + jnz short .columnDCT
1.140 +
1.141 + ; -- AC terms all zero
1.142 +
1.143 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.144 + pmullw xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]
1.145 +
1.146 + movdqa xmm7,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07)
1.147 + punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)
1.148 + punpckhwd xmm7,xmm7 ; xmm7=(04 04 05 05 06 06 07 07)
1.149 +
1.150 + pshufd xmm6,xmm0,0x00 ; xmm6=col0=(00 00 00 00 00 00 00 00)
1.151 + pshufd xmm2,xmm0,0x55 ; xmm2=col1=(01 01 01 01 01 01 01 01)
1.152 + pshufd xmm5,xmm0,0xAA ; xmm5=col2=(02 02 02 02 02 02 02 02)
1.153 + pshufd xmm0,xmm0,0xFF ; xmm0=col3=(03 03 03 03 03 03 03 03)
1.154 + pshufd xmm1,xmm7,0x00 ; xmm1=col4=(04 04 04 04 04 04 04 04)
1.155 + pshufd xmm4,xmm7,0x55 ; xmm4=col5=(05 05 05 05 05 05 05 05)
1.156 + pshufd xmm3,xmm7,0xAA ; xmm3=col6=(06 06 06 06 06 06 06 06)
1.157 + pshufd xmm7,xmm7,0xFF ; xmm7=col7=(07 07 07 07 07 07 07 07)
1.158 +
1.159 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=col1
1.160 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=col3
1.161 + jmp near .column_end
1.162 + alignx 16,7
1.163 +%endif
1.164 +.columnDCT:
1.165 +
1.166 + ; -- Even part
1.167 +
1.168 + movdqa xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]
1.169 + movdqa xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]
1.170 + pmullw xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.171 + pmullw xmm1, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.172 + movdqa xmm2, XMMWORD [XMMBLOCK(4,0,esi,SIZEOF_JCOEF)]
1.173 + movdqa xmm3, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]
1.174 + pmullw xmm2, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.175 + pmullw xmm3, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.176 +
1.177 + movdqa xmm4,xmm0
1.178 + movdqa xmm5,xmm1
1.179 + psubw xmm0,xmm2 ; xmm0=tmp11
1.180 + psubw xmm1,xmm3
1.181 + paddw xmm4,xmm2 ; xmm4=tmp10
1.182 + paddw xmm5,xmm3 ; xmm5=tmp13
1.183 +
1.184 + psllw xmm1,PRE_MULTIPLY_SCALE_BITS
1.185 + pmulhw xmm1,[GOTOFF(ebx,PW_F1414)]
1.186 + psubw xmm1,xmm5 ; xmm1=tmp12
1.187 +
1.188 + movdqa xmm6,xmm4
1.189 + movdqa xmm7,xmm0
1.190 + psubw xmm4,xmm5 ; xmm4=tmp3
1.191 + psubw xmm0,xmm1 ; xmm0=tmp2
1.192 + paddw xmm6,xmm5 ; xmm6=tmp0
1.193 + paddw xmm7,xmm1 ; xmm7=tmp1
1.194 +
1.195 + movdqa XMMWORD [wk(1)], xmm4 ; wk(1)=tmp3
1.196 + movdqa XMMWORD [wk(0)], xmm0 ; wk(0)=tmp2
1.197 +
1.198 + ; -- Odd part
1.199 +
1.200 + movdqa xmm2, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]
1.201 + movdqa xmm3, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]
1.202 + pmullw xmm2, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.203 + pmullw xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.204 + movdqa xmm5, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]
1.205 + movdqa xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]
1.206 + pmullw xmm5, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.207 + pmullw xmm1, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_IFAST_MULT_TYPE)]
1.208 +
1.209 + movdqa xmm4,xmm2
1.210 + movdqa xmm0,xmm5
1.211 + psubw xmm2,xmm1 ; xmm2=z12
1.212 + psubw xmm5,xmm3 ; xmm5=z10
1.213 + paddw xmm4,xmm1 ; xmm4=z11
1.214 + paddw xmm0,xmm3 ; xmm0=z13
1.215 +
1.216 + movdqa xmm1,xmm5 ; xmm1=z10(unscaled)
1.217 + psllw xmm2,PRE_MULTIPLY_SCALE_BITS
1.218 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.219 +
1.220 + movdqa xmm3,xmm4
1.221 + psubw xmm4,xmm0
1.222 + paddw xmm3,xmm0 ; xmm3=tmp7
1.223 +
1.224 + psllw xmm4,PRE_MULTIPLY_SCALE_BITS
1.225 + pmulhw xmm4,[GOTOFF(ebx,PW_F1414)] ; xmm4=tmp11
1.226 +
1.227 + ; To avoid overflow...
1.228 + ;
1.229 + ; (Original)
1.230 + ; tmp12 = -2.613125930 * z10 + z5;
1.231 + ;
1.232 + ; (This implementation)
1.233 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.234 + ; = -1.613125930 * z10 - z10 + z5;
1.235 +
1.236 + movdqa xmm0,xmm5
1.237 + paddw xmm5,xmm2
1.238 + pmulhw xmm5,[GOTOFF(ebx,PW_F1847)] ; xmm5=z5
1.239 + pmulhw xmm0,[GOTOFF(ebx,PW_MF1613)]
1.240 + pmulhw xmm2,[GOTOFF(ebx,PW_F1082)]
1.241 + psubw xmm0,xmm1
1.242 + psubw xmm2,xmm5 ; xmm2=tmp10
1.243 + paddw xmm0,xmm5 ; xmm0=tmp12
1.244 +
1.245 + ; -- Final output stage
1.246 +
1.247 + psubw xmm0,xmm3 ; xmm0=tmp6
1.248 + movdqa xmm1,xmm6
1.249 + movdqa xmm5,xmm7
1.250 + paddw xmm6,xmm3 ; xmm6=data0=(00 01 02 03 04 05 06 07)
1.251 + paddw xmm7,xmm0 ; xmm7=data1=(10 11 12 13 14 15 16 17)
1.252 + psubw xmm1,xmm3 ; xmm1=data7=(70 71 72 73 74 75 76 77)
1.253 + psubw xmm5,xmm0 ; xmm5=data6=(60 61 62 63 64 65 66 67)
1.254 + psubw xmm4,xmm0 ; xmm4=tmp5
1.255 +
1.256 + movdqa xmm3,xmm6 ; transpose coefficients(phase 1)
1.257 + punpcklwd xmm6,xmm7 ; xmm6=(00 10 01 11 02 12 03 13)
1.258 + punpckhwd xmm3,xmm7 ; xmm3=(04 14 05 15 06 16 07 17)
1.259 + movdqa xmm0,xmm5 ; transpose coefficients(phase 1)
1.260 + punpcklwd xmm5,xmm1 ; xmm5=(60 70 61 71 62 72 63 73)
1.261 + punpckhwd xmm0,xmm1 ; xmm0=(64 74 65 75 66 76 67 77)
1.262 +
1.263 + movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp2
1.264 + movdqa xmm1, XMMWORD [wk(1)] ; xmm1=tmp3
1.265 +
1.266 + movdqa XMMWORD [wk(0)], xmm5 ; wk(0)=(60 70 61 71 62 72 63 73)
1.267 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=(64 74 65 75 66 76 67 77)
1.268 +
1.269 + paddw xmm2,xmm4 ; xmm2=tmp4
1.270 + movdqa xmm5,xmm7
1.271 + movdqa xmm0,xmm1
1.272 + paddw xmm7,xmm4 ; xmm7=data2=(20 21 22 23 24 25 26 27)
1.273 + paddw xmm1,xmm2 ; xmm1=data4=(40 41 42 43 44 45 46 47)
1.274 + psubw xmm5,xmm4 ; xmm5=data5=(50 51 52 53 54 55 56 57)
1.275 + psubw xmm0,xmm2 ; xmm0=data3=(30 31 32 33 34 35 36 37)
1.276 +
1.277 + movdqa xmm4,xmm7 ; transpose coefficients(phase 1)
1.278 + punpcklwd xmm7,xmm0 ; xmm7=(20 30 21 31 22 32 23 33)
1.279 + punpckhwd xmm4,xmm0 ; xmm4=(24 34 25 35 26 36 27 37)
1.280 + movdqa xmm2,xmm1 ; transpose coefficients(phase 1)
1.281 + punpcklwd xmm1,xmm5 ; xmm1=(40 50 41 51 42 52 43 53)
1.282 + punpckhwd xmm2,xmm5 ; xmm2=(44 54 45 55 46 56 47 57)
1.283 +
1.284 + movdqa xmm0,xmm3 ; transpose coefficients(phase 2)
1.285 + punpckldq xmm3,xmm4 ; xmm3=(04 14 24 34 05 15 25 35)
1.286 + punpckhdq xmm0,xmm4 ; xmm0=(06 16 26 36 07 17 27 37)
1.287 + movdqa xmm5,xmm6 ; transpose coefficients(phase 2)
1.288 + punpckldq xmm6,xmm7 ; xmm6=(00 10 20 30 01 11 21 31)
1.289 + punpckhdq xmm5,xmm7 ; xmm5=(02 12 22 32 03 13 23 33)
1.290 +
1.291 + movdqa xmm4, XMMWORD [wk(0)] ; xmm4=(60 70 61 71 62 72 63 73)
1.292 + movdqa xmm7, XMMWORD [wk(1)] ; xmm7=(64 74 65 75 66 76 67 77)
1.293 +
1.294 + movdqa XMMWORD [wk(0)], xmm3 ; wk(0)=(04 14 24 34 05 15 25 35)
1.295 + movdqa XMMWORD [wk(1)], xmm0 ; wk(1)=(06 16 26 36 07 17 27 37)
1.296 +
1.297 + movdqa xmm3,xmm1 ; transpose coefficients(phase 2)
1.298 + punpckldq xmm1,xmm4 ; xmm1=(40 50 60 70 41 51 61 71)
1.299 + punpckhdq xmm3,xmm4 ; xmm3=(42 52 62 72 43 53 63 73)
1.300 + movdqa xmm0,xmm2 ; transpose coefficients(phase 2)
1.301 + punpckldq xmm2,xmm7 ; xmm2=(44 54 64 74 45 55 65 75)
1.302 + punpckhdq xmm0,xmm7 ; xmm0=(46 56 66 76 47 57 67 77)
1.303 +
1.304 + movdqa xmm4,xmm6 ; transpose coefficients(phase 3)
1.305 + punpcklqdq xmm6,xmm1 ; xmm6=col0=(00 10 20 30 40 50 60 70)
1.306 + punpckhqdq xmm4,xmm1 ; xmm4=col1=(01 11 21 31 41 51 61 71)
1.307 + movdqa xmm7,xmm5 ; transpose coefficients(phase 3)
1.308 + punpcklqdq xmm5,xmm3 ; xmm5=col2=(02 12 22 32 42 52 62 72)
1.309 + punpckhqdq xmm7,xmm3 ; xmm7=col3=(03 13 23 33 43 53 63 73)
1.310 +
1.311 + movdqa xmm1, XMMWORD [wk(0)] ; xmm1=(04 14 24 34 05 15 25 35)
1.312 + movdqa xmm3, XMMWORD [wk(1)] ; xmm3=(06 16 26 36 07 17 27 37)
1.313 +
1.314 + movdqa XMMWORD [wk(0)], xmm4 ; wk(0)=col1
1.315 + movdqa XMMWORD [wk(1)], xmm7 ; wk(1)=col3
1.316 +
1.317 + movdqa xmm4,xmm1 ; transpose coefficients(phase 3)
1.318 + punpcklqdq xmm1,xmm2 ; xmm1=col4=(04 14 24 34 44 54 64 74)
1.319 + punpckhqdq xmm4,xmm2 ; xmm4=col5=(05 15 25 35 45 55 65 75)
1.320 + movdqa xmm7,xmm3 ; transpose coefficients(phase 3)
1.321 + punpcklqdq xmm3,xmm0 ; xmm3=col6=(06 16 26 36 46 56 66 76)
1.322 + punpckhqdq xmm7,xmm0 ; xmm7=col7=(07 17 27 37 47 57 67 77)
1.323 +.column_end:
1.324 +
1.325 + ; -- Prefetch the next coefficient block
1.326 +
1.327 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 0*32]
1.328 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 1*32]
1.329 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 2*32]
1.330 + prefetchnta [esi + DCTSIZE2*SIZEOF_JCOEF + 3*32]
1.331 +
1.332 + ; ---- Pass 2: process rows from work array, store into output array.
1.333 +
1.334 + mov eax, [original_ebp]
1.335 + mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)
1.336 + mov eax, JDIMENSION [output_col(eax)]
1.337 +
1.338 + ; -- Even part
1.339 +
1.340 + ; xmm6=col0, xmm5=col2, xmm1=col4, xmm3=col6
1.341 +
1.342 + movdqa xmm2,xmm6
1.343 + movdqa xmm0,xmm5
1.344 + psubw xmm6,xmm1 ; xmm6=tmp11
1.345 + psubw xmm5,xmm3
1.346 + paddw xmm2,xmm1 ; xmm2=tmp10
1.347 + paddw xmm0,xmm3 ; xmm0=tmp13
1.348 +
1.349 + psllw xmm5,PRE_MULTIPLY_SCALE_BITS
1.350 + pmulhw xmm5,[GOTOFF(ebx,PW_F1414)]
1.351 + psubw xmm5,xmm0 ; xmm5=tmp12
1.352 +
1.353 + movdqa xmm1,xmm2
1.354 + movdqa xmm3,xmm6
1.355 + psubw xmm2,xmm0 ; xmm2=tmp3
1.356 + psubw xmm6,xmm5 ; xmm6=tmp2
1.357 + paddw xmm1,xmm0 ; xmm1=tmp0
1.358 + paddw xmm3,xmm5 ; xmm3=tmp1
1.359 +
1.360 + movdqa xmm0, XMMWORD [wk(0)] ; xmm0=col1
1.361 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=col3
1.362 +
1.363 + movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp3
1.364 + movdqa XMMWORD [wk(1)], xmm6 ; wk(1)=tmp2
1.365 +
1.366 + ; -- Odd part
1.367 +
1.368 + ; xmm0=col1, xmm5=col3, xmm4=col5, xmm7=col7
1.369 +
1.370 + movdqa xmm2,xmm0
1.371 + movdqa xmm6,xmm4
1.372 + psubw xmm0,xmm7 ; xmm0=z12
1.373 + psubw xmm4,xmm5 ; xmm4=z10
1.374 + paddw xmm2,xmm7 ; xmm2=z11
1.375 + paddw xmm6,xmm5 ; xmm6=z13
1.376 +
1.377 + movdqa xmm7,xmm4 ; xmm7=z10(unscaled)
1.378 + psllw xmm0,PRE_MULTIPLY_SCALE_BITS
1.379 + psllw xmm4,PRE_MULTIPLY_SCALE_BITS
1.380 +
1.381 + movdqa xmm5,xmm2
1.382 + psubw xmm2,xmm6
1.383 + paddw xmm5,xmm6 ; xmm5=tmp7
1.384 +
1.385 + psllw xmm2,PRE_MULTIPLY_SCALE_BITS
1.386 + pmulhw xmm2,[GOTOFF(ebx,PW_F1414)] ; xmm2=tmp11
1.387 +
1.388 + ; To avoid overflow...
1.389 + ;
1.390 + ; (Original)
1.391 + ; tmp12 = -2.613125930 * z10 + z5;
1.392 + ;
1.393 + ; (This implementation)
1.394 + ; tmp12 = (-1.613125930 - 1) * z10 + z5;
1.395 + ; = -1.613125930 * z10 - z10 + z5;
1.396 +
1.397 + movdqa xmm6,xmm4
1.398 + paddw xmm4,xmm0
1.399 + pmulhw xmm4,[GOTOFF(ebx,PW_F1847)] ; xmm4=z5
1.400 + pmulhw xmm6,[GOTOFF(ebx,PW_MF1613)]
1.401 + pmulhw xmm0,[GOTOFF(ebx,PW_F1082)]
1.402 + psubw xmm6,xmm7
1.403 + psubw xmm0,xmm4 ; xmm0=tmp10
1.404 + paddw xmm6,xmm4 ; xmm6=tmp12
1.405 +
1.406 + ; -- Final output stage
1.407 +
1.408 + psubw xmm6,xmm5 ; xmm6=tmp6
1.409 + movdqa xmm7,xmm1
1.410 + movdqa xmm4,xmm3
1.411 + paddw xmm1,xmm5 ; xmm1=data0=(00 10 20 30 40 50 60 70)
1.412 + paddw xmm3,xmm6 ; xmm3=data1=(01 11 21 31 41 51 61 71)
1.413 + psraw xmm1,(PASS1_BITS+3) ; descale
1.414 + psraw xmm3,(PASS1_BITS+3) ; descale
1.415 + psubw xmm7,xmm5 ; xmm7=data7=(07 17 27 37 47 57 67 77)
1.416 + psubw xmm4,xmm6 ; xmm4=data6=(06 16 26 36 46 56 66 76)
1.417 + psraw xmm7,(PASS1_BITS+3) ; descale
1.418 + psraw xmm4,(PASS1_BITS+3) ; descale
1.419 + psubw xmm2,xmm6 ; xmm2=tmp5
1.420 +
1.421 + packsswb xmm1,xmm4 ; xmm1=(00 10 20 30 40 50 60 70 06 16 26 36 46 56 66 76)
1.422 + packsswb xmm3,xmm7 ; xmm3=(01 11 21 31 41 51 61 71 07 17 27 37 47 57 67 77)
1.423 +
1.424 + movdqa xmm5, XMMWORD [wk(1)] ; xmm5=tmp2
1.425 + movdqa xmm6, XMMWORD [wk(0)] ; xmm6=tmp3
1.426 +
1.427 + paddw xmm0,xmm2 ; xmm0=tmp4
1.428 + movdqa xmm4,xmm5
1.429 + movdqa xmm7,xmm6
1.430 + paddw xmm5,xmm2 ; xmm5=data2=(02 12 22 32 42 52 62 72)
1.431 + paddw xmm6,xmm0 ; xmm6=data4=(04 14 24 34 44 54 64 74)
1.432 + psraw xmm5,(PASS1_BITS+3) ; descale
1.433 + psraw xmm6,(PASS1_BITS+3) ; descale
1.434 + psubw xmm4,xmm2 ; xmm4=data5=(05 15 25 35 45 55 65 75)
1.435 + psubw xmm7,xmm0 ; xmm7=data3=(03 13 23 33 43 53 63 73)
1.436 + psraw xmm4,(PASS1_BITS+3) ; descale
1.437 + psraw xmm7,(PASS1_BITS+3) ; descale
1.438 +
1.439 + movdqa xmm2,[GOTOFF(ebx,PB_CENTERJSAMP)] ; xmm2=[PB_CENTERJSAMP]
1.440 +
1.441 + packsswb xmm5,xmm6 ; xmm5=(02 12 22 32 42 52 62 72 04 14 24 34 44 54 64 74)
1.442 + packsswb xmm7,xmm4 ; xmm7=(03 13 23 33 43 53 63 73 05 15 25 35 45 55 65 75)
1.443 +
1.444 + paddb xmm1,xmm2
1.445 + paddb xmm3,xmm2
1.446 + paddb xmm5,xmm2
1.447 + paddb xmm7,xmm2
1.448 +
1.449 + movdqa xmm0,xmm1 ; transpose coefficients(phase 1)
1.450 + punpcklbw xmm1,xmm3 ; xmm1=(00 01 10 11 20 21 30 31 40 41 50 51 60 61 70 71)
1.451 + punpckhbw xmm0,xmm3 ; xmm0=(06 07 16 17 26 27 36 37 46 47 56 57 66 67 76 77)
1.452 + movdqa xmm6,xmm5 ; transpose coefficients(phase 1)
1.453 + punpcklbw xmm5,xmm7 ; xmm5=(02 03 12 13 22 23 32 33 42 43 52 53 62 63 72 73)
1.454 + punpckhbw xmm6,xmm7 ; xmm6=(04 05 14 15 24 25 34 35 44 45 54 55 64 65 74 75)
1.455 +
1.456 + movdqa xmm4,xmm1 ; transpose coefficients(phase 2)
1.457 + punpcklwd xmm1,xmm5 ; xmm1=(00 01 02 03 10 11 12 13 20 21 22 23 30 31 32 33)
1.458 + punpckhwd xmm4,xmm5 ; xmm4=(40 41 42 43 50 51 52 53 60 61 62 63 70 71 72 73)
1.459 + movdqa xmm2,xmm6 ; transpose coefficients(phase 2)
1.460 + punpcklwd xmm6,xmm0 ; xmm6=(04 05 06 07 14 15 16 17 24 25 26 27 34 35 36 37)
1.461 + punpckhwd xmm2,xmm0 ; xmm2=(44 45 46 47 54 55 56 57 64 65 66 67 74 75 76 77)
1.462 +
1.463 + movdqa xmm3,xmm1 ; transpose coefficients(phase 3)
1.464 + punpckldq xmm1,xmm6 ; xmm1=(00 01 02 03 04 05 06 07 10 11 12 13 14 15 16 17)
1.465 + punpckhdq xmm3,xmm6 ; xmm3=(20 21 22 23 24 25 26 27 30 31 32 33 34 35 36 37)
1.466 + movdqa xmm7,xmm4 ; transpose coefficients(phase 3)
1.467 + punpckldq xmm4,xmm2 ; xmm4=(40 41 42 43 44 45 46 47 50 51 52 53 54 55 56 57)
1.468 + punpckhdq xmm7,xmm2 ; xmm7=(60 61 62 63 64 65 66 67 70 71 72 73 74 75 76 77)
1.469 +
1.470 + pshufd xmm5,xmm1,0x4E ; xmm5=(10 11 12 13 14 15 16 17 00 01 02 03 04 05 06 07)
1.471 + pshufd xmm0,xmm3,0x4E ; xmm0=(30 31 32 33 34 35 36 37 20 21 22 23 24 25 26 27)
1.472 + pshufd xmm6,xmm4,0x4E ; xmm6=(50 51 52 53 54 55 56 57 40 41 42 43 44 45 46 47)
1.473 + pshufd xmm2,xmm7,0x4E ; xmm2=(70 71 72 73 74 75 76 77 60 61 62 63 64 65 66 67)
1.474 +
1.475 + mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]
1.476 + mov esi, JSAMPROW [edi+2*SIZEOF_JSAMPROW]
1.477 + movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm1
1.478 + movq XMM_MMWORD [esi+eax*SIZEOF_JSAMPLE], xmm3
1.479 + mov edx, JSAMPROW [edi+4*SIZEOF_JSAMPROW]
1.480 + mov esi, JSAMPROW [edi+6*SIZEOF_JSAMPROW]
1.481 + movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm4
1.482 + movq XMM_MMWORD [esi+eax*SIZEOF_JSAMPLE], xmm7
1.483 +
1.484 + mov edx, JSAMPROW [edi+1*SIZEOF_JSAMPROW]
1.485 + mov esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]
1.486 + movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm5
1.487 + movq XMM_MMWORD [esi+eax*SIZEOF_JSAMPLE], xmm0
1.488 + mov edx, JSAMPROW [edi+5*SIZEOF_JSAMPROW]
1.489 + mov esi, JSAMPROW [edi+7*SIZEOF_JSAMPROW]
1.490 + movq XMM_MMWORD [edx+eax*SIZEOF_JSAMPLE], xmm6
1.491 + movq XMM_MMWORD [esi+eax*SIZEOF_JSAMPLE], xmm2
1.492 +
1.493 + pop edi
1.494 + pop esi
1.495 +; pop edx ; need not be preserved
1.496 +; pop ecx ; unused
1.497 + poppic ebx
1.498 + mov esp,ebp ; esp <- aligned ebp
1.499 + pop esp ; esp <- original ebp
1.500 + pop ebp
1.501 + ret
1.502 +
1.503 +; For some reason, the OS X linker does not honor the request to align the
1.504 +; segment unless we do this.
1.505 + align 16
