• file
• revisions
• annotate
• diff
• comparison
• raw

media/libjpeg/simd/jfmmxfst.asm@6474c204b198 (annotated)

media/libjpeg/simd/jfmmxfst.asm

Wed, 31 Dec 2014 06:09:35 +0100

author

Michael Schloh von Bennewitz <michael@schloh.com>

date

Wed, 31 Dec 2014 06:09:35 +0100

changeset 0

6474c204b198

permissions

-rw-r--r--

Cloned upstream origin tor-browser at tor-browser-31.3.0esr-4.5-1-build1
revision ID fc1c9ff7c1b2defdbc039f12214767608f46423f for hacking purpose.

michael@0	1	;
michael@0	2	; jfmmxfst.asm - fast integer FDCT (MMX)
michael@0	3	;
michael@0	4	; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
michael@0	5	;
michael@0	6	; Based on
michael@0	7	; x86 SIMD extension for IJG JPEG library
michael@0	8	; Copyright (C) 1999-2006, MIYASAKA Masaru.
michael@0	9	; For conditions of distribution and use, see copyright notice in jsimdext.inc
michael@0	10	;
michael@0	11	; This file should be assembled with NASM (Netwide Assembler),
michael@0	12	; can *not* be assembled with Microsoft's MASM or any compatible
michael@0	13	; assembler (including Borland's Turbo Assembler).
michael@0	14	; NASM is available from http://nasm.sourceforge.net/ or
michael@0	15	; http://sourceforge.net/project/showfiles.php?group_id=6208
michael@0	16	;
michael@0	17	; This file contains a fast, not so accurate integer implementation of
michael@0	18	; the forward DCT (Discrete Cosine Transform). The following code is
michael@0	19	; based directly on the IJG's original jfdctfst.c; see the jfdctfst.c
michael@0	20	; for more details.
michael@0	21	;
michael@0	22	; [TAB8]
michael@0	23
michael@0	24	%include "jsimdext.inc"
michael@0	25	%include "jdct.inc"
michael@0	26
michael@0	27	; --------------------------------------------------------------------------
michael@0	28
michael@0	29	%define CONST_BITS 8 ; 14 is also OK.
michael@0	30
michael@0	31	%if CONST_BITS == 8
michael@0	32	F_0_382 equ 98 ; FIX(0.382683433)
michael@0	33	F_0_541 equ 139 ; FIX(0.541196100)
michael@0	34	F_0_707 equ 181 ; FIX(0.707106781)
michael@0	35	F_1_306 equ 334 ; FIX(1.306562965)
michael@0	36	%else
michael@0	37	; NASM cannot do compile-time arithmetic on floating-point constants.
michael@0	38	%define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))
michael@0	39	F_0_382 equ DESCALE( 410903207,30-CONST_BITS) ; FIX(0.382683433)
michael@0	40	F_0_541 equ DESCALE( 581104887,30-CONST_BITS) ; FIX(0.541196100)
michael@0	41	F_0_707 equ DESCALE( 759250124,30-CONST_BITS) ; FIX(0.707106781)
michael@0	42	F_1_306 equ DESCALE(1402911301,30-CONST_BITS) ; FIX(1.306562965)
michael@0	43	%endif
michael@0	44
michael@0	45	; --------------------------------------------------------------------------
michael@0	46	SECTION SEG_CONST
michael@0	47
michael@0	48	; PRE_MULTIPLY_SCALE_BITS <= 2 (to avoid overflow)
michael@0	49	; CONST_BITS + CONST_SHIFT + PRE_MULTIPLY_SCALE_BITS == 16 (for pmulhw)
michael@0	50
michael@0	51	%define PRE_MULTIPLY_SCALE_BITS 2
michael@0	52	%define CONST_SHIFT (16 - PRE_MULTIPLY_SCALE_BITS - CONST_BITS)
michael@0	53
michael@0	54	alignz 16
michael@0	55	global EXTN(jconst_fdct_ifast_mmx)
michael@0	56
michael@0	57	EXTN(jconst_fdct_ifast_mmx):
michael@0	58
michael@0	59	PW_F0707 times 4 dw F_0_707 << CONST_SHIFT
michael@0	60	PW_F0382 times 4 dw F_0_382 << CONST_SHIFT
michael@0	61	PW_F0541 times 4 dw F_0_541 << CONST_SHIFT
michael@0	62	PW_F1306 times 4 dw F_1_306 << CONST_SHIFT
michael@0	63
michael@0	64	alignz 16
michael@0	65
michael@0	66	; --------------------------------------------------------------------------
michael@0	67	SECTION SEG_TEXT
michael@0	68	BITS 32
michael@0	69	;
michael@0	70	; Perform the forward DCT on one block of samples.
michael@0	71	;
michael@0	72	; GLOBAL(void)
michael@0	73	; jsimd_fdct_ifast_mmx (DCTELEM * data)
michael@0	74	;
michael@0	75
michael@0	76	%define data(b) (b)+8 ; DCTELEM * data
michael@0	77
michael@0	78	%define original_ebp ebp+0
michael@0	79	%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
michael@0	80	%define WK_NUM 2
michael@0	81
michael@0	82	align 16
michael@0	83	global EXTN(jsimd_fdct_ifast_mmx)
michael@0	84
michael@0	85	EXTN(jsimd_fdct_ifast_mmx):
michael@0	86	push ebp
michael@0	87	mov eax,esp ; eax = original ebp
michael@0	88	sub esp, byte 4
michael@0	89	and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
michael@0	90	mov [esp],eax
michael@0	91	mov ebp,esp ; ebp = aligned ebp
michael@0	92	lea esp, [wk(0)]
michael@0	93	pushpic ebx
michael@0	94	; push ecx ; need not be preserved
michael@0	95	; push edx ; need not be preserved
michael@0	96	; push esi ; unused
michael@0	97	; push edi ; unused
michael@0	98
michael@0	99	get_GOT ebx ; get GOT address
michael@0	100
michael@0	101	; ---- Pass 1: process rows.
michael@0	102
michael@0	103	mov edx, POINTER [data(eax)] ; (DCTELEM *)
michael@0	104	mov ecx, DCTSIZE/4
michael@0	105	alignx 16,7
michael@0	106	.rowloop:
michael@0	107
michael@0	108	movq mm0, MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
michael@0	109	movq mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
michael@0	110	movq mm2, MMWORD [MMBLOCK(2,1,edx,SIZEOF_DCTELEM)]
michael@0	111	movq mm3, MMWORD [MMBLOCK(3,1,edx,SIZEOF_DCTELEM)]
michael@0	112
michael@0	113	; mm0=(20 21 22 23), mm2=(24 25 26 27)
michael@0	114	; mm1=(30 31 32 33), mm3=(34 35 36 37)
michael@0	115
michael@0	116	movq mm4,mm0 ; transpose coefficients(phase 1)
michael@0	117	punpcklwd mm0,mm1 ; mm0=(20 30 21 31)
michael@0	118	punpckhwd mm4,mm1 ; mm4=(22 32 23 33)
michael@0	119	movq mm5,mm2 ; transpose coefficients(phase 1)
michael@0	120	punpcklwd mm2,mm3 ; mm2=(24 34 25 35)
michael@0	121	punpckhwd mm5,mm3 ; mm5=(26 36 27 37)
michael@0	122
michael@0	123	movq mm6, MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
michael@0	124	movq mm7, MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
michael@0	125	movq mm1, MMWORD [MMBLOCK(0,1,edx,SIZEOF_DCTELEM)]
michael@0	126	movq mm3, MMWORD [MMBLOCK(1,1,edx,SIZEOF_DCTELEM)]
michael@0	127
michael@0	128	; mm6=(00 01 02 03), mm1=(04 05 06 07)
michael@0	129	; mm7=(10 11 12 13), mm3=(14 15 16 17)
michael@0	130
michael@0	131	movq MMWORD [wk(0)], mm4 ; wk(0)=(22 32 23 33)
michael@0	132	movq MMWORD [wk(1)], mm2 ; wk(1)=(24 34 25 35)
michael@0	133
michael@0	134	movq mm4,mm6 ; transpose coefficients(phase 1)
michael@0	135	punpcklwd mm6,mm7 ; mm6=(00 10 01 11)
michael@0	136	punpckhwd mm4,mm7 ; mm4=(02 12 03 13)
michael@0	137	movq mm2,mm1 ; transpose coefficients(phase 1)
michael@0	138	punpcklwd mm1,mm3 ; mm1=(04 14 05 15)
michael@0	139	punpckhwd mm2,mm3 ; mm2=(06 16 07 17)
michael@0	140
michael@0	141	movq mm7,mm6 ; transpose coefficients(phase 2)
michael@0	142	punpckldq mm6,mm0 ; mm6=(00 10 20 30)=data0
michael@0	143	punpckhdq mm7,mm0 ; mm7=(01 11 21 31)=data1
michael@0	144	movq mm3,mm2 ; transpose coefficients(phase 2)
michael@0	145	punpckldq mm2,mm5 ; mm2=(06 16 26 36)=data6
michael@0	146	punpckhdq mm3,mm5 ; mm3=(07 17 27 37)=data7
michael@0	147
michael@0	148	movq mm0,mm7
michael@0	149	movq mm5,mm6
michael@0	150	psubw mm7,mm2 ; mm7=data1-data6=tmp6
michael@0	151	psubw mm6,mm3 ; mm6=data0-data7=tmp7
michael@0	152	paddw mm0,mm2 ; mm0=data1+data6=tmp1
michael@0	153	paddw mm5,mm3 ; mm5=data0+data7=tmp0
michael@0	154
michael@0	155	movq mm2, MMWORD [wk(0)] ; mm2=(22 32 23 33)
michael@0	156	movq mm3, MMWORD [wk(1)] ; mm3=(24 34 25 35)
michael@0	157	movq MMWORD [wk(0)], mm7 ; wk(0)=tmp6
michael@0	158	movq MMWORD [wk(1)], mm6 ; wk(1)=tmp7
michael@0	159
michael@0	160	movq mm7,mm4 ; transpose coefficients(phase 2)
michael@0	161	punpckldq mm4,mm2 ; mm4=(02 12 22 32)=data2
michael@0	162	punpckhdq mm7,mm2 ; mm7=(03 13 23 33)=data3
michael@0	163	movq mm6,mm1 ; transpose coefficients(phase 2)
michael@0	164	punpckldq mm1,mm3 ; mm1=(04 14 24 34)=data4
michael@0	165	punpckhdq mm6,mm3 ; mm6=(05 15 25 35)=data5
michael@0	166
michael@0	167	movq mm2,mm7
michael@0	168	movq mm3,mm4
michael@0	169	paddw mm7,mm1 ; mm7=data3+data4=tmp3
michael@0	170	paddw mm4,mm6 ; mm4=data2+data5=tmp2
michael@0	171	psubw mm2,mm1 ; mm2=data3-data4=tmp4
michael@0	172	psubw mm3,mm6 ; mm3=data2-data5=tmp5
michael@0	173
michael@0	174	; -- Even part
michael@0	175
michael@0	176	movq mm1,mm5
michael@0	177	movq mm6,mm0
michael@0	178	psubw mm5,mm7 ; mm5=tmp13
michael@0	179	psubw mm0,mm4 ; mm0=tmp12
michael@0	180	paddw mm1,mm7 ; mm1=tmp10
michael@0	181	paddw mm6,mm4 ; mm6=tmp11
michael@0	182
michael@0	183	paddw mm0,mm5
michael@0	184	psllw mm0,PRE_MULTIPLY_SCALE_BITS
michael@0	185	pmulhw mm0,[GOTOFF(ebx,PW_F0707)] ; mm0=z1
michael@0	186
michael@0	187	movq mm7,mm1
michael@0	188	movq mm4,mm5
michael@0	189	psubw mm1,mm6 ; mm1=data4
michael@0	190	psubw mm5,mm0 ; mm5=data6
michael@0	191	paddw mm7,mm6 ; mm7=data0
michael@0	192	paddw mm4,mm0 ; mm4=data2
michael@0	193
michael@0	194	movq MMWORD [MMBLOCK(0,1,edx,SIZEOF_DCTELEM)], mm1
michael@0	195	movq MMWORD [MMBLOCK(2,1,edx,SIZEOF_DCTELEM)], mm5
michael@0	196	movq MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)], mm7
michael@0	197	movq MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)], mm4
michael@0	198
michael@0	199	; -- Odd part
michael@0	200
michael@0	201	movq mm6, MMWORD [wk(0)] ; mm6=tmp6
michael@0	202	movq mm0, MMWORD [wk(1)] ; mm0=tmp7
michael@0	203
michael@0	204	paddw mm2,mm3 ; mm2=tmp10
michael@0	205	paddw mm3,mm6 ; mm3=tmp11
michael@0	206	paddw mm6,mm0 ; mm6=tmp12, mm0=tmp7
michael@0	207
michael@0	208	psllw mm2,PRE_MULTIPLY_SCALE_BITS
michael@0	209	psllw mm6,PRE_MULTIPLY_SCALE_BITS
michael@0	210
michael@0	211	psllw mm3,PRE_MULTIPLY_SCALE_BITS
michael@0	212	pmulhw mm3,[GOTOFF(ebx,PW_F0707)] ; mm3=z3
michael@0	213
michael@0	214	movq mm1,mm2 ; mm1=tmp10
michael@0	215	psubw mm2,mm6
michael@0	216	pmulhw mm2,[GOTOFF(ebx,PW_F0382)] ; mm2=z5
michael@0	217	pmulhw mm1,[GOTOFF(ebx,PW_F0541)] ; mm1=MULTIPLY(tmp10,FIX_0_54119610)
michael@0	218	pmulhw mm6,[GOTOFF(ebx,PW_F1306)] ; mm6=MULTIPLY(tmp12,FIX_1_30656296)
michael@0	219	paddw mm1,mm2 ; mm1=z2
michael@0	220	paddw mm6,mm2 ; mm6=z4
michael@0	221
michael@0	222	movq mm5,mm0
michael@0	223	psubw mm0,mm3 ; mm0=z13
michael@0	224	paddw mm5,mm3 ; mm5=z11
michael@0	225
michael@0	226	movq mm7,mm0
michael@0	227	movq mm4,mm5
michael@0	228	psubw mm0,mm1 ; mm0=data3
michael@0	229	psubw mm5,mm6 ; mm5=data7
michael@0	230	paddw mm7,mm1 ; mm7=data5
michael@0	231	paddw mm4,mm6 ; mm4=data1
michael@0	232
michael@0	233	movq MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)], mm0
michael@0	234	movq MMWORD [MMBLOCK(3,1,edx,SIZEOF_DCTELEM)], mm5
michael@0	235	movq MMWORD [MMBLOCK(1,1,edx,SIZEOF_DCTELEM)], mm7
michael@0	236	movq MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)], mm4
michael@0	237
michael@0	238	add edx, byte 4*DCTSIZE*SIZEOF_DCTELEM
michael@0	239	dec ecx
michael@0	240	jnz near .rowloop
michael@0	241
michael@0	242	; ---- Pass 2: process columns.
michael@0	243
michael@0	244	mov edx, POINTER [data(eax)] ; (DCTELEM *)
michael@0	245	mov ecx, DCTSIZE/4
michael@0	246	alignx 16,7
michael@0	247	.columnloop:
michael@0	248
michael@0	249	movq mm0, MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
michael@0	250	movq mm1, MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
michael@0	251	movq mm2, MMWORD [MMBLOCK(6,0,edx,SIZEOF_DCTELEM)]
michael@0	252	movq mm3, MMWORD [MMBLOCK(7,0,edx,SIZEOF_DCTELEM)]
michael@0	253
michael@0	254	; mm0=(02 12 22 32), mm2=(42 52 62 72)
michael@0	255	; mm1=(03 13 23 33), mm3=(43 53 63 73)
michael@0	256
michael@0	257	movq mm4,mm0 ; transpose coefficients(phase 1)
michael@0	258	punpcklwd mm0,mm1 ; mm0=(02 03 12 13)
michael@0	259	punpckhwd mm4,mm1 ; mm4=(22 23 32 33)
michael@0	260	movq mm5,mm2 ; transpose coefficients(phase 1)
michael@0	261	punpcklwd mm2,mm3 ; mm2=(42 43 52 53)
michael@0	262	punpckhwd mm5,mm3 ; mm5=(62 63 72 73)
michael@0	263
michael@0	264	movq mm6, MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
michael@0	265	movq mm7, MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
michael@0	266	movq mm1, MMWORD [MMBLOCK(4,0,edx,SIZEOF_DCTELEM)]
michael@0	267	movq mm3, MMWORD [MMBLOCK(5,0,edx,SIZEOF_DCTELEM)]
michael@0	268
michael@0	269	; mm6=(00 10 20 30), mm1=(40 50 60 70)
michael@0	270	; mm7=(01 11 21 31), mm3=(41 51 61 71)
michael@0	271
michael@0	272	movq MMWORD [wk(0)], mm4 ; wk(0)=(22 23 32 33)
michael@0	273	movq MMWORD [wk(1)], mm2 ; wk(1)=(42 43 52 53)
michael@0	274
michael@0	275	movq mm4,mm6 ; transpose coefficients(phase 1)
michael@0	276	punpcklwd mm6,mm7 ; mm6=(00 01 10 11)
michael@0	277	punpckhwd mm4,mm7 ; mm4=(20 21 30 31)
michael@0	278	movq mm2,mm1 ; transpose coefficients(phase 1)
michael@0	279	punpcklwd mm1,mm3 ; mm1=(40 41 50 51)
michael@0	280	punpckhwd mm2,mm3 ; mm2=(60 61 70 71)
michael@0	281
michael@0	282	movq mm7,mm6 ; transpose coefficients(phase 2)
michael@0	283	punpckldq mm6,mm0 ; mm6=(00 01 02 03)=data0
michael@0	284	punpckhdq mm7,mm0 ; mm7=(10 11 12 13)=data1
michael@0	285	movq mm3,mm2 ; transpose coefficients(phase 2)
michael@0	286	punpckldq mm2,mm5 ; mm2=(60 61 62 63)=data6
michael@0	287	punpckhdq mm3,mm5 ; mm3=(70 71 72 73)=data7
michael@0	288
michael@0	289	movq mm0,mm7
michael@0	290	movq mm5,mm6
michael@0	291	psubw mm7,mm2 ; mm7=data1-data6=tmp6
michael@0	292	psubw mm6,mm3 ; mm6=data0-data7=tmp7
michael@0	293	paddw mm0,mm2 ; mm0=data1+data6=tmp1
michael@0	294	paddw mm5,mm3 ; mm5=data0+data7=tmp0
michael@0	295
michael@0	296	movq mm2, MMWORD [wk(0)] ; mm2=(22 23 32 33)
michael@0	297	movq mm3, MMWORD [wk(1)] ; mm3=(42 43 52 53)
michael@0	298	movq MMWORD [wk(0)], mm7 ; wk(0)=tmp6
michael@0	299	movq MMWORD [wk(1)], mm6 ; wk(1)=tmp7
michael@0	300
michael@0	301	movq mm7,mm4 ; transpose coefficients(phase 2)
michael@0	302	punpckldq mm4,mm2 ; mm4=(20 21 22 23)=data2
michael@0	303	punpckhdq mm7,mm2 ; mm7=(30 31 32 33)=data3
michael@0	304	movq mm6,mm1 ; transpose coefficients(phase 2)
michael@0	305	punpckldq mm1,mm3 ; mm1=(40 41 42 43)=data4
michael@0	306	punpckhdq mm6,mm3 ; mm6=(50 51 52 53)=data5
michael@0	307
michael@0	308	movq mm2,mm7
michael@0	309	movq mm3,mm4
michael@0	310	paddw mm7,mm1 ; mm7=data3+data4=tmp3
michael@0	311	paddw mm4,mm6 ; mm4=data2+data5=tmp2
michael@0	312	psubw mm2,mm1 ; mm2=data3-data4=tmp4
michael@0	313	psubw mm3,mm6 ; mm3=data2-data5=tmp5
michael@0	314
michael@0	315	; -- Even part
michael@0	316
michael@0	317	movq mm1,mm5
michael@0	318	movq mm6,mm0
michael@0	319	psubw mm5,mm7 ; mm5=tmp13
michael@0	320	psubw mm0,mm4 ; mm0=tmp12
michael@0	321	paddw mm1,mm7 ; mm1=tmp10
michael@0	322	paddw mm6,mm4 ; mm6=tmp11
michael@0	323
michael@0	324	paddw mm0,mm5
michael@0	325	psllw mm0,PRE_MULTIPLY_SCALE_BITS
michael@0	326	pmulhw mm0,[GOTOFF(ebx,PW_F0707)] ; mm0=z1
michael@0	327
michael@0	328	movq mm7,mm1
michael@0	329	movq mm4,mm5
michael@0	330	psubw mm1,mm6 ; mm1=data4
michael@0	331	psubw mm5,mm0 ; mm5=data6
michael@0	332	paddw mm7,mm6 ; mm7=data0
michael@0	333	paddw mm4,mm0 ; mm4=data2
michael@0	334
michael@0	335	movq MMWORD [MMBLOCK(4,0,edx,SIZEOF_DCTELEM)], mm1
michael@0	336	movq MMWORD [MMBLOCK(6,0,edx,SIZEOF_DCTELEM)], mm5
michael@0	337	movq MMWORD [MMBLOCK(0,0,edx,SIZEOF_DCTELEM)], mm7
michael@0	338	movq MMWORD [MMBLOCK(2,0,edx,SIZEOF_DCTELEM)], mm4
michael@0	339
michael@0	340	; -- Odd part
michael@0	341
michael@0	342	movq mm6, MMWORD [wk(0)] ; mm6=tmp6
michael@0	343	movq mm0, MMWORD [wk(1)] ; mm0=tmp7
michael@0	344
michael@0	345	paddw mm2,mm3 ; mm2=tmp10
michael@0	346	paddw mm3,mm6 ; mm3=tmp11
michael@0	347	paddw mm6,mm0 ; mm6=tmp12, mm0=tmp7
michael@0	348
michael@0	349	psllw mm2,PRE_MULTIPLY_SCALE_BITS
michael@0	350	psllw mm6,PRE_MULTIPLY_SCALE_BITS
michael@0	351
michael@0	352	psllw mm3,PRE_MULTIPLY_SCALE_BITS
michael@0	353	pmulhw mm3,[GOTOFF(ebx,PW_F0707)] ; mm3=z3
michael@0	354
michael@0	355	movq mm1,mm2 ; mm1=tmp10
michael@0	356	psubw mm2,mm6
michael@0	357	pmulhw mm2,[GOTOFF(ebx,PW_F0382)] ; mm2=z5
michael@0	358	pmulhw mm1,[GOTOFF(ebx,PW_F0541)] ; mm1=MULTIPLY(tmp10,FIX_0_54119610)
michael@0	359	pmulhw mm6,[GOTOFF(ebx,PW_F1306)] ; mm6=MULTIPLY(tmp12,FIX_1_30656296)
michael@0	360	paddw mm1,mm2 ; mm1=z2
michael@0	361	paddw mm6,mm2 ; mm6=z4
michael@0	362
michael@0	363	movq mm5,mm0
michael@0	364	psubw mm0,mm3 ; mm0=z13
michael@0	365	paddw mm5,mm3 ; mm5=z11
michael@0	366
michael@0	367	movq mm7,mm0
michael@0	368	movq mm4,mm5
michael@0	369	psubw mm0,mm1 ; mm0=data3
michael@0	370	psubw mm5,mm6 ; mm5=data7
michael@0	371	paddw mm7,mm1 ; mm7=data5
michael@0	372	paddw mm4,mm6 ; mm4=data1
michael@0	373
michael@0	374	movq MMWORD [MMBLOCK(3,0,edx,SIZEOF_DCTELEM)], mm0
michael@0	375	movq MMWORD [MMBLOCK(7,0,edx,SIZEOF_DCTELEM)], mm5
michael@0	376	movq MMWORD [MMBLOCK(5,0,edx,SIZEOF_DCTELEM)], mm7
michael@0	377	movq MMWORD [MMBLOCK(1,0,edx,SIZEOF_DCTELEM)], mm4
michael@0	378
michael@0	379	add edx, byte 4*SIZEOF_DCTELEM
michael@0	380	dec ecx
michael@0	381	jnz near .columnloop
michael@0	382
michael@0	383	emms ; empty MMX state
michael@0	384
michael@0	385	; pop edi ; unused
michael@0	386	; pop esi ; unused
michael@0	387	; pop edx ; need not be preserved
michael@0	388	; pop ecx ; need not be preserved
michael@0	389	poppic ebx
michael@0	390	mov esp,ebp ; esp <- aligned ebp
michael@0	391	pop esp ; esp <- original ebp
michael@0	392	pop ebp
michael@0	393	ret
michael@0	394
michael@0	395	; For some reason, the OS X linker does not honor the request to align the
michael@0	396	; segment unless we do this.
michael@0	397	align 16